lisp/ob-R.el

   1 ;;; ob-R.el --- org-babel functions for R code evaluation
   2
   3 ;; Copyright (C) 2009-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;;      Dan Davison
   7 ;; Keywords: literate programming, reproducible research, R, statistics
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating R code
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'ob-ref)
  32 (require 'ob-comint)
  33 (require 'ob-eval)
  34 (eval-when-compile (require 'cl))
  35
  36 (declare-function orgtbl-to-tsv "org-table" (table params))
  37 (declare-function R "ext:essd-r" (&optional start-args))
  38 (declare-function inferior-ess-send-input "ext:ess-inf" ())
  39 (declare-function ess-make-buffer-current "ext:ess-inf" ())
  40 (declare-function ess-eval-buffer "ext:ess-inf" (vis))
  41 (declare-function org-number-sequence "org-compat" (from &optional to inc))
  42
  43 (defconst org-babel-header-args:R
  44   '((width               . :any)
  45     (height              . :any)
  46     (bg                  . :any)
  47     (units               . :any)
  48     (pointsize           . :any)
  49     (antialias           . :any)
  50     (quality             . :any)
  51     (compression         . :any)
  52     (res                 . :any)
  53     (type                . :any)
  54     (family              . :any)
  55     (title               . :any)
  56     (fonts               . :any)
  57     (version             . :any)
  58     (paper               . :any)
  59     (encoding            . :any)
  60     (pagecentre          . :any)
  61     (colormodel          . :any)
  62     (useDingbats         . :any)
  63     (horizontal          . :any)
  64     (results             . ((file list vector table scalar verbatim)
  65                             (raw org html latex code pp wrap)
  66                             (replace silent append prepend)
  67                             (output value graphics))))
  68   "R-specific header arguments.")
  69
  70 (defvar org-babel-default-header-args:R '())
  71
  72 (defvar org-babel-R-command "R --slave --no-save"
  73   "Name of command to use for executing R code.")
  74
  75 (defvar ess-local-process-name)
  76 (defun org-babel-edit-prep:R (info)
  77   (let ((session (cdr (assoc :session (nth 2 info)))))
  78     (when (and session (string-match "^\\*\\(.+?\\)\\*$" session))
  79       (save-match-data (org-babel-R-initiate-session session nil))
  80       (setq ess-local-process-name (match-string 1 session)))))
  81
  82 (defun org-babel-expand-body:R (body params &optional graphics-file)
  83   "Expand BODY according to PARAMS, return the expanded body."
  84   (let ((graphics-file
  85          (or graphics-file (org-babel-R-graphical-output-file params))))
  86     (mapconcat
  87      #'identity
  88      ((lambda (inside)
  89         (if graphics-file
  90             (append
  91              (list (org-babel-R-construct-graphics-device-call
  92                     graphics-file params))
  93              inside
  94              (list "dev.off()"))
  95           inside))
  96       (append (org-babel-variable-assignments:R params)
  97               (list body))) "\n")))
  98
  99 (defun org-babel-execute:R (body params)
 100   "Execute a block of R code.
 101 This function is called by `org-babel-execute-src-block'."
 102   (save-excursion
 103     (let* ((result-params (cdr (assoc :result-params params)))
 104            (result-type (cdr (assoc :result-type params)))
 105            (session (org-babel-R-initiate-session
 106                      (cdr (assoc :session params)) params))
 107            (colnames-p (cdr (assoc :colnames params)))
 108            (rownames-p (cdr (assoc :rownames params)))
 109            (graphics-file (org-babel-R-graphical-output-file params))
 110            (full-body (org-babel-expand-body:R body params graphics-file))
 111            (result
 112             (org-babel-R-evaluate
 113              session full-body result-type result-params
 114              (or (equal "yes" colnames-p)
 115                  (org-babel-pick-name
 116                   (cdr (assoc :colname-names params)) colnames-p))
 117              (or (equal "yes" rownames-p)
 118                  (org-babel-pick-name
 119                   (cdr (assoc :rowname-names params)) rownames-p)))))
 120       (if graphics-file nil result))))
 121
 122 (defun org-babel-prep-session:R (session params)
 123   "Prepare SESSION according to the header arguments specified in PARAMS."
 124   (let* ((session (org-babel-R-initiate-session session params))
 125          (var-lines (org-babel-variable-assignments:R params)))
 126     (org-babel-comint-in-buffer session
 127       (mapc (lambda (var)
 128               (end-of-line 1) (insert var) (comint-send-input nil t)
 129               (org-babel-comint-wait-for-output session)) var-lines))
 130     session))
 131
 132 (defun org-babel-load-session:R (session body params)
 133   "Load BODY into SESSION."
 134   (save-window-excursion
 135     (let ((buffer (org-babel-prep-session:R session params)))
 136       (with-current-buffer buffer
 137         (goto-char (process-mark (get-buffer-process (current-buffer))))
 138         (insert (org-babel-chomp body)))
 139       buffer)))
 140
 141 ;; helper functions
 142
 143 (defun org-babel-variable-assignments:R (params)
 144   "Return list of R statements assigning the block's variables"
 145   (let ((vars (mapcar #'cdr (org-babel-get-header params :var))))
 146     (mapcar
 147      (lambda (pair)
 148        (org-babel-R-assign-elisp
 149         (car pair) (cdr pair)
 150         (equal "yes" (cdr (assoc :colnames params)))
 151         (equal "yes" (cdr (assoc :rownames params)))))
 152      (mapcar
 153       (lambda (i)
 154         (cons (car (nth i vars))
 155               (org-babel-reassemble-table
 156                (cdr (nth i vars))
 157                (cdr (nth i (cdr (assoc :colname-names params))))
 158                (cdr (nth i (cdr (assoc :rowname-names params)))))))
 159       (org-number-sequence 0 (1- (length vars)))))))
 160
 161 (defun org-babel-R-quote-tsv-field (s)
 162   "Quote field S for export to R."
 163   (if (stringp s)
 164       (concat "\"" (mapconcat 'identity (split-string s "\"") "\"\"") "\"")
 165     (format "%S" s)))
 166
 167 (defun org-babel-R-assign-elisp (name value colnames-p rownames-p)
 168   "Construct R code assigning the elisp VALUE to a variable named NAME."
 169   (if (listp value)
 170       (let ((transition-file (org-babel-temp-file "R-import-")))
 171         ;; ensure VALUE has an orgtbl structure (depth of at least 2)
 172         (unless (listp (car value)) (setq value (list value)))
 173         (with-temp-file transition-file
 174           (insert (orgtbl-to-tsv value '(:fmt org-babel-R-quote-tsv-field)))
 175           (insert "\n"))
 176         (format "if (max(count.fields(\"%s\", sep=\"\\t\")) == min(count.fields(\"%s\", sep=\"\\t\"))) %s <- read.table(\"%s\", header=%s, row.names=%s, sep=\"\\t\", as.is=TRUE) else  %s <- read.table(\"%s\", header=%s, row.names=%s, sep=\"\\t\", as.is=TRUE, fill=TRUE, col.names = paste(\"V\", seq_len(max(count.fields(\"%s\", sep=\"\\t\"))), sep =\"\"))"
 177                 (org-babel-process-file-name transition-file 'noquote)
 178                 (org-babel-process-file-name transition-file 'noquote)
 179                 name (org-babel-process-file-name transition-file 'noquote)
 180                 (if (or (eq (nth 1 value) 'hline) colnames-p) "TRUE" "FALSE")
 181                 (if rownames-p "1" "NULL")
 182                 name (org-babel-process-file-name transition-file 'noquote)
 183                 (if (or (eq (nth 1 value) 'hline) colnames-p) "TRUE" "FALSE")
 184                 (if rownames-p "1" "NULL")
 185                 (org-babel-process-file-name transition-file 'noquote)))
 186     (format "%s <- %s" name (org-babel-R-quote-tsv-field value))))
 187
 188 (defvar ess-ask-for-ess-directory nil)
 189 (defun org-babel-R-initiate-session (session params)
 190   "If there is not a current R process then create one."
 191   (unless (string= session "none")
 192     (let ((session (or session "*R*"))
 193           (ess-ask-for-ess-directory
 194            (and ess-ask-for-ess-directory (not (cdr (assoc :dir params))))))
 195       (if (org-babel-comint-buffer-livep session)
 196           session
 197         (save-window-excursion
 198           (require 'ess) (R)
 199           (rename-buffer
 200            (if (bufferp session)
 201                (buffer-name session)
 202              (if (stringp session)
 203                  session
 204                (buffer-name))))
 205           (current-buffer))))))
 206
 207 (defvar ess-local-process-name nil)
 208 (defun org-babel-R-associate-session (session)
 209   "Associate R code buffer with an R session.
 210 Make SESSION be the inferior ESS process associated with the
 211 current code buffer."
 212   (setq ess-local-process-name
 213         (process-name (get-buffer-process session)))
 214   (ess-make-buffer-current))
 215
 216 (defun org-babel-R-graphical-output-file (params)
 217   "Name of file to which R should send graphical output."
 218   (and (member "graphics" (cdr (assq :result-params params)))
 219        (cdr (assq :file params))))
 220
 221 (defun org-babel-R-construct-graphics-device-call (out-file params)
 222   "Construct the call to the graphics device."
 223   (let ((devices
 224          '((:bmp . "bmp")
 225            (:jpg . "jpeg")
 226            (:jpeg . "jpeg")
 227            (:tex . "tikz")
 228            (:tiff . "tiff")
 229            (:png . "png")
 230            (:svg . "svg")
 231            (:pdf . "pdf")
 232            (:ps . "postscript")
 233            (:postscript . "postscript")))
 234         (allowed-args '(:width :height :bg :units :pointsize
 235                                :antialias :quality :compression :res
 236                                :type :family :title :fonts :version
 237                                :paper :encoding :pagecentre :colormodel
 238                                :useDingbats :horizontal))
 239         (device (and (string-match ".+\\.\\([^.]+\\)" out-file)
 240                      (match-string 1 out-file)))
 241         (extra-args (cdr (assq :R-dev-args params))) filearg args)
 242     (setq device (or (and device (cdr (assq (intern (concat ":" device))
 243                                             devices))) "png"))
 244     (setq filearg
 245           (if (member device '("pdf" "postscript" "svg" "tikz")) "file" "filename"))
 246     (setq args (mapconcat
 247                 (lambda (pair)
 248                   (if (member (car pair) allowed-args)
 249                       (format ",%s=%s"
 250                               (substring (symbol-name (car pair)) 1)
 251                               (cdr pair)) ""))
 252                 params ""))
 253     (format "%s(%s=\"%s\"%s%s%s)"
 254             device filearg out-file args
 255             (if extra-args "," "") (or extra-args ""))))
 256
 257 (defvar org-babel-R-eoe-indicator "'org_babel_R_eoe'")
 258 (defvar org-babel-R-eoe-output "[1] \"org_babel_R_eoe\"")
 259
 260 (defvar org-babel-R-write-object-command "{function(object,transfer.file){object;invisible(if(inherits(try({tfile<-tempfile();write.table(object,file=tfile,sep=\"\\t\",na=\"nil\",row.names=%s,col.names=%s,quote=FALSE);file.rename(tfile,transfer.file)},silent=TRUE),\"try-error\")){if(!file.exists(transfer.file))file.create(transfer.file)})}}(object=%s,transfer.file=\"%s\")")
 261
 262 (defun org-babel-R-evaluate
 263   (session body result-type result-params column-names-p row-names-p)
 264   "Evaluate R code in BODY."
 265   (if session
 266       (org-babel-R-evaluate-session
 267        session body result-type result-params column-names-p row-names-p)
 268     (org-babel-R-evaluate-external-process
 269      body result-type result-params column-names-p row-names-p)))
 270
 271 (defun org-babel-R-evaluate-external-process
 272   (body result-type result-params column-names-p row-names-p)
 273   "Evaluate BODY in external R process.
 274 If RESULT-TYPE equals 'output then return standard output as a
 275 string. If RESULT-TYPE equals 'value then return the value of the
 276 last statement in BODY, as elisp."
 277   (case result-type
 278     (value
 279      (let ((tmp-file (org-babel-temp-file "R-")))
 280        (org-babel-eval org-babel-R-command
 281                        (format org-babel-R-write-object-command
 282                                (if row-names-p "TRUE" "FALSE")
 283                                (if column-names-p
 284                                    (if row-names-p "NA" "TRUE")
 285                                  "FALSE")
 286                                (format "{function ()\n{\n%s\n}}()" body)
 287                                (org-babel-process-file-name tmp-file 'noquote)))
 288        (org-babel-R-process-value-result
 289         (if (or (member "scalar" result-params)
 290                 (member "verbatim" result-params))
 291             (with-temp-buffer
 292               (insert-file-contents tmp-file)
 293               (buffer-string))
 294           (org-babel-import-elisp-from-file tmp-file '(16)))
 295         column-names-p)))
 296     (output (org-babel-eval org-babel-R-command body))))
 297
 298 (defun org-babel-R-evaluate-session
 299   (session body result-type result-params column-names-p row-names-p)
 300   "Evaluate BODY in SESSION.
 301 If RESULT-TYPE equals 'output then return standard output as a
 302 string. If RESULT-TYPE equals 'value then return the value of the
 303 last statement in BODY, as elisp."
 304   (case result-type
 305     (value
 306      (with-temp-buffer
 307        (insert (org-babel-chomp body))
 308        (let ((ess-local-process-name
 309               (process-name (get-buffer-process session)))
 310              (ess-eval-visibly-p nil))
 311          (ess-eval-buffer nil)))
 312      (let ((tmp-file (org-babel-temp-file "R-")))
 313        (org-babel-comint-eval-invisibly-and-wait-for-file
 314         session tmp-file
 315         (format org-babel-R-write-object-command
 316                 (if row-names-p "TRUE" "FALSE")
 317                 (if column-names-p
 318                     (if row-names-p "NA" "TRUE")
 319                   "FALSE")
 320                 ".Last.value" (org-babel-process-file-name tmp-file 'noquote)))
 321        (org-babel-R-process-value-result
 322         (if (or (member "scalar" result-params)
 323                 (member "verbatim" result-params))
 324             (with-temp-buffer
 325               (insert-file-contents tmp-file)
 326               (buffer-string))
 327           (org-babel-import-elisp-from-file tmp-file '(16)))
 328         column-names-p)))
 329     (output
 330      (mapconcat
 331       #'org-babel-chomp
 332       (butlast
 333        (delq nil
 334              (mapcar
 335               (lambda (line) (when (> (length line) 0) line))
 336               (mapcar
 337                (lambda (line) ;; cleanup extra prompts left in output
 338                  (if (string-match
 339                       "^\\([ ]*[>+\\.][ ]?\\)+\\([[0-9]+\\|[ ]\\)" line)
 340                      (substring line (match-end 1))
 341                    line))
 342                (org-babel-comint-with-output (session org-babel-R-eoe-output)
 343                  (insert (mapconcat #'org-babel-chomp
 344                                     (list body org-babel-R-eoe-indicator)
 345                                     "\n"))
 346                  (inferior-ess-send-input)))))) "\n"))))
 347
 348 (defun org-babel-R-process-value-result (result column-names-p)
 349   "R-specific processing of return value.
 350 Insert hline if column names in output have been requested."
 351   (if column-names-p
 352       (cons (car result) (cons 'hline (cdr result)))
 353     result))
 354
 355 (provide 'ob-R)
 356
 357
 358
 359 ;;; ob-R.el ends here