lisp/ob-exp.el

   1 ;;; ob-exp.el --- Exportation of org-babel source blocks
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.3
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; See the online documentation for more information
  28 ;;
  29 ;;   http://orgmode.org/worg/org-contrib/babel/
  30
  31 ;;; Code:
  32 (require 'ob)
  33 (require 'org-exp-blocks)
  34 (eval-when-compile
  35   (require 'cl))
  36
  37 (defvar obe-marker nil)
  38 (defvar org-current-export-file)
  39 (defvar org-babel-lob-one-liner-regexp)
  40 (defvar org-babel-ref-split-regexp)
  41 (declare-function org-babel-lob-get-info "ob-lob" ())
  42 (declare-function org-babel-ref-literal "ob-ref" (ref))
  43
  44 (add-to-list 'org-export-interblocks '(src org-babel-exp-inline-src-blocks))
  45 (add-to-list 'org-export-interblocks '(lob org-babel-exp-lob-one-liners))
  46 (add-hook 'org-export-blocks-postblock-hook 'org-exp-res/src-name-cleanup)
  47
  48 (org-export-blocks-add-block '(src org-babel-exp-src-blocks nil))
  49
  50 (defcustom org-export-babel-evaluate t
  51   "Switch controlling code evaluation during export.
  52 When set to nil no code will be evaluated as part of the export
  53 process."
  54   :group 'org-babel
  55   :type 'boolean)
  56 (put 'org-export-babel-evaluate 'safe-local-variable (lambda (x) (eq x nil)))
  57
  58 (defvar org-babel-function-def-export-keyword "function"
  59   "The keyword to substitute for the source name line on export.
  60 When exporting a source block function, this keyword will
  61 appear in the exported version in the place of source name
  62 line. A source block is considered to be a source block function
  63 if the source name is present and is followed by a parenthesized
  64 argument list. The parentheses may be empty or contain
  65 whitespace. An example is the following which generates n random
  66 \(uniform) numbers.
  67
  68 #+source: rand(n)
  69 #+begin_src R
  70   runif(n)
  71 #+end_src")
  72
  73 (defvar org-babel-function-def-export-indent 4
  74   "Number of characters to indent a source block on export.
  75 When exporting a source block function, the block contents will
  76 be indented by this many characters. See
  77 `org-babel-function-def-export-name' for the definition of a
  78 source block function.")
  79
  80 (defmacro org-babel-exp-in-export-file (&rest body)
  81   `(let* ((lang-headers (intern (concat "org-babel-default-header-args:" lang)))
  82           (heading (nth 4 (ignore-errors (org-heading-components))))
  83           (link (when org-current-export-file
  84                   (org-make-link-string
  85                    (if heading
  86                        (concat org-current-export-file "::" heading)
  87                      org-current-export-file))))
  88           (export-buffer (current-buffer)) results)
  89      (when link
  90        ;; resolve parameters in the original file so that
  91        ;; headline and file-wide parameters are included, attempt
  92        ;; to go to the same heading in the original file
  93        (set-buffer (get-file-buffer org-current-export-file))
  94        (save-restriction
  95          (condition-case nil
  96              (org-open-link-from-string link)
  97            (error (when heading
  98                     (goto-char (point-min))
  99                     (re-search-forward (regexp-quote heading) nil t))))
 100          (setq results ,@body))
 101        (set-buffer export-buffer)
 102        results)))
 103
 104 (defun org-babel-exp-src-blocks (body &rest headers)
 105   "Process source block for export.
 106 Depending on the 'export' headers argument in replace the source
 107 code block with...
 108
 109 both ---- display the code and the results
 110
 111 code ---- the default, display the code inside the block but do
 112           not process
 113
 114 results - just like none only the block is run on export ensuring
 115           that it's results are present in the org-mode buffer
 116
 117 none ----- do not display either code or results upon export"
 118   (interactive)
 119   (message "org-babel-exp processing...")
 120   (save-excursion
 121     (goto-char (match-beginning 0))
 122     (let* ((info (org-babel-get-src-block-info 'light))
 123            (lang (nth 0 info))
 124            (raw-params (nth 2 info)))
 125       ;; bail if we couldn't get any info from the block
 126       (when info
 127         (org-babel-exp-in-export-file
 128          (setf (nth 2 info)
 129                (org-babel-merge-params
 130                 org-babel-default-header-args
 131                 (org-babel-params-from-buffer)
 132                 (org-babel-params-from-properties lang)
 133                 (if (boundp lang-headers) (eval lang-headers) nil)
 134                 raw-params)))
 135         ;; expand noweb references in the original file
 136         (setf (nth 1 info)
 137               (if (and (cdr (assoc :noweb (nth 2 info)))
 138                        (string= "yes" (cdr (assoc :noweb (nth 2 info)))))
 139                   (org-babel-expand-noweb-references
 140                    info (get-file-buffer org-current-export-file))
 141                 (nth 1 info)))
 142         (org-babel-exp-do-export info 'block)))))
 143
 144 (defun org-babel-exp-inline-src-blocks (start end)
 145   "Process inline source blocks between START and END for export.
 146 See `org-babel-exp-src-blocks' for export options, currently the
 147 options and are taken from `org-babel-default-inline-header-args'."
 148   (interactive)
 149   (save-excursion
 150     (goto-char start)
 151     (while (and (< (point) end)
 152                 (re-search-forward org-babel-inline-src-block-regexp end t))
 153       (let* ((info (save-match-data (org-babel-parse-inline-src-block-match)))
 154              (params (nth 2 info))
 155              (replacement
 156               (save-match-data
 157                 (if (org-babel-in-example-or-verbatim)
 158                     (buffer-substring (match-beginning 0) (match-end 0))
 159                   ;; expand noweb references in the original file
 160                   (setf (nth 1 info)
 161                         (if (and (cdr (assoc :noweb params))
 162                                  (string= "yes" (cdr (assoc :noweb params))))
 163                             (org-babel-expand-noweb-references
 164                              info (get-file-buffer org-current-export-file))
 165                           (nth 1 info)))
 166                   (org-babel-exp-do-export info 'inline)))))
 167         (setq end (+ end (- (length replacement) (length (match-string 1)))))
 168         (replace-match replacement t t nil 1)))))
 169
 170 (defun org-exp-res/src-name-cleanup ()
 171   "Clean up #+results and #+srcname lines for export.
 172 This function should only be called after all block processing
 173 has taken place."
 174   (interactive)
 175   (save-excursion
 176     (goto-char (point-min))
 177     (while (org-re-search-forward-unprotected
 178             (concat
 179              "\\("org-babel-src-name-regexp"\\|"org-babel-result-regexp"\\)")
 180             nil t)
 181       (delete-region
 182        (progn (beginning-of-line) (point))
 183        (progn (end-of-line) (+ 1 (point)))))))
 184
 185 (defun org-babel-in-example-or-verbatim ()
 186   "Return true if point is in example or verbatim code.
 187 Example and verbatim code include escaped portions of
 188 an org-mode buffer code that should be treated as normal
 189 org-mode text."
 190   (or (org-in-indented-comment-line)
 191       (save-excursion
 192         (save-match-data
 193           (goto-char (point-at-bol))
 194           (looking-at "[ \t]*:[ \t]")))
 195       (org-in-regexps-block-p "^[ \t]*#\\+begin_src" "^[ \t]*#\\+end_src")))
 196
 197 (defun org-babel-exp-lob-one-liners (start end)
 198   "Process Library of Babel calls between START and END for export.
 199 See `org-babel-exp-src-blocks' for export options. Currently the
 200 options are taken from `org-babel-default-header-args'."
 201   (interactive)
 202   (let (replacement)
 203     (save-excursion
 204       (goto-char start)
 205       (while (and (< (point) end)
 206                   (re-search-forward org-babel-lob-one-liner-regexp nil t))
 207         (setq replacement
 208               (let ((lob-info (org-babel-lob-get-info)))
 209                 (save-match-data
 210                   (org-babel-exp-do-export
 211                    (list "emacs-lisp" "results"
 212                          (org-babel-merge-params
 213                           org-babel-default-header-args
 214                           (org-babel-params-from-buffer)
 215                           (org-babel-params-from-properties)
 216                           (org-babel-parse-header-arguments
 217                            (org-babel-clean-text-properties
 218                             (concat ":var results="
 219                                     (mapconcat #'identity
 220                                                (butlast lob-info) " ")))))
 221                          (car (last lob-info)))
 222                    'lob))))
 223         (setq end (+ end (- (length replacement) (length (match-string 0)))))
 224         (replace-match replacement t t)))))
 225
 226 (defun org-babel-exp-do-export (info type)
 227   "Return a string with the exported content of a code block.
 228 The function respects the value of the :exports header argument."
 229   (flet ((silently () (let ((session (cdr (assoc :session (nth 2 info)))))
 230                         (when (and session
 231                                    (not (equal "none" session)))
 232                           (org-babel-exp-results info type 'silent))))
 233          (clean () (org-babel-remove-result info)))
 234     (case (intern (or (cdr (assoc :exports (nth 2 info))) "code"))
 235       ('none (silently) (clean) "")
 236       ('code (silently) (clean) (org-babel-exp-code info type))
 237       ('results (org-babel-exp-results info type))
 238       ('both (concat (org-babel-exp-code info type)
 239                      "\n\n"
 240                      (org-babel-exp-results info type))))))
 241
 242 (defvar backend)
 243 (defun org-babel-exp-code (info type)
 244   "Prepare and return code in the current code block for export.
 245 Code is prepared in a manner suitable for export by
 246 org-mode.  This function is called by `org-babel-exp-do-export'.
 247 The code block is not evaluated."
 248   (let ((lang (nth 0 info))
 249         (body (nth 1 info))
 250         (switches (nth 3 info))
 251         (name (nth 4 info))
 252         (args (mapcar #'cdr (org-babel-get-header (nth 2 info) :var))))
 253     (case type
 254       ('inline (format "=%s=" body))
 255       ('block
 256           (let ((str
 257                  (format "#+BEGIN_SRC %s %s\n%s%s#+END_SRC\n" lang switches body
 258                          (if (and body (string-match "\n$" body))
 259                              "" "\n"))))
 260             (when name
 261               (add-text-properties
 262                0 (length str)
 263                (list 'org-caption
 264                      (format "%s(%s)"
 265                              name
 266                              (mapconcat #'identity args ", ")))
 267                str))
 268             str))
 269       ('lob
 270        (let ((call-line (and (string-match "results=" (car args))
 271                              (substring (car args) (match-end 0)))))
 272          (cond
 273           ((eq backend 'html)
 274            (format "\n#+HTML: <label class=\"org-src-name\">%s</label>\n"
 275                    call-line))
 276           ((format ": %s\n" call-line))))))))
 277
 278 (defun org-babel-exp-results (info type &optional silent)
 279   "Evaluate and return the results of the current code block for export.
 280 Results are prepared in a manner suitable for export by org-mode.
 281 This function is called by `org-babel-exp-do-export'.  The code
 282 block will be evaluated.  Optional argument SILENT can be used to
 283 inhibit insertion of results into the buffer."
 284   (or
 285    (when org-export-babel-evaluate
 286      (let ((lang (nth 0 info))
 287            (body (nth 1 info)))
 288        (setf (nth 2 info) (org-babel-exp-in-export-file
 289                            (org-babel-process-params (nth 2 info))))
 290        ;; skip code blocks which we can't evaluate
 291        (when (fboundp (intern (concat "org-babel-execute:" lang)))
 292          (if (equal type 'inline)
 293              (let ((raw (org-babel-execute-src-block
 294                          nil info '((:results . "silent"))))
 295                    (result-params (split-string
 296                                    (cdr (assoc :results (nth 2 info))))))
 297                (unless silent
 298                  (cond ;; respect the value of the :results header argument
 299                   ((member "file" result-params)
 300                    (org-babel-result-to-file raw))
 301                   ((or (member "raw" result-params)
 302                        (member "org" result-params))
 303                    (format "%s" raw))
 304                   ((member "code" result-params)
 305                    (format "src_%s{%s}" lang raw))
 306                   (t
 307                    (if (stringp raw)
 308                        (if (= 0 (length raw)) "=(no results)="
 309                          (format "%s" raw))
 310                      (format "%S" raw))))))
 311            (prog1 nil
 312              (setf (nth 2 info)
 313                    (org-babel-merge-params
 314                     (nth 2 info)
 315                     `((:results . ,(if silent "silent" "replace")))))
 316              (cond
 317               ((equal type 'block) (org-babel-execute-src-block nil info))
 318               ((equal type 'lob)
 319                (save-excursion
 320                  (re-search-backward org-babel-lob-one-liner-regexp nil t)
 321                  (org-babel-execute-src-block nil info)))))))))
 322    ""))
 323
 324 (provide 'ob-exp)
 325
 326 ;; arch-tag: 523abf4c-76d1-44ed-9f27-e3bddf34bf0f
 327
 328 ;;; ob-exp.el ends here