lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- Extract Source Code From Org Files -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extract the code from source blocks out into raw source-code files.
  27
  28 ;;; Code:
  29 (require 'org-src)
  30
  31 (declare-function make-directory "files" (dir &optional parents))
  32 (declare-function org-at-heading-p "org" (&optional ignored))
  33 (declare-function org-babel-update-block-body "ob-core" (new-body))
  34 (declare-function org-back-to-heading "org" (&optional invisible-ok))
  35 (declare-function org-before-first-heading-p "org" ())
  36 (declare-function org-edit-special "org" (&optional arg))
  37 (declare-function org-element-at-point "org-element" ())
  38 (declare-function org-element-type "org-element" (element))
  39 (declare-function org-fill-template "org" (template alist))
  40 (declare-function org-heading-components "org" ())
  41 (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  42 (declare-function org-link-escape "org" (text &optional table merge))
  43 (declare-function org-open-link-from-string "org" (s &optional arg reference-buffer))
  44 (declare-function org-remove-indentation "org" (code &optional n))
  45 (declare-function org-store-link "org" (arg))
  46 (declare-function org-string-nw-p "org-macs" (s))
  47 (declare-function org-trim "org" (s &optional keep-lead))
  48 (declare-function outline-previous-heading "outline" ())
  49
  50 (defvar org-link-types-re)
  51
  52 (defcustom org-babel-tangle-lang-exts
  53   '(("emacs-lisp" . "el")
  54     ("elisp" . "el"))
  55   "Alist mapping languages to their file extensions.
  56 The key is the language name, the value is the string that should
  57 be inserted as the extension commonly used to identify files
  58 written in this language.  If no entry is found in this list,
  59 then the name of the language is used."
  60   :group 'org-babel-tangle
  61   :version "24.1"
  62   :type '(repeat
  63           (cons
  64            (string "Language name")
  65            (string "File Extension"))))
  66
  67 (defcustom org-babel-tangle-use-relative-file-links t
  68   "Use relative path names in links from tangled source back the Org-mode file."
  69   :group 'org-babel-tangle
  70   :type 'boolean)
  71
  72 (defcustom org-babel-post-tangle-hook nil
  73   "Hook run in code files tangled by `org-babel-tangle'."
  74   :group 'org-babel
  75   :version "24.1"
  76   :type 'hook)
  77
  78 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  79   "Hook run at the beginning of `org-babel-tangle'."
  80   :group 'org-babel
  81   :version "24.1"
  82   :type 'hook)
  83
  84 (defcustom org-babel-tangle-body-hook nil
  85   "Hook run over the contents of each code block body."
  86   :group 'org-babel
  87   :version "24.1"
  88   :type 'hook)
  89
  90 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  91   "Format of inserted comments in tangled code files.
  92 The following format strings can be used to insert special
  93 information into the output using `org-fill-template'.
  94 %start-line --- the line number at the start of the code block
  95 %file --------- the file from which the code block was tangled
  96 %link --------- Org-mode style link to the code block
  97 %source-name -- name of the code block
  98
  99 Upon insertion the formatted comment will be commented out, and
 100 followed by a newline.  To inhibit this post-insertion processing
 101 set the `org-babel-tangle-uncomment-comments' variable to a
 102 non-nil value.
 103
 104 Whether or not comments are inserted during tangling is
 105 controlled by the :comments header argument."
 106   :group 'org-babel
 107   :version "24.1"
 108   :type 'string)
 109
 110 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
 111   "Format of inserted comments in tangled code files.
 112 The following format strings can be used to insert special
 113 information into the output using `org-fill-template'.
 114 %start-line --- the line number at the start of the code block
 115 %file --------- the file from which the code block was tangled
 116 %link --------- Org-mode style link to the code block
 117 %source-name -- name of the code block
 118
 119 Upon insertion the formatted comment will be commented out, and
 120 followed by a newline.  To inhibit this post-insertion processing
 121 set the `org-babel-tangle-uncomment-comments' variable to a
 122 non-nil value.
 123
 124 Whether or not comments are inserted during tangling is
 125 controlled by the :comments header argument."
 126   :group 'org-babel
 127   :version "24.1"
 128   :type 'string)
 129
 130 (defcustom org-babel-tangle-uncomment-comments nil
 131   "Inhibits automatic commenting and addition of trailing newline
 132 of tangle comments.  Use `org-babel-tangle-comment-format-beg'
 133 and `org-babel-tangle-comment-format-end' to customize the format
 134 of tangled comments."
 135   :group 'org-babel
 136   :type 'boolean)
 137
 138 (defcustom org-babel-process-comment-text 'org-remove-indentation
 139   "Function called to process raw Org-mode text collected to be
 140 inserted as comments in tangled source-code files.  The function
 141 should take a single string argument and return a string
 142 result.  The default value is `org-remove-indentation'."
 143   :group 'org-babel
 144   :version "24.1"
 145   :type 'function)
 146
 147 (defun org-babel-find-file-noselect-refresh (file)
 148   "Find file ensuring that the latest changes on disk are
 149 represented in the file."
 150   (find-file-noselect file 'nowarn)
 151   (with-current-buffer (get-file-buffer file)
 152     (revert-buffer t t t)))
 153
 154 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 155   "Open FILE into a temporary buffer execute BODY there like
 156 `progn', then kill the FILE buffer returning the result of
 157 evaluating BODY."
 158   (declare (indent 1))
 159   (let ((temp-path (make-symbol "temp-path"))
 160         (temp-result (make-symbol "temp-result"))
 161         (temp-file (make-symbol "temp-file"))
 162         (visited-p (make-symbol "visited-p")))
 163     `(let* ((,temp-path ,file)
 164             (,visited-p (get-file-buffer ,temp-path))
 165             ,temp-result ,temp-file)
 166        (org-babel-find-file-noselect-refresh ,temp-path)
 167        (setf ,temp-file (get-file-buffer ,temp-path))
 168        (with-current-buffer ,temp-file
 169          (setf ,temp-result (progn ,@body)))
 170        (unless ,visited-p (kill-buffer ,temp-file))
 171        ,temp-result)))
 172 (def-edebug-spec org-babel-with-temp-filebuffer (form body))
 173
 174 ;;;###autoload
 175 (defun org-babel-tangle-file (file &optional target-file lang)
 176   "Extract the bodies of source code blocks in FILE.
 177 Source code blocks are extracted with `org-babel-tangle'.
 178 Optional argument TARGET-FILE can be used to specify a default
 179 export file for all source blocks.  Optional argument LANG can be
 180 used to limit the exported source code blocks by language.
 181 Return a list whose CAR is the tangled file name."
 182   (interactive "fFile to tangle: \nP")
 183   (let ((visited-p (get-file-buffer (expand-file-name file)))
 184         to-be-removed)
 185     (prog1
 186         (save-window-excursion
 187           (find-file file)
 188           (setq to-be-removed (current-buffer))
 189           (mapcar #'expand-file-name (org-babel-tangle nil target-file lang)))
 190       (unless visited-p
 191         (kill-buffer to-be-removed)))))
 192
 193 (defun org-babel-tangle-publish (_ filename pub-dir)
 194   "Tangle FILENAME and place the results in PUB-DIR."
 195   (unless (file-exists-p pub-dir)
 196     (make-directory pub-dir t))
 197   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 198
 199 ;;;###autoload
 200 (defun org-babel-tangle (&optional arg target-file lang)
 201   "Write code blocks to source-specific files.
 202 Extract the bodies of all source code blocks from the current
 203 file into their own source-specific files.
 204 With one universal prefix argument, only tangle the block at point.
 205 When two universal prefix arguments, only tangle blocks for the
 206 tangle file of the block at point.
 207 Optional argument TARGET-FILE can be used to specify a default
 208 export file for all source blocks.  Optional argument LANG can be
 209 used to limit the exported source code blocks by language."
 210   (interactive "P")
 211   (run-hooks 'org-babel-pre-tangle-hook)
 212   ;; Possibly Restrict the buffer to the current code block
 213   (save-restriction
 214     (save-excursion
 215       (when (equal arg '(4))
 216         (let ((head (org-babel-where-is-src-block-head)))
 217           (if head
 218               (goto-char head)
 219             (user-error "Point is not in a source code block"))))
 220       (let ((block-counter 0)
 221             (org-babel-default-header-args
 222              (if target-file
 223                  (org-babel-merge-params org-babel-default-header-args
 224                                          (list (cons :tangle target-file)))
 225                org-babel-default-header-args))
 226             (tangle-file
 227              (when (equal arg '(16))
 228                (or (cdr (assoc :tangle (nth 2 (org-babel-get-src-block-info 'light))))
 229                    (user-error "Point is not in a source code block"))))
 230             path-collector)
 231         (mapc ;; map over all languages
 232          (lambda (by-lang)
 233            (let* ((lang (car by-lang))
 234                   (specs (cdr by-lang))
 235                   (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 236                   (lang-f (intern
 237                            (concat
 238                             (or (and (cdr (assoc lang org-src-lang-modes))
 239                                      (symbol-name
 240                                       (cdr (assoc lang org-src-lang-modes))))
 241                                 lang)
 242                             "-mode")))
 243                   she-banged)
 244              (mapc
 245               (lambda (spec)
 246                 (let ((get-spec (lambda (name) (cdr (assoc name (nth 4 spec))))))
 247                   (let* ((tangle (funcall get-spec :tangle))
 248                          (she-bang (let ((sheb (funcall get-spec :shebang)))
 249                                      (when (> (length sheb) 0) sheb)))
 250                          (tangle-mode (funcall get-spec :tangle-mode))
 251                          (base-name (cond
 252                                      ((string= "yes" tangle)
 253                                       (file-name-sans-extension
 254                                        (nth 1 spec)))
 255                                      ((string= "no" tangle) nil)
 256                                      ((> (length tangle) 0) tangle)))
 257                          (file-name (when base-name
 258                                       ;; decide if we want to add ext to base-name
 259                                       (if (and ext (string= "yes" tangle))
 260                                           (concat base-name "." ext) base-name))))
 261                     (when file-name
 262                       ;; Possibly create the parent directories for file.
 263                       (let ((m (funcall get-spec :mkdirp))
 264                             (fnd (file-name-directory file-name)))
 265                         (and m fnd (not (string= m "no"))
 266                              (make-directory fnd 'parents)))
 267                       ;; delete any old versions of file
 268                       (and (file-exists-p file-name)
 269                            (not (member file-name (mapcar #'car path-collector)))
 270                            (delete-file file-name))
 271                       ;; drop source-block to file
 272                       (with-temp-buffer
 273                         (when (fboundp lang-f) (ignore-errors (funcall lang-f)))
 274                         (when (and she-bang (not (member file-name she-banged)))
 275                           (insert (concat she-bang "\n"))
 276                           (setq she-banged (cons file-name she-banged)))
 277                         (org-babel-spec-to-string spec)
 278                         ;; We avoid append-to-file as it does not work with tramp.
 279                         (let ((content (buffer-string)))
 280                           (with-temp-buffer
 281                             (if (file-exists-p file-name)
 282                                 (insert-file-contents file-name))
 283                             (goto-char (point-max))
 284                             ;; Handle :padlines unless first line in file
 285                             (unless (or (string= "no" (cdr (assoc :padline (nth 4 spec))))
 286                                         (= (point) (point-min)))
 287                               (insert "\n"))
 288                             (insert content)
 289                             (write-region nil nil file-name))))
 290                       ;; if files contain she-bangs, then make the executable
 291                       (when she-bang
 292                         (unless tangle-mode (setq tangle-mode #o755)))
 293                       ;; update counter
 294                       (setq block-counter (+ 1 block-counter))
 295                       (unless (assoc file-name path-collector)
 296                         (push (cons file-name tangle-mode) path-collector))))))
 297               specs)))
 298          (if (equal arg '(4))
 299              (org-babel-tangle-single-block 1 t)
 300            (org-babel-tangle-collect-blocks lang tangle-file)))
 301         (message "Tangled %d code block%s from %s" block-counter
 302                  (if (= block-counter 1) "" "s")
 303                  (file-name-nondirectory
 304                   (buffer-file-name
 305                    (or (buffer-base-buffer) (current-buffer)))))
 306         ;; run `org-babel-post-tangle-hook' in all tangled files
 307         (when org-babel-post-tangle-hook
 308           (mapc
 309            (lambda (file)
 310              (org-babel-with-temp-filebuffer file
 311                (run-hooks 'org-babel-post-tangle-hook)))
 312            (mapcar #'car path-collector)))
 313         ;; set permissions on tangled files
 314         (mapc (lambda (pair)
 315                 (when (cdr pair) (set-file-modes (car pair) (cdr pair))))
 316               path-collector)
 317         (mapcar #'car path-collector)))))
 318
 319 (defun org-babel-tangle-clean ()
 320   "Remove comments inserted by `org-babel-tangle'.
 321 Call this function inside of a source-code file generated by
 322 `org-babel-tangle' to remove all comments inserted automatically
 323 by `org-babel-tangle'.  Warning, this comment removes any lines
 324 containing constructs which resemble org-mode file links or noweb
 325 references."
 326   (interactive)
 327   (goto-char (point-min))
 328   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 329              (re-search-forward (org-babel-noweb-wrap) nil t))
 330     (delete-region (save-excursion (beginning-of-line 1) (point))
 331                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 332
 333 (defvar org-stored-links)
 334 (defvar org-bracket-link-regexp)
 335 (defun org-babel-spec-to-string (spec)
 336   "Insert SPEC into the current file.
 337
 338 Insert the source-code specified by SPEC into the current source
 339 code file.  This function uses `comment-region' which assumes
 340 that the appropriate major-mode is set.  SPEC has the form:
 341
 342   (start-line file link source-name params body comment)"
 343   (let* ((start-line (nth 0 spec))
 344          (info (nth 4 spec))
 345          (file (if org-babel-tangle-use-relative-file-links
 346                    (file-relative-name (nth 1 spec))
 347                  (nth 1 spec)))
 348          (link (let ((link (nth 2 spec)))
 349                  (if org-babel-tangle-use-relative-file-links
 350                      (when (string-match org-link-types-re link)
 351                        (let ((type (match-string 0 link))
 352                              (link (substring link (match-end 0))))
 353                          (concat
 354                           type
 355                           (file-relative-name
 356                            link
 357                            (file-name-directory (cdr (assq :tangle info)))))))
 358                    link)))
 359          (source-name (nth 3 spec))
 360          (body (nth 5 spec))
 361          (comment (nth 6 spec))
 362          (comments (cdr (assq :comments info)))
 363          (link-p (or (string= comments "both") (string= comments "link")
 364                      (string= comments "yes") (string= comments "noweb")))
 365          (link-data `(("start-line" . ,(number-to-string start-line))
 366                       ("file" . ,file)
 367                       ("link" . ,link)
 368                       ("source-name" . ,source-name)))
 369          (insert-comment (lambda (text)
 370                            (when (and comments
 371                                       (not (string= comments "no"))
 372                                       (org-string-nw-p text))
 373                              (if org-babel-tangle-uncomment-comments
 374                                  ;; Plain comments: no processing.
 375                                  (insert text)
 376                                ;; Ensure comments are made to be
 377                                ;; comments, and add a trailing
 378                                ;; newline.  Also ignore invisible
 379                                ;; characters when commenting.
 380                                (comment-region
 381                                 (point)
 382                                 (progn (insert (org-no-properties text))
 383                                        (point)))
 384                                (end-of-line)
 385                                (insert "\n"))))))
 386     (when comment (funcall insert-comment comment))
 387     (when link-p
 388       (funcall
 389        insert-comment
 390        (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 391     (insert
 392      (org-unescape-code-in-string
 393       (if org-src-preserve-indentation (org-trim body t)
 394         (org-trim (org-remove-indentation body))))
 395      "\n")
 396     (when link-p
 397       (funcall
 398        insert-comment
 399        (org-fill-template org-babel-tangle-comment-format-end link-data)))))
 400
 401 (defun org-babel-tangle-collect-blocks (&optional language tangle-file)
 402   "Collect source blocks in the current Org file.
 403 Return an association list of source-code block specifications of
 404 the form used by `org-babel-spec-to-string' grouped by language.
 405 Optional argument LANGUAGE can be used to limit the collected
 406 source code blocks by language.  Optional argument TANGLE-FILE
 407 can be used to limit the collected code blocks by target file."
 408   (let ((counter 0) last-heading-pos blocks)
 409     (org-babel-map-src-blocks (buffer-file-name)
 410       (let ((current-heading-pos
 411              (org-with-wide-buffer
 412               (org-with-limited-levels (outline-previous-heading)))))
 413         (if (eq last-heading-pos current-heading-pos) (incf counter)
 414           (setq counter 1)
 415           (setq last-heading-pos current-heading-pos)))
 416       (unless (org-in-commented-heading-p)
 417         (let* ((info (org-babel-get-src-block-info 'light))
 418                (src-lang (nth 0 info))
 419                (src-tfile (cdr (assq :tangle (nth 2 info)))))
 420           (unless (or (string= src-tfile "no")
 421                       (and tangle-file (not (equal tangle-file src-tfile)))
 422                       (and language (not (string= language src-lang))))
 423             ;; Add the spec for this block to blocks under its
 424             ;; language.
 425             (let ((by-lang (assoc src-lang blocks))
 426                   (block (org-babel-tangle-single-block counter)))
 427               (if by-lang (setcdr by-lang (cons block (cdr by-lang)))
 428                 (push (cons src-lang (list block)) blocks)))))))
 429     ;; Ensure blocks are in the correct order.
 430     (mapcar (lambda (b) (cons (car b) (nreverse (cdr b)))) blocks)))
 431
 432 (defun org-babel-tangle-single-block
 433   (block-counter &optional only-this-block)
 434   "Collect the tangled source for current block.
 435 Return the list of block attributes needed by
 436 `org-babel-tangle-collect-blocks'.
 437 When ONLY-THIS-BLOCK is non-nil, return the full association
 438 list to be used by `org-babel-tangle' directly."
 439   (let* ((info (org-babel-get-src-block-info))
 440          (start-line
 441           (save-restriction (widen)
 442                             (+ 1 (line-number-at-pos (point)))))
 443          (file (buffer-file-name (buffer-base-buffer)))
 444          (src-lang (nth 0 info))
 445          (params (nth 2 info))
 446          (extra (nth 3 info))
 447          (cref-fmt (or (and (string-match "-l \"\\(.+\\)\"" extra)
 448                             (match-string 1 extra))
 449                        org-coderef-label-format))
 450          (link (let ((link (org-no-properties
 451                             (org-store-link nil))))
 452                  (and (string-match org-bracket-link-regexp link)
 453                       (match-string 1 link))))
 454          (source-name
 455           (or (nth 4 info)
 456               (format "%s:%d"
 457                       (or (ignore-errors (nth 4 (org-heading-components)))
 458                           "No heading")
 459                       block-counter)))
 460          (expand-cmd
 461           (intern (concat "org-babel-expand-body:" src-lang)))
 462          (assignments-cmd
 463           (intern (concat "org-babel-variable-assignments:" src-lang)))
 464          (body
 465           ;; Run the tangle-body-hook.
 466           (let* ((body ;; Expand the body in language specific manner.
 467                   (if (org-babel-noweb-p params :tangle)
 468                       (org-babel-expand-noweb-references info)
 469                     (nth 1 info)))
 470                  (body
 471                   (if (assoc :no-expand params)
 472                       body
 473                     (if (fboundp expand-cmd)
 474                         (funcall expand-cmd body params)
 475                       (org-babel-expand-body:generic
 476                        body params
 477                        (and (fboundp assignments-cmd)
 478                             (funcall assignments-cmd params)))))))
 479             (with-temp-buffer
 480               (insert body)
 481               (when (string-match "-r" extra)
 482                 (goto-char (point-min))
 483                 (while (re-search-forward
 484                         (replace-regexp-in-string "%s" ".+" cref-fmt) nil t)
 485                   (replace-match "")))
 486               (run-hooks 'org-babel-tangle-body-hook)
 487               (buffer-string))))
 488          (comment
 489           (when (or (string= "both" (cdr (assoc :comments params)))
 490                     (string= "org" (cdr (assoc :comments params))))
 491             ;; From the previous heading or code-block end
 492             (funcall
 493              org-babel-process-comment-text
 494              (buffer-substring
 495               (max (condition-case nil
 496                        (save-excursion
 497                          (org-back-to-heading t)  ; Sets match data
 498                          (match-end 0))
 499                      (error (point-min)))
 500                    (save-excursion
 501                      (if (re-search-backward
 502                           org-babel-src-block-regexp nil t)
 503                          (match-end 0)
 504                        (point-min))))
 505               (point)))))
 506          (result
 507           (list start-line file link source-name params body comment)))
 508     (if only-this-block
 509         (list (cons src-lang (list result)))
 510       result)))
 511
 512 (defun org-babel-tangle-comment-links (&optional info)
 513   "Return a list of begin and end link comments for the code block at point."
 514   (let ((link-data
 515          `(("start-line" . ,(number-to-string
 516                              (org-babel-where-is-src-block-head)))
 517            ("file" . ,(buffer-file-name))
 518            ("link" . ,(org-link-escape
 519                        (progn
 520                          (call-interactively #'org-store-link)
 521                          (org-no-properties (car (pop org-stored-links))))))
 522            ("source-name" .
 523             ,(nth 4 (or info (org-babel-get-src-block-info 'light)))))))
 524     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 525           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 526
 527 ;; de-tangling functions
 528 (defvar org-bracket-link-analytic-regexp)
 529 (defun org-babel-detangle (&optional source-code-file)
 530   "Propagate changes in source file back original to Org-mode file.
 531 This requires that code blocks were tangled with link comments
 532 which enable the original code blocks to be found."
 533   (interactive)
 534   (save-excursion
 535     (when source-code-file (find-file source-code-file))
 536     (goto-char (point-min))
 537     (let ((counter 0) new-body end)
 538       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 539         (when (re-search-forward
 540                (concat " " (regexp-quote (match-string 5)) " ends here"))
 541           (setq end (match-end 0))
 542           (forward-line -1)
 543           (save-excursion
 544             (when (setq new-body (org-babel-tangle-jump-to-org))
 545               (org-babel-update-block-body new-body)))
 546           (setq counter (+ 1 counter)))
 547         (goto-char end))
 548       (prog1 counter (message "Detangled %d code blocks" counter)))))
 549
 550 (defun org-babel-tangle-jump-to-org ()
 551   "Jump from a tangled code file to the related Org mode file."
 552   (interactive)
 553   (let ((mid (point))
 554         start body-start end
 555         target-buffer target-char link path block-name body)
 556     (save-window-excursion
 557       (save-excursion
 558         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 559                     (not ; ever wider searches until matching block comments
 560                      (and (setq start (line-beginning-position))
 561                           (setq body-start (line-beginning-position 2))
 562                           (setq link (match-string 0))
 563                           (setq path (match-string 3))
 564                           (setq block-name (match-string 5))
 565                           (save-excursion
 566                             (save-match-data
 567                               (re-search-forward
 568                                (concat " " (regexp-quote block-name)
 569                                        " ends here") nil t)
 570                               (setq end (line-beginning-position))))))))
 571         (unless (and start (< start mid) (< mid end))
 572           (error "Not in tangled code"))
 573         (setq body (buffer-substring body-start end)))
 574       (when (string-match "::" path)
 575         (setq path (substring path 0 (match-beginning 0))))
 576       (find-file path)
 577       (setq target-buffer (current-buffer))
 578       ;; Go to the beginning of the relative block in Org file.
 579       (org-open-link-from-string link)
 580       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 581           (let ((n (string-to-number (match-string 1 block-name))))
 582             (if (org-before-first-heading-p) (goto-char (point-min))
 583               (org-back-to-heading t))
 584             ;; Do not skip the first block if it begins at point min.
 585             (cond ((or (org-at-heading-p)
 586                        (not (eq (org-element-type (org-element-at-point))
 587                                 'src-block)))
 588                    (org-babel-next-src-block n))
 589                   ((= n 1))
 590                   (t (org-babel-next-src-block (1- n)))))
 591         (org-babel-goto-named-src-block block-name))
 592       (goto-char (org-babel-where-is-src-block-head))
 593       ;; Preserve location of point within the source code in tangled
 594       ;; code file.
 595       (forward-line 1)
 596       (forward-char (- mid body-start))
 597       (setq target-char (point)))
 598     (org-src-switch-to-buffer target-buffer t)
 599     (goto-char target-char)
 600     body))
 601
 602 (provide 'ob-tangle)
 603
 604 ;; Local variables:
 605 ;; generated-autoload-file: "org-loaddefs.el"
 606 ;; End:
 607
 608 ;;; ob-tangle.el ends here