lisp/ob-lob.el

   1 ;;; ob-lob.el --- functions supporting the Library of Babel
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.3
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; See the online documentation for more information
  28 ;;
  29 ;;   http://orgmode.org/worg/org-contrib/babel/
  30
  31 ;;; Code:
  32 (require 'ob)
  33 (require 'ob-table)
  34
  35 (defvar org-babel-library-of-babel nil
  36   "Library of source-code blocks.
  37 This is an association list.  Populate the library by adding
  38 files to `org-babel-lob-files'.")
  39
  40 (defcustom org-babel-lob-files '()
  41   "Files used to populate the `org-babel-library-of-babel'.
  42 To add files to this list use the `org-babel-lob-ingest' command."
  43   :group 'org-babel
  44   :type 'list)
  45
  46 ;;;###autoload
  47 (defun org-babel-lob-ingest (&optional file)
  48   "Add all named source-blocks defined in FILE to
  49 `org-babel-library-of-babel'."
  50   (interactive "f")
  51   (let ((lob-ingest-count 0))
  52     (org-babel-map-src-blocks file
  53       (let* ((info (org-babel-get-src-block-info 'light))
  54              (source-name (nth 4 info)))
  55         (when source-name
  56           (setq source-name (intern source-name)
  57                 org-babel-library-of-babel
  58                 (cons (cons source-name info)
  59                       (assq-delete-all source-name org-babel-library-of-babel))
  60                 lob-ingest-count (1+ lob-ingest-count)))))
  61     (message "%d src block%s added to Library of Babel"
  62              lob-ingest-count (if (> lob-ingest-count 1) "s" ""))
  63     lob-ingest-count))
  64
  65 (defconst org-babel-lob-call-aliases '("lob" "call")
  66   "Aliases to call a source block function.
  67 If you change the value of this variable then your files may
  68   become unusable by other org-babel users, and vice versa.")
  69
  70 (defconst org-babel-lob-one-liner-regexp
  71   (concat
  72    "^\\([ \t]*\\)#\\+\\(?:"
  73    (mapconcat #'regexp-quote org-babel-lob-call-aliases "\\|")
  74    "\\):[ \t]+\\([^\(\)\n]+\\)\(\\([^\n]*\\)\)\\(\\[.+\\]\\|\\)[ \t]*\\([^\n]*\\)")
  75   "Regexp to match calls to predefined source block functions.")
  76
  77 ;; functions for executing lob one-liners
  78 ;;;###autoload
  79 (defun org-babel-lob-execute-maybe ()
  80   "Execute a Library of Babel source block, if appropriate.
  81 Detect if this is context for a Library Of Babel source block and
  82 if so then run the appropriate source block from the Library."
  83   (interactive)
  84   (let ((info (org-babel-lob-get-info)))
  85     (if (nth 0 info) (progn (org-babel-lob-execute info) t) nil)))
  86
  87 ;;;###autoload
  88 (defun org-babel-lob-get-info ()
  89   "Return a Library of Babel function call as a string."
  90   (let ((case-fold-search t))
  91     (save-excursion
  92       (beginning-of-line 1)
  93       (if (looking-at org-babel-lob-one-liner-regexp)
  94           (append
  95            (mapcar #'org-babel-clean-text-properties
  96                    (list
  97                     (format "%s(%s)%s"
  98                             (match-string 2) (match-string 3) (match-string 4))
  99                     (match-string 5)))
 100            (list (length (match-string 1))))))))
 101
 102 (defun org-babel-lob-execute (info)
 103   "Execute the lob call specified by INFO."
 104   (let ((params (org-babel-process-params
 105                  (org-babel-merge-params
 106                   org-babel-default-header-args
 107                   (org-babel-params-from-buffer)
 108                   (org-babel-params-from-properties)
 109                   (org-babel-parse-header-arguments
 110                    (org-babel-clean-text-properties
 111                     (concat ":var results="
 112                             (mapconcat #'identity (butlast info) " "))))))))
 113     (org-babel-execute-src-block
 114      nil (list "emacs-lisp" "results" params nil nil (nth 2 info)))))
 115
 116 (provide 'ob-lob)
 117
 118 ;; arch-tag: ce0712c9-2147-4019-ba3f-42341b8b474b
 119
 120 ;;; ob-lob.el ends here