lisp/org-indent.el

   1 ;;; org-indent.el --- Dynamic indentation for Org    -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2019 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: https://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  23 ;;
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This is an implementation of dynamic virtual indentation.  It works
  29 ;; by adding text properties to a buffer to make sure lines are
  30 ;; indented according to outline structure.
  31 ;;
  32 ;; The process is synchronous, toggled at every buffer modification.
  33 ;; Though, the initialization (indentation of text already in the
  34 ;; buffer), which can take a few seconds in large buffers, happens on
  35 ;; idle time.
  36 ;;
  37 ;;; Code:
  38
  39 (require 'org-macs)
  40 (require 'org-compat)
  41 (require 'org)
  42
  43 (require 'cl-lib)
  44
  45 (declare-function org-inlinetask-get-task-level "org-inlinetask" ())
  46 (declare-function org-inlinetask-in-task-p "org-inlinetask" ())
  47 (declare-function org-list-item-body-column "org-list" (item))
  48 (defvar org-inlinetask-show-first-star)
  49
  50 (defgroup org-indent nil
  51   "Options concerning dynamic virtual outline indentation."
  52   :tag "Org Indent"
  53   :group 'org)
  54
  55 (defvar org-indent-inlinetask-first-star (org-add-props "*" '(face org-warning))
  56   "First star of inline tasks, with correct face.")
  57 (defvar org-indent-agent-timer nil
  58   "Timer running the initialize agent.")
  59 (defvar org-indent-agentized-buffers nil
  60   "List of buffers watched by the initialize agent.")
  61 (defvar org-indent-agent-resume-timer nil
  62   "Timer to reschedule agent after switching to other idle processes.")
  63 (defvar org-indent-agent-active-delay '(0 2 0)
  64   "Time to run agent before switching to other idle processes.
  65 Delay used when the buffer to initialize is current.")
  66 (defvar org-indent-agent-passive-delay '(0 0 400000)
  67   "Time to run agent before switching to other idle processes.
  68 Delay used when the buffer to initialize isn't current.")
  69 (defvar org-indent-agent-resume-delay '(0 0 100000)
  70   "Minimal time for other idle processes before switching back to agent.")
  71 (defvar org-indent--initial-marker nil
  72   "Position of initialization before interrupt.
  73 This is used locally in each buffer being initialized.")
  74 (defvar org-hide-leading-stars-before-indent-mode nil
  75   "Used locally.")
  76 (defvar org-indent-modified-headline-flag nil
  77   "Non-nil means the last deletion operated on a headline.
  78 It is modified by `org-indent-notify-modified-headline'.")
  79
  80
  81 (defcustom org-indent-boundary-char ?\s
  82   "The end of the virtual indentation strings, a single-character string.
  83 The default is just a space, but if you wish, you can use \"|\" or so.
  84 This can be useful on a terminal window - under a windowing system,
  85 it may be prettier to customize the `org-indent' face."
  86   :group 'org-indent
  87   :type 'character)
  88
  89 (defcustom org-indent-mode-turns-off-org-adapt-indentation t
  90   "Non-nil means setting the variable `org-indent-mode' will \
  91 turn off indentation adaptation.
  92 For details see the variable `org-adapt-indentation'."
  93   :group 'org-indent
  94   :type 'boolean)
  95
  96 (defcustom org-indent-mode-turns-on-hiding-stars t
  97   "Non-nil means setting the variable `org-indent-mode' will \
  98 turn on `org-hide-leading-stars'."
  99   :group 'org-indent
 100   :type 'boolean)
 101
 102 (defcustom org-indent-indentation-per-level 2
 103   "Indentation per level in number of characters."
 104   :group 'org-indent
 105   :type 'integer)
 106
 107 (defface org-indent '((t (:inherit org-hide)))
 108   "Face for outline indentation.
 109 The default is to make it look like whitespace.  But you may find it
 110 useful to make it ever so slightly different."
 111   :group 'org-faces)
 112
 113 (defvar org-indent--text-line-prefixes nil
 114   "Vector containing line prefixes strings for regular text.")
 115
 116 (defvar org-indent--heading-line-prefixes nil
 117   "Vector containing line prefix strings for headlines.")
 118
 119 (defvar org-indent--inlinetask-line-prefixes nil
 120   "Vector containing line prefix strings for inline tasks.")
 121
 122 (defconst org-indent--deepest-level 50
 123   "Maximum theoretical headline depth.")
 124
 125 (defun org-indent--compute-prefixes ()
 126   "Compute prefix strings for regular text and headlines."
 127   (setq org-indent--heading-line-prefixes
 128         (make-vector org-indent--deepest-level nil))
 129   (setq org-indent--inlinetask-line-prefixes
 130         (make-vector org-indent--deepest-level nil))
 131   (setq org-indent--text-line-prefixes
 132         (make-vector org-indent--deepest-level nil))
 133   (dotimes (n org-indent--deepest-level)
 134     (let ((indentation (if (<= n 1) 0
 135                          (* (1- org-indent-indentation-per-level)
 136                             (1- n)))))
 137       ;; Headlines line prefixes.
 138       (let ((heading-prefix (make-string indentation ?*)))
 139         (aset org-indent--heading-line-prefixes
 140               n
 141               (org-add-props heading-prefix nil 'face 'org-indent))
 142         ;; Inline tasks line prefixes
 143         (aset org-indent--inlinetask-line-prefixes
 144               n
 145               (cond ((<= n 1) "")
 146                     ((bound-and-true-p org-inlinetask-show-first-star)
 147                      (concat org-indent-inlinetask-first-star
 148                              (substring heading-prefix 1)))
 149                     (t (org-add-props heading-prefix nil 'face 'org-indent)))))
 150       ;; Text line prefixes.
 151       (aset org-indent--text-line-prefixes
 152             n
 153             (org-add-props
 154                 (concat (make-string (+ n indentation) ?\s)
 155                         (and (> n 0)
 156                              (char-to-string org-indent-boundary-char)))
 157                 nil 'face 'org-indent)))))
 158
 159 (defsubst org-indent-remove-properties (beg end)
 160   "Remove indentations between BEG and END."
 161   (with-silent-modifications
 162     (remove-text-properties beg end '(line-prefix nil wrap-prefix nil))))
 163
 164 ;;;###autoload
 165 (define-minor-mode org-indent-mode
 166   "When active, indent text according to outline structure.
 167
 168 Internally this works by adding `line-prefix' and `wrap-prefix'
 169 properties, after each buffer modification, on the modified zone.
 170
 171 The process is synchronous.  Though, initial indentation of
 172 buffer, which can take a few seconds on large buffers, is done
 173 during idle time."
 174   nil " Ind" nil
 175   (cond
 176    (org-indent-mode
 177     ;; mode was turned on.
 178     (setq-local indent-tabs-mode nil)
 179     (setq-local org-indent--initial-marker (copy-marker 1))
 180     (when org-indent-mode-turns-off-org-adapt-indentation
 181       (setq-local org-adapt-indentation nil))
 182     (when org-indent-mode-turns-on-hiding-stars
 183       (setq-local org-hide-leading-stars-before-indent-mode
 184                   org-hide-leading-stars)
 185       (setq-local org-hide-leading-stars t))
 186     (org-indent--compute-prefixes)
 187     (if (boundp 'filter-buffer-substring-functions)
 188         (add-hook 'filter-buffer-substring-functions
 189                   (lambda (fun start end delete)
 190                     (org-indent-remove-properties-from-string
 191                      (funcall fun start end delete)))
 192                   nil t)
 193       ;; Emacs >= 24.4.
 194       (add-function :filter-return (local 'filter-buffer-substring-function)
 195                     #'org-indent-remove-properties-from-string))
 196     (add-hook 'after-change-functions 'org-indent-refresh-maybe nil 'local)
 197     (add-hook 'before-change-functions
 198               'org-indent-notify-modified-headline nil 'local)
 199     (and font-lock-mode (org-restart-font-lock))
 200     (org-indent-remove-properties (point-min) (point-max))
 201     ;; Submit current buffer to initialize agent.  If it's the first
 202     ;; buffer submitted, also start the agent.  Current buffer is
 203     ;; pushed in both cases to avoid a race condition.
 204     (if org-indent-agentized-buffers
 205         (push (current-buffer) org-indent-agentized-buffers)
 206       (push (current-buffer) org-indent-agentized-buffers)
 207       (setq org-indent-agent-timer
 208             (run-with-idle-timer 0.2 t #'org-indent-initialize-agent))))
 209    (t
 210     ;; mode was turned off (or we refused to turn it on)
 211     (kill-local-variable 'org-adapt-indentation)
 212     (setq org-indent-agentized-buffers
 213           (delq (current-buffer) org-indent-agentized-buffers))
 214     (when (markerp org-indent--initial-marker)
 215       (set-marker org-indent--initial-marker nil))
 216     (when (boundp 'org-hide-leading-stars-before-indent-mode)
 217       (setq-local org-hide-leading-stars
 218                   org-hide-leading-stars-before-indent-mode))
 219     (if (boundp 'filter-buffer-substring-functions)
 220         (remove-hook 'filter-buffer-substring-functions
 221                      (lambda (fun start end delete)
 222                        (org-indent-remove-properties-from-string
 223                         (funcall fun start end delete))))
 224       (remove-function (local 'filter-buffer-substring-function)
 225                        #'org-indent-remove-properties-from-string))
 226     (remove-hook 'after-change-functions 'org-indent-refresh-maybe 'local)
 227     (remove-hook 'before-change-functions
 228                  'org-indent-notify-modified-headline 'local)
 229     (org-with-wide-buffer
 230      (org-indent-remove-properties (point-min) (point-max)))
 231     (and font-lock-mode (org-restart-font-lock))
 232     (redraw-display))))
 233
 234 (defun org-indent-indent-buffer ()
 235   "Add indentation properties to the accessible part of the buffer."
 236   (interactive)
 237   (if (not (derived-mode-p 'org-mode))
 238       (error "Not in Org mode")
 239     (message "Setting buffer indentation.  It may take a few seconds...")
 240     (org-indent-remove-properties (point-min) (point-max))
 241     (org-indent-add-properties (point-min) (point-max))
 242     (message "Indentation of buffer set.")))
 243
 244 (defun org-indent-remove-properties-from-string (string)
 245   "Remove indentation properties from STRING."
 246   (remove-text-properties 0 (length string)
 247                           '(line-prefix nil wrap-prefix nil) string)
 248   string)
 249
 250 (defun org-indent-initialize-agent ()
 251   "Start or resume current buffer initialization.
 252 Only buffers in `org-indent-agentized-buffers' trigger an action.
 253 When no more buffer is being watched, the agent suppress itself."
 254   (when org-indent-agent-resume-timer
 255     (cancel-timer org-indent-agent-resume-timer))
 256   (setq org-indent-agentized-buffers
 257         (cl-remove-if-not #'buffer-live-p org-indent-agentized-buffers))
 258   (cond
 259    ;; Job done:  kill agent.
 260    ((not org-indent-agentized-buffers) (cancel-timer org-indent-agent-timer))
 261    ;; Current buffer is agentized: start/resume initialization
 262    ;; somewhat aggressively.
 263    ((memq (current-buffer) org-indent-agentized-buffers)
 264     (org-indent-initialize-buffer (current-buffer)
 265                                   org-indent-agent-active-delay))
 266    ;; Else, start/resume initialization of the last agentized buffer,
 267    ;; softly.
 268    (t (org-indent-initialize-buffer (car org-indent-agentized-buffers)
 269                                     org-indent-agent-passive-delay))))
 270
 271 (defun org-indent-initialize-buffer (buffer delay)
 272   "Set virtual indentation for the buffer BUFFER, asynchronously.
 273 Give hand to other idle processes if it takes longer than DELAY,
 274 a time value."
 275   (with-current-buffer buffer
 276     (when org-indent-mode
 277       (org-with-wide-buffer
 278        (let ((interruptp
 279               ;; Always nil unless interrupted.
 280               (catch 'interrupt
 281                 (and org-indent--initial-marker
 282                      (marker-position org-indent--initial-marker)
 283                      (equal (marker-buffer org-indent--initial-marker)
 284                             buffer)
 285                      (org-indent-add-properties org-indent--initial-marker
 286                                                 (point-max)
 287                                                 delay)
 288                      nil))))
 289          (move-marker org-indent--initial-marker interruptp)
 290          ;; Job is complete: un-agentize buffer.
 291          (unless interruptp
 292            (setq org-indent-agentized-buffers
 293                  (delq buffer org-indent-agentized-buffers))))))))
 294
 295 (defun org-indent-set-line-properties (level indentation &optional heading)
 296   "Set prefix properties on current line an move to next one.
 297
 298 LEVEL is the current level of heading.  INDENTATION is the
 299 expected indentation when wrapping line.
 300
 301 When optional argument HEADING is non-nil, assume line is at
 302 a heading.  Moreover, if is is `inlinetask', the first star will
 303 have `org-warning' face."
 304   (let* ((line (aref (pcase heading
 305                        (`nil org-indent--text-line-prefixes)
 306                        (`inlinetask org-indent--inlinetask-line-prefixes)
 307                        (_ org-indent--heading-line-prefixes))
 308                      level))
 309          (wrap
 310           (org-add-props
 311               (concat line
 312                       (if heading (concat (make-string level ?*) " ")
 313                         (make-string indentation ?\s)))
 314               nil 'face 'org-indent)))
 315     ;; Add properties down to the next line to indent empty lines.
 316     (add-text-properties (line-beginning-position) (line-beginning-position 2)
 317                          `(line-prefix ,line wrap-prefix ,wrap)))
 318   (forward-line))
 319
 320 (defun org-indent-add-properties (beg end &optional delay)
 321   "Add indentation properties between BEG and END.
 322
 323 When DELAY is non-nil, it must be a time value.  In that case,
 324 the process is asynchronous and can be interrupted, either by
 325 user request, or after DELAY.  This is done by throwing the
 326 `interrupt' tag along with the buffer position where the process
 327 stopped."
 328   (save-match-data
 329     (org-with-wide-buffer
 330      (goto-char beg)
 331      (beginning-of-line)
 332      ;; Initialize prefix at BEG, according to current entry's level.
 333      (let* ((case-fold-search t)
 334             (limited-re (org-get-limited-outline-regexp))
 335             (level (or (org-current-level) 0))
 336             (time-limit (and delay (time-add (current-time) delay))))
 337        ;; For each line, set `line-prefix' and `wrap-prefix'
 338        ;; properties depending on the type of line (headline, inline
 339        ;; task, item or other).
 340        (with-silent-modifications
 341          (while (and (<= (point) end) (not (eobp)))
 342            (cond
 343             ;; When in asynchronous mode, check if interrupt is
 344             ;; required.
 345             ((and delay (input-pending-p)) (throw 'interrupt (point)))
 346             ;; In asynchronous mode, take a break of
 347             ;; `org-indent-agent-resume-delay' every DELAY to avoid
 348             ;; blocking any other idle timer or process output.
 349             ((and delay (time-less-p time-limit (current-time)))
 350              (setq org-indent-agent-resume-timer
 351                    (run-with-idle-timer
 352                     (time-add (current-idle-time) org-indent-agent-resume-delay)
 353                     nil #'org-indent-initialize-agent))
 354              (throw 'interrupt (point)))
 355             ;; Headline or inline task.
 356             ((looking-at org-outline-regexp)
 357              (let* ((nstars (- (match-end 0) (match-beginning 0) 1))
 358                     (type (or (looking-at-p limited-re) 'inlinetask)))
 359                (org-indent-set-line-properties nstars 0 type)
 360                ;; At an headline, define new value for LEVEL.
 361                (unless (eq type 'inlinetask) (setq level nstars))))
 362             ;; List item: `wrap-prefix' is set where body starts.
 363             ((org-at-item-p)
 364              (org-indent-set-line-properties
 365               level (org-list-item-body-column (point))))
 366             ;; Regular line.
 367             (t
 368              (org-indent-set-line-properties level (current-indentation))))))))))
 369
 370 (defun org-indent-notify-modified-headline (beg end)
 371   "Set `org-indent-modified-headline-flag' depending on context.
 372
 373 BEG and END are the positions of the beginning and end of the
 374 range of deleted text.
 375
 376 This function is meant to be called by `before-change-functions'.
 377 Flag will be non-nil if command is going to modify or delete an
 378 headline."
 379   (when org-indent-mode
 380     (setq org-indent-modified-headline-flag
 381           (org-with-wide-buffer
 382            (goto-char beg)
 383            (save-match-data
 384              (or (and (org-at-heading-p) (< beg (match-end 0)))
 385                  (re-search-forward
 386                   (org-with-limited-levels org-outline-regexp-bol) end t)))))))
 387
 388 (defun org-indent-refresh-maybe (beg end _)
 389   "Refresh indentation properties in an adequate portion of buffer.
 390 BEG and END are the positions of the beginning and end of the
 391 range of inserted text.  DUMMY is an unused argument.
 392
 393 This function is meant to be called by `after-change-functions'."
 394   (when org-indent-mode
 395     (save-match-data
 396       ;; If a headline was modified or inserted, set properties until
 397       ;; next headline.
 398       (org-with-wide-buffer
 399        (if (or org-indent-modified-headline-flag
 400                (save-excursion
 401                  (goto-char beg)
 402                  (beginning-of-line)
 403                  (re-search-forward
 404                   (org-with-limited-levels org-outline-regexp-bol) end t)))
 405            (let ((end (save-excursion
 406                         (goto-char end)
 407                         (org-with-limited-levels (outline-next-heading))
 408                         (point))))
 409              (setq org-indent-modified-headline-flag nil)
 410              (org-indent-add-properties beg end))
 411          ;; Otherwise, only set properties on modified area.
 412          (org-indent-add-properties beg end))))))
 413
 414 (provide 'org-indent)
 415
 416 ;; Local variables:
 417 ;; generated-autoload-file: "org-loaddefs.el"
 418 ;; End:
 419
 420 ;;; org-indent.el ends here