lisp/org-archive.el

   1 ;;; org-archive.el --- Archiving for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 7.5
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the face definitions for Org.
  30
  31 ;;; Code:
  32
  33 (require 'org)
  34
  35 (declare-function org-inlinetask-remove-END-maybe "org-inlinetask" ())
  36
  37 (defcustom org-archive-default-command 'org-archive-subtree
  38   "The default archiving command."
  39   :group 'org-archive
  40   :type '(choice
  41           (const org-archive-subtree)
  42           (const org-archive-to-archive-sibling)
  43           (const org-archive-set-tag)))
  44
  45 (defcustom org-archive-reversed-order nil
  46   "Non-nil means make the tree first child under the archive heading, not last."
  47   :group 'org-archive
  48   :type 'boolean)
  49
  50 (defcustom org-archive-sibling-heading "Archive"
  51   "Name of the local archive sibling that is used to archive entries locally.
  52 Locally means: in the tree, under a sibling.
  53 See `org-archive-to-archive-sibling' for more information."
  54   :group 'org-archive
  55   :type 'string)
  56
  57 (defcustom org-archive-mark-done nil
  58   "Non-nil means mark entries as DONE when they are moved to the archive file.
  59 This can be a string to set the keyword to use.  When t, Org-mode will
  60 use the first keyword in its list that means done."
  61   :group 'org-archive
  62   :type '(choice
  63           (const :tag "No" nil)
  64           (const :tag "Yes" t)
  65           (string :tag "Use this keyword")))
  66
  67 (defcustom org-archive-stamp-time t
  68   "Non-nil means add a time stamp to entries moved to an archive file.
  69 This variable is obsolete and has no effect anymore, instead add or remove
  70 `time' from the variable `org-archive-save-context-info'."
  71   :group 'org-archive
  72   :type 'boolean)
  73
  74 (defcustom org-archive-subtree-add-inherited-tags 'infile
  75   "Non-nil means append inherited tags when archiving a subtree."
  76   :group 'org-archive
  77   :type '(choice
  78           (const :tag "Never" nil)
  79           (const :tag "When archiving a subtree to the same file" infile)
  80           (const :tag "Always" t)))
  81
  82 (defcustom org-archive-save-context-info '(time file olpath category todo itags)
  83   "Parts of context info that should be stored as properties when archiving.
  84 When a subtree is moved to an archive file, it loses information given by
  85 context, like inherited tags, the category, and possibly also the TODO
  86 state (depending on the variable `org-archive-mark-done').
  87 This variable can be a list of any of the following symbols:
  88
  89 time       The time of archiving.
  90 file       The file where the entry originates.
  91 ltags      The local tags, in the headline of the subtree.
  92 itags      The tags the subtree inherits from further up the hierarchy.
  93 todo       The pre-archive TODO state.
  94 category   The category, taken from file name or #+CATEGORY lines.
  95 olpath     The outline path to the item.  These are all headlines above
  96            the current item, separated by /, like a file path.
  97
  98 For each symbol present in the list, a property will be created in
  99 the archived entry, with a prefix \"ARCHIVE_\", to remember this
 100 information."
 101   :group 'org-archive
 102   :type '(set :greedy t
 103           (const :tag "Time" time)
 104           (const :tag "File" file)
 105           (const :tag "Category" category)
 106           (const :tag "TODO state" todo)
 107           (const :tag "Priority" priority)
 108           (const :tag "Inherited tags" itags)
 109           (const :tag "Outline path" olpath)
 110           (const :tag "Local tags" ltags)))
 111
 112 (defun org-get-local-archive-location ()
 113   "Get the archive location applicable at point."
 114   (let ((re "^#\\+ARCHIVE:[ \t]+\\(\\S-.*\\S-\\)[ \t]*$")
 115         prop)
 116     (save-excursion
 117       (save-restriction
 118         (widen)
 119         (setq prop (org-entry-get nil "ARCHIVE" 'inherit))
 120         (cond
 121          ((and prop (string-match "\\S-" prop))
 122           prop)
 123          ((or (re-search-backward re nil t)
 124               (re-search-forward re nil t))
 125           (match-string 1))
 126          (t org-archive-location))))))
 127
 128 (defun org-add-archive-files (files)
 129   "Splice the archive files into the list of files.
 130 This implies visiting all these files and finding out what the
 131 archive file is."
 132   (org-uniquify
 133    (apply
 134     'append
 135     (mapcar
 136      (lambda (f)
 137        (if (not (file-exists-p f))
 138            nil
 139          (with-current-buffer (org-get-agenda-file-buffer f)
 140            (cons f (org-all-archive-files)))))
 141      files))))
 142
 143 (defun org-all-archive-files ()
 144   "Get a list of all archive files used in the current buffer."
 145   (let (file files)
 146     (save-excursion
 147       (save-restriction
 148         (goto-char (point-min))
 149         (while (re-search-forward
 150                 "^\\(#\\+\\|[ \t]*:\\)ARCHIVE:[ \t]+\\(.*\\)"
 151                 nil t)
 152           (setq file (org-extract-archive-file
 153                       (org-match-string-no-properties 2)))
 154           (and file (> (length file) 0) (file-exists-p file)
 155                (add-to-list 'files file)))))
 156     (setq files (nreverse files))
 157     (setq file (org-extract-archive-file))
 158     (and file (> (length file) 0) (file-exists-p file)
 159          (add-to-list 'files file))
 160     files))
 161
 162 (defun org-extract-archive-file (&optional location)
 163   "Extract and expand the file name from archive LOCATION.
 164 if LOCATION is not given, the value of `org-archive-location' is used."
 165   (setq location (or location org-archive-location))
 166   (if (string-match "\\(.*\\)::\\(.*\\)" location)
 167       (if (= (match-beginning 1) (match-end 1))
 168           (buffer-file-name)
 169         (expand-file-name
 170          (format (match-string 1 location)
 171                  (file-name-nondirectory buffer-file-name))))))
 172
 173 (defun org-extract-archive-heading (&optional location)
 174   "Extract the heading from archive LOCATION.
 175 if LOCATION is not given, the value of `org-archive-location' is used."
 176   (setq location (or location org-archive-location))
 177   (if (string-match "\\(.*\\)::\\(.*\\)" location)
 178       (format (match-string 2 location)
 179               (file-name-nondirectory buffer-file-name))))
 180
 181 (defun org-archive-subtree (&optional find-done)
 182   "Move the current subtree to the archive.
 183 The archive can be a certain top-level heading in the current file, or in
 184 a different file.  The tree will be moved to that location, the subtree
 185 heading be marked DONE, and the current time will be added.
 186
 187 When called with prefix argument FIND-DONE, find whole trees without any
 188 open TODO items and archive them (after getting confirmation from the user).
 189 If the cursor is not at a headline when this command is called, try all level
 190 1 trees.  If the cursor is on a headline, only try the direct children of
 191 this heading."
 192   (interactive "P")
 193   (if find-done
 194       (org-archive-all-done)
 195     ;; Save all relevant TODO keyword-relatex variables
 196
 197     (let ((tr-org-todo-line-regexp org-todo-line-regexp) ; keep despite compiler
 198           (tr-org-todo-keywords-1 org-todo-keywords-1)
 199           (tr-org-todo-kwd-alist org-todo-kwd-alist)
 200           (tr-org-done-keywords org-done-keywords)
 201           (tr-org-todo-regexp org-todo-regexp)
 202           (tr-org-todo-line-regexp org-todo-line-regexp)
 203           (tr-org-odd-levels-only org-odd-levels-only)
 204           (this-buffer (current-buffer))
 205           ;; start of variables that will be used for saving context
 206           ;; The compiler complains about them - keep them anyway!
 207           (file (abbreviate-file-name (buffer-file-name)))
 208           (olpath (mapconcat 'identity (org-get-outline-path) "/"))
 209           (time (format-time-string
 210                  (substring (cdr org-time-stamp-formats) 1 -1)
 211                  (current-time)))
 212           category todo priority ltags itags atags
 213           ;; end of variables that will be used for saving context
 214           location afile heading buffer level newfile-p infile-p visiting)
 215
 216       ;; Find the local archive location
 217       (setq location (org-get-local-archive-location)
 218             afile (org-extract-archive-file location)
 219             heading (org-extract-archive-heading location)
 220             infile-p (equal file (abbreviate-file-name afile)))
 221       (unless afile
 222         (error "Invalid `org-archive-location'"))
 223
 224       (if (> (length afile) 0)
 225           (setq newfile-p (not (file-exists-p afile))
 226                 visiting (find-buffer-visiting afile)
 227                 buffer (or visiting (find-file-noselect afile)))
 228         (setq buffer (current-buffer)))
 229       (unless buffer
 230         (error "Cannot access file \"%s\"" afile))
 231       (if (and (> (length heading) 0)
 232                (string-match "^\\*+" heading))
 233           (setq level (match-end 0))
 234         (setq heading nil level 0))
 235       (save-excursion
 236         (org-back-to-heading t)
 237         ;; Get context information that will be lost by moving the tree
 238         (setq category (org-get-category nil 'force-refresh)
 239               todo (and (looking-at org-todo-line-regexp)
 240                         (match-string 2))
 241               priority (org-get-priority
 242                         (if (match-end 3) (match-string 3) ""))
 243               ltags (org-get-tags)
 244               itags (org-delete-all ltags (org-get-tags-at))
 245               atags (org-get-tags-at))
 246         (setq ltags (mapconcat 'identity ltags " ")
 247               itags (mapconcat 'identity itags " "))
 248         ;; We first only copy, in case something goes wrong
 249         ;; we need to protect `this-command', to avoid kill-region sets it,
 250         ;; which would lead to duplication of subtrees
 251         (let (this-command) (org-copy-subtree 1 nil t))
 252         (set-buffer buffer)
 253         ;; Enforce org-mode for the archive buffer
 254         (if (not (org-mode-p))
 255             ;; Force the mode for future visits.
 256             (let ((org-insert-mode-line-in-empty-file t)
 257                   (org-inhibit-startup t))
 258               (call-interactively 'org-mode)))
 259         (when newfile-p
 260           (goto-char (point-max))
 261           (insert (format "\nArchived entries from file %s\n\n"
 262                           (buffer-file-name this-buffer))))
 263         ;; Force the TODO keywords of the original buffer
 264         (let ((org-todo-line-regexp tr-org-todo-line-regexp)
 265               (org-todo-keywords-1 tr-org-todo-keywords-1)
 266               (org-todo-kwd-alist tr-org-todo-kwd-alist)
 267               (org-done-keywords tr-org-done-keywords)
 268               (org-todo-regexp tr-org-todo-regexp)
 269               (org-todo-line-regexp tr-org-todo-line-regexp)
 270               (org-odd-levels-only
 271                (if (local-variable-p 'org-odd-levels-only (current-buffer))
 272                    org-odd-levels-only
 273                  tr-org-odd-levels-only)))
 274           (goto-char (point-min))
 275           (show-all)
 276           (if heading
 277               (progn
 278                 (if (re-search-forward
 279                      (concat "^" (regexp-quote heading)
 280                              (org-re "[ \t]*\\(:[[:alnum:]_@#%:]+:\\)?[ \t]*\\($\\|\r\\)"))
 281                      nil t)
 282                     (goto-char (match-end 0))
 283                   ;; Heading not found, just insert it at the end
 284                   (goto-char (point-max))
 285                   (or (bolp) (insert "\n"))
 286                   (insert "\n" heading "\n")
 287                   (end-of-line 0))
 288                 ;; Make the subtree visible
 289                 (show-subtree)
 290                 (if org-archive-reversed-order
 291                     (progn
 292                       (org-back-to-heading t)
 293                       (outline-next-heading))
 294                   (org-end-of-subtree t))
 295                 (skip-chars-backward " \t\r\n")
 296                 (and (looking-at "[ \t\r\n]*")
 297                      (replace-match "\n\n")))
 298             ;; No specific heading, just go to end of file.
 299             (goto-char (point-max)) (insert "\n"))
 300           ;; Paste
 301           (org-paste-subtree (org-get-valid-level level (and heading 1)))
 302           ;; Shall we append inherited tags?
 303           (and itags
 304                (or (and (eq org-archive-subtree-add-inherited-tags 'infile)
 305                         infile-p)
 306                    (eq org-archive-subtree-add-inherited-tags t))
 307                (org-set-tags-to atags))
 308           ;; Mark the entry as done
 309           (when (and org-archive-mark-done
 310                      (looking-at org-todo-line-regexp)
 311                      (or (not (match-end 2))
 312                          (not (member (match-string 2) org-done-keywords))))
 313             (let (org-log-done org-todo-log-states)
 314               (org-todo
 315                (car (or (member org-archive-mark-done org-done-keywords)
 316                         org-done-keywords)))))
 317
 318           ;; Add the context info
 319           (when org-archive-save-context-info
 320             (let ((l org-archive-save-context-info) e n v)
 321               (while (setq e (pop l))
 322                 (when (and (setq v (symbol-value e))
 323                            (stringp v) (string-match "\\S-" v))
 324                   (setq n (concat "ARCHIVE_" (upcase (symbol-name e))))
 325                   (org-entry-put (point) n v)))))
 326
 327           ;; Save and kill the buffer, if it is not the same buffer.
 328           (when (not (eq this-buffer buffer))
 329             (save-buffer))
 330           ))
 331       ;; Here we are back in the original buffer.  Everything seems to have
 332       ;; worked.  So now cut the tree and finish up.
 333       (let (this-command) (org-cut-subtree))
 334       (when (featurep 'org-inlinetask)
 335         (org-inlinetask-remove-END-maybe))
 336       (setq org-markers-to-move nil)
 337       (message "Subtree archived %s"
 338                (if (eq this-buffer buffer)
 339                    (concat "under heading: " heading)
 340                  (concat "in file: " (abbreviate-file-name afile))))))
 341   (org-reveal)
 342   (if (looking-at "^[ \t]*$")
 343       (outline-next-visible-heading 1)))
 344
 345 (defun org-archive-to-archive-sibling ()
 346   "Archive the current heading by moving it under the archive sibling.
 347 The archive sibling is a sibling of the heading with the heading name
 348 `org-archive-sibling-heading' and an `org-archive-tag' tag.  If this
 349 sibling does not exist, it will be created at the end of the subtree."
 350   (interactive)
 351   (save-restriction
 352     (widen)
 353     (let (b e pos leader level)
 354       (org-back-to-heading t)
 355       (looking-at outline-regexp)
 356       (setq leader (match-string 0)
 357             level (funcall outline-level))
 358       (setq pos (point))
 359       (condition-case nil
 360           (outline-up-heading 1 t)
 361         (error (setq e (point-max)) (goto-char (point-min))))
 362       (setq b (point))
 363       (unless e
 364         (condition-case nil
 365             (org-end-of-subtree t t)
 366           (error (goto-char (point-max))))
 367         (setq e (point)))
 368       (goto-char b)
 369       (unless (re-search-forward
 370                (concat "^" (regexp-quote leader)
 371                        "[ \t]*"
 372                        org-archive-sibling-heading
 373                        "[ \t]*:"
 374                        org-archive-tag ":") e t)
 375         (goto-char e)
 376         (or (bolp) (newline))
 377         (insert leader org-archive-sibling-heading "\n")
 378         (beginning-of-line 0)
 379         (org-toggle-tag org-archive-tag 'on))
 380       (beginning-of-line 1)
 381       (if org-archive-reversed-order
 382           (outline-next-heading)
 383         (org-end-of-subtree t t))
 384       (save-excursion
 385         (goto-char pos)
 386         (let ((this-command this-command)) (org-cut-subtree)))
 387       (org-paste-subtree (org-get-valid-level level 1))
 388       (org-set-property
 389        "ARCHIVE_TIME"
 390        (format-time-string
 391         (substring (cdr org-time-stamp-formats) 1 -1)
 392         (current-time)))
 393       (outline-up-heading 1 t)
 394       (hide-subtree)
 395       (org-cycle-show-empty-lines 'folded)
 396       (goto-char pos)))
 397   (org-reveal)
 398   (if (looking-at "^[ \t]*$")
 399       (outline-next-visible-heading 1)))
 400
 401 (defun org-archive-all-done (&optional tag)
 402   "Archive sublevels of the current tree without open TODO items.
 403 If the cursor is not on a headline, try all level 1 trees.  If
 404 it is on a headline, try all direct children.
 405 When TAG is non-nil, don't move trees, but mark them with the ARCHIVE tag."
 406   (let ((re (concat "^\\*+ +" org-not-done-regexp)) re1
 407         (rea (concat ".*:" org-archive-tag ":"))
 408         (begm (make-marker))
 409         (endm (make-marker))
 410         (question (if tag "Set ARCHIVE tag (no open TODO items)? "
 411                     "Move subtree to archive (no open TODO items)? "))
 412         beg end (cntarch 0))
 413     (if (org-on-heading-p)
 414         (progn
 415           (setq re1 (concat "^" (regexp-quote
 416                                  (make-string
 417                                   (+ (- (match-end 0) (match-beginning 0) 1)
 418                                      (if org-odd-levels-only 2 1))
 419                                   ?*))
 420                             " "))
 421           (move-marker begm (point))
 422           (move-marker endm (org-end-of-subtree t)))
 423       (setq re1 "^* ")
 424       (move-marker begm (point-min))
 425       (move-marker endm (point-max)))
 426     (save-excursion
 427       (goto-char begm)
 428       (while (re-search-forward re1 endm t)
 429         (setq beg (match-beginning 0)
 430               end (save-excursion (org-end-of-subtree t) (point)))
 431         (goto-char beg)
 432         (if (re-search-forward re end t)
 433             (goto-char end)
 434           (goto-char beg)
 435           (if (and (or (not tag) (not (looking-at rea)))
 436                    (y-or-n-p question))
 437               (progn
 438                 (if tag
 439                     (org-toggle-tag org-archive-tag 'on)
 440                   (org-archive-subtree))
 441                 (setq cntarch (1+ cntarch)))
 442             (goto-char end)))))
 443     (message "%d trees archived" cntarch)))
 444
 445 (defun org-toggle-archive-tag (&optional find-done)
 446   "Toggle the archive tag for the current headline.
 447 With prefix ARG, check all children of current headline and offer tagging
 448 the children that do not contain any open TODO items."
 449   (interactive "P")
 450   (if find-done
 451       (org-archive-all-done 'tag)
 452     (let (set)
 453       (save-excursion
 454         (org-back-to-heading t)
 455         (setq set (org-toggle-tag org-archive-tag))
 456         (when set (hide-subtree)))
 457       (and set (beginning-of-line 1))
 458       (message "Subtree %s" (if set "archived" "unarchived")))))
 459
 460 (defun org-archive-set-tag ()
 461   "Set the ARCHIVE tag."
 462   (interactive)
 463   (org-toggle-tag org-archive-tag 'on))
 464
 465 ;;;###autoload
 466 (defun org-archive-subtree-default ()
 467   "Archive the current subtree with the default command.
 468 This command is set with the variable `org-archive-default-command'."
 469   (interactive)
 470   (call-interactively org-archive-default-command))
 471
 472 ;;;###autoload
 473 (defun org-archive-subtree-default-with-confirmation ()
 474   "Archive the current subtree with the default command.
 475 This command is set with the variable `org-archive-default-command'."
 476   (interactive)
 477   (if (y-or-n-p "Archive this subtree or entry? ")
 478       (call-interactively org-archive-default-command)
 479     (error "Abort")))
 480
 481 (provide 'org-archive)
 482
 483 ;; arch-tag: 0837f601-9699-43c3-8b90-631572ae6c85
 484
 485 ;;; org-archive.el ends here