lisp/org-ctags.el

   1 ;;; org-ctags.el - Integrate Emacs "tags" Facility with Org -*- lexical-binding: t; -*-
   2 ;;
   3 ;; Copyright (C) 2007-2019 Free Software Foundation, Inc.
   4
   5 ;; Author: Paul Sexton <eeeickythump@gmail.com>
   6
   7
   8 ;; Keywords: org, wp
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  24
  25 ;;
  26 ;; Synopsis
  27 ;; ========
  28 ;;
  29 ;; Allows Org mode to make use of the Emacs `etags' system.  Defines
  30 ;; tag destinations in Org files as any text between <<double angled
  31 ;; brackets>>. This allows the tags-generation program `exuberant
  32 ;; ctags' to parse these files and create tag tables that record where
  33 ;; these destinations are found.  Plain [[links]] in org mode files
  34 ;; which do not have <<matching destinations>> within the same file
  35 ;; will then be interpreted as links to these 'tagged' destinations,
  36 ;; allowing seamless navigation between multiple Org files.  Topics
  37 ;; can be created in any org mode file and will always be found by
  38 ;; plain links from other files.  Other file types recognized by ctags
  39 ;; (source code files, latex files, etc) will also be available as
  40 ;; destinations for plain links, and similarly, Org links will be
  41 ;; available as tags from source files.  Finally, the function
  42 ;; `org-ctags-find-tag-interactive' lets you choose any known tag,
  43 ;; using autocompletion, and quickly jump to it.
  44 ;;
  45 ;; Installation
  46 ;; ============
  47 ;;
  48 ;; Install org mode
  49 ;; Ensure org-ctags.el is somewhere in your emacs load path.
  50 ;; Download and install Exuberant ctags -- "http://ctags.sourceforge.net/"
  51 ;; Edit your .emacs file (see next section) and load emacs.
  52
  53 ;; To put in your init file (.emacs):
  54 ;; ==================================
  55 ;;
  56 ;; Assuming you already have org mode installed and set up:
  57 ;;
  58 ;;    (setq org-ctags-path-to-ctags "/path/to/ctags/executable")
  59 ;;    (add-hook 'org-mode-hook
  60 ;;      (lambda ()
  61 ;;        (define-key org-mode-map "\C-co" 'org-ctags-find-tag-interactive)))
  62 ;;
  63 ;; By default, with org-ctags loaded, org will first try and visit the tag
  64 ;; with the same name as the link; then, if unsuccessful, ask the user if
  65 ;; he/she wants to rebuild the 'TAGS' database and try again; then ask if
  66 ;; the user wishes to append 'tag' as a new toplevel heading at the end of
  67 ;; the buffer; and finally, defer to org's default behavior which is to
  68 ;; search the entire text of the current buffer for 'tag'.
  69 ;;
  70 ;; This behavior can be modified by changing the value of
  71 ;; ORG-CTAGS-OPEN-LINK-FUNCTIONS. For example I have the following in my
  72 ;; .emacs, which describes the same behavior as the above paragraph with
  73 ;; one difference:
  74 ;;
  75 ;; (setq org-ctags-open-link-functions
  76 ;;       '(org-ctags-find-tag
  77 ;;         org-ctags-ask-rebuild-tags-file-then-find-tag
  78 ;;         org-ctags-ask-append-topic
  79 ;;         org-ctags-fail-silently))  ; <-- prevents org default behavior
  80 ;;
  81 ;;
  82 ;; Usage
  83 ;; =====
  84 ;;
  85 ;; When you click on a link "[[foo]]" and org cannot find a matching "<<foo>>"
  86 ;; in the current buffer, the tags facility will take over.  The file TAGS in
  87 ;; the active directory is examined to see if the tags facility knows about
  88 ;; "<<foo>>" in any other files.  If it does, the matching file will be opened
  89 ;; and the cursor will jump to the position of "<<foo>>" in that file.
  90 ;;
  91 ;; User-visible functions:
  92 ;; - `org-ctags-find-tag-interactive': type a tag (plain link) name and visit
  93 ;;   it.  With autocompletion.  Bound to ctrl-O in the above setup.
  94 ;; - All the etags functions should work.  These include:
  95 ;;
  96 ;;      M-.    `find-tag' -- finds the tag at point
  97 ;;
  98 ;;      C-M-.  find-tag based on regular expression
  99 ;;
 100 ;;      M-x tags-search RET -- like C-M-. but searches through ENTIRE TEXT
 101 ;;             of ALL the files referenced in the TAGS file.  A quick way to
 102 ;;             search through an entire 'project'.
 103 ;;
 104 ;;      M-*    "go back" from a tag jump.  Like `org-mark-ring-goto'.
 105 ;;             You may need to bind this key yourself with (eg)
 106 ;;             (global-set-key (kbd "<M-kp-multiply>") 'pop-tag-mark)
 107 ;;
 108 ;;      (see etags chapter in Emacs manual for more)
 109 ;;
 110 ;;
 111 ;; Keeping the TAGS file up to date
 112 ;; ================================
 113 ;;
 114 ;; Tags mode has no way of knowing that you have created new tags by
 115 ;; typing in your Org buffer.  New tags make it into the TAGS file in
 116 ;; 3 ways:
 117 ;;
 118 ;; 1. You re-run (org-ctags-create-tags "directory") to rebuild the file.
 119 ;; 2. You put the function `org-ctags-ask-rebuild-tags-file-then-find-tag' in
 120 ;;    your `org-open-link-functions' list, as is done in the setup
 121 ;;    above.  This will cause the TAGS file to be rebuilt whenever a link
 122 ;;    cannot be found.  This may be slow with large file collections however.
 123 ;; 3. You run the following from the command line (all 1 line):
 124 ;;
 125 ;;      ctags --langdef=orgmode --langmap=orgmode:.org
 126 ;;        --regex-orgmode="/<<([^>]+)>>/\1/d,definition/"
 127 ;;          -f /your/path/TAGS -e -R /your/path/*.org
 128 ;;
 129 ;; If you are paranoid, you might want to run (org-ctags-create-tags
 130 ;; "/path/to/org/files") at startup, by including the following toplevel form
 131 ;; in .emacs.  However this can cause a pause of several seconds if ctags has
 132 ;; to scan lots of files.
 133 ;;
 134 ;;     (progn
 135 ;;       (message "-- rebuilding tags tables...")
 136 ;;       (mapc 'org-ctags-create-tags tags-table-list))
 137
 138 ;;; Code:
 139
 140 (eval-when-compile (require 'cl-lib))
 141 (require 'org)
 142
 143 (defgroup org-ctags nil
 144   "Options concerning use of ctags within org mode."
 145   :tag "Org-Ctags"
 146   :group 'org-link)
 147
 148 (defvar org-ctags-enabled-p t
 149   "Activate ctags support in org mode?")
 150
 151 (defvar org-ctags-tag-regexp "/<<([^>]+)>>/\\1/d,definition/"
 152   "Regexp expression used by ctags external program.
 153 The regexp matches tag destinations in Org files.
 154 Format is: /REGEXP/TAGNAME/FLAGS,TAGTYPE/
 155 See the ctags documentation for more information.")
 156
 157 (defcustom org-ctags-path-to-ctags
 158   (if (executable-find "ctags-exuberant") "ctags-exuberant" "ctags")
 159   "Name of the ctags executable file."
 160   :group 'org-ctags
 161   :version "24.1"
 162   :type 'file)
 163
 164 (defcustom org-ctags-open-link-functions
 165   '(org-ctags-find-tag
 166     org-ctags-ask-rebuild-tags-file-then-find-tag
 167     org-ctags-ask-append-topic)
 168   "List of functions to be prepended to ORG-OPEN-LINK-FUNCTIONS when ORG-CTAGS is active."
 169   :group 'org-ctags
 170   :version "24.1"
 171   :type 'hook
 172   :options '(org-ctags-find-tag
 173              org-ctags-ask-rebuild-tags-file-then-find-tag
 174              org-ctags-rebuild-tags-file-then-find-tag
 175              org-ctags-ask-append-topic
 176              org-ctags-append-topic
 177              org-ctags-ask-visit-buffer-or-file
 178              org-ctags-visit-buffer-or-file
 179              org-ctags-fail-silently))
 180
 181
 182 (defvar org-ctags-tag-list nil
 183   "List of all tags in the active TAGS file.
 184 Created as a local variable in each buffer.")
 185
 186 (defcustom org-ctags-new-topic-template
 187   "* <<%t>>\n\n\n\n\n\n"
 188   "Text to insert when creating a new org file via opening a hyperlink.
 189 The following patterns are replaced in the string:
 190     `%t' - replaced with the capitalized title of the hyperlink"
 191   :group 'org-ctags
 192   :version "24.1"
 193   :type 'string)
 194
 195
 196 (add-hook 'org-mode-hook
 197           (lambda ()
 198             (when (and org-ctags-enabled-p
 199                        (buffer-file-name))
 200               ;; Make sure this file's directory is added to default
 201               ;; directories in which to search for tags.
 202               (let ((tags-filename
 203                      (expand-file-name
 204                       (concat (file-name-directory (buffer-file-name))
 205                               "/TAGS"))))
 206                 (when (file-exists-p tags-filename)
 207                   (visit-tags-table tags-filename))))))
 208
 209
 210 (defadvice visit-tags-table (after org-ctags-load-tag-list activate compile)
 211   (when (and org-ctags-enabled-p tags-file-name)
 212     (setq-local org-ctags-tag-list
 213                 (org-ctags-all-tags-in-current-tags-table))))
 214
 215
 216 (defun org-ctags-enable ()
 217   (put 'org-mode 'find-tag-default-function 'org-ctags-find-tag-at-point)
 218   (setq org-ctags-enabled-p t)
 219   (dolist (fn org-ctags-open-link-functions)
 220     (add-hook 'org-open-link-functions fn t)))
 221
 222
 223 ;;; General utility functions.  ===============================================
 224 ;; These work outside org-ctags mode.
 225
 226 (defun org-ctags-get-filename-for-tag (tag)
 227   "TAG is a string.  Search the active TAGS file for a matching tag.
 228 If the tag is found, return a list containing the filename, line number, and
 229 buffer position where the tag is found."
 230   (interactive "sTag: ")
 231   (unless tags-file-name
 232     (call-interactively (visit-tags-table)))
 233   (save-excursion
 234     (visit-tags-table-buffer 'same)
 235     (when tags-file-name
 236       (with-current-buffer (get-file-buffer tags-file-name)
 237         (goto-char (point-min))
 238         (cond
 239          ((re-search-forward (format "^.*\^?%s\^A\\([0-9]+\\),\\([0-9]+\\)$"
 240                                      (regexp-quote tag)) nil t)
 241           (let ((line (string-to-number (match-string 1)))
 242                 (pos (string-to-number (match-string 2))))
 243             (cond
 244              ((re-search-backward "\f\n\\(.*\\),[0-9]+\n")
 245               (list (match-string 1) line pos))
 246              (t              ; can't find a file name preceding the matched
 247                                         ; tag??
 248               (error "Malformed TAGS file: %s" (buffer-name))))))
 249          (t                               ; tag not found
 250           nil))))))
 251
 252
 253 (defun org-ctags-all-tags-in-current-tags-table ()
 254   "Read all tags defined in the active TAGS file, into a list of strings.
 255 Return the list."
 256   (interactive)
 257   (let ((taglist nil))
 258     (unless tags-file-name
 259       (call-interactively (visit-tags-table)))
 260     (save-excursion
 261       (visit-tags-table-buffer 'same)
 262       (with-current-buffer (get-file-buffer tags-file-name)
 263         (goto-char (point-min))
 264         (while (re-search-forward "^.*\^?\\(.*\\)\^A\\([0-9]+\\),\\([0-9]+\\)$"
 265                                   nil t)
 266           (push (substring-no-properties (match-string 1)) taglist)))
 267       taglist)))
 268
 269
 270 (defun org-ctags-string-search-and-replace (search replace string)
 271   "Replace all instances of SEARCH with REPLACE in STRING."
 272   (replace-regexp-in-string (regexp-quote search) replace string t t))
 273
 274
 275 ;;; Internal functions =======================================================
 276
 277
 278 (defun org-ctags-open-file (name &optional title)
 279   "Visit or create a file called `NAME.org', and insert a new topic.
 280 The new topic will be titled NAME (or TITLE if supplied)."
 281   (interactive "sFile name: ")
 282   (condition-case v
 283       (progn
 284         (org-open-file name t)
 285         (message "Opened file OK")
 286         (goto-char (point-max))
 287         (insert (org-ctags-string-search-and-replace
 288                  "%t" (capitalize (or title name))
 289                  org-ctags-new-topic-template))
 290         (message "Inserted new file text OK")
 291         (org-mode-restart))
 292     (error (error "Error %S in org-ctags-open-file" v))))
 293
 294
 295 ;;;; Misc interoperability with etags system =================================
 296
 297
 298 (defadvice xref-find-definitions
 299     (before org-ctags-set-org-mark-before-finding-tag activate compile)
 300   "Before trying to find a tag, save our current position on org mark ring."
 301   (save-excursion
 302     (when (and (derived-mode-p 'org-mode) org-ctags-enabled-p)
 303       (org-mark-ring-push))))
 304
 305
 306
 307 (defun org-ctags-find-tag-at-point ()
 308   "Determine default tag to search for, based on text at point.
 309 If there is no plausible default, return nil."
 310   (let (from to bound)
 311     (when (or (ignore-errors
 312                 ;; Look for hyperlink around `point'.
 313                 (save-excursion
 314                   (search-backward "[[") (setq from (+ 2 (point))))
 315                 (save-excursion
 316                   (goto-char from)
 317                   (search-forward "]") (setq to (- (point) 1)))
 318                 (and (> to from) (>= (point) from) (<= (point) to)))
 319               (progn
 320                 ;; Look at text around `point'.
 321                 (save-excursion
 322                   (skip-syntax-backward "w_") (setq from (point)))
 323                 (save-excursion
 324                   (skip-syntax-forward "w_") (setq to (point)))
 325                 (> to from))
 326               ;; Look between `line-beginning-position' and `point'.
 327               (save-excursion
 328                 (and (setq bound (line-beginning-position))
 329                      (skip-syntax-backward "^w_" bound)
 330                      (> (setq to (point)) bound)
 331                      (skip-syntax-backward "w_")
 332                      (setq from (point))))
 333               ;; Look between `point' and `line-end-position'.
 334               (save-excursion
 335                 (and (setq bound (line-end-position))
 336                      (skip-syntax-forward "^w_" bound)
 337                      (< (setq from (point)) bound)
 338                      (skip-syntax-forward "w_")
 339                      (setq to (point)))))
 340       (buffer-substring-no-properties from to))))
 341
 342
 343 ;;; Functions for use with 'org-open-link-functions' hook =================
 344
 345
 346 (defun org-ctags-find-tag (name)
 347   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 348 Look for a tag called `NAME' in the current TAGS table.  If it is found,
 349 visit the file and location where the tag is found."
 350   (interactive "sTag: ")
 351   (let ((old-buf (current-buffer))
 352         (old-pnt (point-marker))
 353         (old-mark (copy-marker (mark-marker))))
 354     (condition-case nil
 355         (progn (xref-find-definitions name)
 356                t)
 357       (error
 358        ;; only restore old location if find-tag raises error
 359        (set-buffer old-buf)
 360        (goto-char old-pnt)
 361        (set-marker (mark-marker) old-mark)
 362        nil))))
 363
 364
 365 (defun org-ctags-visit-buffer-or-file (name &optional create)
 366   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 367 Visit buffer named `NAME.org'.  If there is no such buffer, visit the file
 368 with the same name if it exists.  If the file does not exist, then behavior
 369 depends on the value of CREATE.
 370
 371 If CREATE is nil (default), then return nil.  Do not create a new file.
 372 If CREATE is t, create the new file and visit it.
 373 If CREATE is the symbol `ask', then ask the user if they wish to create
 374 the new file."
 375   (interactive)
 376   (let ((filename (concat (substitute-in-file-name
 377                            (expand-file-name name))
 378                           ".org")))
 379     (cond
 380      ((get-buffer (concat name ".org"))
 381       ;; Buffer is already open
 382       (pop-to-buffer-same-window (get-buffer (concat name ".org"))))
 383      ((file-exists-p filename)
 384       ;; File exists but is not open --> open it
 385       (message "Opening existing org file `%S'..."
 386                filename)
 387       (org-open-file filename t))
 388      ((or (eql create t)
 389           (and (eql create 'ask)
 390                (y-or-n-p (format-message
 391                           "File `%s.org' not found; create?" name))))
 392       (org-ctags-open-file filename name))
 393      (t ;; File does not exist, and we don't want to create it.
 394       nil))))
 395
 396
 397 (defun org-ctags-ask-visit-buffer-or-file (name)
 398   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 399 Wrapper for org-ctags-visit-buffer-or-file, which ensures the user is
 400 asked before creating a new file."
 401   (org-ctags-visit-buffer-or-file name 'ask))
 402
 403
 404 (defun org-ctags-append-topic (name &optional narrowp)
 405   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 406 Append a new toplevel heading to the end of the current buffer.  The
 407 heading contains NAME surrounded by <<angular brackets>>, thus making
 408 the heading a destination for the tag `NAME'."
 409   (interactive "sTopic: ")
 410   (widen)
 411   (goto-char (point-max))
 412   (newline 2)
 413   (message "Adding topic in buffer %s" (buffer-name))
 414   (insert (org-ctags-string-search-and-replace
 415            "%t" (capitalize name) org-ctags-new-topic-template))
 416   (backward-char 4)
 417   (end-of-line)
 418   (forward-line 2)
 419   (when narrowp
 420     ;;(org-tree-to-indirect-buffer 1)  ;; opens new frame
 421     (org-narrow-to-subtree))
 422   t)
 423
 424
 425 (defun org-ctags-ask-append-topic (name &optional narrowp)
 426   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 427 Wrapper for org-ctags-append-topic, which first asks the user if they want
 428 to append a new topic."
 429   (if (y-or-n-p (format-message
 430                  "Topic `%s' not found; append to end of buffer?" name))
 431       (org-ctags-append-topic name narrowp)
 432     nil))
 433
 434
 435 (defun org-ctags-rebuild-tags-file-then-find-tag (name)
 436   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 437 Like ORG-CTAGS-FIND-TAG, but calls the external ctags program first,
 438 to rebuild (update) the TAGS file."
 439   (unless tags-file-name
 440     (call-interactively (visit-tags-table)))
 441   (when (buffer-file-name)
 442     (org-ctags-create-tags))
 443   (org-ctags-find-tag name))
 444
 445
 446 (defun org-ctags-ask-rebuild-tags-file-then-find-tag (name)
 447   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 448 Wrapper for org-ctags-rebuild-tags-file-then-find-tag."
 449   (if (and (buffer-file-name)
 450            (y-or-n-p
 451             (format-message
 452              "Tag `%s' not found.  Rebuild table `%s/TAGS' and look again?"
 453              name
 454              (file-name-directory (buffer-file-name)))))
 455       (org-ctags-rebuild-tags-file-then-find-tag name)
 456     nil))
 457
 458
 459 (defun org-ctags-fail-silently (_name)
 460   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 461 Put as the last function in the list if you want to prevent Org's
 462 default behavior of free text search."
 463   t)
 464
 465
 466 ;;; User-visible functions ===================================================
 467
 468
 469 (defun org-ctags-create-tags (&optional directory-name)
 470   "(Re)create tags file in the directory of the active buffer.
 471 The file will contain tag definitions for all the files in the
 472 directory and its subdirectories which are recognized by ctags.
 473 This will include files ending in `.org' as well as most other
 474 source files (.C, .H, .EL, .LISP, etc).  All the resulting tags
 475 end up in one file, called TAGS, located in the directory.  This
 476 function may take several seconds to finish if the directory or
 477 its subdirectories contain large numbers of taggable files."
 478   (interactive)
 479   (cl-assert (buffer-file-name))
 480   (let ((dir-name (or directory-name
 481                       (file-name-directory (buffer-file-name))))
 482         (exitcode nil))
 483     (save-excursion
 484       (setq exitcode
 485             (shell-command
 486              (format (concat "%s --langdef=orgmode --langmap=orgmode:.org "
 487                              "--regex-orgmode=\"%s\" -f \"%s\" -e -R \"%s\"")
 488                      org-ctags-path-to-ctags
 489                      org-ctags-tag-regexp
 490                      (expand-file-name (concat dir-name "/TAGS"))
 491                      (expand-file-name (concat dir-name "/*")))))
 492       (cond
 493        ((eql 0 exitcode)
 494         (setq-local org-ctags-tag-list
 495                     (org-ctags-all-tags-in-current-tags-table)))
 496        (t
 497         ;; This seems to behave differently on Linux, so just ignore
 498         ;; error codes for now
 499         ;;(error "Calling ctags executable resulted in error code: %s"
 500         ;;       exitcode)
 501         nil)))))
 502
 503
 504 (defvar org-ctags-find-tag-history nil
 505   "History of tags visited by org-ctags-find-tag-interactive.")
 506
 507 (defun org-ctags-find-tag-interactive ()
 508   "Prompt for the name of a tag, with autocompletion, then visit the named tag.
 509 Uses `ido-mode' if available.
 510 If the user enters a string that does not match an existing tag, create
 511 a new topic."
 512   (interactive)
 513   (let* ((completing-read-fn (if (fboundp 'ido-completing-read)
 514                                  'ido-completing-read
 515                                'completing-read))
 516          (tag (funcall completing-read-fn "Topic: " org-ctags-tag-list
 517                        nil 'confirm nil 'org-ctags-find-tag-history)))
 518     (when tag
 519       (cond
 520        ((member tag org-ctags-tag-list)
 521         ;; Existing tag
 522         (push tag org-ctags-find-tag-history)
 523         (xref-find-definitions tag))
 524        (t
 525         ;; New tag
 526         (run-hook-with-args-until-success
 527          'org-open-link-functions tag))))))
 528
 529
 530 (org-ctags-enable)
 531
 532 (provide 'org-ctags)
 533
 534 ;;; org-ctags.el ends here