lisp/ob-octave.el

   1 ;;; ob-octave.el --- Babel Functions for Octave and Matlab -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2010-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Requirements:
  27
  28 ;; octave
  29 ;; octave-mode.el and octave-inf.el come with GNU emacs
  30
  31 ;;; Code:
  32 (require 'ob)
  33 (eval-when-compile (require 'cl))
  34
  35 (declare-function matlab-shell "ext:matlab-mode")
  36 (declare-function matlab-shell-run-region "ext:matlab-mode")
  37 (declare-function org-trim "org" (s &optional keep-lead))
  38
  39 (defvar org-babel-default-header-args:matlab '())
  40 (defvar org-babel-default-header-args:octave '())
  41
  42 (defvar org-babel-matlab-shell-command "matlab -nosplash"
  43   "Shell command to run matlab as an external process.")
  44 (defvar org-babel-octave-shell-command "octave -q"
  45   "Shell command to run octave as an external process.")
  46
  47 (defvar org-babel-matlab-with-emacs-link nil
  48   "If non-nil use matlab-shell-run-region for session evaluation.
  49   This will use EmacsLink if (matlab-with-emacs-link) evaluates
  50   to a non-nil value.")
  51
  52 (defvar org-babel-matlab-emacs-link-wrapper-method
  53   "%s
  54 if ischar(ans), fid = fopen('%s', 'w'); fprintf(fid, '%%s\\n', ans); fclose(fid);
  55 else, save -ascii %s ans
  56 end
  57 delete('%s')
  58 ")
  59 (defvar org-babel-octave-wrapper-method
  60   "%s
  61 if ischar(ans), fid = fopen('%s', 'w'); fprintf(fid, '%%s\\n', ans); fclose(fid);
  62 else, dlmwrite('%s', ans, '\\t')
  63 end")
  64
  65 (defvar org-babel-octave-eoe-indicator "'org_babel_eoe'")
  66
  67 (defvar org-babel-octave-eoe-output "ans = org_babel_eoe")
  68
  69 (defun org-babel-execute:matlab (body params)
  70   "Execute a block of matlab code with Babel."
  71   (org-babel-execute:octave body params 'matlab))
  72
  73 (defun org-babel-execute:octave (body params &optional matlabp)
  74   "Execute a block of octave code with Babel."
  75   (let* ((session
  76           (funcall (intern (format "org-babel-%s-initiate-session"
  77                                    (if matlabp "matlab" "octave")))
  78                    (cdr (assoc :session params)) params))
  79          (result-type (cdr (assoc :result-type params)))
  80          (full-body
  81           (org-babel-expand-body:generic
  82            body params (org-babel-variable-assignments:octave params)))
  83          (gfx-file (ignore-errors (org-babel-graphical-output-file params)))
  84          (result (org-babel-octave-evaluate
  85                   session
  86                   (if gfx-file
  87                       (mapconcat 'identity
  88                                  (list
  89                                   "set (0, \"defaultfigurevisible\", \"off\");"
  90                                   full-body
  91                                   (format "print -dpng %s" gfx-file))
  92                                  "\n")
  93                     full-body)
  94                   result-type matlabp)))
  95     (if gfx-file
  96         nil
  97       (org-babel-reassemble-table
  98        result
  99        (org-babel-pick-name
 100         (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
 101        (org-babel-pick-name
 102         (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params)))))))
 103
 104 (defun org-babel-prep-session:matlab (session params)
 105   "Prepare SESSION according to PARAMS."
 106   (org-babel-prep-session:octave session params 'matlab))
 107
 108 (defun org-babel-variable-assignments:octave (params)
 109   "Return list of octave statements assigning the block's variables."
 110   (mapcar
 111    (lambda (pair)
 112      (format "%s=%s;"
 113              (car pair)
 114              (org-babel-octave-var-to-octave (cdr pair))))
 115    (org-babel--get-vars params)))
 116
 117 (defalias 'org-babel-variable-assignments:matlab
 118   'org-babel-variable-assignments:octave)
 119
 120 (defun org-babel-octave-var-to-octave (var)
 121   "Convert an emacs-lisp value into an octave variable.
 122 Converts an emacs-lisp variable into a string of octave code
 123 specifying a variable of the same value."
 124   (if (listp var)
 125       (concat "[" (mapconcat #'org-babel-octave-var-to-octave var
 126                              (if (listp (car var)) "; " ",")) "]")
 127     (cond
 128      ((stringp var)
 129       (format "'%s'" var))
 130      (t
 131       (format "%s" var)))))
 132
 133 (defun org-babel-prep-session:octave (session params &optional matlabp)
 134   "Prepare SESSION according to the header arguments specified in PARAMS."
 135   (let* ((session (org-babel-octave-initiate-session session params matlabp))
 136          (var-lines (org-babel-variable-assignments:octave params)))
 137     (org-babel-comint-in-buffer session
 138       (mapc (lambda (var)
 139               (end-of-line 1) (insert var) (comint-send-input nil t)
 140               (org-babel-comint-wait-for-output session)) var-lines))
 141     session))
 142
 143 (defun org-babel-matlab-initiate-session (&optional session params)
 144   "Create a matlab inferior process buffer.
 145 If there is not a current inferior-process-buffer in SESSION then
 146 create.  Return the initialized session."
 147   (org-babel-octave-initiate-session session params 'matlab))
 148
 149 (defun org-babel-octave-initiate-session (&optional session _params matlabp)
 150   "Create an octave inferior process buffer.
 151 If there is not a current inferior-process-buffer in SESSION then
 152 create.  Return the initialized session."
 153   (if matlabp (require 'matlab) (or (require 'octave-inf nil 'noerror)
 154                                     (require 'octave)))
 155   (unless (string= session "none")
 156     (let ((session (or session
 157                        (if matlabp "*Inferior Matlab*" "*Inferior Octave*"))))
 158       (if (org-babel-comint-buffer-livep session) session
 159         (save-window-excursion
 160           (if matlabp (unless org-babel-matlab-with-emacs-link (matlab-shell))
 161             (run-octave))
 162           (rename-buffer (if (bufferp session) (buffer-name session)
 163                            (if (stringp session) session (buffer-name))))
 164           (current-buffer))))))
 165
 166 (defun org-babel-octave-evaluate
 167   (session body result-type &optional matlabp)
 168   "Pass BODY to the octave process in SESSION.
 169 If RESULT-TYPE equals `output' then return the outputs of the
 170 statements in BODY, if RESULT-TYPE equals `value' then return the
 171 value of the last statement in BODY, as elisp."
 172   (if session
 173       (org-babel-octave-evaluate-session session body result-type matlabp)
 174     (org-babel-octave-evaluate-external-process body result-type matlabp)))
 175
 176 (defun org-babel-octave-evaluate-external-process (body result-type matlabp)
 177   "Evaluate BODY in an external octave process."
 178   (let ((cmd (if matlabp
 179                  org-babel-matlab-shell-command
 180                org-babel-octave-shell-command)))
 181     (case result-type
 182       (output (org-babel-eval cmd body))
 183       (value (let ((tmp-file (org-babel-temp-file "octave-")))
 184                (org-babel-eval
 185                 cmd
 186                 (format org-babel-octave-wrapper-method body
 187                         (org-babel-process-file-name tmp-file 'noquote)
 188                         (org-babel-process-file-name tmp-file 'noquote)))
 189                (org-babel-octave-import-elisp-from-file tmp-file))))))
 190
 191 (defun org-babel-octave-evaluate-session
 192   (session body result-type &optional matlabp)
 193   "Evaluate BODY in SESSION."
 194   (let* ((tmp-file (org-babel-temp-file (if matlabp "matlab-" "octave-")))
 195          (wait-file (org-babel-temp-file "matlab-emacs-link-wait-signal-"))
 196          (full-body
 197           (case result-type
 198             (output
 199              (mapconcat
 200               #'org-babel-chomp
 201               (list body org-babel-octave-eoe-indicator) "\n"))
 202             (value
 203              (if (and matlabp org-babel-matlab-with-emacs-link)
 204                  (concat
 205                   (format org-babel-matlab-emacs-link-wrapper-method
 206                           body
 207                           (org-babel-process-file-name tmp-file 'noquote)
 208                           (org-babel-process-file-name tmp-file 'noquote) wait-file) "\n")
 209                (mapconcat
 210                 #'org-babel-chomp
 211                 (list (format org-babel-octave-wrapper-method
 212                               body
 213                               (org-babel-process-file-name tmp-file 'noquote)
 214                               (org-babel-process-file-name tmp-file 'noquote))
 215                       org-babel-octave-eoe-indicator) "\n")))))
 216          (raw (if (and matlabp org-babel-matlab-with-emacs-link)
 217                   (save-window-excursion
 218                     (with-temp-buffer
 219                       (insert full-body)
 220                       (write-region "" 'ignored wait-file nil nil nil 'excl)
 221                       (matlab-shell-run-region (point-min) (point-max))
 222                       (message "Waiting for Matlab Emacs Link")
 223                       (while (file-exists-p wait-file) (sit-for 0.01))
 224                       "")) ;; matlab-shell-run-region doesn't seem to
 225                 ;; make *matlab* buffer contents easily
 226                 ;; available, so :results output currently
 227                 ;; won't work
 228                 (org-babel-comint-with-output
 229                     (session
 230                      (if matlabp
 231                          org-babel-octave-eoe-indicator
 232                        org-babel-octave-eoe-output)
 233                      t full-body)
 234                   (insert full-body) (comint-send-input nil t)))) results)
 235     (case result-type
 236       (value
 237        (org-babel-octave-import-elisp-from-file tmp-file))
 238       (output
 239        (progn
 240          (setq results
 241                (if matlabp
 242                    (cdr (reverse (delq "" (mapcar
 243                                            #'org-babel-octave-read-string
 244                                            (mapcar #'org-trim raw)))))
 245                  (cdr (member org-babel-octave-eoe-output
 246                               (reverse (mapcar
 247                                         #'org-babel-octave-read-string
 248                                         (mapcar #'org-trim raw)))))))
 249          (mapconcat #'identity (reverse results) "\n"))))))
 250
 251 (defun org-babel-octave-import-elisp-from-file (file-name)
 252   "Import data from FILE-NAME.
 253 This removes initial blank and comment lines and then calls
 254 `org-babel-import-elisp-from-file'."
 255   (let ((temp-file (org-babel-temp-file "octave-matlab-")) beg end)
 256     (with-temp-file temp-file
 257       (insert-file-contents file-name)
 258       (re-search-forward "^[ \t]*[^# \t]" nil t)
 259       (if (< (setq beg (point-min))
 260              (setq end (point-at-bol)))
 261           (delete-region beg end)))
 262     (org-babel-import-elisp-from-file temp-file '(16))))
 263
 264 (defun org-babel-octave-read-string (string)
 265   "Strip \\\"s from around octave string."
 266   (if (string-match "^\"\\([^\000]+\\)\"$" string)
 267       (match-string 1 string)
 268     string))
 269
 270 (provide 'ob-octave)
 271
 272
 273
 274 ;;; ob-octave.el ends here