lisp/org-compat.el

   1 ;;; org-compat.el --- Compatibility Code for Older Emacsen -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2004-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains code needed for compatibility with older
  28 ;; versions of GNU Emacs.
  29
  30 ;;; Code:
  31
  32 (require 'cl-lib)
  33 (require 'org-macs)
  34
  35 (declare-function org-at-table.el-p "org" (&optional table-type))
  36 (declare-function org-element-at-point "org-element" ())
  37 (declare-function org-element-type "org-element" (element))
  38 (declare-function org-end-of-subtree "org" (&optional invisible-ok to-heading))
  39 (declare-function org-link-set-parameters "org" (type &rest rest))
  40 (declare-function org-table-end (&optional table-type))
  41 (declare-function outline-next-heading "outline" ())
  42 (declare-function table--at-cell-p "table" (position &optional object at-column))
  43
  44 (defvar org-table-any-border-regexp)
  45 (defvar org-table-dataline-regexp)
  46 (defvar org-table-tab-recognizes-table.el)
  47 (defvar org-table1-hline-regexp)
  48
  49 ;;; Emacs < 25.1 compatibility
  50
  51 (when (< emacs-major-version 25)
  52   (defalias 'outline-hide-entry 'hide-entry)
  53   (defalias 'outline-hide-sublevels 'hide-sublevels)
  54   (defalias 'outline-hide-subtree 'hide-subtree)
  55   (defalias 'outline-show-all 'show-all)
  56   (defalias 'outline-show-branches 'show-branches)
  57   (defalias 'outline-show-children 'show-children)
  58   (defalias 'outline-show-entry 'show-entry)
  59   (defalias 'outline-show-subtree 'show-subtree)
  60   (defalias 'xref-find-definitions 'find-tag)
  61   (defalias 'format-message 'format)
  62   (defalias 'gui-get-selection 'x-get-selection))
  63
  64 (unless (fboundp 'directory-name-p)
  65   (defun directory-name-p (name)
  66     "Return non-nil if NAME ends with a directory separator character."
  67     (let ((len (length name))
  68           (lastc ?.))
  69       (if (> len 0)
  70           (setq lastc (aref name (1- len))))
  71       (or (= lastc ?/)
  72           (and (memq system-type '(windows-nt ms-dos))
  73                (= lastc ?\\))))))
  74
  75 (unless (fboundp 'directory-files-recursively)
  76   (defun directory-files-recursively (dir regexp &optional include-directories)
  77     "Return list of all files under DIR that have file names matching REGEXP.
  78 This function works recursively.  Files are returned in \"depth first\"
  79 order, and files from each directory are sorted in alphabetical order.
  80 Each file name appears in the returned list in its absolute form.
  81 Optional argument INCLUDE-DIRECTORIES non-nil means also include in the
  82 output directories whose names match REGEXP."
  83     (let ((result nil)
  84           (files nil)
  85           ;; When DIR is "/", remote file names like "/method:" could
  86           ;; also be offered.  We shall suppress them.
  87           (tramp-mode (and tramp-mode (file-remote-p (expand-file-name dir)))))
  88       (dolist (file (sort (file-name-all-completions "" dir)
  89                           'string<))
  90         (unless (member file '("./" "../"))
  91           (if (directory-name-p file)
  92               (let* ((leaf (substring file 0 (1- (length file))))
  93                      (full-file (expand-file-name leaf dir)))
  94                 ;; Don't follow symlinks to other directories.
  95                 (unless (file-symlink-p full-file)
  96                   (setq result
  97                         (nconc result (directory-files-recursively
  98                                        full-file regexp include-directories))))
  99                 (when (and include-directories
 100                            (string-match regexp leaf))
 101                   (setq result (nconc result (list full-file)))))
 102             (when (string-match regexp file)
 103               (push (expand-file-name file dir) files)))))
 104       (nconc result (nreverse files)))))
 105
 106 \f
 107 ;;; Obsolete aliases (remove them once the next major release is released).
 108
 109 ;;;; XEmacs compatibility, now removed.
 110 (define-obsolete-function-alias 'org-activate-mark 'activate-mark)
 111 (define-obsolete-function-alias 'org-add-hook 'add-hook "Org 9.0")
 112 (define-obsolete-function-alias 'org-bound-and-true-p 'bound-and-true-p "Org 9.0")
 113 (define-obsolete-function-alias 'org-decompose-region 'decompose-region "Org 9.0")
 114 (define-obsolete-function-alias 'org-defvaralias 'defvaralias "Org 9.0")
 115 (define-obsolete-function-alias 'org-detach-overlay 'delete-overlay "Org 9.0")
 116 (define-obsolete-function-alias 'org-file-equal-p 'file-equal-p "Org 9.0")
 117 (define-obsolete-function-alias 'org-float-time 'float-time "Org 9.0")
 118 (define-obsolete-function-alias 'org-indent-line-to 'indent-line-to "Org 9.0")
 119 (define-obsolete-function-alias 'org-indent-to-column 'indent-to-column "Org 9.0")
 120 (define-obsolete-function-alias 'org-looking-at-p 'looking-at-p "Org 9.0")
 121 (define-obsolete-function-alias 'org-looking-back 'looking-back "Org 9.0")
 122 (define-obsolete-function-alias 'org-match-string-no-properties 'match-string-no-properties "Org 9.0")
 123 (define-obsolete-function-alias 'org-propertize 'propertize "Org 9.0")
 124 (define-obsolete-function-alias 'org-select-frame-set-input-focus 'select-frame-set-input-focus "Org 9.0")
 125
 126 (defmacro org-re (s)
 127   "Replace posix classes in regular expression S."
 128   (declare (debug (form))
 129            (obsolete "you can safely remove it." "Org 9.0"))
 130   s)
 131
 132 ;;;; Functions from cl-lib that Org used to have its own implementation of.
 133 (define-obsolete-function-alias 'org-count 'cl-count "Org 9.0")
 134 (define-obsolete-function-alias 'org-every 'cl-every "Org 9.0")
 135 (define-obsolete-function-alias 'org-find-if 'cl-find-if "Org 9.0")
 136 (define-obsolete-function-alias 'org-reduce 'cl-reduce "Org 9.0")
 137 (define-obsolete-function-alias 'org-remove-if 'cl-remove-if "Org 9.0")
 138 (define-obsolete-function-alias 'org-remove-if-not 'cl-remove-if-not "Org 9.0")
 139 (define-obsolete-function-alias 'org-some 'cl-some "Org 9.0")
 140 (define-obsolete-function-alias 'org-floor* 'cl-floor "Org 9.0")
 141
 142 (defun org-sublist (list start end)
 143   "Return a section of LIST, from START to END.
 144 Counting starts at 1."
 145   (cl-subseq list (1- start) end))
 146 (make-obsolete 'org-sublist
 147                "use cl-subseq (note the 0-based counting)."
 148                "Org 9.0")
 149
 150
 151 ;;;; Functions available since Emacs 24.3
 152 (define-obsolete-function-alias 'org-buffer-narrowed-p 'buffer-narrowed-p "Org 9.0")
 153 (define-obsolete-function-alias 'org-called-interactively-p 'called-interactively-p "Org 9.0")
 154 (define-obsolete-function-alias 'org-char-to-string 'char-to-string "Org 9.0")
 155 (define-obsolete-function-alias 'org-delete-directory 'delete-directory "Org 9.0")
 156 (define-obsolete-function-alias 'org-format-seconds 'format-seconds "Org 9.0")
 157 (define-obsolete-function-alias 'org-link-escape-browser 'url-encode-url "Org 9.0")
 158 (define-obsolete-function-alias 'org-no-warnings 'with-no-warnings "Org 9.0")
 159 (define-obsolete-function-alias 'org-number-sequence 'number-sequence "Org 9.0")
 160 (define-obsolete-function-alias 'org-pop-to-buffer-same-window 'pop-to-buffer-same-window "Org 9.0")
 161 (define-obsolete-function-alias 'org-string-match-p 'string-match-p "Org 9.0")
 162
 163 ;;;; Functions and variables from previous releases now obsolete.
 164 (define-obsolete-function-alias 'org-element-remove-indentation
 165   'org-remove-indentation "Org 9.0")
 166 (define-obsolete-variable-alias 'org-latex-create-formula-image-program
 167   'org-preview-latex-default-process "Org 9.0")
 168 (define-obsolete-variable-alias 'org-latex-preview-ltxpng-directory
 169   'org-preview-latex-image-directory "Org 9.0")
 170 (define-obsolete-function-alias 'org-table-p 'org-at-table-p "Org 9.0")
 171 (define-obsolete-function-alias 'org-on-heading-p 'org-at-heading-p "Org 9.0")
 172 (define-obsolete-function-alias 'org-at-regexp-p 'org-in-regexp "Org 8.3")
 173 (define-obsolete-function-alias 'org-image-file-name-regexp
 174   'image-file-name-regexp "Org 9.0")
 175 (define-obsolete-function-alias 'org-completing-read-no-i
 176   'completing-read "Org 9.0")
 177 (define-obsolete-function-alias 'org-icompleting-read
 178   'completing-read "Org 9.0")
 179 (define-obsolete-function-alias 'org-iread-file-name 'read-file-name "Org 9.0")
 180 (define-obsolete-function-alias 'org-days-to-time
 181   'org-time-stamp-to-now "Org 8.2")
 182 (define-obsolete-variable-alias 'org-agenda-ignore-drawer-properties
 183   'org-agenda-ignore-properties "Org 9.0")
 184 (define-obsolete-function-alias 'org-preview-latex-fragment
 185   'org-toggle-latex-fragment "Org 8.3")
 186 (define-obsolete-function-alias 'org-export-get-genealogy
 187   'org-element-lineage "Org 9.0")
 188 (define-obsolete-variable-alias 'org-latex-with-hyperref
 189   'org-latex-hyperref-template "Org 9.0")
 190 (define-obsolete-variable-alias 'hfy-optimisations 'hfy-optimizations "Org 9.0")
 191 (define-obsolete-variable-alias 'org-export-htmlized-org-css-url
 192   'org-org-htmlized-css-url "Org 8.2")
 193 (define-obsolete-function-alias 'org-list-parse-list 'org-list-to-lisp "Org 9.0")
 194 (define-obsolete-function-alias 'org-agenda-todayp
 195   'org-agenda-today-p "Org 9.0")
 196 (define-obsolete-function-alias 'org-babel-examplize-region
 197   'org-babel-examplify-region "Org 9.0")
 198 (define-obsolete-variable-alias 'org-babel-capitalize-example-region-markers
 199   'org-babel-uppercase-example-markers "Org 9.1")
 200
 201 (define-obsolete-function-alias 'org-babel-trim 'org-trim "Org 9.0")
 202 (define-obsolete-variable-alias 'org-html-style 'org-html-head "24.4")
 203 (define-obsolete-function-alias 'org-insert-columns-dblock
 204   'org-columns-insert-dblock "Org 9.0")
 205 (define-obsolete-variable-alias 'org-export-babel-evaluate
 206   'org-export-use-babel "Org 9.1")
 207
 208 (defun org-in-fixed-width-region-p ()
 209   "Non-nil if point in a fixed-width region."
 210   (save-match-data
 211     (eq 'fixed-width (org-element-type (org-element-at-point)))))
 212 (make-obsolete 'org-in-fixed-width-region-p
 213                "use `org-element' library"
 214                "Org 9.0")
 215
 216 (defun org-compatible-face (inherits specs)
 217   "Make a compatible face specification.
 218 If INHERITS is an existing face and if the Emacs version supports
 219 it, just inherit the face.  If INHERITS is not given and SPECS
 220 is, use SPECS to define the face."
 221   (declare (indent 1))
 222   (if (facep inherits)
 223       (list (list t :inherit inherits))
 224     specs))
 225 (make-obsolete 'org-compatible-face "you can remove it." "Org 9.0")
 226
 227 (defun org-add-link-type (type &optional follow export)
 228   "Add a new TYPE link.
 229 FOLLOW and EXPORT are two functions.
 230
 231 FOLLOW should take the link path as the single argument and do whatever
 232 is necessary to follow the link, for example find a file or display
 233 a mail message.
 234
 235 EXPORT should format the link path for export to one of the export formats.
 236 It should be a function accepting three arguments:
 237
 238   path    the path of the link, the text after the prefix (like \"http:\")
 239   desc    the description of the link, if any
 240   format  the export format, a symbol like `html' or `latex' or `ascii'.
 241
 242 The function may use the FORMAT information to return different values
 243 depending on the format.  The return value will be put literally into
 244 the exported file.  If the return value is nil, this means Org should
 245 do what it normally does with links which do not have EXPORT defined.
 246
 247 Org mode has a built-in default for exporting links.  If you are happy with
 248 this default, there is no need to define an export function for the link
 249 type.  For a simple example of an export function, see `org-bbdb.el'.
 250
 251 If TYPE already exists, update it with the arguments.
 252 See `org-link-parameters' for documentation on the other parameters."
 253   (org-link-set-parameters type :follow follow :export export)
 254   (message "Created %s link." type))
 255
 256 (make-obsolete 'org-add-link-type "use `org-link-set-parameters' instead." "Org 9.0")
 257
 258 (defun org-table-recognize-table.el ()
 259   "If there is a table.el table nearby, recognize it and move into it."
 260   (when (and org-table-tab-recognizes-table.el (org-at-table.el-p))
 261     (beginning-of-line)
 262     (unless (or (looking-at org-table-dataline-regexp)
 263                 (not (looking-at org-table1-hline-regexp)))
 264       (forward-line)
 265       (when (looking-at org-table-any-border-regexp)
 266         (forward-line -2)))
 267     (if (re-search-forward "|" (org-table-end t) t)
 268         (progn
 269           (require 'table)
 270           (if (table--at-cell-p (point)) t
 271             (message "recognizing table.el table...")
 272             (table-recognize-table)
 273             (message "recognizing table.el table...done")))
 274       (error "This should not happen"))))
 275
 276 ;; Not used by Org core since commit 6d1e3082, Feb 2010.
 277 (make-obsolete 'org-table-recognize-table.el
 278                "please notify the org mailing list if you use this function."
 279                "Org 9.0")
 280
 281 (defun org-remove-angle-brackets (s)
 282   (org-unbracket-string "<" ">" s))
 283 (make-obsolete 'org-remove-angle-brackets 'org-unbracket-string "Org 9.0")
 284
 285 (defun org-remove-double-quotes (s)
 286   (org-unbracket-string "\"" "\"" s))
 287 (make-obsolete 'org-remove-double-quotes 'org-unbracket-string "Org 9.0")
 288
 289 (defcustom org-publish-sitemap-file-entry-format "%t"
 290   "Format string for site-map file entry.
 291 You could use brackets to delimit on what part the link will be.
 292
 293 %t is the title.
 294 %a is the author.
 295 %d is the date formatted using `org-publish-sitemap-date-format'."
 296   :group 'org-export-publish
 297   :type 'string)
 298 (make-obsolete-variable
 299  'org-publish-sitemap-file-entry-format
 300  "set `:sitemap-format-entry' in `org-publish-project-alist' instead."
 301  "Org 9.1")
 302
 303 (defvar org-agenda-skip-regexp)
 304 (defun org-agenda-skip-entry-when-regexp-matches ()
 305   "Check if the current entry contains match for `org-agenda-skip-regexp'.
 306 If yes, it returns the end position of this entry, causing agenda commands
 307 to skip the entry but continuing the search in the subtree.  This is a
 308 function that can be put into `org-agenda-skip-function' for the duration
 309 of a command."
 310   (declare (obsolete "use `org-agenda-skip-if' instead." "Org 9.1"))
 311   (let ((end (save-excursion (org-end-of-subtree t)))
 312         skip)
 313     (save-excursion
 314       (setq skip (re-search-forward org-agenda-skip-regexp end t)))
 315     (and skip end)))
 316
 317 (defun org-agenda-skip-subtree-when-regexp-matches ()
 318   "Check if the current subtree contains match for `org-agenda-skip-regexp'.
 319 If yes, it returns the end position of this tree, causing agenda commands
 320 to skip this subtree.  This is a function that can be put into
 321 `org-agenda-skip-function' for the duration of a command."
 322   (declare (obsolete "use `org-agenda-skip-if' instead." "Org 9.1"))
 323   (let ((end (save-excursion (org-end-of-subtree t)))
 324         skip)
 325     (save-excursion
 326       (setq skip (re-search-forward org-agenda-skip-regexp end t)))
 327     (and skip end)))
 328
 329 (defun org-agenda-skip-entry-when-regexp-matches-in-subtree ()
 330   "Check if the current subtree contains match for `org-agenda-skip-regexp'.
 331 If yes, it returns the end position of the current entry (NOT the tree),
 332 causing agenda commands to skip the entry but continuing the search in
 333 the subtree.  This is a function that can be put into
 334 `org-agenda-skip-function' for the duration of a command.  An important
 335 use of this function is for the stuck project list."
 336   (declare (obsolete "use `org-agenda-skip-if' instead." "Org 9.1"))
 337   (let ((end (save-excursion (org-end-of-subtree t)))
 338         (entry-end (save-excursion (outline-next-heading) (1- (point))))
 339         skip)
 340     (save-excursion
 341       (setq skip (re-search-forward org-agenda-skip-regexp end t)))
 342     (and skip entry-end)))
 343
 344 (define-obsolete-function-alias 'org-minutes-to-clocksum-string
 345   'org-duration-from-minutes "Org 9.1")
 346
 347 (define-obsolete-function-alias 'org-hh:mm-string-to-minutes
 348   'org-duration-to-minutes "Org 9.1")
 349
 350 (define-obsolete-function-alias 'org-duration-string-to-minutes
 351   'org-duration-to-minutes "Org 9.1")
 352
 353 (make-obsolete-variable 'org-time-clocksum-format
 354   "set `org-duration-format' instead." "Org 9.1")
 355
 356 (make-obsolete-variable 'org-time-clocksum-use-fractional
 357   "set `org-duration-format' instead." "Org 9.1")
 358
 359 (make-obsolete-variable 'org-time-clocksum-fractional-format
 360   "set `org-duration-format' instead." "Org 9.1")
 361
 362 (make-obsolete-variable 'org-time-clocksum-use-effort-durations
 363   "set `org-duration-units' instead." "Org 9.1")
 364
 365
 366 ;;;; Obsolete link types
 367
 368 (eval-after-load 'org
 369   '(progn
 370      (org-link-set-parameters "file+emacs") ;since Org 9.0
 371      (org-link-set-parameters "file+sys"))) ;since Org 9.0
 372
 373
 374 \f
 375 ;;; Miscellaneous functions
 376
 377 (defun org-version-check (version feature level)
 378   (let* ((v1 (mapcar 'string-to-number (split-string version "[.]")))
 379          (v2 (mapcar 'string-to-number (split-string emacs-version "[.]")))
 380          (rmaj (or (nth 0 v1) 99))
 381          (rmin (or (nth 1 v1) 99))
 382          (rbld (or (nth 2 v1) 99))
 383          (maj (or (nth 0 v2) 0))
 384          (min (or (nth 1 v2) 0))
 385          (bld (or (nth 2 v2) 0)))
 386     (if (or (< maj rmaj)
 387             (and (= maj rmaj)
 388                  (< min rmin))
 389             (and (= maj rmaj)
 390                  (= min rmin)
 391                  (< bld rbld)))
 392         (if (eq level :predicate)
 393             ;; just return if we have the version
 394             nil
 395           (let ((msg (format "Emacs %s or greater is recommended for %s"
 396                              version feature)))
 397             (display-warning 'org msg level)
 398             t))
 399       t)))
 400
 401 (defun org-get-x-clipboard (value)
 402   "Get the value of the X or Windows clipboard."
 403   (cond ((and (eq window-system 'x)
 404               (fboundp 'gui-get-selection)) ;Silence byte-compiler.
 405          (org-no-properties
 406           (ignore-errors
 407             (or (gui-get-selection value 'UTF8_STRING)
 408                 (gui-get-selection value 'COMPOUND_TEXT)
 409                 (gui-get-selection value 'STRING)
 410                 (gui-get-selection value 'TEXT)))))
 411         ((and (eq window-system 'w32) (fboundp 'w32-get-clipboard-data))
 412          (w32-get-clipboard-data))))
 413
 414 (defun org-add-props (string plist &rest props)
 415   "Add text properties to entire string, from beginning to end.
 416 PLIST may be a list of properties, PROPS are individual properties and values
 417 that will be added to PLIST.  Returns the string that was modified."
 418   (add-text-properties
 419    0 (length string) (if props (append plist props) plist) string)
 420   string)
 421 (put 'org-add-props 'lisp-indent-function 2)
 422
 423 (defun org-fit-window-to-buffer (&optional window max-height min-height
 424                                            shrink-only)
 425   "Fit WINDOW to the buffer, but only if it is not a side-by-side window.
 426 WINDOW defaults to the selected window.  MAX-HEIGHT and MIN-HEIGHT are
 427 passed through to `fit-window-to-buffer'.  If SHRINK-ONLY is set, call
 428 `shrink-window-if-larger-than-buffer' instead, the height limit is
 429 ignored in this case."
 430   (cond ((if (fboundp 'window-full-width-p)
 431              (not (window-full-width-p window))
 432            ;; do nothing if another window would suffer
 433            (> (frame-width) (window-width window))))
 434         ((and (fboundp 'fit-window-to-buffer) (not shrink-only))
 435          (fit-window-to-buffer window max-height min-height))
 436         ((fboundp 'shrink-window-if-larger-than-buffer)
 437          (shrink-window-if-larger-than-buffer window)))
 438   (or window (selected-window)))
 439
 440 ;; `set-transient-map' is only in Emacs >= 24.4
 441 (defalias 'org-set-transient-map
 442   (if (fboundp 'set-transient-map)
 443       'set-transient-map
 444     'set-temporary-overlay-map))
 445
 446 ;;; Region compatibility
 447
 448 (defvar org-ignore-region nil
 449   "Non-nil means temporarily disable the active region.")
 450
 451 (defun org-region-active-p ()
 452   "Non-nil when the region active.
 453 Unlike to `use-region-p', this function also checks
 454 `org-ignore-region'."
 455   (and (not org-ignore-region) (use-region-p)))
 456
 457 (defun org-cursor-to-region-beginning ()
 458   (when (and (org-region-active-p)
 459              (> (point) (region-beginning)))
 460     (exchange-point-and-mark)))
 461
 462 ;;; Invisibility compatibility
 463
 464 (defun org-remove-from-invisibility-spec (arg)
 465   "Remove elements from `buffer-invisibility-spec'."
 466   (if (fboundp 'remove-from-invisibility-spec)
 467       (remove-from-invisibility-spec arg)
 468     (if (consp buffer-invisibility-spec)
 469         (setq buffer-invisibility-spec
 470               (delete arg buffer-invisibility-spec)))))
 471
 472 (defun org-in-invisibility-spec-p (arg)
 473   "Is ARG a member of `buffer-invisibility-spec'?"
 474   (if (consp buffer-invisibility-spec)
 475       (member arg buffer-invisibility-spec)))
 476
 477 (defun org-move-to-column (column &optional force _buffer)
 478   "Move to column COLUMN.
 479 Pass COLUMN and FORCE to `move-to-column'."
 480   (let ((buffer-invisibility-spec
 481          (if (listp buffer-invisibility-spec)
 482              (remove '(org-filtered) buffer-invisibility-spec)
 483            buffer-invisibility-spec)))
 484     (move-to-column column force)))
 485
 486 (defmacro org-find-library-dir (library)
 487   `(file-name-directory (or (locate-library ,library) "")))
 488
 489 (defun org-count-lines (s)
 490   "How many lines in string S?"
 491   (let ((start 0) (n 1))
 492     (while (string-match "\n" s start)
 493       (setq start (match-end 0) n (1+ n)))
 494     (if (and (> (length s) 0) (= (aref s (1- (length s))) ?\n))
 495         (setq n (1- n)))
 496     n))
 497
 498 (defun org-kill-new (string &rest args)
 499   (remove-text-properties 0 (length string) '(line-prefix t wrap-prefix t)
 500                           string)
 501   (apply 'kill-new string args))
 502
 503 ;; `font-lock-ensure' is only available from 24.4.50 on
 504 (defalias 'org-font-lock-ensure
 505   (if (fboundp 'font-lock-ensure)
 506       #'font-lock-ensure
 507     (lambda (&optional _beg _end)
 508       (with-no-warnings (font-lock-fontify-buffer)))))
 509
 510 ;; `file-local-name' was added in Emacs 26.1.
 511 (defalias 'org-babel-local-file-name
 512   (if (fboundp 'file-local-name)
 513       'file-local-name
 514     (lambda (file)
 515       "Return the local name component of FILE."
 516       (or (file-remote-p file 'localname) file))))
 517
 518 (defmacro org-no-popups (&rest body)
 519   "Suppress popup windows.
 520 Let-bind some variables to nil around BODY to achieve the desired
 521 effect, which variables to use depends on the Emacs version."
 522   (if (org-version-check "24.2.50" "" :predicate)
 523       `(let (pop-up-frames display-buffer-alist)
 524          ,@body)
 525     `(let (pop-up-frames special-display-buffer-names special-display-regexps special-display-function)
 526        ,@body)))
 527
 528 ;;;###autoload
 529 (defmacro org-check-version ()
 530   "Try very hard to provide sensible version strings."
 531   (let* ((org-dir        (org-find-library-dir "org"))
 532          (org-version.el (concat org-dir "org-version.el"))
 533          (org-fixup.el   (concat org-dir "../mk/org-fixup.el")))
 534     (if (require 'org-version org-version.el 'noerror)
 535         '(progn
 536            (autoload 'org-release     "org-version.el")
 537            (autoload 'org-git-version "org-version.el"))
 538       (if (require 'org-fixup org-fixup.el 'noerror)
 539           '(org-fixup)
 540         ;; provide fallback definitions and complain
 541         (warn "Could not define org version correctly.  Check installation!")
 542         '(progn
 543            (defun org-release () "N/A")
 544            (defun org-git-version () "N/A !!check installation!!"))))))
 545
 546 (defmacro org-with-silent-modifications (&rest body)
 547   (if (fboundp 'with-silent-modifications)
 548       `(with-silent-modifications ,@body)
 549     `(org-unmodified ,@body)))
 550 (def-edebug-spec org-with-silent-modifications (body))
 551
 552 ;; Functions for Emacs < 24.4 compatibility
 553 (defun org-define-error (name message)
 554   "Define NAME as a new error signal.
 555 MESSAGE is a string that will be output to the echo area if such
 556 an error is signaled without being caught by a `condition-case'.
 557 Implements `define-error' for older emacsen."
 558   (if (fboundp 'define-error) (define-error name message)
 559     (put name 'error-conditions
 560          (copy-sequence (cons name (get 'error 'error-conditions))))))
 561
 562 (unless (fboundp 'string-suffix-p)
 563   ;; From Emacs subr.el.
 564   (defun string-suffix-p (suffix string  &optional ignore-case)
 565     "Return non-nil if SUFFIX is a suffix of STRING.
 566 If IGNORE-CASE is non-nil, the comparison is done without paying
 567 attention to case differences."
 568     (let ((start-pos (- (length string) (length suffix))))
 569       (and (>= start-pos 0)
 570            (eq t (compare-strings suffix nil nil
 571                                   string start-pos nil ignore-case))))))
 572
 573 (provide 'org-compat)
 574
 575 ;;; org-compat.el ends here