lisp/org-bbdb.el

   1 ;;; org-bbdb.el --- Support for links to BBDB entries from within Org-mode
   2
   3 ;; Copyright (C) 2004-2012  Free Software Foundation, Inc.
   4
   5 ;; Authors: Carsten Dominik <carsten at orgmode dot org>
   6 ;;       Thomas Baumann <thomas dot baumann at ch dot tum dot de>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements links to BBDB database entries from within Org-mode.
  29 ;; Org-mode loads this module by default - if this is not what you want,
  30 ;; configure the variable `org-modules'.
  31
  32 ;; It also implements an interface (based on Ivar Rummelhoff's
  33 ;; bbdb-anniv.el) for those org-mode users, who do not use the diary
  34 ;; but who do want to include the anniversaries stored in the BBDB
  35 ;; into the org-agenda.  If you already include the `diary' into the
  36 ;; agenda, you might want to prefer to include the anniversaries in
  37 ;; the diary using bbdb-anniv.el.
  38 ;;
  39 ;; Put the following in /somewhere/at/home/diary.org and make sure
  40 ;; that this file is in `org-agenda-files`
  41 ;;
  42 ;; %%(org-bbdb-anniversaries)
  43 ;;
  44 ;; For example my diary.org looks like:
  45 ;; * Anniversaries
  46 ;; #+CATEGORY: Anniv
  47 ;; %%(org-bbdb-anniversaries)
  48 ;;
  49 ;;
  50 ;; To add an anniversary to a BBDB record, press `C-o' in the record.
  51 ;; You will be prompted for the field name, in this case it must be
  52 ;; "anniversary".  If this is the first time you are using this field,
  53 ;; you need to confirm that it should be created.
  54 ;;
  55 ;; The format of an anniversary field stored in BBDB is the following
  56 ;; (items in {} are optional):
  57 ;;
  58 ;;     YYYY-MM-DD{ CLASS-OR-FORMAT-STRING}
  59 ;;     {\nYYYY-MM-DD CLASS-OR-FORMAT-STRING}...
  60 ;;
  61 ;; CLASS-OR-FORMAT-STRING is one of two things:
  62 ;;
  63 ;;  - an identifier for a class of anniversaries (eg. birthday or
  64 ;;    wedding) from `org-bbdb-anniversary-format-alist' which then
  65 ;;    defines the format string for this class
  66 ;;  - the (format) string displayed in the diary.
  67 ;;
  68 ;; You can enter multiple anniversaries for a single BBDB record by
  69 ;; separating them with a newline character.  At the BBDB prompt for
  70 ;; the field value, type `C-q C-j' to enter a newline between two
  71 ;; anniversaries.
  72 ;;
  73 ;; If you omit the CLASS-OR-FORMAT-STRING entirely, it defaults to the
  74 ;; value of `org-bbdb-default-anniversary-format' ("birthday" by
  75 ;; default).
  76 ;;
  77 ;; The substitutions in the format string are (in order):
  78 ;;  - the name of the record containing this anniversary
  79 ;;  - the number of years
  80 ;;  - an ordinal suffix (st, nd, rd, th) for the year
  81 ;;
  82 ;; See the documentation of `org-bbdb-anniversary-format-alist' for
  83 ;; further options.
  84 ;;
  85 ;; Example
  86 ;;
  87 ;;       1973-06-22
  88 ;;       20??-??-?? wedding
  89 ;;       1998-03-12 %s created bbdb-anniv.el %d years ago
  90 ;;
  91 ;; From Org's agenda, you can use `C-c C-o' to jump to the BBDB
  92 ;; link from which the entry at point originates.
  93 ;;
  94 ;;; Code:
  95
  96 (require 'org)
  97 (eval-when-compile
  98   (require 'cl))
  99
 100 ;; Declare external functions and variables
 101
 102 (declare-function bbdb "ext:bbdb-com" (string elidep))
 103 (declare-function bbdb-company "ext:bbdb-com" (string elidep))
 104 (declare-function bbdb-current-record "ext:bbdb-com"
 105                   (&optional planning-on-modifying))
 106 (declare-function bbdb-name "ext:bbdb-com" (string elidep))
 107 (declare-function bbdb-completing-read-record "ext:bbdb-com"
 108                   (prompt &optional omit-records))
 109 (declare-function bbdb-record-getprop "ext:bbdb" (record property))
 110 (declare-function bbdb-record-name "ext:bbdb" (record))
 111 (declare-function bbdb-records "ext:bbdb"
 112           (&optional dont-check-disk already-in-db-buffer))
 113 (declare-function bbdb-split "ext:bbdb" (string separators))
 114 (declare-function bbdb-string-trim "ext:bbdb" (string))
 115 (declare-function bbdb-record-get-field "ext:bbdb" (record field))
 116 (declare-function bbdb-search-name "ext:bbdb-com" (regexp &optional layout))
 117 (declare-function bbdb-search-organization "ext:bbdb-com" (regexp &optional layout))
 118
 119 ;; `bbdb-record-note' is part of BBDB v3.x
 120 (declare-function bbdb-record-note "ext:bbdb" (record label))
 121
 122 (declare-function calendar-leap-year-p "calendar" (year))
 123 (declare-function diary-ordinal-suffix "diary-lib" (n))
 124
 125 (defvar date)   ;; dynamically scoped from Org
 126
 127 ;; Customization
 128
 129 (defgroup org-bbdb-anniversaries nil
 130   "Customizations for including anniversaries from BBDB into Agenda."
 131   :group 'org-bbdb)
 132
 133 (defcustom org-bbdb-default-anniversary-format "birthday"
 134   "Default anniversary class."
 135   :type  'string
 136   :group 'org-bbdb-anniversaries
 137   :require 'bbdb)
 138
 139 (defcustom org-bbdb-anniversary-format-alist
 140   '(("birthday" .
 141      (lambda (name years suffix)
 142        (concat "Birthday: [[bbdb:" name "][" name " ("
 143                (format "%s" years)        ; handles numbers as well as strings
 144                suffix ")]]")))
 145     ("wedding" .
 146      (lambda (name years suffix)
 147        (concat "[[bbdb:" name "][" name "'s "
 148                (format "%s" years)
 149                suffix " wedding anniversary]]"))))
 150   "How different types of anniversaries should be formatted.
 151 An alist of elements (STRING . FORMAT) where STRING is the name of an
 152 anniversary class and format is either:
 153 1) A format string with the following substitutions (in order):
 154     - the name of the record containing this anniversary
 155     - the number of years
 156     - an ordinal suffix (st, nd, rd, th) for the year
 157
 158 2) A function to be called with three arguments: NAME YEARS SUFFIX
 159    (string int string) returning a string for the diary or nil.
 160
 161 3) An Emacs Lisp form that should evaluate to a string (or nil) in the
 162    scope of variables NAME, YEARS and SUFFIX (among others)."
 163   :type '(alist :key-type   (string   :tag "Class")
 164                 :value-type (function :tag "Function"))
 165   :group 'org-bbdb-anniversaries
 166   :require 'bbdb)
 167
 168 (defcustom org-bbdb-anniversary-field 'anniversary
 169   "The BBDB field which contains anniversaries.
 170 The anniversaries are stored in the following format
 171
 172 YYYY-MM-DD Class-or-Format-String
 173
 174 where class is one of the customized classes for anniversaries;
 175 birthday and wedding are predefined.  Format-String can take three
 176 substitutions 1) the name of the record containing this
 177 anniversary, 2) the number of years, and 3) an ordinal suffix for
 178 the year.
 179
 180 Multiple anniversaries can be separated by \\n."
 181   :type    'symbol
 182   :group   'org-bbdb-anniversaries
 183   :require 'bbdb)
 184
 185 (defcustom org-bbdb-extract-date-fun 'org-bbdb-anniv-extract-date
 186   "How to retrieve `month date year' from the anniversary field.
 187
 188 Customize if you have already filled your BBDB with dates
 189 different from YYYY-MM-DD.  The function must return a list (month
 190 date year)."
 191   :type 'function
 192   :group 'org-bbdb-anniversaries
 193   :require 'bbdb)
 194
 195
 196 ;; Install the link type
 197 (org-add-link-type "bbdb" 'org-bbdb-open 'org-bbdb-export)
 198 (add-hook 'org-store-link-functions 'org-bbdb-store-link)
 199
 200 ;; Implementation
 201 (defun org-bbdb-store-link ()
 202   "Store a link to a BBDB database entry."
 203   (when (eq major-mode 'bbdb-mode)
 204     ;; This is BBDB, we make this link!
 205     (let* ((rec (bbdb-current-record))
 206            (name (bbdb-record-name rec))
 207            (company (if (fboundp 'bbdb-record-getprop)
 208                         (bbdb-record-getprop rec 'company)
 209                       (car (bbdb-record-get-field rec 'organization))))
 210            (link (org-make-link "bbdb:" name)))
 211       (org-store-link-props :type "bbdb" :name name :company company
 212                             :link link :description name)
 213       link)))
 214
 215 (defun org-bbdb-export (path desc format)
 216   "Create the export version of a BBDB link specified by PATH or DESC.
 217 If exporting to either HTML or LaTeX FORMAT the link will be
 218 italicized, in all other cases it is left unchanged."
 219   (when (string= desc (format "bbdb:%s" path))
 220     (setq desc path))
 221   (cond
 222    ((eq format 'html) (format "<i>%s</i>" desc))
 223    ((eq format 'latex) (format "\\textit{%s}" desc))
 224    (t desc)))
 225
 226 (defun org-bbdb-open (name)
 227   "Follow a BBDB link to NAME."
 228   (require 'bbdb-com)
 229   (let ((inhibit-redisplay (not debug-on-error))
 230         (bbdb-electric-p nil))
 231     (if (fboundp 'bbdb-name)
 232         (org-bbdb-open-old name)
 233       (org-bbdb-open-new name))))
 234
 235 (defun org-bbdb-open-old (name)
 236   (catch 'exit
 237     ;; Exact match on name
 238     (bbdb-name (concat "\\`" name "\\'") nil)
 239     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 240     ;; Exact match on name
 241     (bbdb-company (concat "\\`" name "\\'") nil)
 242     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 243     ;; Partial match on name
 244     (bbdb-name name nil)
 245     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 246     ;; Partial match on company
 247     (bbdb-company name nil)
 248     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 249     ;; General match including network address and notes
 250     (bbdb name nil)
 251     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 252       (delete-window (get-buffer-window "*BBDB*"))
 253       (error "No matching BBDB record"))))
 254
 255 (defun org-bbdb-open-new (name)
 256   (catch 'exit
 257     ;; Exact match on name
 258     (bbdb-search-name (concat "\\`" name "\\'") nil)
 259     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 260     ;; Exact match on name
 261     (bbdb-search-organization (concat "\\`" name "\\'") nil)
 262     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 263     ;; Partial match on name
 264     (bbdb-search-name name nil)
 265     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 266     ;; Partial match on company
 267     (bbdb-search-organization name nil)
 268     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 269     ;; General match including network address and notes
 270     (bbdb name nil)
 271     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 272       (delete-window (get-buffer-window "*BBDB*"))
 273       (error "No matching BBDB record"))))
 274
 275 (defun org-bbdb-anniv-extract-date (time-str)
 276   "Convert YYYY-MM-DD to (month date year).
 277 Argument TIME-STR is the value retrieved from BBDB.  If YYYY- is omitted
 278 it will be considered unknown."
 279   (multiple-value-bind (a b c) (values-list (org-split-string time-str "-"))
 280     (if (eq c nil)
 281         (list (string-to-number a)
 282               (string-to-number b)
 283               nil)
 284       (list (string-to-number b)
 285             (string-to-number c)
 286             (string-to-number a)))))
 287
 288 (defun org-bbdb-anniv-split (str)
 289   "Split multiple entries in the BBDB anniversary field.
 290 Argument STR is the anniversary field in BBDB."
 291   (let ((pos (string-match "[ \t]" str)))
 292     (if pos (list (substring str 0 pos)
 293                   (bbdb-string-trim (substring str pos)))
 294       (list str nil))))
 295
 296 (defvar org-bbdb-anniv-hash nil
 297   "A hash holding anniversaries extracted from BBDB.
 298 The hash table is created on first use.")
 299
 300 (defvar org-bbdb-updated-p t
 301   "This is non-nil if BBDB has been updated since we last built the hash.")
 302
 303 (defun org-bbdb-make-anniv-hash ()
 304   "Create a hash with anniversaries extracted from BBDB, for fast access.
 305 The anniversaries are assumed to be stored `org-bbdb-anniversary-field'."
 306   (let ((old-bbdb (fboundp 'bbdb-record-getprop))
 307         split tmp annivs)
 308     (clrhash org-bbdb-anniv-hash)
 309     (dolist (rec (bbdb-records))
 310       (when (setq annivs (if old-bbdb
 311                              (bbdb-record-getprop
 312                               rec org-bbdb-anniversary-field)
 313                            (bbdb-record-note
 314                             rec org-bbdb-anniversary-field)))
 315         (setq annivs (if old-bbdb
 316                          (bbdb-split annivs "\n")
 317                        ;; parameter order is reversed in new bbdb
 318                        (bbdb-split "\n" annivs)))
 319         (while annivs
 320           (setq split (org-bbdb-anniv-split (pop annivs)))
 321           (multiple-value-bind (m d y)
 322               (values-list (funcall org-bbdb-extract-date-fun (car split)))
 323             (setq tmp (gethash (list m d) org-bbdb-anniv-hash))
 324             (puthash (list m d) (cons (list y
 325                                             (bbdb-record-name rec)
 326                                             (cadr split))
 327                                       tmp)
 328                      org-bbdb-anniv-hash))))))
 329   (setq org-bbdb-updated-p nil))
 330
 331 (defun org-bbdb-updated (rec)
 332   "Record the fact that BBDB has been updated.
 333 This is used by Org to re-create the anniversary hash table."
 334   (setq org-bbdb-updated-p t))
 335
 336 (add-hook 'bbdb-after-change-hook 'org-bbdb-updated)
 337
 338 ;;;###autoload
 339 (defun org-bbdb-anniversaries()
 340   "Extract anniversaries from BBDB for display in the agenda."
 341   (require 'bbdb)
 342   (require 'diary-lib)
 343   (unless (hash-table-p org-bbdb-anniv-hash)
 344     (setq org-bbdb-anniv-hash
 345           (make-hash-table :test 'equal :size 366)))
 346
 347   (when (or org-bbdb-updated-p
 348             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 349     (org-bbdb-make-anniv-hash))
 350
 351   (let* ((m (car date))    ; month
 352          (d (nth 1 date))  ; day
 353          (y (nth 2 date))  ; year
 354          (annivs (gethash (list m d) org-bbdb-anniv-hash))
 355          (text ())
 356          rec recs)
 357
 358     ;; we don't want to miss people born on Feb. 29th
 359     (when (and (= m 3) (= d 1)
 360                (not (null (gethash (list 2 29) org-bbdb-anniv-hash)))
 361                (not (calendar-leap-year-p y)))
 362       (setq recs (gethash (list 2 29) org-bbdb-anniv-hash))
 363       (while (setq rec (pop recs))
 364         (push rec annivs)))
 365
 366     (when annivs
 367       (while (setq rec (pop annivs))
 368         (when rec
 369           (let* ((class (or (nth 2 rec)
 370                             org-bbdb-default-anniversary-format))
 371                  (form (or (cdr (assoc-string
 372                                  class org-bbdb-anniversary-format-alist t))
 373                            class))      ; (as format string)
 374                  (name (nth 1 rec))
 375                  (years (if (eq (car rec) nil)
 376                             "unknown"
 377                           (- y (car rec))))
 378                  (suffix (if (eq (car rec) nil)
 379                              ""
 380                            (diary-ordinal-suffix years)))
 381                  (tmp (cond
 382                        ((functionp form)
 383                         (funcall form name years suffix))
 384                        ((listp form) (eval form))
 385                        (t (format form name years suffix)))))
 386             (org-add-props tmp nil 'org-bbdb-name name)
 387             (if text
 388                 (setq text (append text (list tmp)))
 389               (setq text (list tmp)))))
 390         ))
 391     text))
 392
 393 (defun org-bbdb-complete-link ()
 394   "Read a bbdb link with name completion."
 395   (require 'bbdb-com)
 396   (concat "bbdb:"
 397           (bbdb-record-name (car (bbdb-completing-read-record "Name: ")))))
 398
 399 (defun org-bbdb-anniv-export-ical ()
 400   "Extract anniversaries from BBDB and convert them to icalendar format."
 401   (require 'bbdb)
 402   (require 'diary-lib)
 403   (unless (hash-table-p org-bbdb-anniv-hash)
 404     (setq org-bbdb-anniv-hash
 405           (make-hash-table :test 'equal :size 366)))
 406   (when (or org-bbdb-updated-p
 407             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 408     (org-bbdb-make-anniv-hash))
 409   (maphash 'org-bbdb-format-vevent org-bbdb-anniv-hash))
 410
 411 (defun org-bbdb-format-vevent (key recs)
 412   (let (rec categ)
 413     (while (setq rec (pop recs))
 414       (setq categ (or (nth 2 rec) org-bbdb-default-anniversary-format))
 415       (princ (format "BEGIN:VEVENT
 416 UID: ANNIV-%4i%02i%02i-%s
 417 DTSTART:%4i%02i%02i
 418 SUMMARY:%s
 419 DESCRIPTION:%s
 420 CATEGORIES:%s
 421 RRULE:FREQ=YEARLY
 422 END:VEVENT\n"
 423                      (nth 0 rec) (nth 0 key) (nth 1 key)
 424                      (mapconcat 'identity
 425                                 (org-split-string (nth 1 rec) "[^a-zA-Z0-90]+")
 426                                 "-")
 427                      (nth 0 rec) (nth 0 key) (nth 1 key)
 428                      (nth 1 rec)
 429                      (concat (capitalize categ) " " (nth 1 rec))
 430                      categ)))))
 431
 432 (provide 'org-bbdb)
 433
 434 ;;; org-bbdb.el ends here