lisp/org-protocol.el

   1 ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
   2 ;;
   3 ;; Copyright (C) 2008, 2009, 2010
   4 ;;          Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Bastien Guerry <bzg AT altern DOT org>
   7 ;; Author: Daniel M German <dmg AT uvic DOT org>
   8 ;; Author: Sebastian Rose <sebastian_rose AT gmx DOT de>
   9 ;; Author: Ross Patterson <me AT rpatterson DOT net>
  10 ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  11 ;; Keywords: org, emacsclient, wp
  12 ;; Version: 7.5
  13
  14 ;; This file is part of GNU Emacs.
  15 ;;
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  30 ;;; Commentary:
  31 ;;
  32 ;; Intercept calls from emacsclient to trigger custom actions.
  33 ;;
  34 ;; This is done by advising `server-visit-files' to scan the list of filenames
  35 ;; for `org-protocol-the-protocol' and sub-protocols defined in
  36 ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  37 ;;
  38 ;; Any application that supports calling external programs with an URL
  39 ;; as argument may be used with this functionality.
  40 ;;
  41 ;;
  42 ;; Usage:
  43 ;; ------
  44 ;;
  45 ;;   1.) Add this to your init file (.emacs probably):
  46 ;;
  47 ;;       (add-to-list 'load-path "/path/to/org-protocol/")
  48 ;;       (require 'org-protocol)
  49 ;;
  50 ;;   3.) Ensure emacs-server is up and running.
  51 ;;   4.) Try this from the command line (adjust the URL as needed):
  52 ;;
  53 ;;       $ emacsclient \
  54 ;;         org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  55 ;;
  56 ;;   5.) Optionally add custom sub-protocols and handlers:
  57 ;;
  58 ;;       (setq org-protocol-protocol-alist
  59 ;;             '(("my-protocol"
  60 ;;                :protocol "my-protocol"
  61 ;;                :function my-protocol-handler-function)))
  62 ;;
  63 ;;       A "sub-protocol" will be found in URLs like this:
  64 ;;
  65 ;;           org-protocol://sub-protocol://data
  66 ;;
  67 ;; If it works, you can now setup other applications for using this feature.
  68 ;;
  69 ;;
  70 ;; As of March 2009 Firefox users follow the steps documented on
  71 ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  72 ;; http://www.opera.com/support/kb/view/535/
  73 ;;
  74 ;;
  75 ;; Documentation
  76 ;; -------------
  77 ;;
  78 ;; org-protocol.el comes with and installs handlers to open sources of published
  79 ;; online content, store and insert the browser's URLs and cite online content
  80 ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  81 ;; applications:
  82 ;;
  83 ;;   * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  84 ;;     URLs to local filenames defined in `org-protocol-project-alist'.
  85 ;;
  86 ;;   * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  87 ;;     pushes the browsers URL to the `kill-ring' for yanking.  This handler is
  88 ;;     triggered through the sub-protocol \"store-link\".
  89 ;;
  90 ;;   * Call `org-protocol-capture' by using the sub-protocol \"capture\".  If
  91 ;;     Org-mode is loaded, Emacs will pop-up a capture buffer and fill the
  92 ;;     template with the data provided.  I.e. the browser's URL is inserted as an
  93 ;;     Org-link of which the page title will be the description part.  If text
  94 ;;     was select in the browser, that text will be the body of the entry.
  95 ;;
  96 ;;   * Call `org-protocol-remember' by using the sub-protocol \"remember\".
  97 ;;     This is provided for backward compatibility.
  98 ;;     You may read `org-capture' as `org-remember' throughout this file if
  99 ;;     you still use `org-remember'.
 100 ;;
 101 ;; You may use the same bookmark URL for all those standard handlers and just
 102 ;; adjust the sub-protocol used:
 103 ;;
 104 ;;     location.href='org-protocol://sub-protocol://'+
 105 ;;           encodeURIComponent(location.href)+'/'+
 106 ;;           encodeURIComponent(document.title)+'/'+
 107 ;;           encodeURIComponent(window.getSelection())
 108 ;;
 109 ;; The handler for the sub-protocol \"capture\" detects an optional template
 110 ;; char that, if present, triggers the use of a special template.
 111 ;; Example:
 112 ;;
 113 ;;     location.href='org-protocol://sub-protocol://x/'+ ...
 114 ;;
 115 ;;  use template ?x.
 116 ;;
 117 ;; Note, that using double slashes is optional from org-protocol.el's point of
 118 ;; view because emacsclient squashes the slashes to one.
 119 ;;
 120 ;;
 121 ;; provides: 'org-protocol
 122 ;;
 123 ;;; Code:
 124
 125 (require 'org)
 126 (eval-when-compile
 127   (require 'cl))
 128
 129 (declare-function org-publish-get-project-from-filename "org-publish"
 130                   (filename &optional up))
 131 (declare-function server-edit "server" (&optional arg))
 132
 133 (define-obsolete-function-alias
 134   'org-protocol-unhex-compound 'org-link-unescape-compound
 135   "2011-02-17")
 136
 137 (define-obsolete-function-alias
 138   'org-protocol-unhex-string 'org-link-unescape
 139   "2011-02-17")
 140
 141 (define-obsolete-function-alias
 142   'org-protocol-unhex-single-byte-sequence
 143   'org-link-unescape-single-byte-sequence
 144   "2011-02-17")
 145
 146 (defgroup org-protocol nil
 147   "Intercept calls from emacsclient to trigger custom actions.
 148
 149 This is done by advising `server-visit-files' to scann the list of filenames
 150 for `org-protocol-the-protocol' and sub-procols defined in
 151 `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
 152   :version "22.1"
 153   :group 'convenience
 154   :group 'org)
 155
 156
 157 ;;; Variables:
 158
 159 (defconst org-protocol-protocol-alist-default
 160   '(("org-remember"    :protocol "remember"    :function org-protocol-remember :kill-client t)
 161     ("org-capture"     :protocol "capture"     :function org-protocol-capture  :kill-client t)
 162     ("org-store-link"  :protocol "store-link"  :function org-protocol-store-link)
 163     ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
 164   "Default protocols to use.
 165 See `org-protocol-protocol-alist' for a description of this variable.")
 166
 167 (defconst org-protocol-the-protocol "org-protocol"
 168   "This is the protocol to detect if org-protocol.el is loaded.
 169 `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold
 170 the sub-protocols that trigger the required action.  You will have to define
 171 just one protocol handler OS-wide (MS-Windows) or per application (Linux).
 172 That protocol handler should call emacsclient.")
 173
 174 ;;; User variables:
 175
 176 (defcustom org-protocol-reverse-list-of-files t
 177   "Non-nil means re-reverse the list of filenames passed on the command line.
 178 The filenames passed on the command line are passed to the emacs-server in
 179 reverse order.  Set to t (default) to re-reverse the list, i.e. use the
 180 sequence on the command line.  If nil, the sequence of the filenames is
 181 unchanged."
 182   :group 'org-protocol
 183   :type 'boolean)
 184
 185 (defcustom org-protocol-project-alist nil
 186   "Map URLs to local filenames for `org-protocol-open-source' (open-source).
 187
 188 Each element of this list must be of the form:
 189
 190   (module-name :property value property: value ...)
 191
 192 where module-name is an arbitrary name. All the values are strings.
 193
 194 Possible properties are:
 195
 196   :online-suffix     - the suffix to strip from the published URLs
 197   :working-suffix    - the replacement for online-suffix
 198   :base-url          - the base URL, e.g. http://www.example.com/project/
 199                        Last slash required.
 200   :working-directory - the local working directory. This is, what base-url will
 201                        be replaced with.
 202   :redirects         - A list of cons cells, each of which maps a regular
 203                        expression to match to a path relative to :working-directory.
 204
 205 Example:
 206
 207    (setq org-protocol-project-alist
 208        '((\"http://orgmode.org/worg/\"
 209           :online-suffix \".php\"
 210           :working-suffix \".org\"
 211           :base-url \"http://orgmode.org/worg/\"
 212           :working-directory \"/home/user/org/Worg/\")
 213          (\"http://localhost/org-notes/\"
 214           :online-suffix \".html\"
 215           :working-suffix \".org\"
 216           :base-url \"http://localhost/org/\"
 217           :working-directory \"/home/user/org/\"
 218           :rewrites ((\"org/?$\" . \"index.php\")))))
 219
 220    The last line tells `org-protocol-open-source' to open
 221    /home/user/org/index.php, if the URL cannot be mapped to an existing
 222    file, and ends with either \"org\" or \"org/\".
 223
 224 Consider using the interactive functions `org-protocol-create' and
 225 `org-protocol-create-for-org' to help you filling this variable with valid contents."
 226   :group 'org-protocol
 227   :type 'alist)
 228
 229 (defcustom org-protocol-protocol-alist nil
 230   "* Register custom handlers for org-protocol.
 231
 232 Each element of this list must be of the form:
 233
 234   (module-name :protocol protocol :function func :kill-client nil)
 235
 236 protocol - protocol to detect in a filename without trailing colon and slashes.
 237            See rfc1738 section 2.1 for more on this.
 238            If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
 239            will search filenames for \"org-protocol:/my-protocol:/\"
 240            and trigger your action for every match. `org-protocol' is defined in
 241            `org-protocol-the-protocol'. Double and triple slashes are compressed
 242            to one by emacsclient.
 243
 244 function - function that handles requests with protocol and takes exactly one
 245            argument: the filename with all protocols stripped. If the function
 246            returns nil, emacsclient and -server do nothing. Any non-nil return
 247            value is considered a valid filename and thus passed to the server.
 248
 249            `org-protocol.el provides some support for handling those filenames,
 250            if you stay with the conventions used for the standard handlers in
 251            `org-protocol-protocol-alist-default'. See `org-protocol-split-data'.
 252
 253 kill-client - If t, kill the client immediately, once the sub-protocol is
 254            detected. This is necessary for actions that can be interrupted by
 255            `C-g' to avoid dangling emacsclients. Note, that all other command
 256            line arguments but the this one will be discarded, greedy handlers
 257            still receive the whole list of arguments though.
 258
 259 Here is an example:
 260
 261   (setq org-protocol-protocol-alist
 262       '((\"my-protocol\"
 263          :protocol \"my-protocol\"
 264          :function my-protocol-handler-function)
 265         (\"your-protocol\"
 266          :protocol \"your-protocol\"
 267          :function your-protocol-handler-function)))"
 268   :group 'org-protocol
 269   :type '(alist))
 270
 271 (defcustom org-protocol-default-template-key nil
 272   "The default org-remember-templates key to use."
 273   :group 'org-protocol
 274   :type 'string)
 275
 276 ;;; Helper functions:
 277
 278 (defun org-protocol-sanitize-uri (uri)
 279   "emacsclient compresses double and triple slashes.
 280 Slashes are sanitized to double slashes here."
 281   (when (string-match "^\\([a-z]+\\):/" uri)
 282     (let* ((splitparts (split-string uri "/+")))
 283       (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
 284   uri)
 285
 286 (defun org-protocol-split-data (data &optional unhexify separator)
 287   "Split what an org-protocol handler function gets as only argument.
 288 DATA is that one argument.  DATA is split at each occurrence of
 289 SEPARATOR (regexp).  If no SEPARATOR is specified or SEPARATOR is
 290 nil, assume \"/+\".  The results of that splitting are returned
 291 as a list.  If UNHEXIFY is non-nil, hex-decode each split part.
 292 If UNHEXIFY is a function, use that function to decode each split
 293 part."
 294   (let* ((sep (or separator "/+"))
 295          (split-parts (split-string data sep)))
 296     (if unhexify
 297         (if (fboundp unhexify)
 298             (mapcar unhexify split-parts)
 299           (mapcar 'org-link-unescape split-parts))
 300       split-parts)))
 301
 302 (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
 303   "Greedy handlers might receive a list like this from emacsclient:
 304  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 305 where \"/dir/\" is the absolute path to emacsclients working directory.  This
 306 function transforms it into a flat list utilizing `org-protocol-flatten' and
 307 transforms the elements of that list as follows:
 308
 309 If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
 310 param-list.
 311
 312 If replacement is string, replace the \"/dir/\" prefix with it.
 313
 314 The first parameter, the one that contains the protocols, is always changed.
 315 Everything up to the end of the protocols is stripped.
 316
 317 Note, that this function will always behave as if
 318 `org-protocol-reverse-list-of-files' was set to t and the returned list will
 319 reflect that. I.e. emacsclients first parameter will be the first one in the
 320 returned list."
 321 (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
 322                                     param-list
 323                                   (reverse param-list))))
 324       (trigger (car l))
 325       (len 0)
 326       dir
 327       ret)
 328   (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
 329     (setq dir (match-string 1 trigger))
 330     (setq len (length dir))
 331     (setcar l (concat dir (match-string 3 trigger))))
 332   (if strip-path
 333       (progn
 334        (dolist (e l ret)
 335          (setq ret
 336                (append ret
 337                        (list
 338                         (if (stringp e)
 339                             (if (stringp replacement)
 340                                 (setq e (concat replacement (substring e len)))
 341                               (setq e (substring e len)))
 342                           e)))))
 343        ret)
 344     l)))
 345
 346 (defun org-protocol-flatten (l)
 347   "Greedy handlers might receive a list like this from emacsclient:
 348  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 349 where \"/dir/\" is the absolute path to emacsclients working directory.
 350 This function transforms it into a flat list."
 351   (if (null l) ()
 352     (if (listp l)
 353        (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
 354       (list l))))
 355
 356
 357 ;;; Standard protocol handlers:
 358
 359 (defun org-protocol-store-link (fname)
 360   "Process an org-protocol://store-link:// style url.
 361 Additionally store a browser URL as an org link. Also pushes the
 362 link's URL to the `kill-ring'.
 363
 364 The location for a browser's bookmark has to look like this:
 365
 366   javascript:location.href='org-protocol://store-link://'+ \\
 367         encodeURIComponent(location.href)
 368         encodeURIComponent(document.title)+'/'+ \\
 369
 370 Don't use `escape()'! Use `encodeURIComponent()' instead. The title of the page
 371 could contain slashes and the location definitely will.
 372
 373 The sub-protocol used to reach this function is set in
 374 `org-protocol-protocol-alist'."
 375   (let* ((splitparts (org-protocol-split-data fname t))
 376          (uri (org-protocol-sanitize-uri (car splitparts)))
 377          (title (cadr splitparts))
 378          orglink)
 379     (if (boundp 'org-stored-links)
 380       (setq org-stored-links (cons (list uri title) org-stored-links)))
 381     (kill-new uri)
 382     (message "`%s' to insert new org-link, `%s' to insert `%s'"
 383              (substitute-command-keys"\\[org-insert-link]")
 384              (substitute-command-keys"\\[yank]")
 385              uri))
 386   nil)
 387
 388 (defun org-protocol-remember (info)
 389   "Process an org-protocol://remember:// style url.
 390
 391 The location for a browser's bookmark has to look like this:
 392
 393   javascript:location.href='org-protocol://remember://'+ \\
 394         encodeURIComponent(location.href)+'/' \\
 395         encodeURIComponent(document.title)+'/'+ \\
 396         encodeURIComponent(window.getSelection())
 397
 398 See the docs for `org-protocol-capture' for more information."
 399
 400   (if (and (boundp 'org-stored-links)
 401            (or (fboundp 'org-capture))
 402            (org-protocol-do-capture info 'org-remember))
 403       (message "Org-mode not loaded."))
 404   nil)
 405
 406 (defun org-protocol-capture (info)
 407   "Process an org-protocol://capture:// style url.
 408
 409 The sub-protocol used to reach this function is set in
 410 `org-protocol-protocol-alist'.
 411
 412 This function detects an URL, title and optional text, separated by '/'
 413 The location for a browser's bookmark has to look like this:
 414
 415   javascript:location.href='org-protocol://capture://'+ \\
 416         encodeURIComponent(location.href)+'/' \\
 417         encodeURIComponent(document.title)+'/'+ \\
 418         encodeURIComponent(window.getSelection())
 419
 420 By default, it uses the character `org-protocol-default-template-key',
 421 which should be associated with a template in `org-capture-templates'.
 422 But you may prepend the encoded URL with a character and a slash like so:
 423
 424   javascript:location.href='org-protocol://capture://b/'+ ...
 425
 426 Now template ?b will be used."
 427   (if (and (boundp 'org-stored-links)
 428            (or (fboundp 'org-capture))
 429            (org-protocol-do-capture info 'org-capture))
 430       (message "Org-mode not loaded."))
 431   nil)
 432
 433 (defun org-protocol-do-capture (info capture-func)
 434   "Support `org-capture' and `org-remember' alike.
 435 CAPTURE-FUNC is either the symbol `org-remember' or `org-capture'."
 436   (let* ((parts (org-protocol-split-data info t))
 437          (template (or (and (= 1 (length (car parts))) (pop parts))
 438                        org-protocol-default-template-key))
 439          (url (org-protocol-sanitize-uri (car parts)))
 440          (type (if (string-match "^\\([a-z]+\\):" url)
 441                    (match-string 1 url)))
 442          (title (or (cadr parts) ""))
 443          (region (or (caddr parts) ""))
 444          (orglink (org-make-link-string
 445                    url (if (string-match "[^[:space:]]" title) title url)))
 446          (org-capture-link-is-already-stored t) ;; avoid call to org-store-link
 447          remember-annotation-functions)
 448     (setq org-stored-links
 449           (cons (list url title) org-stored-links))
 450     (kill-new orglink)
 451     (org-store-link-props :type type
 452                           :link url
 453                           :description title
 454                           :annotation orglink
 455                           :initial region)
 456     (raise-frame)
 457     (funcall capture-func nil template)))
 458
 459 (defun org-protocol-open-source (fname)
 460   "Process an org-protocol://open-source:// style url.
 461
 462 Change a filename by mapping URLs to local filenames as set
 463 in `org-protocol-project-alist'.
 464
 465 The location for a browser's bookmark should look like this:
 466
 467   javascript:location.href='org-protocol://open-source://'+ \\
 468         encodeURIComponent(location.href)"
 469   ;; As we enter this function for a match on our protocol, the return value
 470   ;; defaults to nil.
 471   (let ((result nil)
 472         (f (org-link-unescape fname)))
 473     (catch 'result
 474       (dolist (prolist org-protocol-project-alist)
 475         (let* ((base-url (plist-get (cdr prolist) :base-url))
 476                (wsearch (regexp-quote base-url)))
 477
 478           (when (string-match wsearch f)
 479             (let* ((wdir (plist-get (cdr prolist) :working-directory))
 480                    (strip-suffix (plist-get (cdr prolist) :online-suffix))
 481                    (add-suffix (plist-get (cdr prolist) :working-suffix))
 482                    ;; Strip "[?#].*$" if `f' is a redirect with another
 483                    ;; ending than strip-suffix here:
 484                    (f1 (substring f 0 (string-match "\\([\\?#].*\\)?$" f)))
 485                    (start-pos (+ (string-match wsearch f1) (length base-url)))
 486                    (end-pos (string-match
 487                              (regexp-quote strip-suffix) f1))
 488                    ;; We have to compare redirects without suffix below:
 489                    (f2 (concat wdir (substring f1 start-pos end-pos)))
 490                    (the-file (concat f2 add-suffix)))
 491
 492               ;; Note: the-file may still contain `%C3' et al here because browsers
 493               ;; tend to encode `&auml;' in URLs to `%25C3' - `%25' being `%'.
 494               ;; So the results may vary.
 495
 496               ;; -- start redirects --
 497               (unless (file-exists-p the-file)
 498                 (message "File %s does not exist.\nTesting for rewritten URLs." the-file)
 499                 (let ((rewrites (plist-get (cdr prolist) :rewrites)))
 500                   (when rewrites
 501                     (message "Rewrites found: %S" rewrites)
 502                     (mapc
 503                      (lambda (rewrite)
 504                        "Try to match a rewritten URL and map it to a real file."
 505                        ;; Compare redirects without suffix:
 506                        (if (string-match (car rewrite) f2)
 507                            (throw 'result (concat wdir (cdr rewrite)))))
 508                      rewrites))))
 509               ;; -- end of redirects --
 510
 511               (if (file-readable-p the-file)
 512                   (throw 'result the-file))
 513               (if (file-exists-p the-file)
 514                   (message "%s: permission denied!" the-file)
 515                 (message "%s: no such file or directory." the-file))))))
 516       result)))
 517
 518
 519 ;;; Core functions:
 520
 521 (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
 522   "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
 523 Sub-protocols are registered in `org-protocol-protocol-alist' and
 524 `org-protocol-protocol-alist-default'.
 525 This is, how the matching is done:
 526
 527   (string-match \"protocol:/+sub-protocol:/+\" ...)
 528
 529 protocol and sub-protocol are regexp-quoted.
 530
 531 If a matching protocol is found, the protocol is stripped from fname and the
 532 result is passed to the protocols function as the only parameter. If the
 533 function returns nil, the filename is removed from the list of filenames
 534 passed from emacsclient to the server.
 535 If the function returns a non nil value, that value is passed to the server
 536 as filename."
 537   (let ((sub-protocols (append org-protocol-protocol-alist
 538                                org-protocol-protocol-alist-default)))
 539     (catch 'fname
 540       (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
 541         (when (string-match the-protocol fname)
 542           (dolist (prolist sub-protocols)
 543             (let ((proto (concat the-protocol
 544                                  (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
 545               (when (string-match proto fname)
 546                 (let* ((func (plist-get (cdr prolist) :function))
 547                        (greedy (plist-get (cdr prolist) :greedy))
 548                        (splitted (split-string fname proto))
 549                        (result (if greedy restoffiles (cadr splitted))))
 550                   (when (plist-get (cdr prolist) :kill-client)
 551                     (message "Greedy org-protocol handler. Killing client.")
 552                     (server-edit))
 553                   (when (fboundp func)
 554                     (unless greedy
 555                       (throw 'fname (funcall func result)))
 556                     (funcall func result)
 557                     (throw 'fname t))))))))
 558       ;; (message "fname: %s" fname)
 559       fname)))
 560
 561 (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
 562   "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
 563   (let ((flist (if org-protocol-reverse-list-of-files
 564                    (reverse  (ad-get-arg 0))
 565                  (ad-get-arg 0)))
 566         (client (ad-get-arg 1)))
 567     (catch 'greedy
 568       (dolist (var flist)
 569         ;; `\' to `/' on windows. FIXME: could this be done any better?
 570         (let ((fname  (expand-file-name (car var))))
 571           (setq fname (org-protocol-check-filename-for-protocol
 572                        fname (member var flist)  client))
 573           (if (eq fname t) ;; greedy? We need the `t' return value.
 574               (progn
 575                 (ad-set-arg 0 nil)
 576                 (throw 'greedy t))
 577             (if (stringp fname) ;; probably filename
 578                 (setcar var fname)
 579               (ad-set-arg 0 (delq var (ad-get-arg 0))))))))))
 580
 581 ;;; Org specific functions:
 582
 583 (defun org-protocol-create-for-org ()
 584   "Create a org-protocol project for the current file's Org-mode project.
 585 This works, if the file visited is part of a publishing project in
 586 `org-publish-project-alist'.  This function calls `org-protocol-create' to do
 587 most of the work."
 588   (interactive)
 589   (require 'org-publish)
 590   (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
 591     (if all (org-protocol-create (cdr all))
 592       (message "Not in an org-project. Did mean %s?"
 593                (substitute-command-keys"\\[org-protocol-create]")))))
 594
 595 (defun org-protocol-create (&optional project-plist)
 596   "Create a new org-protocol project interactively.
 597 An org-protocol project is an entry in `org-protocol-project-alist'
 598 which is used by `org-protocol-open-source'.
 599 Optionally use project-plist to initialize the defaults for this project. If
 600 project-plist is the CDR of an element in `org-publish-project-alist', reuse
 601 :base-directory, :html-extension and :base-extension."
 602   (interactive)
 603   (let ((working-dir (expand-file-name
 604                       (or (plist-get project-plist :base-directory)
 605                           default-directory)))
 606         (base-url "http://orgmode.org/worg/")
 607         (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
 608         (working-suffix (if (plist-get project-plist :base-extension)
 609                             (concat "." (plist-get project-plist :base-extension))
 610                           ".org"))
 611         (worglet-buffer nil)
 612         (insert-default-directory t)
 613         (minibuffer-allow-text-properties nil))
 614
 615     (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
 616     (if (not (string-match "\\/$" base-url))
 617         (setq base-url (concat base-url "/")))
 618
 619     (setq working-dir
 620           (expand-file-name
 621            (read-directory-name "Local working directory: " working-dir working-dir t)))
 622     (if (not (string-match "\\/$" working-dir))
 623         (setq working-dir (concat working-dir "/")))
 624
 625     (setq strip-suffix
 626           (read-string
 627            (concat "Extension to strip from published URLs (" strip-suffix "): ")
 628                    strip-suffix nil strip-suffix t))
 629
 630     (setq working-suffix
 631           (read-string
 632            (concat "Extension of editable files (" working-suffix "): ")
 633                    working-suffix nil working-suffix t))
 634
 635     (when (yes-or-no-p "Save the new org-protocol-project to your init file? ")
 636       (setq org-protocol-project-alist
 637             (cons `(,base-url . (:base-url ,base-url
 638                                  :working-directory ,working-dir
 639                                  :online-suffix ,strip-suffix
 640                                  :working-suffix ,working-suffix))
 641                   org-protocol-project-alist))
 642       (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))))
 643
 644 (provide 'org-protocol)
 645
 646 ;; arch-tag: b5c5c2ac-77cf-4a94-a649-2163dff95846
 647 ;;; org-protocol.el ends here