lisp/ob-asymptote.el

   1 ;;; ob-asymptote.el --- org-babel functions for asymptote evaluation
   2
   3 ;; Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating asymptote source code.
  28 ;;
  29 ;; This differs from most standard languages in that
  30 ;;
  31 ;; 1) there is no such thing as a "session" in asymptote
  32 ;;
  33 ;; 2) we are generally only going to return results of type "file"
  34 ;;
  35 ;; 3) we are adding the "file" and "cmdline" header arguments, if file
  36 ;;    is omitted then the -V option is passed to the asy command for
  37 ;;    interactive viewing
  38
  39 ;;; Requirements:
  40
  41 ;; - The asymptote program :: http://asymptote.sourceforge.net/
  42 ;;
  43 ;; - asy-mode :: Major mode for editing asymptote files
  44
  45 ;;; Code:
  46 (require 'ob)
  47 (eval-when-compile (require 'cl))
  48
  49 (declare-function orgtbl-to-generic "org-table" (table params))
  50 (declare-function org-combine-plists "org" (&rest plists))
  51
  52 (defvar org-babel-tangle-lang-exts)
  53 (add-to-list 'org-babel-tangle-lang-exts '("asymptote" . "asy"))
  54
  55 (defvar org-babel-default-header-args:asymptote
  56   '((:results . "file") (:exports . "results"))
  57   "Default arguments when evaluating an Asymptote source block.")
  58
  59 (defun org-babel-execute:asymptote (body params)
  60   "Execute a block of Asymptote code.
  61 This function is called by `org-babel-execute-src-block'."
  62   (let* ((result-params (split-string (or (cdr (assoc :results params)) "")))
  63          (out-file (cdr (assoc :file params)))
  64          (format (or (and out-file
  65                           (string-match ".+\\.\\(.+\\)" out-file)
  66                           (match-string 1 out-file))
  67                      "pdf"))
  68          (cmdline (cdr (assoc :cmdline params)))
  69          (in-file (org-babel-temp-file "asymptote-"))
  70          (cmd
  71           (concat "asy "
  72                   (if out-file
  73                       (concat
  74                        "-globalwrite -f " format
  75                        " -o " (org-babel-process-file-name out-file))
  76                     "-V")
  77                   " " cmdline
  78                   " " (org-babel-process-file-name in-file))))
  79     (with-temp-file in-file
  80       (insert (org-babel-expand-body:generic
  81                body params
  82                (org-babel-variable-assignments:asymptote params))))
  83     (message cmd) (shell-command cmd)
  84     nil)) ;; signal that output has already been written to file
  85
  86 (defun org-babel-prep-session:asymptote (session params)
  87   "Return an error if the :session header argument is set.
  88 Asymptote does not support sessions"
  89   (error "Asymptote does not support sessions"))
  90
  91 (defun org-babel-variable-assignments:asymptote (params)
  92   "Return list of asymptote statements assigning the block's variables"
  93   (mapcar #'org-babel-asymptote-var-to-asymptote
  94           (mapcar #'cdr (org-babel-get-header params :var))))
  95
  96 (defun org-babel-asymptote-var-to-asymptote (pair)
  97   "Convert an elisp value into an Asymptote variable.
  98 The elisp value PAIR is converted into Asymptote code specifying
  99 a variable of the same value."
 100   (let ((var (car pair))
 101         (val (if (symbolp (cdr pair))
 102                  (symbol-name (cdr pair))
 103                (cdr pair))))
 104     (cond
 105      ((integerp val)
 106       (format "int %S=%S;" var val))
 107      ((floatp val)
 108       (format "real %S=%S;" var val))
 109      ((stringp val)
 110       (format "string %S=\"%s\";" var val))
 111      ((listp val)
 112       (let* ((dimension-2-p (not (null (cdr val))))
 113              (dim (if dimension-2-p "[][]" "[]"))
 114              (type (org-babel-asymptote-define-type val))
 115              (array (org-babel-asymptote-table-to-array
 116                      val
 117                      (if dimension-2-p '(:lstart "{" :lend "}," :llend "}")))))
 118         (format "%S%s %S=%s;" type dim var array))))))
 119
 120 (defun org-babel-asymptote-table-to-array (table params)
 121   "Convert values of an elisp table into a string of an asymptote array.
 122 Empty cells are ignored."
 123   (labels ((atom-to-string (table)
 124                            (cond
 125                             ((null table) '())
 126                             ((not (listp (car table)))
 127                              (cons (if (and (stringp (car table))
 128                                             (not (string= (car table) "")))
 129                                        (format "\"%s\"" (car table))
 130                                      (format "%s" (car table)))
 131                                    (atom-to-string (cdr table))))
 132                             (t
 133                              (cons (atom-to-string (car table))
 134                                    (atom-to-string (cdr table))))))
 135            ;; Remove any empty row
 136            (fix-empty-lines (table)
 137                             (delq nil (mapcar (lambda (l) (delq "" l)) table))))
 138     (orgtbl-to-generic
 139      (fix-empty-lines (atom-to-string table))
 140      (org-combine-plists '(:hline nil :sep "," :tstart "{" :tend "}") params))))
 141
 142 (defun org-babel-asymptote-define-type (data)
 143   "Determine type of DATA.
 144 DATA is a list. Type symbol is returned as 'symbol. The type is
 145 usually the type of the first atom encountered, except for arrays
 146 of int, where every cell must be of int type."
 147   (labels ((anything-but-int (el)
 148                              (cond
 149                               ((null el) nil)
 150                               ((not (listp (car el)))
 151                                (cond
 152                                 ((floatp (car el)) 'real)
 153                                 ((stringp (car el)) 'string)
 154                                 (t
 155                                  (anything-but-int (cdr el)))))
 156                               (t
 157                                (or (anything-but-int (car el))
 158                                    (anything-but-int (cdr el)))))))
 159     (or (anything-but-int data) 'int)))
 160
 161 (provide 'ob-asymptote)
 162
 163 ;; arch-tag: f2f5bd0d-78e8-412b-8e6c-6dadc94cc06b
 164
 165 ;;; ob-asymptote.el ends here