lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- Extract Source Code From Org Files -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extract the code from source blocks out into raw source-code files.
  27
  28 ;;; Code:
  29
  30 (require 'cl-lib)
  31 (require 'org-src)
  32
  33 (declare-function make-directory "files" (dir &optional parents))
  34 (declare-function org-at-heading-p "org" (&optional ignored))
  35 (declare-function org-babel-update-block-body "ob-core" (new-body))
  36 (declare-function org-back-to-heading "org" (&optional invisible-ok))
  37 (declare-function org-before-first-heading-p "org" ())
  38 (declare-function org-edit-special "org" (&optional arg))
  39 (declare-function org-element-at-point "org-element" ())
  40 (declare-function org-element-type "org-element" (element))
  41 (declare-function org-fill-template "org" (template alist))
  42 (declare-function org-heading-components "org" ())
  43 (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  44 (declare-function org-link-escape "org" (text &optional table merge))
  45 (declare-function org-open-link-from-string "org" (s &optional arg reference-buffer))
  46 (declare-function org-remove-indentation "org" (code &optional n))
  47 (declare-function org-store-link "org" (arg))
  48 (declare-function org-string-nw-p "org-macs" (s))
  49 (declare-function org-trim "org" (s &optional keep-lead))
  50 (declare-function outline-previous-heading "outline" ())
  51 (declare-function org-id-find "org-id" (id &optional markerp))
  52
  53 (defvar org-link-types-re)
  54
  55 (defcustom org-babel-tangle-lang-exts
  56   '(("emacs-lisp" . "el")
  57     ("elisp" . "el"))
  58   "Alist mapping languages to their file extensions.
  59 The key is the language name, the value is the string that should
  60 be inserted as the extension commonly used to identify files
  61 written in this language.  If no entry is found in this list,
  62 then the name of the language is used."
  63   :group 'org-babel-tangle
  64   :version "24.1"
  65   :type '(repeat
  66           (cons
  67            (string "Language name")
  68            (string "File Extension"))))
  69
  70 (defcustom org-babel-tangle-use-relative-file-links t
  71   "Use relative path names in links from tangled source back the Org file."
  72   :group 'org-babel-tangle
  73   :type 'boolean)
  74
  75 (defcustom org-babel-post-tangle-hook nil
  76   "Hook run in code files tangled by `org-babel-tangle'."
  77   :group 'org-babel
  78   :version "24.1"
  79   :type 'hook)
  80
  81 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  82   "Hook run at the beginning of `org-babel-tangle'."
  83   :group 'org-babel
  84   :version "24.1"
  85   :type 'hook)
  86
  87 (defcustom org-babel-tangle-body-hook nil
  88   "Hook run over the contents of each code block body."
  89   :group 'org-babel
  90   :version "24.1"
  91   :type 'hook)
  92
  93 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  94   "Format of inserted comments in tangled code files.
  95 The following format strings can be used to insert special
  96 information into the output using `org-fill-template'.
  97 %start-line --- the line number at the start of the code block
  98 %file --------- the file from which the code block was tangled
  99 %link --------- Org style link to the code block
 100 %source-name -- name of the code block
 101
 102 Upon insertion the formatted comment will be commented out, and
 103 followed by a newline.  To inhibit this post-insertion processing
 104 set the `org-babel-tangle-uncomment-comments' variable to a
 105 non-nil value.
 106
 107 Whether or not comments are inserted during tangling is
 108 controlled by the :comments header argument."
 109   :group 'org-babel
 110   :version "24.1"
 111   :type 'string)
 112
 113 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
 114   "Format of inserted comments in tangled code files.
 115 The following format strings can be used to insert special
 116 information into the output using `org-fill-template'.
 117 %start-line --- the line number at the start of the code block
 118 %file --------- the file from which the code block was tangled
 119 %link --------- Org style link to the code block
 120 %source-name -- name of the code block
 121
 122 Upon insertion the formatted comment will be commented out, and
 123 followed by a newline.  To inhibit this post-insertion processing
 124 set the `org-babel-tangle-uncomment-comments' variable to a
 125 non-nil value.
 126
 127 Whether or not comments are inserted during tangling is
 128 controlled by the :comments header argument."
 129   :group 'org-babel
 130   :version "24.1"
 131   :type 'string)
 132
 133 (defcustom org-babel-tangle-uncomment-comments nil
 134   "Inhibits automatic commenting and addition of trailing newline
 135 of tangle comments.  Use `org-babel-tangle-comment-format-beg'
 136 and `org-babel-tangle-comment-format-end' to customize the format
 137 of tangled comments."
 138   :group 'org-babel
 139   :type 'boolean)
 140
 141 (defcustom org-babel-process-comment-text 'org-remove-indentation
 142   "Function called to process raw Org text collected to be
 143 inserted as comments in tangled source-code files.  The function
 144 should take a single string argument and return a string
 145 result.  The default value is `org-remove-indentation'."
 146   :group 'org-babel
 147   :version "24.1"
 148   :type 'function)
 149
 150 (defun org-babel-find-file-noselect-refresh (file)
 151   "Find file ensuring that the latest changes on disk are
 152 represented in the file."
 153   (find-file-noselect file 'nowarn)
 154   (with-current-buffer (get-file-buffer file)
 155     (revert-buffer t t t)))
 156
 157 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 158   "Open FILE into a temporary buffer execute BODY there like
 159 `progn', then kill the FILE buffer returning the result of
 160 evaluating BODY."
 161   (declare (indent 1))
 162   (let ((temp-path (make-symbol "temp-path"))
 163         (temp-result (make-symbol "temp-result"))
 164         (temp-file (make-symbol "temp-file"))
 165         (visited-p (make-symbol "visited-p")))
 166     `(let* ((,temp-path ,file)
 167             (,visited-p (get-file-buffer ,temp-path))
 168             ,temp-result ,temp-file)
 169        (org-babel-find-file-noselect-refresh ,temp-path)
 170        (setf ,temp-file (get-file-buffer ,temp-path))
 171        (with-current-buffer ,temp-file
 172          (setf ,temp-result (progn ,@body)))
 173        (unless ,visited-p (kill-buffer ,temp-file))
 174        ,temp-result)))
 175 (def-edebug-spec org-babel-with-temp-filebuffer (form body))
 176
 177 ;;;###autoload
 178 (defun org-babel-tangle-file (file &optional target-file lang)
 179   "Extract the bodies of source code blocks in FILE.
 180 Source code blocks are extracted with `org-babel-tangle'.
 181 Optional argument TARGET-FILE can be used to specify a default
 182 export file for all source blocks.  Optional argument LANG can be
 183 used to limit the exported source code blocks by language.
 184 Return a list whose CAR is the tangled file name."
 185   (interactive "fFile to tangle: \nP")
 186   (let ((visited-p (get-file-buffer (expand-file-name file)))
 187         to-be-removed)
 188     (prog1
 189         (save-window-excursion
 190           (find-file file)
 191           (setq to-be-removed (current-buffer))
 192           (mapcar #'expand-file-name (org-babel-tangle nil target-file lang)))
 193       (unless visited-p
 194         (kill-buffer to-be-removed)))))
 195
 196 (defun org-babel-tangle-publish (_ filename pub-dir)
 197   "Tangle FILENAME and place the results in PUB-DIR."
 198   (unless (file-exists-p pub-dir)
 199     (make-directory pub-dir t))
 200   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 201
 202 ;;;###autoload
 203 (defun org-babel-tangle (&optional arg target-file lang)
 204   "Write code blocks to source-specific files.
 205 Extract the bodies of all source code blocks from the current
 206 file into their own source-specific files.
 207 With one universal prefix argument, only tangle the block at point.
 208 When two universal prefix arguments, only tangle blocks for the
 209 tangle file of the block at point.
 210 Optional argument TARGET-FILE can be used to specify a default
 211 export file for all source blocks.  Optional argument LANG can be
 212 used to limit the exported source code blocks by language."
 213   (interactive "P")
 214   (run-hooks 'org-babel-pre-tangle-hook)
 215   ;; Possibly Restrict the buffer to the current code block
 216   (save-restriction
 217     (save-excursion
 218       (when (equal arg '(4))
 219         (let ((head (org-babel-where-is-src-block-head)))
 220           (if head
 221               (goto-char head)
 222             (user-error "Point is not in a source code block"))))
 223       (let ((block-counter 0)
 224             (org-babel-default-header-args
 225              (if target-file
 226                  (org-babel-merge-params org-babel-default-header-args
 227                                          (list (cons :tangle target-file)))
 228                org-babel-default-header-args))
 229             (tangle-file
 230              (when (equal arg '(16))
 231                (or (cdr (assq :tangle (nth 2 (org-babel-get-src-block-info 'light))))
 232                    (user-error "Point is not in a source code block"))))
 233             path-collector)
 234         (mapc ;; map over all languages
 235          (lambda (by-lang)
 236            (let* ((lang (car by-lang))
 237                   (specs (cdr by-lang))
 238                   (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 239                   (lang-f (intern
 240                            (concat
 241                             (or (and (cdr (assoc lang org-src-lang-modes))
 242                                      (symbol-name
 243                                       (cdr (assoc lang org-src-lang-modes))))
 244                                 lang)
 245                             "-mode")))
 246                   she-banged)
 247              (mapc
 248               (lambda (spec)
 249                 (let ((get-spec (lambda (name) (cdr (assoc name (nth 4 spec))))))
 250                   (let* ((tangle (funcall get-spec :tangle))
 251                          (she-bang (let ((sheb (funcall get-spec :shebang)))
 252                                      (when (> (length sheb) 0) sheb)))
 253                          (tangle-mode (funcall get-spec :tangle-mode))
 254                          (base-name (cond
 255                                      ((string= "yes" tangle)
 256                                       (file-name-sans-extension
 257                                        (nth 1 spec)))
 258                                      ((string= "no" tangle) nil)
 259                                      ((> (length tangle) 0) tangle)))
 260                          (file-name (when base-name
 261                                       ;; decide if we want to add ext to base-name
 262                                       (if (and ext (string= "yes" tangle))
 263                                           (concat base-name "." ext) base-name))))
 264                     (when file-name
 265                       ;; Possibly create the parent directories for file.
 266                       (let ((m (funcall get-spec :mkdirp))
 267                             (fnd (file-name-directory file-name)))
 268                         (and m fnd (not (string= m "no"))
 269                              (make-directory fnd 'parents)))
 270                       ;; delete any old versions of file
 271                       (and (file-exists-p file-name)
 272                            (not (member file-name (mapcar #'car path-collector)))
 273                            (delete-file file-name))
 274                       ;; drop source-block to file
 275                       (with-temp-buffer
 276                         (when (fboundp lang-f) (ignore-errors (funcall lang-f)))
 277                         (when (and she-bang (not (member file-name she-banged)))
 278                           (insert (concat she-bang "\n"))
 279                           (setq she-banged (cons file-name she-banged)))
 280                         (org-babel-spec-to-string spec)
 281                         ;; We avoid append-to-file as it does not work with tramp.
 282                         (let ((content (buffer-string)))
 283                           (with-temp-buffer
 284                             (when (file-exists-p file-name)
 285                               (insert-file-contents file-name))
 286                             (goto-char (point-max))
 287                             ;; Handle :padlines unless first line in file
 288                             (unless (or (string= "no" (cdr (assq :padline (nth 4 spec))))
 289                                         (= (point) (point-min)))
 290                               (insert "\n"))
 291                             (insert content)
 292                             (write-region nil nil file-name))))
 293                       ;; if files contain she-bangs, then make the executable
 294                       (when she-bang
 295                         (unless tangle-mode (setq tangle-mode #o755)))
 296                       ;; update counter
 297                       (setq block-counter (+ 1 block-counter))
 298                       (unless (assoc file-name path-collector)
 299                         (push (cons file-name tangle-mode) path-collector))))))
 300               specs)))
 301          (if (equal arg '(4))
 302              (org-babel-tangle-single-block 1 t)
 303            (org-babel-tangle-collect-blocks lang tangle-file)))
 304         (message "Tangled %d code block%s from %s" block-counter
 305                  (if (= block-counter 1) "" "s")
 306                  (file-name-nondirectory
 307                   (buffer-file-name
 308                    (or (buffer-base-buffer) (current-buffer)))))
 309         ;; run `org-babel-post-tangle-hook' in all tangled files
 310         (when org-babel-post-tangle-hook
 311           (mapc
 312            (lambda (file)
 313              (org-babel-with-temp-filebuffer file
 314                (run-hooks 'org-babel-post-tangle-hook)))
 315            (mapcar #'car path-collector)))
 316         ;; set permissions on tangled files
 317         (mapc (lambda (pair)
 318                 (when (cdr pair) (set-file-modes (car pair) (cdr pair))))
 319               path-collector)
 320         (mapcar #'car path-collector)))))
 321
 322 (defun org-babel-tangle-clean ()
 323   "Remove comments inserted by `org-babel-tangle'.
 324 Call this function inside of a source-code file generated by
 325 `org-babel-tangle' to remove all comments inserted automatically
 326 by `org-babel-tangle'.  Warning, this comment removes any lines
 327 containing constructs which resemble Org file links or noweb
 328 references."
 329   (interactive)
 330   (goto-char (point-min))
 331   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 332              (re-search-forward (org-babel-noweb-wrap) nil t))
 333     (delete-region (save-excursion (beginning-of-line 1) (point))
 334                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 335
 336 (defvar org-stored-links)
 337 (defvar org-bracket-link-regexp)
 338 (defun org-babel-spec-to-string (spec)
 339   "Insert SPEC into the current file.
 340
 341 Insert the source-code specified by SPEC into the current source
 342 code file.  This function uses `comment-region' which assumes
 343 that the appropriate major-mode is set.  SPEC has the form:
 344
 345   (start-line file link source-name params body comment)"
 346   (let* ((start-line (nth 0 spec))
 347          (info (nth 4 spec))
 348          (file (if org-babel-tangle-use-relative-file-links
 349                    (file-relative-name (nth 1 spec))
 350                  (nth 1 spec)))
 351          (link (let ((link (nth 2 spec)))
 352                  (if org-babel-tangle-use-relative-file-links
 353                      (when (string-match org-link-types-re link)
 354                        (let ((type (match-string 0 link))
 355                              (link (substring link (match-end 0))))
 356                          (concat
 357                           type
 358                           (file-relative-name
 359                            link
 360                            (file-name-directory (cdr (assq :tangle info)))))))
 361                    link)))
 362          (source-name (nth 3 spec))
 363          (body (nth 5 spec))
 364          (comment (nth 6 spec))
 365          (comments (cdr (assq :comments info)))
 366          (link-p (or (string= comments "both") (string= comments "link")
 367                      (string= comments "yes") (string= comments "noweb")))
 368          (link-data `(("start-line" . ,(number-to-string start-line))
 369                       ("file" . ,file)
 370                       ("link" . ,link)
 371                       ("source-name" . ,source-name)))
 372          (insert-comment (lambda (text)
 373                            (when (and comments
 374                                       (not (string= comments "no"))
 375                                       (org-string-nw-p text))
 376                              (if org-babel-tangle-uncomment-comments
 377                                  ;; Plain comments: no processing.
 378                                  (insert text)
 379                                ;; Ensure comments are made to be
 380                                ;; comments, and add a trailing
 381                                ;; newline.  Also ignore invisible
 382                                ;; characters when commenting.
 383                                (comment-region
 384                                 (point)
 385                                 (progn (insert (org-no-properties text))
 386                                        (point)))
 387                                (end-of-line)
 388                                (insert "\n"))))))
 389     (when comment (funcall insert-comment comment))
 390     (when link-p
 391       (funcall
 392        insert-comment
 393        (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 394     (insert
 395      (org-unescape-code-in-string
 396       (if org-src-preserve-indentation (org-trim body t)
 397         (org-trim (org-remove-indentation body))))
 398      "\n")
 399     (when link-p
 400       (funcall
 401        insert-comment
 402        (org-fill-template org-babel-tangle-comment-format-end link-data)))))
 403
 404 (defun org-babel-tangle-collect-blocks (&optional language tangle-file)
 405   "Collect source blocks in the current Org file.
 406 Return an association list of source-code block specifications of
 407 the form used by `org-babel-spec-to-string' grouped by language.
 408 Optional argument LANGUAGE can be used to limit the collected
 409 source code blocks by language.  Optional argument TANGLE-FILE
 410 can be used to limit the collected code blocks by target file."
 411   (let ((counter 0) last-heading-pos blocks)
 412     (org-babel-map-src-blocks (buffer-file-name)
 413       (let ((current-heading-pos
 414              (org-with-wide-buffer
 415               (org-with-limited-levels (outline-previous-heading)))))
 416         (if (eq last-heading-pos current-heading-pos) (cl-incf counter)
 417           (setq counter 1)
 418           (setq last-heading-pos current-heading-pos)))
 419       (unless (org-in-commented-heading-p)
 420         (let* ((info (org-babel-get-src-block-info 'light))
 421                (src-lang (nth 0 info))
 422                (src-tfile (cdr (assq :tangle (nth 2 info)))))
 423           (unless (or (string= src-tfile "no")
 424                       (and tangle-file (not (equal tangle-file src-tfile)))
 425                       (and language (not (string= language src-lang))))
 426             ;; Add the spec for this block to blocks under its
 427             ;; language.
 428             (let ((by-lang (assoc src-lang blocks))
 429                   (block (org-babel-tangle-single-block counter)))
 430               (if by-lang (setcdr by-lang (cons block (cdr by-lang)))
 431                 (push (cons src-lang (list block)) blocks)))))))
 432     ;; Ensure blocks are in the correct order.
 433     (mapcar (lambda (b) (cons (car b) (nreverse (cdr b)))) blocks)))
 434
 435 (defun org-babel-tangle-single-block
 436   (block-counter &optional only-this-block)
 437   "Collect the tangled source for current block.
 438 Return the list of block attributes needed by
 439 `org-babel-tangle-collect-blocks'.
 440 When ONLY-THIS-BLOCK is non-nil, return the full association
 441 list to be used by `org-babel-tangle' directly."
 442   (let* ((info (org-babel-get-src-block-info))
 443          (start-line
 444           (save-restriction (widen)
 445                             (+ 1 (line-number-at-pos (point)))))
 446          (file (buffer-file-name (buffer-base-buffer)))
 447          (src-lang (nth 0 info))
 448          (params (nth 2 info))
 449          (extra (nth 3 info))
 450          (cref-fmt (or (and (string-match "-l \"\\(.+\\)\"" extra)
 451                             (match-string 1 extra))
 452                        org-coderef-label-format))
 453          (link (let ((link (org-no-properties
 454                             (org-store-link nil))))
 455                  (and (string-match org-bracket-link-regexp link)
 456                       (match-string 1 link))))
 457          (source-name
 458           (or (nth 4 info)
 459               (format "%s:%d"
 460                       (or (ignore-errors (nth 4 (org-heading-components)))
 461                           "No heading")
 462                       block-counter)))
 463          (expand-cmd
 464           (intern (concat "org-babel-expand-body:" src-lang)))
 465          (assignments-cmd
 466           (intern (concat "org-babel-variable-assignments:" src-lang)))
 467          (body
 468           ;; Run the tangle-body-hook.
 469           (let* ((body ;; Expand the body in language specific manner.
 470                   (if (org-babel-noweb-p params :tangle)
 471                       (org-babel-expand-noweb-references info)
 472                     (nth 1 info)))
 473                  (body
 474                   (if (assq :no-expand params)
 475                       body
 476                     (if (fboundp expand-cmd)
 477                         (funcall expand-cmd body params)
 478                       (org-babel-expand-body:generic
 479                        body params
 480                        (and (fboundp assignments-cmd)
 481                             (funcall assignments-cmd params)))))))
 482             (with-temp-buffer
 483               (insert body)
 484               (when (string-match "-r" extra)
 485                 (goto-char (point-min))
 486                 (while (re-search-forward
 487                         (replace-regexp-in-string "%s" ".+" cref-fmt) nil t)
 488                   (replace-match "")))
 489               (run-hooks 'org-babel-tangle-body-hook)
 490               (buffer-string))))
 491          (comment
 492           (when (or (string= "both" (cdr (assq :comments params)))
 493                     (string= "org" (cdr (assq :comments params))))
 494             ;; From the previous heading or code-block end
 495             (funcall
 496              org-babel-process-comment-text
 497              (buffer-substring
 498               (max (condition-case nil
 499                        (save-excursion
 500                          (org-back-to-heading t)  ; Sets match data
 501                          (match-end 0))
 502                      (error (point-min)))
 503                    (save-excursion
 504                      (if (re-search-backward
 505                           org-babel-src-block-regexp nil t)
 506                          (match-end 0)
 507                        (point-min))))
 508               (point)))))
 509          (result
 510           (list start-line file link source-name params body comment)))
 511     (if only-this-block
 512         (list (cons src-lang (list result)))
 513       result)))
 514
 515 (defun org-babel-tangle-comment-links (&optional info)
 516   "Return a list of begin and end link comments for the code block at point."
 517   (let ((link-data
 518          `(("start-line" . ,(number-to-string
 519                              (org-babel-where-is-src-block-head)))
 520            ("file" . ,(buffer-file-name))
 521            ("link" . ,(org-link-escape
 522                        (progn
 523                          (call-interactively #'org-store-link)
 524                          (org-no-properties (car (pop org-stored-links))))))
 525            ("source-name" .
 526             ,(nth 4 (or info (org-babel-get-src-block-info 'light)))))))
 527     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 528           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 529
 530 ;; de-tangling functions
 531 (defvar org-bracket-link-analytic-regexp)
 532 (defun org-babel-detangle (&optional source-code-file)
 533   "Propagate changes in source file back original to Org file.
 534 This requires that code blocks were tangled with link comments
 535 which enable the original code blocks to be found."
 536   (interactive)
 537   (save-excursion
 538     (when source-code-file (find-file source-code-file))
 539     (goto-char (point-min))
 540     (let ((counter 0) new-body end)
 541       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 542         (when (re-search-forward
 543                (concat " " (regexp-quote (match-string 5)) " ends here"))
 544           (setq end (match-end 0))
 545           (forward-line -1)
 546           (save-excursion
 547             (when (setq new-body (org-babel-tangle-jump-to-org))
 548               (org-babel-update-block-body new-body)))
 549           (setq counter (+ 1 counter)))
 550         (goto-char end))
 551       (prog1 counter (message "Detangled %d code blocks" counter)))))
 552
 553 (defun org-babel-tangle-jump-to-org ()
 554   "Jump from a tangled code file to the related Org mode file."
 555   (interactive)
 556   (let ((mid (point))
 557         start body-start end
 558         target-buffer target-char link path block-name body)
 559     (save-window-excursion
 560       (save-excursion
 561         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 562                     (not ; ever wider searches until matching block comments
 563                      (and (setq start (line-beginning-position))
 564                           (setq body-start (line-beginning-position 2))
 565                           (setq link (match-string 0))
 566                           (setq path (match-string 3))
 567                           (setq block-name (match-string 5))
 568                           (save-excursion
 569                             (save-match-data
 570                               (re-search-forward
 571                                (concat " " (regexp-quote block-name)
 572                                        " ends here") nil t)
 573                               (setq end (line-beginning-position))))))))
 574         (unless (and start (< start mid) (< mid end))
 575           (error "Not in tangled code"))
 576         (setq body (buffer-substring body-start end)))
 577       (when (string-match "::" path)
 578         (setq path (substring path 0 (match-beginning 0))))
 579       (find-file (or (car (org-id-find path)) path))
 580       (setq target-buffer (current-buffer))
 581       ;; Go to the beginning of the relative block in Org file.
 582       (org-open-link-from-string link)
 583       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 584           (let ((n (string-to-number (match-string 1 block-name))))
 585             (if (org-before-first-heading-p) (goto-char (point-min))
 586               (org-back-to-heading t))
 587             ;; Do not skip the first block if it begins at point min.
 588             (cond ((or (org-at-heading-p)
 589                        (not (eq (org-element-type (org-element-at-point))
 590                                 'src-block)))
 591                    (org-babel-next-src-block n))
 592                   ((= n 1))
 593                   (t (org-babel-next-src-block (1- n)))))
 594         (org-babel-goto-named-src-block block-name))
 595       (goto-char (org-babel-where-is-src-block-head))
 596       ;; Preserve location of point within the source code in tangled
 597       ;; code file.
 598       (forward-line 1)
 599       (forward-char (- mid body-start))
 600       (setq target-char (point)))
 601     (org-src-switch-to-buffer target-buffer t)
 602     (goto-char target-char)
 603     body))
 604
 605 (provide 'ob-tangle)
 606
 607 ;; Local variables:
 608 ;; generated-autoload-file: "org-loaddefs.el"
 609 ;; End:
 610
 611 ;;; ob-tangle.el ends here