lisp/ob-python.el

   1 ;;; ob-python.el --- org-babel functions for python evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.3
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'ob-ref)
  32 (require 'ob-comint)
  33 (require 'ob-eval)
  34 (eval-when-compile (require 'cl))
  35
  36 (declare-function org-remove-indentation "org" )
  37 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  38 (declare-function run-python "ext:python" (&optional cmd noshow new))
  39
  40 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  41
  42 (defvar org-babel-default-header-args:python '())
  43
  44 (defvar org-babel-python-command "python"
  45   "Name of command for executing python code.")
  46
  47 (defvar org-babel-python-mode (if (featurep 'xemacs) 'python-mode 'python)
  48   "Preferred python mode for use in running python interactively.")
  49
  50 (defvar org-src-preserve-indentation)
  51
  52 (defun org-babel-execute:python (body params)
  53   "Execute a block of Python code with Babel.
  54 This function is called by `org-babel-execute-src-block'."
  55   (let* ((session (org-babel-python-initiate-session
  56                    (cdr (assoc :session params))))
  57          (result-params (cdr (assoc :result-params params)))
  58          (result-type (cdr (assoc :result-type params)))
  59          (full-body
  60           (org-babel-expand-body:generic
  61            body params (org-babel-variable-assignments:python params)))
  62          (result (org-babel-python-evaluate
  63                   session full-body result-type result-params)))
  64     (or (cdr (assoc :file params))
  65         (org-babel-reassemble-table
  66          result
  67          (org-babel-pick-name (cdr (assoc :colname-names params))
  68                               (cdr (assoc :colnames params)))
  69          (org-babel-pick-name (cdr (assoc :rowname-names params))
  70                               (cdr (assoc :rownames params)))))))
  71
  72 (defun org-babel-prep-session:python (session params)
  73   "Prepare SESSION according to the header arguments in PARAMS.
  74 VARS contains resolved variable references"
  75   (let* ((session (org-babel-python-initiate-session session))
  76          (var-lines
  77           (org-babel-variable-assignments:python params)))
  78     (org-babel-comint-in-buffer session
  79       (mapc (lambda (var)
  80               (end-of-line 1) (insert var) (comint-send-input)
  81               (org-babel-comint-wait-for-output session)) var-lines))
  82     session))
  83
  84 (defun org-babel-load-session:python (session body params)
  85   "Load BODY into SESSION."
  86   (save-window-excursion
  87     (let ((buffer (org-babel-prep-session:python session params)))
  88       (with-current-buffer buffer
  89         (goto-char (process-mark (get-buffer-process (current-buffer))))
  90         (insert (org-babel-chomp body)))
  91       buffer)))
  92
  93 ;; helper functions
  94
  95 (defun org-babel-variable-assignments:python (params)
  96   "Return list of python statements assigning the block's variables"
  97   (mapcar
  98    (lambda (pair)
  99      (format "%s=%s"
 100              (car pair)
 101              (org-babel-python-var-to-python (cdr pair))))
 102    (mapcar #'cdr (org-babel-get-header params :var))))
 103
 104 (defun org-babel-python-var-to-python (var)
 105   "Convert an elisp value to a python variable.
 106 Convert an elisp value, VAR, into a string of python source code
 107 specifying a variable of the same value."
 108   (if (listp var)
 109       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 110     (if (equal var 'hline)
 111         "None"
 112       (format
 113        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 114        var))))
 115
 116 (defun org-babel-python-table-or-string (results)
 117   "Convert RESULTS into an appropriate elisp value.
 118 If the results look like a list or tuple, then convert them into an
 119 Emacs-lisp table, otherwise return the results as a string."
 120   ((lambda (res)
 121      (if (listp res)
 122          (mapcar (lambda (el) (if (equal el 'None) 'hline el)) res)
 123        res))
 124    (org-babel-read
 125     (if (and (stringp results) (string-match "^[([].+[])]$" results))
 126        (org-babel-read
 127         (concat "'"
 128                 (replace-regexp-in-string
 129                  "\\[" "(" (replace-regexp-in-string
 130                             "\\]" ")" (replace-regexp-in-string
 131                                        ", " " " (replace-regexp-in-string
 132                                                  "'" "\"" results t))))))
 133      results))))
 134
 135 (defvar org-babel-python-buffers '((:default . nil)))
 136
 137 (defun org-babel-python-session-buffer (session)
 138   "Return the buffer associated with SESSION."
 139   (cdr (assoc session org-babel-python-buffers)))
 140
 141 (defun org-babel-python-initiate-session-by-key (&optional session)
 142   "Initiate a python session.
 143 If there is not a current inferior-process-buffer in SESSION
 144 then create.  Return the initialized session."
 145   (require org-babel-python-mode)
 146   (save-window-excursion
 147     (let* ((session (if session (intern session) :default))
 148            (python-buffer (org-babel-python-session-buffer session)))
 149       (cond
 150        ((and (eq 'python org-babel-python-mode)
 151              (fboundp 'run-python)) ; python.el
 152         (run-python))
 153        ((and (eq 'python-mode org-babel-python-mode)
 154              (fboundp 'py-shell)) ; python-mode.el
 155         ;; `py-shell' creates a buffer whose name is the value of
 156         ;; `py-which-bufname' with '*'s at the beginning and end
 157         (let* ((bufname (if python-buffer
 158                             (replace-regexp-in-string ;; zap surrounding *
 159                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 160                           (concat "Python-" (symbol-name session))))
 161                (py-which-bufname bufname))
 162           (py-shell)
 163           (setq python-buffer (concat "*" bufname "*"))))
 164        (t
 165         (error "No function available for running an inferior python.")))
 166       (setq org-babel-python-buffers
 167             (cons (cons session python-buffer)
 168                   (assq-delete-all session org-babel-python-buffers)))
 169       session)))
 170
 171 (defun org-babel-python-initiate-session (&optional session params)
 172   "Create a session named SESSION according to PARAMS."
 173   (unless (string= session "none")
 174     (org-babel-python-session-buffer
 175      (org-babel-python-initiate-session-by-key session))))
 176
 177 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 178   "A string to indicate that evaluation has completed.")
 179 (defvar org-babel-python-wrapper-method
 180   "
 181 def main():
 182 %s
 183
 184 open('%s', 'w').write( str(main()) )")
 185 (defvar org-babel-python-pp-wrapper-method
 186   "
 187 import pprint
 188 def main():
 189 %s
 190
 191 open('%s', 'w').write( pprint.pformat(main()) )")
 192
 193 (defun org-babel-python-evaluate
 194   (session body &optional result-type result-params)
 195   "Evaluate BODY as python code."
 196   (if session
 197       (org-babel-python-evaluate-session
 198        session body result-type result-params)
 199     (org-babel-python-evaluate-external-process
 200      body result-type result-params)))
 201
 202 (defun org-babel-python-evaluate-external-process
 203   (body &optional result-type result-params)
 204   "Evaluate BODY in external python process.
 205 If RESULT-TYPE equals 'output then return standard output as a
 206 string. If RESULT-TYPE equals 'value then return the value of the
 207 last statement in BODY, as elisp."
 208   (case result-type
 209     (output (org-babel-eval org-babel-python-command body))
 210     (value (let ((tmp-file (org-babel-temp-file "python-")))
 211              (org-babel-eval org-babel-python-command
 212                              (format
 213                               (if (member "pp" result-params)
 214                                   org-babel-python-pp-wrapper-method
 215                                 org-babel-python-wrapper-method)
 216                               (mapconcat
 217                                (lambda (line) (format "\t%s" line))
 218                                (split-string
 219                                 (org-remove-indentation
 220                                  (org-babel-trim body))
 221                                 "[\r\n]") "\n")
 222                               (org-babel-process-file-name tmp-file 'noquote)))
 223              ((lambda (raw)
 224                 (if (or (member "code" result-params)
 225                         (member "pp" result-params))
 226                     raw
 227                   (org-babel-python-table-or-string raw)))
 228               (org-babel-eval-read-file tmp-file))))))
 229
 230 (defun org-babel-python-evaluate-session
 231   (session body &optional result-type result-params)
 232   "Pass BODY to the Python process in SESSION.
 233 If RESULT-TYPE equals 'output then return standard output as a
 234 string. If RESULT-TYPE equals 'value then return the value of the
 235 last statement in BODY, as elisp."
 236   (flet ((dump-last-value
 237           (tmp-file pp)
 238           (mapc
 239            (lambda (statement) (insert statement) (comint-send-input))
 240            (if pp
 241                (list
 242                 "import pp"
 243                 (format "open('%s', 'w').write(pprint.pformat(_))"
 244                         (org-babel-process-file-name tmp-file 'noquote)))
 245              (list (format "open('%s', 'w').write(str(_))"
 246                            (org-babel-process-file-name tmp-file 'noquote))))))
 247          (input-body (body)
 248                      (mapc (lambda (statement) (insert statement) (comint-send-input))
 249                            (split-string (org-babel-trim body) "[\r\n]+"))
 250                      (comint-send-input) (comint-send-input)))
 251     (case result-type
 252       (output
 253        (mapconcat
 254         #'org-babel-trim
 255         (butlast
 256          (org-babel-comint-with-output
 257              (session org-babel-python-eoe-indicator t body)
 258            (let ((comint-process-echoes nil))
 259              (input-body body)
 260              (insert org-babel-python-eoe-indicator)
 261              (comint-send-input))) 2) "\n"))
 262       (value
 263        ((lambda (results)
 264           (if (or (member "code" result-params) (member "pp" result-params))
 265               results
 266             (org-babel-python-table-or-string results)))
 267         (let ((tmp-file (org-babel-temp-file "python-")))
 268           (org-babel-comint-with-output
 269               (session org-babel-python-eoe-indicator t body)
 270             (let ((comint-process-echoes nil))
 271               (input-body body)
 272               (dump-last-value tmp-file (member "pp" result-params))
 273               (comint-send-input) (comint-send-input)
 274               (insert org-babel-python-eoe-indicator)
 275               (comint-send-input)))
 276           (org-babel-eval-read-file tmp-file)))))))
 277
 278 (defun org-babel-python-read-string (string)
 279   "Strip 's from around python string"
 280   (if (string-match "^'\\([^\000]+\\)'$" string)
 281       (match-string 1 string)
 282     string))
 283
 284 (provide 'ob-python)
 285
 286 ;; arch-tag: f19b6c3d-dfcb-4a1a-9ce0-45ade1ebc212
 287
 288 ;;; ob-python.el ends here