lisp/org-src.el

   1 ;;; org-src.el --- Source code examples in Org       -*- lexical-binding: t; -*-
   2 ;;
   3 ;; Copyright (C) 2004-2015 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;         Bastien Guerry <bzg@gnu.org>
   7 ;;         Dan Davison <davison at stats dot ox dot ac dot uk>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the code dealing with source code examples in Org-mode.
  30
  31 ;;; Code:
  32
  33 (require 'org-macs)
  34 (require 'org-compat)
  35 (require 'ob-keys)
  36 (require 'ob-comint)
  37 (eval-when-compile (require 'cl))
  38
  39 (declare-function org-base-buffer "org" (buffer))
  40 (declare-function org-do-remove-indentation "org" (&optional n))
  41 (declare-function org-element-at-point "org-element" ())
  42 (declare-function org-element-context "org-element" (&optional element))
  43 (declare-function org-element-lineage "org-element"
  44                   (blob &optional types with-self))
  45 (declare-function org-element-property "org-element" (property element))
  46 (declare-function org-element-type "org-element" (element))
  47 (declare-function org-footnote-goto-definition "org-footnote"
  48                   (label &optional location))
  49 (declare-function org-get-indentation "org" (&optional line))
  50 (declare-function org-pop-to-buffer-same-window "org-compat"
  51                   (&optional buffer-or-name norecord label))
  52 (declare-function org-some "org" (pred seq))
  53 (declare-function org-switch-to-buffer-other-window "org" (&rest args))
  54 (declare-function org-trim "org" (s))
  55
  56 (defvar org-element-all-elements)
  57 (defvar org-inhibit-startup)
  58
  59 (defcustom org-edit-src-turn-on-auto-save nil
  60   "Non-nil means turn `auto-save-mode' on when editing a source block.
  61 This will save the content of the source code editing buffer into
  62 a newly created file, not the base buffer for this source block.
  63
  64 If you want to regularly save the base buffer instead of the source
  65 code editing buffer, see `org-edit-src-auto-save-idle-delay' instead."
  66   :group 'org-edit-structure
  67   :version "24.4"
  68   :package-version '(Org . "8.0")
  69   :type 'boolean)
  70
  71 (defcustom org-edit-src-auto-save-idle-delay 0
  72   "Delay before saving a source code buffer back into its base buffer.
  73 When a positive integer N, save after N seconds of idle time.
  74 When 0 (the default), don't auto-save.
  75
  76 If you want to save the source code buffer itself, don't use this.
  77 Check `org-edit-src-turn-on-auto-save' instead."
  78   :group 'org-edit-structure
  79   :version "24.4"
  80   :package-version '(Org . "8.0")
  81   :type 'integer)
  82
  83 (defcustom org-coderef-label-format "(ref:%s)"
  84   "The default coderef format.
  85 This format string will be used to search for coderef labels in literal
  86 examples (EXAMPLE and SRC blocks).  The format can be overwritten in
  87 an individual literal example with the -l option, like
  88
  89 #+BEGIN_SRC pascal +n -r -l \"((%s))\"
  90 ...
  91 #+END_SRC
  92
  93 If you want to use this for HTML export, make sure that the format does
  94 not introduce special font-locking, and avoid the HTML special
  95 characters `<', `>', and `&'.  The reason for this restriction is that
  96 the labels are searched for only after htmlize has done its job."
  97   :group 'org-edit-structure ; FIXME this is not in the right group
  98   :type 'string)
  99
 100 (defcustom org-edit-fixed-width-region-mode 'artist-mode
 101   "The mode that should be used to edit fixed-width regions.
 102 These are the regions where each line starts with a colon."
 103   :group 'org-edit-structure
 104   :type '(choice
 105           (const artist-mode)
 106           (const picture-mode)
 107           (const fundamental-mode)
 108           (function :tag "Other (specify)")))
 109
 110 (defcustom org-src-preserve-indentation nil
 111   "If non-nil preserve leading whitespace characters on export.
 112 If non-nil leading whitespace characters in source code blocks
 113 are preserved on export, and when switching between the org
 114 buffer and the language mode edit buffer.
 115
 116 When this variable is nil, after editing with \\[org-edit-src-code],
 117 the minimum (across-lines) number of leading whitespace characters
 118 are removed from all lines, and the code block is uniformly indented
 119 according to the value of `org-edit-src-content-indentation'."
 120   :group 'org-edit-structure
 121   :type 'boolean)
 122
 123 (defcustom org-edit-src-content-indentation 2
 124   "Indentation for the content of a source code block.
 125 This should be the number of spaces added to the indentation of the #+begin
 126 line in order to compute the indentation of the block content after
 127 editing it with \\[org-edit-src-code].  Has no effect if
 128 `org-src-preserve-indentation' is non-nil."
 129   :group 'org-edit-structure
 130   :type 'integer)
 131
 132 (defcustom org-edit-src-persistent-message t
 133   "Non-nil means show persistent exit help message while editing src examples.
 134 The message is shown in the header-line, which will be created in the
 135 first line of the window showing the editing buffer."
 136   :group 'org-edit-structure
 137   :type 'boolean)
 138
 139 (defcustom org-src-ask-before-returning-to-edit-buffer t
 140   "Non-nil means ask before switching to an existing edit buffer.
 141 If nil, when `org-edit-src-code' is used on a block that already
 142 has an active edit buffer, it will switch to that edit buffer
 143 immediately; otherwise it will ask whether you want to return to
 144 the existing edit buffer."
 145   :group 'org-edit-structure
 146   :version "24.4"
 147   :package-version '(Org . "8.0")
 148   :type 'boolean)
 149
 150 (defcustom org-src-window-setup 'reorganize-frame
 151   "How the source code edit buffer should be displayed.
 152 Possible values for this option are:
 153
 154 current-window    Show edit buffer in the current window, keeping all other
 155                   windows.
 156 other-window      Use `switch-to-buffer-other-window' to display edit buffer.
 157 reorganize-frame  Show only two windows on the current frame, the current
 158                   window and the edit buffer.  When exiting the edit buffer,
 159                   return to one window.
 160 other-frame       Use `switch-to-buffer-other-frame' to display edit buffer.
 161                   Also, when exiting the edit buffer, kill that frame."
 162   :group 'org-edit-structure
 163   :type '(choice
 164           (const current-window)
 165           (const other-frame)
 166           (const other-window)
 167           (const reorganize-frame)))
 168
 169 (defvar org-src-mode-hook nil
 170   "Hook run after Org switched a source code snippet to its Emacs mode.
 171 \\<org-mode-map>
 172 This hook will run:
 173 - when editing a source code snippet with \\[org-edit-special]
 174 - when formatting a source code snippet for export with htmlize.
 175
 176 You may want to use this hook for example to turn off `outline-minor-mode'
 177 or similar things which you want to have when editing a source code file,
 178 but which mess up the display of a snippet in Org exported files.")
 179
 180 (defcustom org-src-lang-modes
 181   '(("ocaml" . tuareg) ("elisp" . emacs-lisp) ("ditaa" . artist)
 182     ("asymptote" . asy) ("dot" . fundamental) ("sqlite" . sql)
 183     ("calc" . fundamental) ("C" . c) ("cpp" . c++) ("C++" . c++)
 184     ("screen" . shell-script) ("shell" . sh) ("bash" . sh))
 185   "Alist mapping languages to their major mode.
 186 The key is the language name, the value is the string that should
 187 be inserted as the name of the major mode.  For many languages this is
 188 simple, but for language where this is not the case, this variable
 189 provides a way to simplify things on the user side.
 190 For example, there is no ocaml-mode in Emacs, but the mode to use is
 191 `tuareg-mode'."
 192   :group 'org-edit-structure
 193   :type '(repeat
 194           (cons
 195            (string "Language name")
 196            (symbol "Major mode"))))
 197
 198 (defcustom org-src-tab-acts-natively nil
 199   "If non-nil, the effect of TAB in a code block is as if it were
 200 issued in the language major mode buffer."
 201   :type 'boolean
 202   :version "24.1"
 203   :group 'org-babel)
 204
 205
 206 \f
 207 ;;; Internal functions and variables
 208
 209 (defvar org-src--allow-write-back t)
 210 (defvar org-src--auto-save-timer nil)
 211 (defvar org-src--babel-info nil)
 212 (defvar org-src--beg-marker nil)
 213 (defvar org-src--block-indentation nil)
 214 (defvar org-src--end-marker nil)
 215 (defvar org-src--from-org-mode nil)
 216 (defvar org-src--overlay nil)
 217 (defvar org-src--preserve-indentation nil)
 218 (defvar org-src--remote nil)
 219 (defvar org-src--saved-temp-window-config nil)
 220
 221 (defun org-src--construct-edit-buffer-name (org-buffer-name lang)
 222   "Construct the buffer name for a source editing buffer."
 223   (concat "*Org Src " org-buffer-name "[ " lang " ]*"))
 224
 225 (defun org-src--edit-buffer (beg end)
 226   "Return buffer editing area between BEG and END.
 227 Return nil if there is no such buffer."
 228   (catch 'exit
 229     (dolist (b (buffer-list))
 230       (with-current-buffer b
 231         (and (org-src-edit-buffer-p)
 232              (= beg org-src--beg-marker)
 233              (eq (marker-buffer beg) (marker-buffer org-src--beg-marker))
 234              (= end org-src--end-marker)
 235              (eq (marker-buffer end) (marker-buffer org-src--end-marker))
 236              (throw 'exit b))))))
 237
 238 (defun org-src--source-buffer ()
 239   "Return source buffer edited by current buffer."
 240   (unless (org-src-edit-buffer-p) (error "Not in a source buffer"))
 241   (or (marker-buffer org-src--beg-marker)
 242       (error "No source buffer available for current editing session")))
 243
 244 (defun org-src--get-lang-mode (lang)
 245   "Return major mode that should be used for LANG.
 246 LANG is a string, and the returned major mode is a symbol."
 247   (intern
 248    (concat
 249     (let ((l (or (cdr (assoc lang org-src-lang-modes)) lang)))
 250       (if (symbolp l) (symbol-name l) l))
 251     "-mode")))
 252
 253 (defun org-src--coordinates (pos beg end)
 254   "Return coordinates of POS relatively to BEG and END.
 255 POS, BEG and END are buffer positions.  Return value is either
 256 a cons cell (LINE . COLUMN) or symbol `end'.  See also
 257 `org-src--goto-coordinates'."
 258   (if (>= pos end) 'end
 259     (org-with-wide-buffer
 260      (goto-char (max beg pos))
 261      (cons (count-lines beg (line-beginning-position))
 262            ;; Column is relative to the end of line to avoid problems of
 263            ;; comma escaping or colons appended in front of the line.
 264            (- (current-column)
 265               (progn (end-of-line) (current-column)))))))
 266
 267 (defun org-src--goto-coordinates (coord beg end)
 268   "Move to coordinates COORD relatively to BEG and END.
 269 COORD are coordinates, as returned by `org-src--coordinates',
 270 which see.  BEG and END are buffer positions."
 271   (goto-char
 272    (if (eq coord 'end) (max (1- end) beg)
 273      ;; If BEG happens to be located outside of the narrowed part of
 274      ;; the buffer, widen it first.
 275      (org-with-wide-buffer
 276       (goto-char beg)
 277       (forward-line (car coord))
 278       (end-of-line)
 279       (org-move-to-column (max (+ (current-column) (cdr coord)) 0))
 280       (point)))))
 281
 282 (defun org-src--contents-area (datum)
 283   "Return contents boundaries of DATUM.
 284 DATUM is an element or object.  Return a list (BEG END CONTENTS)
 285 where BEG and END are buffer positions and CONTENTS is a string."
 286   (let ((type (org-element-type datum)))
 287     (org-with-wide-buffer
 288      (cond
 289       ((eq type 'footnote-definition)
 290        (let* ((beg (progn
 291                      (goto-char (org-element-property :post-affiliated datum))
 292                      (search-forward "]")))
 293               (end (or (org-element-property :contents-end datum) beg)))
 294          (list beg end (buffer-substring-no-properties beg end))))
 295       ((org-element-property :contents-begin datum)
 296        (let ((beg (org-element-property :contents-begin datum))
 297              (end (org-element-property :contents-end datum)))
 298          (list beg end (buffer-substring-no-properties beg end))))
 299       ((memq type '(example-block export-block src-block))
 300        (list (progn (goto-char (org-element-property :post-affiliated datum))
 301                     (line-beginning-position 2))
 302              (progn (goto-char (org-element-property :end datum))
 303                     (skip-chars-backward " \r\t\n")
 304                     (line-beginning-position 1))
 305              (org-element-property :value datum)))
 306       ((memq type '(fixed-width table))
 307        (let ((beg (org-element-property :post-affiliated datum))
 308              (end (progn (goto-char (org-element-property :end datum))
 309                          (skip-chars-backward " \r\t\n")
 310                          (line-beginning-position 2))))
 311          (list beg
 312                end
 313                (if (eq type 'fixed-width) (org-element-property :value datum)
 314                  (buffer-substring-no-properties beg end)))))
 315       (t (error "Unsupported element or object: %s" type))))))
 316
 317 (defun org-src--make-source-overlay (beg end edit-buffer)
 318   "Create overlay between BEG and END positions and return it.
 319 EDIT-BUFFER is the buffer currently editing area between BEG and
 320 END."
 321   (let ((overlay (make-overlay beg end)))
 322     (overlay-put overlay 'face 'secondary-selection)
 323     (overlay-put overlay 'edit-buffer edit-buffer)
 324     (overlay-put overlay 'help-echo
 325                  "Click with mouse-1 to switch to buffer editing this segment")
 326     (overlay-put overlay 'face 'secondary-selection)
 327     (overlay-put overlay 'keymap
 328                  (let ((map (make-sparse-keymap)))
 329                    (define-key map [mouse-1] 'org-edit-src-continue)
 330                    map))
 331     (let ((read-only
 332            (list
 333             (lambda (&rest _)
 334               (user-error
 335                "Cannot modify an area being edited in a dedicated buffer")))))
 336       (overlay-put overlay 'modification-hooks read-only)
 337       (overlay-put overlay 'insert-in-front-hooks read-only)
 338       (overlay-put overlay 'insert-behind-hooks read-only))
 339     overlay))
 340
 341 (defun org-src--remove-overlay ()
 342   "Remove overlay from current source buffer."
 343   (when (overlayp org-src--overlay) (delete-overlay org-src--overlay)))
 344
 345 (defun org-src--on-datum-p (datum)
 346   "Non-nil when point is on DATUM.
 347 DATUM is an element or an object.  Consider blank lines or white
 348 spaces after it as being outside."
 349   (and (>= (point) (org-element-property :begin datum))
 350        (<= (point)
 351            (org-with-wide-buffer
 352             (goto-char (org-element-property :end datum))
 353             (skip-chars-backward " \r\t\n")
 354             (if (memq (org-element-type datum) org-element-all-elements)
 355                 (line-end-position)
 356               (point))))))
 357
 358 (defun org-src--contents-for-write-back ()
 359   "Return buffer contents in a format appropriate for write back.
 360 Assume point is in the corresponding edit buffer."
 361   (let ((indentation (or org-src--block-indentation 0))
 362         (preserve-indentation org-src--preserve-indentation)
 363         (contents (org-with-wide-buffer (buffer-string)))
 364         (write-back org-src--allow-write-back))
 365     (with-temp-buffer
 366       (insert (org-no-properties contents))
 367       (goto-char (point-min))
 368       (when (functionp write-back) (funcall write-back))
 369       (unless (or preserve-indentation (= indentation 0))
 370         (let ((ind (make-string indentation ?\s)))
 371           (goto-char (point-min))
 372           (while (not (eobp))
 373             (when (org-looking-at-p "[ \t]*\\S-") (insert ind))
 374             (forward-line))))
 375       (buffer-string))))
 376
 377 (defun org-src--edit-element
 378     (datum name &optional major write-back contents remote)
 379   "Edit DATUM contents in a dedicated buffer NAME.
 380
 381 MAJOR is the major mode used in the edit buffer.  A nil value is
 382 equivalent to `fundamental-mode'.
 383
 384 When WRITE-BACK is non-nil, assume contents will replace original
 385 region.  Moreover, if it is a function, apply it in the edit
 386 buffer, from point min, before returning the contents.
 387
 388 When CONTENTS is non-nil, display them in the edit buffer.
 389 Otherwise, show DATUM contents as specified by
 390 `org-src--contents-area'.
 391
 392 When REMOTE is non-nil, do not try to preserve point or mark when
 393 moving from the edit area to the source.
 394
 395 Leave point in edit buffer."
 396   (setq org-src--saved-temp-window-config (current-window-configuration))
 397   (let* ((area (org-src--contents-area datum))
 398          (beg (copy-marker (nth 0 area)))
 399          (end (copy-marker (nth 1 area) t))
 400          (old-edit-buffer (org-src--edit-buffer beg end))
 401          (contents (or contents (nth 2 area))))
 402     (if (and old-edit-buffer
 403              (or (not org-src-ask-before-returning-to-edit-buffer)
 404                  (y-or-n-p "Return to existing edit buffer ([n] will revert changes)? ")))
 405         ;; Move to existing buffer.
 406         (org-src-switch-to-buffer old-edit-buffer 'return)
 407       ;; Discard old edit buffer.
 408       (when old-edit-buffer
 409         (with-current-buffer old-edit-buffer (org-src--remove-overlay))
 410         (kill-buffer old-edit-buffer))
 411       (let* ((org-mode-p (derived-mode-p 'org-mode))
 412              (type (org-element-type datum))
 413              (ind (org-with-wide-buffer
 414                    (goto-char (org-element-property :begin datum))
 415                    (org-get-indentation)))
 416              (preserve-ind
 417               (and (memq type '(example-block src-block))
 418                    (or (org-element-property :preserve-indent datum)
 419                        org-src-preserve-indentation)))
 420              ;; Store relative positions of mark (if any) and point
 421              ;; within the edited area.
 422              (point-coordinates (and (not remote)
 423                                      (org-src--coordinates (point) beg end)))
 424              (mark-coordinates (and (not remote)
 425                                     (org-region-active-p)
 426                                     (let ((m (mark)))
 427                                       (and (>= m beg) (>= end m)
 428                                            (org-src--coordinates m beg end)))))
 429              ;; Generate a new edit buffer.
 430              (buffer (generate-new-buffer name))
 431              ;; Add an overlay on top of source.
 432              (overlay (org-src--make-source-overlay beg end buffer)))
 433         ;; Switch to edit buffer.
 434         (org-src-switch-to-buffer buffer 'edit)
 435         ;; Insert contents.
 436         (insert contents)
 437         (remove-text-properties (point-min) (point-max)
 438                                 '(display nil invisible nil intangible nil))
 439         (unless preserve-ind (org-do-remove-indentation))
 440         (set-buffer-modified-p nil)
 441         (setq buffer-file-name nil)
 442         ;; Start major mode.
 443         (if (not major) (fundamental-mode)
 444           (let ((org-inhibit-startup t))
 445             (condition-case e (funcall major)
 446               (error (message "Language mode `%s' fails with: %S"
 447                               major (nth 1 e))))))
 448         ;; Transmit buffer-local variables for exit function.  It must
 449         ;; be done after initializing major mode, as this operation
 450         ;; may reset them otherwise.
 451         (org-set-local 'org-src--from-org-mode org-mode-p)
 452         (org-set-local 'org-src--beg-marker beg)
 453         (org-set-local 'org-src--end-marker end)
 454         (org-set-local 'org-src--remote remote)
 455         (org-set-local 'org-src--block-indentation ind)
 456         (org-set-local 'org-src--preserve-indentation preserve-ind)
 457         (org-set-local 'org-src--overlay overlay)
 458         (org-set-local 'org-src--allow-write-back write-back)
 459         ;; Start minor mode.
 460         (org-src-mode)
 461         ;; Move mark and point in edit buffer to the corresponding
 462         ;; location.
 463         (if remote
 464             (progn
 465               ;; Put point at first non read-only character after
 466               ;; leading blank.
 467               (goto-char
 468                (or (text-property-any (point-min) (point-max) 'read-only nil)
 469                    (point-max)))
 470               (skip-chars-forward " \r\t\n"))
 471           ;; Set mark and point.
 472           (when mark-coordinates
 473             (org-src--goto-coordinates mark-coordinates (point-min) (point-max))
 474             (push-mark (point) 'no-message t)
 475             (setq deactivate-mark nil))
 476           (org-src--goto-coordinates
 477            point-coordinates (point-min) (point-max)))))))
 478
 479
 480 \f
 481 ;;; Fontification of source blocks
 482
 483 (defun org-src-font-lock-fontify-block (lang start end)
 484   "Fontify code block.
 485 This function is called by emacs automatic fontification, as long
 486 as `org-src-fontify-natively' is non-nil."
 487   (let ((lang-mode (org-src--get-lang-mode lang)))
 488     (when (fboundp lang-mode)
 489       (let ((string (buffer-substring-no-properties start end))
 490             (modified (buffer-modified-p))
 491             (org-buffer (current-buffer)) pos next)
 492         (remove-text-properties start end '(face nil))
 493         (with-current-buffer
 494             (get-buffer-create
 495              (concat " org-src-fontification:" (symbol-name lang-mode)))
 496           (delete-region (point-min) (point-max))
 497           (insert string " ") ;; so there's a final property change
 498           (unless (eq major-mode lang-mode) (funcall lang-mode))
 499           ;; Avoid `font-lock-ensure', which does not display fonts in
 500           ;; source block.
 501           (font-lock-fontify-buffer)
 502           (setq pos (point-min))
 503           (while (setq next (next-single-property-change pos 'face))
 504             (put-text-property
 505              (+ start (1- pos)) (1- (+ start next)) 'face
 506              (get-text-property pos 'face) org-buffer)
 507             (setq pos next)))
 508         (add-text-properties
 509          start end
 510          '(font-lock-fontified t fontified t font-lock-multiline t))
 511         (set-buffer-modified-p modified)))))
 512
 513
 514 \f
 515 ;;; Escape contents
 516
 517 (defun org-escape-code-in-region (beg end)
 518   "Escape lines between BEG and END.
 519 Escaping happens when a line starts with \"*\", \"#+\", \",*\" or
 520 \",#+\" by appending a comma to it."
 521   (interactive "r")
 522   (save-excursion
 523     (goto-char end)
 524     (while (re-search-backward "^[ \t]*,?\\(\\*\\|#\\+\\)" beg t)
 525       (save-excursion (replace-match ",\\1" nil nil nil 1)))))
 526
 527 (defun org-escape-code-in-string (s)
 528   "Escape lines in string S.
 529 Escaping happens when a line starts with \"*\", \"#+\", \",*\" or
 530 \",#+\" by appending a comma to it."
 531   (replace-regexp-in-string "^[ \t]*,?\\(\\*\\|#\\+\\)" ",\\1" s nil nil 1))
 532
 533 (defun org-unescape-code-in-region (beg end)
 534   "Un-escape lines between BEG and END.
 535 Un-escaping happens by removing the first comma on lines starting
 536 with \",*\", \",#+\", \",,*\" and \",,#+\"."
 537   (interactive "r")
 538   (save-excursion
 539     (goto-char end)
 540     (while (re-search-backward "^[ \t]*,?\\(,\\)\\(?:\\*\\|#\\+\\)" beg t)
 541       (save-excursion (replace-match "" nil nil nil 1)))))
 542
 543 (defun org-unescape-code-in-string (s)
 544   "Un-escape lines in string S.
 545 Un-escaping happens by removing the first comma on lines starting
 546 with \",*\", \",#+\", \",,*\" and \",,#+\"."
 547   (replace-regexp-in-string
 548    "^[ \t]*,?\\(,\\)\\(?:\\*\\|#\\+\\)" "" s nil nil 1))
 549
 550
 551 \f
 552 ;;; Org src minor mode
 553
 554 (defvar org-src-mode-map
 555   (let ((map (make-sparse-keymap)))
 556     (define-key map "\C-c'" 'org-edit-src-exit)
 557     (define-key map "\C-c\C-k" 'org-edit-src-abort)
 558     (define-key map "\C-x\C-s" 'org-edit-src-save)
 559     map))
 560
 561 (define-minor-mode org-src-mode
 562   "Minor mode for language major mode buffers generated by Org.
 563 \\<org-mode-map>
 564 This minor mode is turned on in two situations:
 565   - when editing a source code snippet with \\[org-edit-special]
 566   - when formatting a source code snippet for export with htmlize.
 567
 568 \\{org-src-mode-map}
 569
 570 See also `org-src-mode-hook'."
 571   nil " OrgSrc" nil
 572   (when org-edit-src-persistent-message
 573     (org-set-local
 574      'header-line-format
 575      (substitute-command-keys
 576       (if org-src--allow-write-back
 577           "Edit, then exit with \\[org-edit-src-exit] or abort with \
 578 \\[org-edit-src-abort]"
 579         "Exit with \\[org-edit-src-exit] or abort with \
 580 \\[org-edit-src-abort]"))))
 581   ;; Possibly activate various auto-save features (for the edit buffer
 582   ;; or the source buffer).
 583   (when org-edit-src-turn-on-auto-save
 584     (setq buffer-auto-save-file-name
 585           (concat (make-temp-name "org-src-")
 586                   (format-time-string "-%Y-%d-%m")
 587                   ".txt")))
 588   (unless (or org-src--auto-save-timer (zerop org-edit-src-auto-save-idle-delay))
 589     (setq org-src--auto-save-timer
 590           (run-with-idle-timer
 591            org-edit-src-auto-save-idle-delay t
 592            (lambda ()
 593              (save-excursion
 594                (let (edit-flag)
 595                  (dolist (b (buffer-list))
 596                    (with-current-buffer b
 597                      (when (org-src-edit-buffer-p)
 598                        (unless edit-flag (setq edit-flag t))
 599                        (when (buffer-modified-p) (org-edit-src-save)))))
 600                  (unless edit-flag
 601                    (cancel-timer org-src--auto-save-timer)
 602                    (setq org-src--auto-save-timer nil)))))))))
 603
 604 (defun org-src-mode-configure-edit-buffer ()
 605   (when (org-bound-and-true-p org-src--from-org-mode)
 606     (org-add-hook 'kill-buffer-hook #'org-src--remove-overlay nil 'local)
 607     (if (org-bound-and-true-p org-src--allow-write-back)
 608         (progn
 609           (setq buffer-offer-save t)
 610           (setq buffer-file-name
 611                 (concat (buffer-file-name (marker-buffer org-src--beg-marker))
 612                         "[" (buffer-name) "]"))
 613           (if (featurep 'xemacs)
 614               (progn
 615                 (make-variable-buffer-local 'write-contents-hooks) ; needed only for 21.4
 616                 (setq write-contents-hooks '(org-edit-src-save)))
 617             (setq write-contents-functions '(org-edit-src-save))))
 618       (setq buffer-read-only t))))
 619
 620 (org-add-hook 'org-src-mode-hook #'org-src-mode-configure-edit-buffer)
 621
 622
 623 \f
 624 ;;; Babel related functions
 625
 626 (defun org-src-associate-babel-session (info)
 627   "Associate edit buffer with comint session."
 628   (interactive)
 629   (let ((session (cdr (assoc :session (nth 2 info)))))
 630     (and session (not (string= session "none"))
 631          (org-babel-comint-buffer-livep session)
 632          (let ((f (intern (format "org-babel-%s-associate-session"
 633                                   (nth 0 info)))))
 634            (and (fboundp f) (funcall f session))))))
 635
 636 (defun org-src-babel-configure-edit-buffer ()
 637   (when org-src--babel-info
 638     (org-src-associate-babel-session org-src--babel-info)))
 639
 640 (org-add-hook 'org-src-mode-hook #'org-src-babel-configure-edit-buffer)
 641
 642 (defmacro org-src-do-at-code-block (&rest body)
 643   "Execute a command from an edit buffer in the Org mode buffer."
 644   `(let ((beg-marker org-src--beg-marker))
 645      (when beg-marker
 646        (with-current-buffer (marker-buffer beg-marker)
 647          (goto-char beg-marker)
 648          ,@body))))
 649 (def-edebug-spec org-src-do-at-code-block (body))
 650
 651 (defun org-src-do-key-sequence-at-code-block (&optional key)
 652   "Execute key sequence at code block in the source Org buffer.
 653 The command bound to KEY in the Org-babel key map is executed
 654 remotely with point temporarily at the start of the code block in
 655 the Org buffer.
 656
 657 This command is not bound to a key by default, to avoid conflicts
 658 with language major mode bindings.  To bind it to C-c @ in all
 659 language major modes, you could use
 660
 661   (add-hook \\='org-src-mode-hook
 662             (lambda () (define-key org-src-mode-map \"\\C-c@\"
 663                     \\='org-src-do-key-sequence-at-code-block)))
 664
 665 In that case, for example, C-c @ t issued in code edit buffers
 666 would tangle the current Org code block, C-c @ e would execute
 667 the block and C-c @ h would display the other available
 668 Org-babel commands."
 669   (interactive "kOrg-babel key: ")
 670   (if (equal key (kbd "C-g")) (keyboard-quit)
 671     (org-edit-src-save)
 672     (org-src-do-at-code-block
 673      (call-interactively (lookup-key org-babel-map key)))))
 674
 675
 676 \f
 677 ;;; Public functions
 678
 679 (defun org-src-edit-buffer-p (&optional buffer)
 680   "Non-nil when current buffer is a source editing buffer.
 681 If BUFFER is non-nil, test it instead."
 682   (let ((buffer (org-base-buffer (or buffer (current-buffer)))))
 683     (and (buffer-live-p buffer)
 684          (local-variable-p 'org-src--beg-marker buffer)
 685          (local-variable-p 'org-src--end-marker buffer))))
 686
 687 (defun org-src-switch-to-buffer (buffer context)
 688   (case org-src-window-setup
 689     (current-window (org-pop-to-buffer-same-window buffer))
 690     (other-window
 691      (switch-to-buffer-other-window buffer))
 692     (other-frame
 693      (case context
 694        (exit
 695         (let ((frame (selected-frame)))
 696           (switch-to-buffer-other-frame buffer)
 697           (delete-frame frame)))
 698        (save
 699         (kill-buffer (current-buffer))
 700         (org-pop-to-buffer-same-window buffer))
 701        (t (switch-to-buffer-other-frame buffer))))
 702     (reorganize-frame
 703      (when (eq context 'edit) (delete-other-windows))
 704      (org-switch-to-buffer-other-window buffer)
 705      (when (eq context 'exit) (delete-other-windows)))
 706     (switch-invisibly (set-buffer buffer))
 707     (t
 708      (message "Invalid value %s for `org-src-window-setup'"
 709               org-src-window-setup)
 710      (org-pop-to-buffer-same-window buffer))))
 711
 712 (defun org-edit-footnote-reference ()
 713   "Edit definition of footnote reference at point."
 714   (interactive)
 715   (let* ((context (org-element-context))
 716          (label (org-element-property :label context)))
 717     (unless (and (eq (org-element-type context) 'footnote-reference)
 718                  (org-src--on-datum-p context))
 719       (user-error "Not on a footnote reference"))
 720     (unless label (user-error "Cannot edit remotely anonymous footnotes"))
 721     (let* ((definition (org-with-wide-buffer
 722                         (org-footnote-goto-definition label)
 723                         (backward-char)
 724                         (org-element-context)))
 725            (inline (eq (org-element-type definition) 'footnote-reference))
 726            (contents
 727             (let ((c (org-with-wide-buffer
 728                       (org-trim (buffer-substring-no-properties
 729                                  (org-element-property :begin definition)
 730                                  (org-element-property :end definition))))))
 731               (add-text-properties
 732                0
 733                (progn (string-match (if inline "\\`\\[fn:.*?:" "\\`.*?\\]") c)
 734                       (match-end 0))
 735                '(read-only "Cannot edit footnote label" front-sticky t
 736                            rear-nonsticky t)
 737                c)
 738               (when inline
 739                 (let ((l (length c)))
 740                   (add-text-properties
 741                    (1- l) l
 742                    '(read-only "Cannot edit past footnote reference"
 743                                front-sticky nil rear-nonsticky nil)
 744                    c)))
 745               c)))
 746       (org-src--edit-element
 747        definition
 748        (format "*Edit footnote [%s]*" label)
 749        #'org-mode
 750        `(lambda ()
 751           (if ,(not inline) (delete-region (point) (search-forward "]"))
 752             (delete-region (point) (search-forward ":" nil t 2))
 753             (delete-region (1- (point-max)) (point-max))
 754             (when (re-search-forward "\n[ \t]*\n" nil t)
 755               (user-error "Inline definitions cannot contain blank lines"))
 756             ;; If footnote reference belongs to a table, make sure to
 757             ;; remove any newline characters in order to preserve
 758             ;; table's structure.
 759             (when ,(org-element-lineage definition '(table-cell))
 760               (while (search-forward "\n" nil t) (delete-char -1)))))
 761        (concat contents
 762                (and (not (org-element-property :contents-begin definition))
 763                     " "))
 764        'remote))
 765     ;; Report success.
 766     t))
 767
 768 (defun org-edit-table.el ()
 769   "Edit \"table.el\" table at point.
 770
 771 A new buffer is created and the table is copied into it.  Then
 772 the table is recognized with `table-recognize'.  When done
 773 editing, exit with \\[org-edit-src-exit].  The edited text will
 774 then replace the area in the Org mode buffer.
 775
 776 Throw an error when not at such a table."
 777   (interactive)
 778   (let ((element (org-element-at-point)))
 779     (unless (and (eq (org-element-type element) 'table)
 780                  (eq (org-element-property :type element) 'table.el)
 781                  (org-src--on-datum-p element))
 782       (user-error "Not in a table.el table"))
 783     (org-src--edit-element
 784      element
 785      (org-src--construct-edit-buffer-name (buffer-name) "Table")
 786      #'text-mode t)
 787     (when (org-bound-and-true-p flyspell-mode) (flyspell-mode -1))
 788     (table-recognize)
 789     t))
 790
 791 (defun org-edit-export-block ()
 792   "Edit export block at point.
 793
 794 A new buffer is created and the block is copied into it, and the
 795 buffer is switched into an appropriate major mode.  See also
 796 `org-src-lang-modes'.  When done, exit with
 797 \\[org-edit-src-exit].  The edited text will then replace the
 798 area in the Org mode buffer.
 799
 800 Throw an error when not at an export block."
 801   (interactive)
 802   (let ((element (org-element-at-point)))
 803     (unless (and (eq (org-element-type element) 'export-block)
 804                  (org-src--on-datum-p element))
 805       (user-error "Not in an export block"))
 806     (let* ((type (downcase (org-element-property :type element)))
 807            (mode (org-src--get-lang-mode type)))
 808       (unless (functionp mode) (error "No such language mode: %s" mode))
 809       (org-src--edit-element
 810        element
 811        (org-src--construct-edit-buffer-name (buffer-name) type)
 812        mode
 813        (lambda () (org-escape-code-in-region (point-min) (point-max)))))
 814     t))
 815
 816 (defun org-edit-src-code (&optional code edit-buffer-name)
 817   "Edit the source or example block at point.
 818 \\<org-src-mode-map>
 819 The code is copied to a separate buffer and the appropriate mode
 820 is turned on.  When done, exit with \\[org-edit-src-exit].  This \
 821 will remove the
 822 original code in the Org buffer, and replace it with the edited
 823 version.  See `org-src-window-setup' to configure the display of
 824 windows containing the Org buffer and the code buffer.
 825
 826 When optional argument CODE is a string, edit it in a dedicated
 827 buffer instead.
 828
 829 When optional argument EDIT-BUFFER-NAME is non-nil, use it as the
 830 name of the sub-editing buffer."
 831   (interactive)
 832   (let* ((element (org-element-at-point))
 833          (type (org-element-type element)))
 834     (unless (and (memq type '(example-block src-block))
 835                  (org-src--on-datum-p element))
 836       (user-error "Not in a source or example block"))
 837     (let* ((lang
 838             (if (eq type 'src-block) (org-element-property :language element)
 839               "example"))
 840            (lang-f (and (eq type 'src-block) (org-src--get-lang-mode lang)))
 841            (babel-info (and (eq type 'src-block)
 842                             (org-babel-get-src-block-info 'light)))
 843            deactivate-mark)
 844       (when (and (eq type 'src-block) (not (functionp lang-f)))
 845         (error "No such language mode: %s" lang-f))
 846       (org-src--edit-element
 847        element
 848        (or edit-buffer-name
 849            (org-src--construct-edit-buffer-name (buffer-name) lang))
 850        lang-f
 851        (and (null code)
 852             `(lambda ()
 853                (unless ,(or org-src-preserve-indentation
 854                             (org-element-property :preserve-indent element))
 855                  (when (> org-edit-src-content-indentation 0)
 856                    (while (not (eobp))
 857                      (unless (looking-at "[ \t]*$")
 858                        (indent-line-to (+ (org-get-indentation)
 859                                           org-edit-src-content-indentation)))
 860                      (forward-line))))
 861                (org-escape-code-in-region (point-min) (point-max))))
 862        (and code (org-unescape-code-in-string code)))
 863       ;; Finalize buffer.
 864       (org-set-local 'org-coderef-label-format
 865                      (or (org-element-property :label-fmt element)
 866                          org-coderef-label-format))
 867       (when (eq type 'src-block)
 868         (org-set-local 'org-src--babel-info babel-info)
 869         (let ((edit-prep-func (intern (concat "org-babel-edit-prep:" lang))))
 870           (when (fboundp edit-prep-func)
 871             (funcall edit-prep-func babel-info))))
 872       t)))
 873
 874 (defun org-edit-fixed-width-region ()
 875   "Edit the fixed-width ASCII drawing at point.
 876
 877 This must be a region where each line starts with a colon
 878 followed by a space or a newline character.
 879
 880 A new buffer is created and the fixed-width region is copied into
 881 it, and the buffer is switched into the major mode defined in
 882 `org-edit-fixed-width-region-mode', which see.  When done, exit
 883 with \\[org-edit-src-exit].  The edited text will then replace
 884 the area in the Org mode buffer."
 885   (interactive)
 886   (let ((element (org-element-at-point)))
 887     (unless (and (eq (org-element-type element) 'fixed-width)
 888                  (org-src--on-datum-p element))
 889       (user-error "Not in a fixed-width area"))
 890     (org-src--edit-element
 891      element
 892      (org-src--construct-edit-buffer-name (buffer-name) "Fixed Width")
 893      org-edit-fixed-width-region-mode
 894      (lambda () (while (not (eobp)) (insert ": ") (forward-line))))
 895     ;; Return success.
 896     t))
 897
 898 (defun org-edit-src-abort ()
 899   "Abort editing of the src code and return to the Org buffer."
 900   (interactive)
 901   (let (org-src--allow-write-back) (org-edit-src-exit)))
 902
 903 (defun org-edit-src-continue (e)
 904   "Unconditionally return to buffer editing area under point.
 905 Throw an error if there is no such buffer."
 906   (interactive "e")
 907   (mouse-set-point e)
 908   (let ((buf (get-char-property (point) 'edit-buffer)))
 909     (if buf (org-src-switch-to-buffer buf 'continue)
 910       (user-error "No sub-editing buffer for area at point"))))
 911
 912 (defun org-edit-src-save ()
 913   "Save parent buffer with current state source-code buffer."
 914   (interactive)
 915   (unless (org-src-edit-buffer-p) (user-error "Not in a sub-editing buffer"))
 916   (set-buffer-modified-p nil)
 917   (let ((edited-code (org-src--contents-for-write-back))
 918         (beg org-src--beg-marker)
 919         (end org-src--end-marker)
 920         (overlay org-src--overlay))
 921     (with-current-buffer (org-src--source-buffer)
 922       (undo-boundary)
 923       (goto-char beg)
 924       ;; Temporarily disable read-only features of OVERLAY in order to
 925       ;; insert new contents.
 926       (delete-overlay overlay)
 927       (delete-region beg end)
 928       (let ((expecting-bol (bolp)))
 929         (insert edited-code)
 930         (when (and expecting-bol (not (bolp))) (insert "\n")))
 931       (save-buffer)
 932       (move-overlay overlay beg (point)))))
 933
 934 (defun org-edit-src-exit ()
 935   "Kill current sub-editing buffer and return to source buffer."
 936   (interactive)
 937   (unless (org-src-edit-buffer-p) (error "Not in a sub-editing buffer"))
 938   (let* ((beg org-src--beg-marker)
 939          (end org-src--end-marker)
 940          (write-back org-src--allow-write-back)
 941          (remote org-src--remote)
 942          (coordinates (and (not remote)
 943                            (org-src--coordinates (point) 1 (point-max))))
 944          (code (and write-back (org-src--contents-for-write-back))))
 945     (set-buffer-modified-p nil)
 946     ;; Switch to source buffer.  Kill sub-editing buffer.
 947     (let ((edit-buffer (current-buffer)))
 948       (org-src-switch-to-buffer (marker-buffer beg) 'exit)
 949       (kill-buffer edit-buffer))
 950     ;; Insert modified code.  Ensure it ends with a newline character.
 951     (org-with-wide-buffer
 952      (when (and write-back (not (equal (buffer-substring beg end) code)))
 953        (undo-boundary)
 954        (goto-char beg)
 955        (delete-region beg end)
 956        (let ((expecting-bol (bolp)))
 957          (insert code)
 958          (when (and expecting-bol (not (bolp))) (insert "\n")))))
 959     ;; If we are to return to source buffer, put point at an
 960     ;; appropriate location.  In particular, if block is hidden, move
 961     ;; to the beginning of the block opening line.
 962     (unless remote
 963       (goto-char beg)
 964       (cond
 965        ;; Block is hidden; move at start of block.
 966        ((org-some (lambda (o) (eq (overlay-get o 'invisible) 'org-hide-block))
 967                   (overlays-at (point)))
 968         (beginning-of-line 0))
 969        (write-back (org-src--goto-coordinates coordinates beg end))))
 970     ;; Clean up left-over markers and restore window configuration.
 971     (set-marker beg nil)
 972     (set-marker end nil)
 973     (when org-src--saved-temp-window-config
 974       (set-window-configuration org-src--saved-temp-window-config)
 975       (setq org-src--saved-temp-window-config nil))))
 976
 977
 978 (provide 'org-src)
 979
 980 ;;; org-src.el ends here