lisp/ox-md.el

   1 ;;; ox-md.el --- Markdown Back-End for Org Export Engine -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2012-2019 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp, markdown
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library implements a Markdown back-end (vanilla flavor) for
  26 ;; Org exporter, based on `html' back-end.  See Org manual for more
  27 ;; information.
  28
  29 ;;; Code:
  30
  31 (require 'cl-lib)
  32 (require 'ox-html)
  33 (require 'ox-publish)
  34
  35 \f
  36 ;;; User-Configurable Variables
  37
  38 (defgroup org-export-md nil
  39   "Options specific to Markdown export back-end."
  40   :tag "Org Markdown"
  41   :group 'org-export
  42   :version "24.4"
  43   :package-version '(Org . "8.0"))
  44
  45 (defcustom org-md-headline-style 'atx
  46   "Style used to format headlines.
  47 This variable can be set to either `atx' or `setext'."
  48   :group 'org-export-md
  49   :type '(choice
  50           (const :tag "Use \"atx\" style" atx)
  51           (const :tag "Use \"Setext\" style" setext)))
  52
  53
  54 ;;;; Footnotes
  55
  56 (defcustom org-md-footnotes-section "%s%s"
  57   "Format string for the footnotes section.
  58 The first %s placeholder will be replaced with the localized Footnotes section
  59 heading, the second with the contents of the Footnotes section."
  60  :group 'org-export-md
  61  :type 'string
  62  :version "26.1"
  63  :package-version '(Org . "9.0"))
  64
  65 (defcustom org-md-footnote-format "<sup>%s</sup>"
  66   "Format string for the footnote reference.
  67 The %s will be replaced by the footnote reference itself."
  68   :group 'org-export-md
  69   :type 'string
  70   :version "26.1"
  71   :package-version '(Org . "9.0"))
  72
  73 \f
  74 ;;; Define Back-End
  75
  76 (org-export-define-derived-backend 'md 'html
  77   :filters-alist '((:filter-parse-tree . org-md-separate-elements))
  78   :menu-entry
  79   '(?m "Export to Markdown"
  80        ((?M "To temporary buffer"
  81             (lambda (a s v b) (org-md-export-as-markdown a s v)))
  82         (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
  83         (?o "To file and open"
  84             (lambda (a s v b)
  85               (if a (org-md-export-to-markdown t s v)
  86                 (org-open-file (org-md-export-to-markdown nil s v)))))))
  87   :translate-alist '((bold . org-md-bold)
  88                      (code . org-md-verbatim)
  89                      (example-block . org-md-example-block)
  90                      (export-block . org-md-export-block)
  91                      (fixed-width . org-md-example-block)
  92                      (headline . org-md-headline)
  93                      (horizontal-rule . org-md-horizontal-rule)
  94                      (inline-src-block . org-md-verbatim)
  95                      (inner-template . org-md-inner-template)
  96                      (italic . org-md-italic)
  97                      (item . org-md-item)
  98                      (keyword . org-md-keyword)
  99                      (line-break . org-md-line-break)
 100                      (link . org-md-link)
 101                      (node-property . org-md-node-property)
 102                      (paragraph . org-md-paragraph)
 103                      (plain-list . org-md-plain-list)
 104                      (plain-text . org-md-plain-text)
 105                      (property-drawer . org-md-property-drawer)
 106                      (quote-block . org-md-quote-block)
 107                      (section . org-md-section)
 108                      (src-block . org-md-example-block)
 109                      (template . org-md-template)
 110                      (verbatim . org-md-verbatim))
 111   :options-alist
 112   '((:md-footnote-format nil nil org-md-footnote-format)
 113     (:md-footnotes-section nil nil org-md-footnotes-section)
 114     (:md-headline-style nil nil org-md-headline-style)))
 115
 116 \f
 117 ;;; Filters
 118
 119 (defun org-md-separate-elements (tree _backend info)
 120   "Fix blank lines between elements.
 121
 122 TREE is the parse tree being exported.  BACKEND is the export
 123 back-end used.  INFO is a plist used as a communication channel.
 124
 125 Enforce a blank line between elements.  There are two exceptions
 126 to this rule:
 127
 128   1. Preserve blank lines between sibling items in a plain list,
 129
 130   2. In an item, remove any blank line before the very first
 131      paragraph and the next sub-list when the latter ends the
 132      current item.
 133
 134 Assume BACKEND is `md'."
 135   (org-element-map tree (remq 'item org-element-all-elements)
 136     (lambda (e)
 137       (org-element-put-property
 138        e :post-blank
 139        (if (and (eq (org-element-type e) 'paragraph)
 140                 (eq (org-element-type (org-element-property :parent e)) 'item)
 141                 (org-export-first-sibling-p e info)
 142                 (let ((next (org-export-get-next-element e info)))
 143                   (and (eq (org-element-type next) 'plain-list)
 144                        (not (org-export-get-next-element next info)))))
 145            0
 146          1))))
 147   ;; Return updated tree.
 148   tree)
 149
 150
 151 \f
 152 ;;; Transcode Functions
 153
 154 ;;;; Bold
 155
 156 (defun org-md-bold (_bold contents _info)
 157   "Transcode BOLD object into Markdown format.
 158 CONTENTS is the text within bold markup.  INFO is a plist used as
 159 a communication channel."
 160   (format "**%s**" contents))
 161
 162
 163 ;;;; Code and Verbatim
 164
 165 (defun org-md-verbatim (verbatim _contents _info)
 166   "Transcode VERBATIM object into Markdown format.
 167 CONTENTS is nil.  INFO is a plist used as a communication
 168 channel."
 169   (let ((value (org-element-property :value verbatim)))
 170     (format (cond ((not (string-match "`" value)) "`%s`")
 171                   ((or (string-prefix-p "`" value)
 172                        (string-suffix-p "`" value))
 173                    "`` %s ``")
 174                   (t "``%s``"))
 175             value)))
 176
 177
 178 ;;;; Example Block, Src Block and Export Block
 179
 180 (defun org-md-example-block (example-block _contents info)
 181   "Transcode EXAMPLE-BLOCK element into Markdown format.
 182 CONTENTS is nil.  INFO is a plist used as a communication
 183 channel."
 184   (replace-regexp-in-string
 185    "^" "    "
 186    (org-remove-indentation
 187     (org-export-format-code-default example-block info))))
 188
 189 (defun org-md-export-block (export-block contents info)
 190   "Transcode a EXPORT-BLOCK element from Org to Markdown.
 191 CONTENTS is nil.  INFO is a plist holding contextual information."
 192   (if (member (org-element-property :type export-block) '("MARKDOWN" "MD"))
 193       (org-remove-indentation (org-element-property :value export-block))
 194     ;; Also include HTML export blocks.
 195     (org-export-with-backend 'html export-block contents info)))
 196
 197
 198 ;;;; Headline
 199
 200 (defun org-md-headline (headline contents info)
 201   "Transcode HEADLINE element into Markdown format.
 202 CONTENTS is the headline contents.  INFO is a plist used as
 203 a communication channel."
 204   (unless (org-element-property :footnote-section-p headline)
 205     (let* ((level (org-export-get-relative-level headline info))
 206            (title (org-export-data (org-element-property :title headline) info))
 207            (todo (and (plist-get info :with-todo-keywords)
 208                       (let ((todo (org-element-property :todo-keyword
 209                                                         headline)))
 210                         (and todo (concat (org-export-data todo info) " ")))))
 211            (tags (and (plist-get info :with-tags)
 212                       (let ((tag-list (org-export-get-tags headline info)))
 213                         (and tag-list
 214                              (concat "     " (org-make-tag-string tag-list))))))
 215            (priority
 216             (and (plist-get info :with-priority)
 217                  (let ((char (org-element-property :priority headline)))
 218                    (and char (format "[#%c] " char)))))
 219            ;; Headline text without tags.
 220            (heading (concat todo priority title))
 221            (style (plist-get info :md-headline-style)))
 222       (cond
 223        ;; Cannot create a headline.  Fall-back to a list.
 224        ((or (org-export-low-level-p headline info)
 225             (not (memq style '(atx setext)))
 226             (and (eq style 'atx) (> level 6))
 227             (and (eq style 'setext) (> level 2)))
 228         (let ((bullet
 229                (if (not (org-export-numbered-headline-p headline info)) "-"
 230                  (concat (number-to-string
 231                           (car (last (org-export-get-headline-number
 232                                       headline info))))
 233                          "."))))
 234           (concat bullet (make-string (- 4 (length bullet)) ?\s) heading tags "\n\n"
 235                   (and contents (replace-regexp-in-string "^" "    " contents)))))
 236        (t
 237         (let ((anchor
 238                (and (org-md--headline-referred-p headline info)
 239                     (format "<a id=\"%s\"></a>"
 240                             (or (org-element-property :CUSTOM_ID headline)
 241                                 (org-export-get-reference headline info))))))
 242           (concat (org-md--headline-title style level heading anchor tags)
 243                   contents)))))))
 244
 245
 246 (defun org-md--headline-referred-p (headline info)
 247   "Non-nil when HEADLINE is being referred to.
 248 INFO is a plist used as a communication channel.  Links and table
 249 of contents can refer to headlines."
 250   (unless (org-element-property :footnote-section-p headline)
 251     (or
 252      ;; Global table of contents includes HEADLINE.
 253      (and (plist-get info :with-toc)
 254           (memq headline
 255                 (org-export-collect-headlines info (plist-get info :with-toc))))
 256      ;; A local table of contents includes HEADLINE.
 257      (cl-some
 258       (lambda (h)
 259         (let ((section (car (org-element-contents h))))
 260           (and
 261            (eq 'section (org-element-type section))
 262            (org-element-map section 'keyword
 263              (lambda (keyword)
 264                (when (equal "TOC" (org-element-property :key keyword))
 265                  (let ((case-fold-search t)
 266                        (value (org-element-property :value keyword)))
 267                    (and (string-match-p "\\<headlines\\>" value)
 268                         (let ((n (and
 269                                   (string-match "\\<[0-9]+\\>" value)
 270                                   (string-to-number (match-string 0 value))))
 271                               (local? (string-match-p "\\<local\\>" value)))
 272                           (memq headline
 273                                 (org-export-collect-headlines
 274                                  info n (and local? keyword))))))))
 275              info t))))
 276       (org-element-lineage headline))
 277      ;; A link refers internally to HEADLINE.
 278      (org-element-map (plist-get info :parse-tree) 'link
 279        (lambda (link)
 280          (eq headline
 281              (pcase (org-element-property :type link)
 282                ((or "custom-id" "id") (org-export-resolve-id-link link info))
 283                ("fuzzy" (org-export-resolve-fuzzy-link link info))
 284                (_ nil))))
 285        info t))))
 286
 287 (defun org-md--headline-title (style level title &optional anchor tags)
 288   "Generate a headline title in the preferred Markdown headline style.
 289 STYLE is the preferred style (`atx' or `setext').  LEVEL is the
 290 header level.  TITLE is the headline title.  ANCHOR is the HTML
 291 anchor tag for the section as a string.  TAGS are the tags set on
 292 the section."
 293   (let ((anchor-lines (and anchor (concat anchor "\n\n"))))
 294     ;; Use "Setext" style
 295     (if (and (eq style 'setext) (< level 3))
 296         (let* ((underline-char (if (= level 1) ?= ?-))
 297                (underline (concat (make-string (length title) underline-char)
 298                                   "\n")))
 299           (concat "\n" anchor-lines title tags "\n" underline "\n"))
 300         ;; Use "Atx" style
 301         (let ((level-mark (make-string level ?#)))
 302           (concat "\n" anchor-lines level-mark " " title tags "\n\n")))))
 303
 304 ;;;; Horizontal Rule
 305
 306 (defun org-md-horizontal-rule (_horizontal-rule _contents _info)
 307   "Transcode HORIZONTAL-RULE element into Markdown format.
 308 CONTENTS is the horizontal rule contents.  INFO is a plist used
 309 as a communication channel."
 310   "---")
 311
 312
 313 ;;;; Italic
 314
 315 (defun org-md-italic (_italic contents _info)
 316   "Transcode ITALIC object into Markdown format.
 317 CONTENTS is the text within italic markup.  INFO is a plist used
 318 as a communication channel."
 319   (format "*%s*" contents))
 320
 321
 322 ;;;; Item
 323
 324 (defun org-md-item (item contents info)
 325   "Transcode ITEM element into Markdown format.
 326 CONTENTS is the item contents.  INFO is a plist used as
 327 a communication channel."
 328   (let* ((type (org-element-property :type (org-export-get-parent item)))
 329          (struct (org-element-property :structure item))
 330          (bullet (if (not (eq type 'ordered)) "-"
 331                    (concat (number-to-string
 332                             (car (last (org-list-get-item-number
 333                                         (org-element-property :begin item)
 334                                         struct
 335                                         (org-list-prevs-alist struct)
 336                                         (org-list-parents-alist struct)))))
 337                            "."))))
 338     (concat bullet
 339             (make-string (- 4 (length bullet)) ? )
 340             (pcase (org-element-property :checkbox item)
 341               (`on "[X] ")
 342               (`trans "[-] ")
 343               (`off "[ ] "))
 344             (let ((tag (org-element-property :tag item)))
 345               (and tag (format "**%s:** "(org-export-data tag info))))
 346             (and contents
 347                  (org-trim (replace-regexp-in-string "^" "    " contents))))))
 348
 349
 350
 351 ;;;; Keyword
 352
 353 (defun org-md-keyword (keyword contents info)
 354   "Transcode a KEYWORD element into Markdown format.
 355 CONTENTS is nil.  INFO is a plist used as a communication
 356 channel."
 357   (pcase (org-element-property :key keyword)
 358     ((or "MARKDOWN" "MD") (org-element-property :value keyword))
 359     ("TOC"
 360      (let ((case-fold-search t)
 361            (value (org-element-property :value keyword)))
 362        (cond
 363         ((string-match-p "\\<headlines\\>" value)
 364          (let ((depth (and (string-match "\\<[0-9]+\\>" value)
 365                            (string-to-number (match-string 0 value))))
 366                (local? (string-match-p "\\<local\\>" value)))
 367            (org-remove-indentation
 368             (org-md--build-toc info depth keyword local?)))))))
 369     (_ (org-export-with-backend 'html keyword contents info))))
 370
 371
 372 ;;;; Line Break
 373
 374 (defun org-md-line-break (_line-break _contents _info)
 375   "Transcode LINE-BREAK object into Markdown format.
 376 CONTENTS is nil.  INFO is a plist used as a communication
 377 channel."
 378   "  \n")
 379
 380
 381 ;;;; Link
 382
 383 (defun org-md-link (link contents info)
 384   "Transcode LINE-BREAK object into Markdown format.
 385 CONTENTS is the link's description.  INFO is a plist used as
 386 a communication channel."
 387   (let ((link-org-files-as-md
 388          (lambda (raw-path)
 389            ;; Treat links to `file.org' as links to `file.md'.
 390            (if (string= ".org" (downcase (file-name-extension raw-path ".")))
 391                (concat (file-name-sans-extension raw-path) ".md")
 392              raw-path)))
 393         (type (org-element-property :type link)))
 394     (cond
 395      ;; Link type is handled by a special function.
 396      ((org-export-custom-protocol-maybe link contents 'md))
 397      ((member type '("custom-id" "id" "fuzzy"))
 398       (let ((destination (if (string= type "fuzzy")
 399                              (org-export-resolve-fuzzy-link link info)
 400                            (org-export-resolve-id-link link info))))
 401         (pcase (org-element-type destination)
 402           (`plain-text                  ; External file.
 403            (let ((path (funcall link-org-files-as-md destination)))
 404              (if (not contents) (format "<%s>" path)
 405                (format "[%s](%s)" contents path))))
 406           (`headline
 407            (format
 408             "[%s](#%s)"
 409             ;; Description.
 410             (cond ((org-string-nw-p contents))
 411                   ((org-export-numbered-headline-p destination info)
 412                    (mapconcat #'number-to-string
 413                               (org-export-get-headline-number destination info)
 414                               "."))
 415                   (t (org-export-data (org-element-property :title destination)
 416                                       info)))
 417             ;; Reference.
 418             (or (org-element-property :CUSTOM_ID destination)
 419                 (org-export-get-reference destination info))))
 420           (_
 421            (let ((description
 422                   (or (org-string-nw-p contents)
 423                       (let ((number (org-export-get-ordinal destination info)))
 424                         (cond
 425                          ((not number) nil)
 426                          ((atom number) (number-to-string number))
 427                          (t (mapconcat #'number-to-string number ".")))))))
 428              (when description
 429                (format "[%s](#%s)"
 430                        description
 431                        (org-export-get-reference destination info))))))))
 432      ((org-export-inline-image-p link org-html-inline-image-rules)
 433       (let ((path (let ((raw-path (org-element-property :path link)))
 434                     (cond ((not (equal "file" type)) (concat type ":" raw-path))
 435                           ((not (file-name-absolute-p raw-path)) raw-path)
 436                           (t (expand-file-name raw-path)))))
 437             (caption (org-export-data
 438                       (org-export-get-caption
 439                        (org-export-get-parent-element link)) info)))
 440         (format "![img](%s)"
 441                 (if (not (org-string-nw-p caption)) path
 442                   (format "%s \"%s\"" path caption)))))
 443      ((string= type "coderef")
 444       (let ((ref (org-element-property :path link)))
 445         (format (org-export-get-coderef-format ref contents)
 446                 (org-export-resolve-coderef ref info))))
 447      ((equal type "radio") contents)
 448      (t (let* ((raw-path (org-element-property :path link))
 449                (path
 450                 (cond
 451                  ((member type '("http" "https" "ftp" "mailto"))
 452                   (concat type ":" raw-path))
 453                  ((string= type "file")
 454                   (org-export-file-uri (funcall link-org-files-as-md raw-path)))
 455                  (t raw-path))))
 456           (if (not contents) (format "<%s>" path)
 457             (format "[%s](%s)" contents path)))))))
 458
 459
 460 ;;;; Node Property
 461
 462 (defun org-md-node-property (node-property _contents _info)
 463   "Transcode a NODE-PROPERTY element into Markdown syntax.
 464 CONTENTS is nil.  INFO is a plist holding contextual
 465 information."
 466   (format "%s:%s"
 467           (org-element-property :key node-property)
 468           (let ((value (org-element-property :value node-property)))
 469             (if value (concat " " value) ""))))
 470
 471
 472 ;;;; Paragraph
 473
 474 (defun org-md-paragraph (paragraph contents _info)
 475   "Transcode PARAGRAPH element into Markdown format.
 476 CONTENTS is the paragraph contents.  INFO is a plist used as
 477 a communication channel."
 478   (let ((first-object (car (org-element-contents paragraph))))
 479     ;; If paragraph starts with a #, protect it.
 480     (if (and (stringp first-object) (string-prefix-p "#" first-object))
 481         (concat "\\" contents)
 482       contents)))
 483
 484
 485 ;;;; Plain List
 486
 487 (defun org-md-plain-list (_plain-list contents _info)
 488   "Transcode PLAIN-LIST element into Markdown format.
 489 CONTENTS is the plain-list contents.  INFO is a plist used as
 490 a communication channel."
 491   contents)
 492
 493
 494 ;;;; Plain Text
 495
 496 (defun org-md-plain-text (text info)
 497   "Transcode a TEXT string into Markdown format.
 498 TEXT is the string to transcode.  INFO is a plist holding
 499 contextual information."
 500   (when (plist-get info :with-smart-quotes)
 501     (setq text (org-export-activate-smart-quotes text :html info)))
 502   ;; The below series of replacements in `text' is order sensitive.
 503   ;; Protect `, *, _, and \
 504   (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
 505   ;; Protect ambiguous #.  This will protect # at the beginning of
 506   ;; a line, but not at the beginning of a paragraph.  See
 507   ;; `org-md-paragraph'.
 508   (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
 509   ;; Protect ambiguous !
 510   (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
 511   ;; Handle special strings, if required.
 512   (when (plist-get info :with-special-strings)
 513     (setq text (org-html-convert-special-strings text)))
 514   ;; Handle break preservation, if required.
 515   (when (plist-get info :preserve-breaks)
 516     (setq text (replace-regexp-in-string "[ \t]*\n" "  \n" text)))
 517   ;; Return value.
 518   text)
 519
 520
 521 ;;;; Property Drawer
 522
 523 (defun org-md-property-drawer (_property-drawer contents _info)
 524   "Transcode a PROPERTY-DRAWER element into Markdown format.
 525 CONTENTS holds the contents of the drawer.  INFO is a plist
 526 holding contextual information."
 527   (and (org-string-nw-p contents)
 528        (replace-regexp-in-string "^" "    " contents)))
 529
 530
 531 ;;;; Quote Block
 532
 533 (defun org-md-quote-block (_quote-block contents _info)
 534   "Transcode QUOTE-BLOCK element into Markdown format.
 535 CONTENTS is the quote-block contents.  INFO is a plist used as
 536 a communication channel."
 537   (replace-regexp-in-string
 538    "^" "> "
 539    (replace-regexp-in-string "\n\\'" "" contents)))
 540
 541
 542 ;;;; Section
 543
 544 (defun org-md-section (_section contents _info)
 545   "Transcode SECTION element into Markdown format.
 546 CONTENTS is the section contents.  INFO is a plist used as
 547 a communication channel."
 548   contents)
 549
 550
 551 ;;;; Template
 552
 553 (defun org-md--build-toc (info &optional n keyword local)
 554   "Return a table of contents.
 555
 556 INFO is a plist used as a communication channel.
 557
 558 Optional argument N, when non-nil, is an integer specifying the
 559 depth of the table.
 560
 561 Optional argument KEYWORD specifies the TOC keyword, if any, from
 562 which the table of contents generation has been initiated.
 563
 564 When optional argument LOCAL is non-nil, build a table of
 565 contents according to the current headline."
 566   (concat
 567    (unless local
 568      (let ((style (plist-get info :md-headline-style))
 569            (title (org-html--translate "Table of Contents" info)))
 570        (org-md--headline-title style 1 title nil)))
 571    (mapconcat
 572     (lambda (headline)
 573       (let* ((indentation
 574               (make-string
 575                (* 4 (1- (org-export-get-relative-level headline info)))
 576                ?\s))
 577              (bullet
 578               (if (not (org-export-numbered-headline-p headline info)) "-   "
 579                 (let ((prefix
 580                        (format "%d." (org-last (org-export-get-headline-number
 581                                                 headline info)))))
 582                   (concat prefix (make-string (max 1 (- 4 (length prefix)))
 583                                               ?\s)))))
 584              (title
 585               (format "[%s](#%s)"
 586                       (org-export-data-with-backend
 587                        (org-export-get-alt-title headline info)
 588                        (org-export-toc-entry-backend 'md)
 589                        info)
 590                       (or (org-element-property :CUSTOM_ID headline)
 591                           (org-export-get-reference headline info))))
 592              (tags (and (plist-get info :with-tags)
 593                         (not (eq 'not-in-toc (plist-get info :with-tags)))
 594                         (org-make-tag-string
 595                          (org-export-get-tags headline info)))))
 596         (concat indentation bullet title tags)))
 597     (org-export-collect-headlines info n (and local keyword)) "\n")
 598    "\n"))
 599
 600 (defun org-md--footnote-formatted (footnote info)
 601   "Formats a single footnote entry FOOTNOTE.
 602 FOOTNOTE is a cons cell of the form (number . definition).
 603 INFO is a plist with contextual information."
 604   (let* ((fn-num (car footnote))
 605          (fn-text (cdr footnote))
 606          (fn-format (plist-get info :md-footnote-format))
 607          (fn-anchor (format "fn.%d" fn-num))
 608          (fn-href (format " href=\"#fnr.%d\"" fn-num))
 609          (fn-link-to-ref (org-html--anchor fn-anchor fn-num fn-href info)))
 610     (concat (format fn-format fn-link-to-ref) " " fn-text "\n")))
 611
 612 (defun org-md--footnote-section (info)
 613   "Format the footnote section.
 614 INFO is a plist used as a communication channel."
 615   (let* ((fn-alist (org-export-collect-footnote-definitions info))
 616          (fn-alist (cl-loop for (n _type raw) in fn-alist collect
 617                             (cons n (org-trim (org-export-data raw info)))))
 618          (headline-style (plist-get info :md-headline-style))
 619          (section-title (org-html--translate "Footnotes" info)))
 620     (when fn-alist
 621       (format (plist-get info :md-footnotes-section)
 622               (org-md--headline-title headline-style 1 section-title)
 623               (mapconcat (lambda (fn) (org-md--footnote-formatted fn info))
 624                          fn-alist
 625                          "\n")))))
 626
 627 (defun org-md-inner-template (contents info)
 628   "Return body of document after converting it to Markdown syntax.
 629 CONTENTS is the transcoded contents string.  INFO is a plist
 630 holding export options."
 631   ;; Make sure CONTENTS is separated from table of contents and
 632   ;; footnotes with at least a blank line.
 633   (concat
 634    ;; Table of contents.
 635    (let ((depth (plist-get info :with-toc)))
 636      (when depth
 637        (concat (org-md--build-toc info (and (wholenump depth) depth)) "\n")))
 638    ;; Document contents.
 639    contents
 640    "\n"
 641    ;; Footnotes section.
 642    (org-md--footnote-section info)))
 643
 644 (defun org-md-template (contents _info)
 645   "Return complete document string after Markdown conversion.
 646 CONTENTS is the transcoded contents string.  INFO is a plist used
 647 as a communication channel."
 648   contents)
 649
 650
 651 \f
 652 ;;; Interactive function
 653
 654 ;;;###autoload
 655 (defun org-md-export-as-markdown (&optional async subtreep visible-only)
 656   "Export current buffer to a Markdown buffer.
 657
 658 If narrowing is active in the current buffer, only export its
 659 narrowed part.
 660
 661 If a region is active, export that region.
 662
 663 A non-nil optional argument ASYNC means the process should happen
 664 asynchronously.  The resulting buffer should be accessible
 665 through the `org-export-stack' interface.
 666
 667 When optional argument SUBTREEP is non-nil, export the sub-tree
 668 at point, extracting information from the headline properties
 669 first.
 670
 671 When optional argument VISIBLE-ONLY is non-nil, don't export
 672 contents of hidden elements.
 673
 674 Export is done in a buffer named \"*Org MD Export*\", which will
 675 be displayed when `org-export-show-temporary-export-buffer' is
 676 non-nil."
 677   (interactive)
 678   (org-export-to-buffer 'md "*Org MD Export*"
 679     async subtreep visible-only nil nil (lambda () (text-mode))))
 680
 681 ;;;###autoload
 682 (defun org-md-convert-region-to-md ()
 683   "Assume the current region has Org syntax, and convert it to Markdown.
 684 This can be used in any buffer.  For example, you can write an
 685 itemized list in Org syntax in a Markdown buffer and use
 686 this command to convert it."
 687   (interactive)
 688   (org-export-replace-region-by 'md))
 689
 690
 691 ;;;###autoload
 692 (defun org-md-export-to-markdown (&optional async subtreep visible-only)
 693   "Export current buffer to a Markdown file.
 694
 695 If narrowing is active in the current buffer, only export its
 696 narrowed part.
 697
 698 If a region is active, export that region.
 699
 700 A non-nil optional argument ASYNC means the process should happen
 701 asynchronously.  The resulting file should be accessible through
 702 the `org-export-stack' interface.
 703
 704 When optional argument SUBTREEP is non-nil, export the sub-tree
 705 at point, extracting information from the headline properties
 706 first.
 707
 708 When optional argument VISIBLE-ONLY is non-nil, don't export
 709 contents of hidden elements.
 710
 711 Return output file's name."
 712   (interactive)
 713   (let ((outfile (org-export-output-file-name ".md" subtreep)))
 714     (org-export-to-file 'md outfile async subtreep visible-only)))
 715
 716 ;;;###autoload
 717 (defun org-md-publish-to-md (plist filename pub-dir)
 718   "Publish an org file to Markdown.
 719
 720 FILENAME is the filename of the Org file to be published.  PLIST
 721 is the property list for the given project.  PUB-DIR is the
 722 publishing directory.
 723
 724 Return output file name."
 725   (org-publish-org-to 'md filename ".md" plist pub-dir))
 726
 727 (provide 'ox-md)
 728
 729 ;; Local variables:
 730 ;; generated-autoload-file: "org-loaddefs.el"
 731 ;; End:
 732
 733 ;;; ox-md.el ends here