lisp/org-inlinetask.el

   1 ;;; org-inlinetask.el --- Tasks Independent of Outline Hierarchy -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2019 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: https://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  24
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28 ;;
  29 ;; This module implements inline tasks in Org mode.  Inline tasks are
  30 ;; tasks that have all the properties of normal outline nodes,
  31 ;; including the ability to store meta data like scheduling dates,
  32 ;; TODO state, tags and properties.  However, these nodes are treated
  33 ;; specially by the visibility cycling.
  34 ;;
  35 ;; Visibility cycling exempts these nodes from cycling.  So whenever
  36 ;; their parent is opened, so are these tasks.  This will only work
  37 ;; with `org-cycle', so if you are also using other commands to
  38 ;; show/hide entries, you will occasionally find these tasks to behave
  39 ;; like all other outline nodes, seemingly splitting the text of the
  40 ;; parent into children.
  41 ;;
  42 ;; Special fontification of inline tasks, so that they can be
  43 ;; immediately recognized.  From the stars of the headline, only last
  44 ;; two will be visible, the others will be hidden using the `org-hide'
  45 ;; face.
  46 ;;
  47 ;; An inline task is identified solely by a minimum outline level,
  48 ;; given by the variable `org-inlinetask-min-level', default 15.
  49 ;;
  50 ;; If you need to have a time planning line (DEADLINE etc), drawers,
  51 ;; for example LOGBOOK of PROPERTIES, or even normal text as part of
  52 ;; the inline task, you must add an "END" headline with the same
  53 ;; number of stars.
  54 ;;
  55 ;; As an example, here are two valid inline tasks:
  56 ;;
  57 ;;    **************** TODO A small task
  58 ;;
  59 ;; and
  60 ;;
  61 ;;    **************** TODO Another small task
  62 ;;                     DEADLINE: <2009-03-30 Mon>
  63 ;;                     :PROPERTIES:
  64 ;;                     :SOMETHING: another thing
  65 ;;                     :END:
  66 ;;                     And here is some extra text
  67 ;;    **************** END
  68 ;;
  69 ;; Also, if you want to use refiling and archiving for inline tasks,
  70 ;; The END line must be present to make things work properly.
  71 ;;
  72 ;; Note that you should not try to use inline tasks within plain list,
  73 ;; visibility cycling is known to be problematic when doing so.
  74 ;;
  75 ;; This package installs one new command:
  76 ;;
  77 ;; C-c C-x t      Insert a new inline task with END line
  78
  79 ;;; Code:
  80
  81 (require 'org)
  82
  83 (defgroup org-inlinetask nil
  84   "Options concerning inline tasks in Org mode."
  85   :tag "Org Inline Tasks"
  86   :group 'org-structure)
  87
  88 (defcustom org-inlinetask-min-level 15
  89   "Minimum level a headline must have before it is treated as an inline task.
  90 Don't set it to something higher than `29' or clocking will break since this
  91 is the hardcoded maximum number of stars `org-clock-sum' will work with.
  92
  93 It is strongly recommended that you set `org-cycle-max-level' not at all,
  94 or to a number smaller than this one.  In fact, when `org-cycle-max-level' is
  95 not set, it will be assumed to be one less than the value of smaller than
  96 the value of this variable."
  97   :group 'org-inlinetask
  98   :type '(choice
  99           (const :tag "Off" nil)
 100           (integer)))
 101
 102 (defcustom org-inlinetask-show-first-star nil
 103   "Non-nil means display the first star of an inline task as additional marker.
 104 When nil, the first star is not shown."
 105   :tag "Org Inline Tasks"
 106   :group 'org-structure
 107   :type 'boolean)
 108
 109 (defvar org-odd-levels-only)
 110 (defvar org-keyword-time-regexp)
 111 (defvar org-complex-heading-regexp)
 112 (defvar org-property-end-re)
 113
 114 (defcustom org-inlinetask-default-state nil
 115   "Non-nil means make inline tasks have a TODO keyword initially.
 116 This should be the state `org-inlinetask-insert-task' should use by
 117 default, or nil if no state should be assigned."
 118   :group 'org-inlinetask
 119   :version "24.1"
 120   :type '(choice
 121           (const :tag "No state" nil)
 122           (string :tag "Specific state")))
 123
 124 (defun org-inlinetask-insert-task (&optional no-state)
 125   "Insert an inline task.
 126 If prefix arg NO-STATE is set, ignore `org-inlinetask-default-state'.
 127 If there is a region wrap it inside the inline task."
 128   (interactive "P")
 129   ;; Error when inside an inline task, except if point was at its very
 130   ;; beginning, in which case the new inline task will be inserted
 131   ;; before this one.
 132   (when (and (org-inlinetask-in-task-p)
 133              (not (and (org-inlinetask-at-task-p) (bolp))))
 134     (error "Cannot nest inline tasks"))
 135   (or (bolp) (newline))
 136   (let* ((indent (if org-odd-levels-only
 137                      (1- (* 2 org-inlinetask-min-level))
 138                    org-inlinetask-min-level))
 139          (indent-string (concat (make-string indent ?*) " "))
 140          (rbeg (if (org-region-active-p) (region-beginning) (point)))
 141          (rend (if (org-region-active-p) (region-end) (point))))
 142     (goto-char rend)
 143     (insert "\n" indent-string "END\n")
 144     (goto-char rbeg)
 145     (unless (bolp) (insert "\n"))
 146     (insert indent-string
 147             (if (or no-state (not org-inlinetask-default-state))
 148                 ""
 149               (concat org-inlinetask-default-state " "))
 150             (if (= rend rbeg) "" "\n"))
 151     (unless (= rend rbeg) (end-of-line 0))))
 152 (define-key org-mode-map "\C-c\C-xt" 'org-inlinetask-insert-task)
 153
 154 (defun org-inlinetask-outline-regexp ()
 155   "Return string matching an inline task heading.
 156 The number of levels is controlled by `org-inlinetask-min-level'."
 157   (let ((nstars (if org-odd-levels-only
 158                     (1- (* org-inlinetask-min-level 2))
 159                   org-inlinetask-min-level)))
 160     (format "^\\(\\*\\{%d,\\}\\)[ \t]+" nstars)))
 161
 162 (defun org-inlinetask-end-p ()
 163   "Return a non-nil value if point is on inline task's END part."
 164   (let ((case-fold-search t))
 165     (org-match-line (concat (org-inlinetask-outline-regexp) "END[ \t]*$"))))
 166
 167 (defun org-inlinetask-at-task-p ()
 168   "Return non-nil if point is at beginning of an inline task."
 169   (and (org-match-line (concat (org-inlinetask-outline-regexp)  "\\(.*\\)"))
 170        (not (org-inlinetask-end-p))))
 171
 172 (defun org-inlinetask-in-task-p ()
 173   "Return true if point is inside an inline task."
 174   (save-excursion
 175     (beginning-of-line)
 176     (let ((case-fold-search t))
 177       (or (looking-at-p (concat (org-inlinetask-outline-regexp) "\\(?:.*\\)"))
 178           (and (re-search-forward "^\\*+[ \t]+" nil t)
 179                (org-inlinetask-end-p))))))
 180
 181 (defun org-inlinetask-goto-beginning ()
 182   "Go to the beginning of the inline task at point."
 183   (end-of-line)
 184   (let ((case-fold-search t)
 185         (inlinetask-re (org-inlinetask-outline-regexp)))
 186     (re-search-backward inlinetask-re nil t)
 187     (when (org-inlinetask-end-p)
 188       (re-search-backward inlinetask-re nil t))))
 189
 190 (defun org-inlinetask-goto-end ()
 191   "Go to the end of the inline task at point.
 192     Return point."
 193   (save-match-data
 194     (beginning-of-line)
 195     (let ((case-fold-search t)
 196           (inlinetask-re (org-inlinetask-outline-regexp)))
 197       (cond
 198        ((org-inlinetask-end-p)
 199         (forward-line))
 200        ((looking-at-p inlinetask-re)
 201         (forward-line)
 202         (cond
 203          ((org-inlinetask-end-p) (forward-line))
 204          ((looking-at-p inlinetask-re))
 205          ((org-inlinetask-in-task-p)
 206           (re-search-forward inlinetask-re nil t)
 207           (forward-line))
 208          (t nil)))
 209        (t
 210         (re-search-forward inlinetask-re nil t)
 211         (forward-line)))))
 212   (point))
 213
 214 (defun org-inlinetask-get-task-level ()
 215   "Get the level of the inline task around.
 216 This assumes the point is inside an inline task."
 217   (save-excursion
 218     (end-of-line)
 219     (re-search-backward (org-inlinetask-outline-regexp) nil t)
 220     (- (match-end 1) (match-beginning 1))))
 221
 222 (defun org-inlinetask-promote ()
 223   "Promote the inline task at point.
 224 If the task has an end part, promote it.  Also, prevents level from
 225 going below `org-inlinetask-min-level'."
 226   (interactive)
 227   (if (not (org-inlinetask-in-task-p))
 228       (error "Not in an inline task")
 229     (save-excursion
 230       (let* ((lvl (org-inlinetask-get-task-level))
 231              (next-lvl (org-get-valid-level lvl -1))
 232              (diff (- next-lvl lvl))
 233              (down-task (concat (make-string next-lvl ?*)))
 234              beg)
 235         (if (< next-lvl org-inlinetask-min-level)
 236             (error "Cannot promote an inline task at minimum level")
 237           (org-inlinetask-goto-beginning)
 238           (setq beg (point))
 239           (replace-match down-task nil t nil 1)
 240           (org-inlinetask-goto-end)
 241           (if (eobp) (beginning-of-line) (forward-line -1))
 242           (unless (= (point) beg)
 243             (replace-match down-task nil t nil 1)
 244             (when org-adapt-indentation
 245               (goto-char beg)
 246               (org-fixup-indentation diff))))))))
 247
 248 (defun org-inlinetask-demote ()
 249   "Demote the inline task at point.
 250 If the task has an end part, also demote it."
 251   (interactive)
 252   (if (not (org-inlinetask-in-task-p))
 253       (error "Not in an inline task")
 254     (save-excursion
 255       (let* ((lvl (org-inlinetask-get-task-level))
 256              (next-lvl (org-get-valid-level lvl 1))
 257              (diff (- next-lvl lvl))
 258              (down-task (concat (make-string next-lvl ?*)))
 259              beg)
 260         (org-inlinetask-goto-beginning)
 261         (setq beg (point))
 262         (replace-match down-task nil t nil 1)
 263         (org-inlinetask-goto-end)
 264         (if (eobp) (beginning-of-line) (forward-line -1))
 265         (unless (= (point) beg)
 266           (replace-match down-task nil t nil 1)
 267           (when org-adapt-indentation
 268             (goto-char beg)
 269             (org-fixup-indentation diff)))))))
 270
 271 (defvar org-indent-indentation-per-level) ; defined in org-indent.el
 272
 273 (defface org-inlinetask '((t :inherit shadow))
 274   "Face for inlinetask headlines."
 275   :group 'org-faces)
 276
 277 (defun org-inlinetask-fontify (limit)
 278   "Fontify the inline tasks down to LIMIT."
 279   (let* ((nstars (if org-odd-levels-only
 280                      (1- (* 2 (or org-inlinetask-min-level 200)))
 281                    (or org-inlinetask-min-level 200)))
 282          (re (concat "^\\(\\*\\)\\(\\*\\{"
 283                      (format "%d" (- nstars 3))
 284                      ",\\}\\)\\(\\*\\* .*\\)"))
 285          ;; Virtual indentation will add the warning face on the first
 286          ;; star.  Thus, in that case, only hide it.
 287          (start-face (if (and (bound-and-true-p org-indent-mode)
 288                               (> org-indent-indentation-per-level 1))
 289                          'org-hide
 290                        'org-warning)))
 291     (while (re-search-forward re limit t)
 292       (if org-inlinetask-show-first-star
 293           (add-text-properties (match-beginning 1) (match-end 1)
 294                                `(face ,start-face font-lock-fontified t)))
 295       (add-text-properties (match-beginning
 296                             (if org-inlinetask-show-first-star 2 1))
 297                            (match-end 2)
 298                            '(face org-hide font-lock-fontified t))
 299       (add-text-properties (match-beginning 3) (match-end 3)
 300                            '(face org-inlinetask font-lock-fontified t)))))
 301
 302 (defun org-inlinetask-toggle-visibility ()
 303   "Toggle visibility of inline task at point."
 304   (let ((end (save-excursion
 305                (org-inlinetask-goto-end)
 306                (if (bolp) (1- (point)) (point))))
 307         (start (save-excursion
 308                  (org-inlinetask-goto-beginning)
 309                  (point-at-eol))))
 310     (cond
 311      ;; Nothing to show/hide.
 312      ((= end start))
 313      ;; Inlinetask was folded: expand it.
 314      ((eq (get-char-property (1+ start) 'invisible) 'outline)
 315       (org-flag-region start end nil 'outline))
 316      (t (org-flag-region start end t 'outline)))))
 317
 318 (defun org-inlinetask-hide-tasks (state)
 319   "Hide inline tasks in buffer when STATE is `contents' or `children'.
 320 This function is meant to be used in `org-cycle-hook'."
 321   (pcase state
 322     (`contents
 323      (let ((regexp (org-inlinetask-outline-regexp)))
 324        (save-excursion
 325          (goto-char (point-min))
 326          (while (re-search-forward regexp nil t)
 327            (org-inlinetask-toggle-visibility)
 328            (org-inlinetask-goto-end)))))
 329     (`children
 330      (save-excursion
 331        (while
 332            (or (org-inlinetask-at-task-p)
 333                (and (outline-next-heading) (org-inlinetask-at-task-p)))
 334          (org-inlinetask-toggle-visibility)
 335          (org-inlinetask-goto-end))))))
 336
 337 (defun org-inlinetask-remove-END-maybe ()
 338   "Remove an END line when present."
 339   (when (looking-at (format "\\([ \t]*\n\\)*\\*\\{%d,\\}[ \t]+END[ \t]*$"
 340                             org-inlinetask-min-level))
 341     (replace-match "")))
 342
 343 (add-hook 'org-font-lock-hook 'org-inlinetask-fontify)
 344 (add-hook 'org-cycle-hook 'org-inlinetask-hide-tasks)
 345
 346 (provide 'org-inlinetask)
 347
 348 ;;; org-inlinetask.el ends here