lisp/org-protocol.el

   1 ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
   2 ;;
   3 ;; Copyright (c) 2008, 2009
   4 ;;          Bastien Guerry <bzg AT altern DOT org>,
   5 ;;          Daniel German <dmg AT uvic DOT org>,
   6 ;;          Sebastian Rose <sebastian_rose AT gmx DOT de>,
   7 ;;          Ross Patterson <me AT rpatterson DOT net>
   8 ;;          David Moffat
   9 ;;          (will be FSF when done)
  10 ;;
  11 ;;
  12 ;; Filename: org-protocol.el
  13 ;; Version: 6.26b
  14 ;; Author: Bastien Guerry <bzg AT altern DOT org>
  15 ;; Author: Daniel M German <dmg AT uvic DOT org>
  16 ;; Author: Sebastian Rose <sebastian_rose AT gmx DOT de>
  17 ;; Author: Ross Patterson <me AT rpatterson DOT net>
  18 ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  19 ;; Keywords: org, emacsclient, wp
  20
  21 ;; This file is not part of GNU Emacs.
  22
  23 ;; This program is free software: you can redistribute it and/or modify
  24 ;; it under the terms of the GNU General Public License as published by
  25 ;; the Free Software Foundation, either version 3 of the License, or
  26 ;; (at your option) any later version.
  27
  28 ;; This program is distributed in the hope that it will be useful,
  29 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  30 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  31 ;; GNU General Public License for more details.
  32
  33 ;; See <http://www.gnu.org/licenses/>.
  34
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Commentary:
  37 ;;
  38 ;; Intercept calls from emacsclient to trigger custom actions.
  39 ;;
  40 ;; This is done by advising `server-visit-files' to scann the list of filenames
  41 ;; for `org-protocol-the-protocol' and sub-procols defined in
  42 ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  43 ;;
  44 ;; Any application that supports calling external programs with an URL
  45 ;; as argument may be used with this functionality.
  46 ;;
  47 ;;
  48 ;; Usage:
  49 ;; ------
  50 ;;
  51 ;;   1.) Add this to your init file (.emacs probably):
  52 ;;
  53 ;;       (add-to-list 'load-path "/path/to/org-protocol/")
  54 ;;       (require 'org-protocol)
  55 ;;
  56 ;;   3.) Ensure emacs-server is up and running.
  57 ;;   4.) Try this from the command line (adjust the URL as needed):
  58 ;;
  59 ;;       $ emacsclient \
  60 ;;         org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  61 ;;
  62 ;;   5.) Optionally add custom sub-protocols and handlers:
  63 ;;
  64 ;;       (setq org-protocol-protocol-alist
  65 ;;             '(("my-protocol"
  66 ;;                :protocol "my-protocol"
  67 ;;                :function my-protocol-handler-fuction)))
  68 ;;
  69 ;;       A "sub-protocol" will be found in URLs like this:
  70 ;;
  71 ;;           org-protocol://sub-protocol://data
  72 ;;
  73 ;; If it works, you can now setup other applications for using this feature.
  74 ;;
  75 ;;
  76 ;; As of March 2009 Firefox users follow the steps documented on
  77 ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  78 ;; http://www.opera.com/support/kb/view/535/
  79 ;;
  80 ;;
  81 ;; Documentation
  82 ;; -------------
  83 ;;
  84 ;; org-protocol.el comes with and installs handlers to open sources of published
  85 ;; online content, store and insert the browser's URLs and cite online content
  86 ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  87 ;; applications:
  88 ;;
  89 ;;   * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  90 ;;     URLs to local filenames defined in `org-protocol-project-alist'.
  91 ;;
  92 ;;   * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  93 ;;     pushes the browsers URL to the `kill-ring' for yanking. This handler is
  94 ;;     triggered through the sub-protocol \"store-link\".
  95 ;;
  96 ;;   * Call `org-protocol-remember' by using the sub-protocol \"remember\".  If
  97 ;;     Org-mode is loaded, emacs will popup a remember buffer and fill the
  98 ;;     template with the data provided. I.e. the browser's URL is inserted as an
  99 ;;     Org-link of which the page title will be the description part. If text
 100 ;;     was select in the browser, that text will be the body of the entry.
 101 ;;
 102 ;; You may use the same bookmark URL for all those standard handlers and just
 103 ;; adjust the sub-protocol used:
 104 ;;
 105 ;;     location.href='org-protocol://sub-protocol://'+
 106 ;;           encodeURIComponent(location.href)+'/'+
 107 ;;           encodeURIComponent(document.title)+'/'+
 108 ;;           encodeURIComponent(window.getSelection())
 109 ;;
 110 ;; The handler for the sub-protocol \"remember\" detects an optional template
 111 ;; char that, if present, triggers the use of a special template.
 112 ;; Example:
 113 ;;
 114 ;;     location.href='org-protocol://sub-protocol://x/'+ ...
 115 ;;
 116 ;;  use template ?x.
 117 ;;
 118 ;; Note, that using double shlashes is optional from org-protocol.el's point of
 119 ;; view because emacsclient sqashes the slashes to one.
 120 ;;
 121 ;;
 122 ;; provides: 'org-protocol
 123 ;;
 124 ;;; Code:
 125
 126 (require 'org)
 127 (require 'url)
 128 (eval-when-compile
 129   (require 'cl))
 130
 131 (declare-function org-publish-initialize-files-alist "org-publish"
 132                   (&optional refresh))
 133 (declare-function org-publish-get-project-from-filename "org-publish"
 134                   (filename &optional up))
 135 (declare-function server-edit "server" ())
 136
 137
 138 (defgroup org-protocol nil
 139   "Intercept calls from emacsclient to trigger custom actions.
 140
 141 This is done by advising `server-visit-files' to scann the list of filenames
 142 for `org-protocol-the-protocol' and sub-procols defined in
 143 `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
 144   :version "22.1"
 145   :group 'convenience
 146   :group 'org)
 147
 148
 149 ;;; Variables:
 150
 151 (defconst org-protocol-protocol-alist-default
 152   '(("org-remember"    :protocol "remember"    :function org-protocol-remember :kill-client t)
 153     ("org-store-link"  :protocol "store-link"  :function org-protocol-store-link)
 154     ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
 155   "Default protocols to use.
 156 See `org-protocol-protocol-alist' for a description of this variable.")
 157
 158
 159 (defconst org-protocol-the-protocol "org-protocol"
 160   "This is the protocol to detect if org-protocol.el is loaded.
 161 `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold the
 162 sub-protocols that trigger the required action. You will have to define just one
 163 protocol handler OS-wide (MS-Windows) or per application (Linux). That protocol
 164 handler should call emacsclient.")
 165
 166
 167 ;;; User variables:
 168
 169 (defcustom org-protocol-reverse-list-of-files t
 170   "* The filenames passed on the commandline are passed to the emacs-server in
 171 reversed order. Set to `t' (default) to re-reverse the list, i.e. use the
 172 sequence on the command line. If nil, the sequence of the filenames is
 173 unchanged."
 174   :group 'org-protocol
 175   :type 'boolean)
 176
 177
 178 (defcustom org-protocol-project-alist nil
 179   "* Map URLs to local filenames for `org-protocol-open-source' (open-source).
 180
 181 Each element of this list must be of the form:
 182
 183   (module-name :property value property: value ...)
 184
 185 where module-name is an arbitrary name. All the values are strings.
 186
 187 Possible properties are:
 188
 189   :online-suffix     - the suffix to strip from the published URLs
 190   :working-suffix    - the replacement for online-suffix
 191   :base-url          - the base URL, e.g. http://www.example.com/project/
 192                        Last slash required.
 193   :working-directory - the local working directory. This is, what base-url will
 194                        be replaced with.
 195
 196 Example:
 197
 198    (setq org-protocol-project-alist
 199        '((\"http://orgmode.org/worg/\"
 200           :online-suffix \".php\"
 201           :working-suffix \".org\"
 202           :base-url \"http://orgmode.org/worg/\"
 203           :working-directory \"/home/user/org/Worg/\")
 204          (\"http://localhost/org-notes/\"
 205           :online-suffix \".html\"
 206           :working-suffix \".org\"
 207           :base-url \"http://localhost/org/\"
 208           :working-directory \"/home/user/org/\")))
 209
 210 Consider using the interactive functions `org-protocol-create' and
 211 `org-protocol-create-for-org' to help you filling this variable with valid contents."
 212   :group 'org-protocol
 213   :type 'alist)
 214
 215
 216 (defcustom org-protocol-protocol-alist nil
 217   "* Register custom handlers for org-protocol.
 218
 219 Each element of this list must be of the form:
 220
 221   (module-name :protocol protocol :function func :kill-client nil)
 222
 223 protocol - protocol to detect in a filename without trailing colon and slashes.
 224            See rfc1738 section 2.1 for more on this.
 225            If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
 226            will search filenames for \"org-protocol:/my-protocol:/\"
 227            and trigger your action for every match. `org-protocol' is defined in
 228            `org-protocol-the-protocol'. Double and tripple slashes are compressed
 229            to one by emacsclient.
 230
 231 function - function that handles requests with protocol and takes exactly one
 232            argument: the filename with all protocols stripped. If the function
 233            returns nil, emacsclient and -server do nothing. Any non-nil return
 234            value is considered a valid filename and thus passed to the server.
 235
 236            `org-protocol.el provides some support for handling those filenames,
 237            if you stay with the conventions used for the standard handlers in
 238            `org-protocol-protocol-alist-default'. See `org-protocol-split-data'.
 239
 240 kill-client - If t, kill the client immediately, once the sub-protocol is
 241            detected. This is neccessary for actions that can be interupted by
 242            `C-g' to avoid dangeling emacsclients. Note, that all other command
 243            line arguments but the this one will be discarded, greedy handlers
 244            still receive the whole list of arguments though.
 245
 246 Here is an example:
 247
 248   (setq org-protocol-protocol-alist
 249       '((\"my-protocol\"
 250          :protocol \"my-protocol\"
 251          :function my-protocol-handler-fuction)
 252         (\"your-protocol\"
 253          :protocol \"your-protocol\"
 254          :function your-protocol-handler-fuction)))"
 255   :group 'org-protocol
 256   :type '(alist))
 257
 258
 259 ;;; Helper functions:
 260
 261 (defun org-protocol-sanitize-uri (uri)
 262   "emacsclient compresses double and tripple slashes.
 263 Slashes are sanitized to double slashes here."
 264   (when (string-match "^\\([a-z]+\\):/" uri)
 265     (let* ((splitparts (split-string uri "/+")))
 266       (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
 267   uri)
 268
 269
 270 (defun org-protocol-split-data(data &optional unhexify separator)
 271   "Split, what a org-protocol handler function gets as only argument.
 272 data is that one argument. Data is splitted at each occurrence of separator
 273  (regexp). If no separator is specified or separator is nil, assume \"/+\".
 274 The results of that splitting are return as a list. If unhexify is non-nil,
 275 hex-decode each split part. If unhexify is a function, use that function to
 276 decode each split part."
 277   (let* ((sep (or separator "/+"))
 278          (split-parts (split-string data sep)))
 279     (if unhexify
 280         (if (fboundp unhexify)
 281             (mapcar unhexify split-parts)
 282           (mapcar 'org-protocol-unhex-string split-parts))
 283       split-parts)))
 284
 285 (defun org-protocol-unhex-string(str)
 286   "Unhex hexified unicode strings as returned from the JavaScript function
 287 encodeURIComponent. E.g. `%C3%B6' is the german Umlaut `ü'."
 288   (setq str (or str ""))
 289   (let ((tmp "")
 290         (case-fold-search t))
 291     (while (string-match "\\(%[0-9a-f][0-9a-f]\\)+" str)
 292       (let* ((start (match-beginning 0))
 293              (end (match-end 0))
 294              (hex (match-string 0 str))
 295              (replacement (org-protocol-unhex-compound hex)))
 296         (setq tmp (concat tmp (substring str 0 start) replacement))
 297         (setq str (substring str end))))
 298     (setq tmp (concat tmp str))
 299     tmp))
 300
 301
 302 (defun org-protocol-unhex-compound (hex)
 303   "Unhexify unicode hex-chars. E.g. `%C3%B6' is the german Umlaut `ü'."
 304   (let* ((bytes (remove "" (split-string hex "%")))
 305          (ret "")
 306          (eat 0)
 307          (sum 0))
 308     (while bytes
 309       (let* ((b (pop bytes))
 310              (c1 (url-unhex (elt b 0)))
 311              (c2 (url-unhex (elt b 1)))
 312              (val (+ (lsh c1 4) c2))
 313              (shift
 314               (if (= 0 eat) ;; new byte
 315                   (if (>= val 252) 6
 316                     (if (>= val 248) 5
 317                       (if (>= val 240) 4
 318                         (if (>= val 224) 3
 319                           (if (>= val 192) 2 0)))))
 320                 6))
 321              (xor
 322               (if (= 0 eat) ;; new byte
 323                   (if (>= val 252) 252
 324                     (if (>= val 248) 248
 325                       (if (>= val 240) 240
 326                         (if (>= val 224) 224
 327                           (if (>= val 192) 192 0)))))
 328                 128)))
 329         (if (>= val 192) (setq eat shift))
 330         (setq val (logxor val xor))
 331         (setq sum (+ (lsh sum shift) val))
 332         (if (> eat 0) (setq eat (- eat 1)))
 333         (when (= 0 eat)
 334           (setq ret (concat ret (char-to-string sum)))
 335           (setq sum 0))
 336         )) ;; end (while bytes
 337     ret ))
 338
 339 (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
 340   "Greedy handlers might recieve a list like this from emacsclient:
 341  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 342 where \"/dir/\" is the absolute path to emacsclients working directory. This
 343 function transforms it into a flat list utilizing `org-protocol-flatten' and
 344 transforms the elements of that list as follows:
 345
 346 If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
 347 param-list.
 348
 349 If replacement is string, replace the \"/dir/\" prefix with it.
 350
 351 The first parameter, the one that contains the protocols, is always changed.
 352 Everything up to the end of the protocols is stripped.
 353
 354 Note, that this function will always behave as if
 355 `org-protocol-reverse-list-of-files' was set to t and the returned list will
 356 reflect that. I.e. emacsclients first parameter will be the first one in the
 357 returned list."
 358 (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
 359                                     param-list
 360                                   (reverse param-list))))
 361       (trigger (car l))
 362       (len 0)
 363       dir
 364       ret)
 365   (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
 366     (setq dir (match-string 1 trigger))
 367     (setq len (length dir))
 368     (setcar l (concat dir (match-string 3 trigger))))
 369   (if strip-path
 370       (progn
 371        (dolist (e l ret)
 372          (setq ret
 373                (append ret
 374                        (list
 375                         (if (stringp e)
 376                             (if (stringp replacement)
 377                                 (setq e (concat replacement (substring e len)))
 378                               (setq e (substring e len)))
 379                           e)))))
 380        ret)
 381     l)))
 382
 383
 384 (defun org-protocol-flatten (l)
 385   "Greedy handlers might recieve a list like this from emacsclient:
 386  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 387 where \"/dir/\" is the absolute path to emacsclients working directory. This
 388 function transforms it into a flat list."
 389   (if (null l) ()
 390     (if (listp l)
 391        (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
 392       (list l))))
 393
 394 ;;; Standard protocol handlers:
 395
 396 (defun org-protocol-store-link (fname)
 397   "Process an org-protocol://store-link:// style url
 398 and store a browser URL as an org link. Also pushes the links URL to the
 399 `kill-ring'.
 400
 401 The location for a browser's bookmark has to look like this:
 402
 403   javascript:location.href='org-protocol://store-link://'+ \\
 404         encodeURIComponent(location.href)
 405         encodeURIComponent(document.title)+'/'+ \\
 406
 407 Don't use `escape()'! Use `encodeURIComponent()' instead. The title of the page
 408 could contain slashes and the location definitely will.
 409
 410 The sub-protocol used to reach this function is set in
 411 `org-protocol-protocol-alist'."
 412   (let* ((splitparts (org-protocol-split-data fname t))
 413          (uri (org-protocol-sanitize-uri (car splitparts)))
 414          (title (cadr splitparts))
 415          orglink)
 416     (if (boundp 'org-stored-links)
 417       (setq org-stored-links (cons (list uri title) org-stored-links)))
 418     (kill-new uri)
 419     (message "`%s' to insert new org-link, `%s' to insert `%s'"
 420              (substitute-command-keys"\\[org-insert-link]")
 421              (substitute-command-keys"\\[yank]")
 422              uri))
 423   nil)
 424
 425
 426 (defun org-protocol-remember  (info)
 427   "Process an org-protocol://remember:// style url.
 428
 429 The sub-protocol used to reach this function is set in
 430 `org-protocol-protocol-alist'.
 431
 432 This function detects an URL, title and optinal text, separated by '/'
 433 The location for a browser's bookmark has to look like this:
 434
 435   javascript:location.href='org-protocol://remember://'+ \\
 436         encodeURIComponent(location.href)+ \\
 437         encodeURIComponent(document.title)+'/'+ \\
 438         encodeURIComponent(window.getSelection())
 439
 440 By default the template character ?w is used. But you may prepend the encoded
 441 URL with a character and a slash like so:
 442
 443   javascript:location.href='org-protocol://org-store-link://b/'+ ...
 444
 445 Now template ?b will be used."
 446
 447   (if (and (boundp 'org-stored-links)
 448            (fboundp 'org-remember))
 449       (let* ((parts (org-protocol-split-data info t))
 450              (template (or (and (= 1 (length (car parts))) (pop parts)) "w"))
 451              (url (org-protocol-sanitize-uri (car parts)))
 452              (type (if (string-match "^\\([a-z]+\\):" url)
 453                        (match-string 1 url)))
 454              (title (cadr parts))
 455              (region (caddr parts))
 456              (orglink (org-make-link-string url title))
 457              remember-annotation-functions)
 458         (setq org-stored-links
 459               (cons (list url title) org-stored-links))
 460         (kill-new orglink)
 461         (org-store-link-props :type type
 462                               :link url
 463                               :description title
 464                               :initial region)
 465         (raise-frame)
 466         (org-remember nil (string-to-char template)))
 467
 468     (message "Org-mode not loaded."))
 469   nil)
 470
 471
 472 (defun org-protocol-open-source (fname)
 473   "Process an org-protocol://open-source:// style url.
 474
 475 Change a filename by mapping URLs to local filenames as set
 476 in `org-protocol-project-alist'.
 477
 478 The location for a browser's bookmark should look like this:
 479
 480   javascript:location.href='org-protocol://open-source://'+ \\
 481         encodeURIComponent(location.href)"
 482
 483   ;; As we enter this function for a match on our protocol, the return value
 484   ;; defaults to nil.
 485   (let ((result nil)
 486         (f (url-unhex-string fname)))
 487     (catch 'result
 488       (dolist (prolist org-protocol-project-alist)
 489         (let* ((base-url (plist-get (cdr prolist) :base-url))
 490                (wsearch (regexp-quote base-url)))
 491
 492           (when (string-match wsearch f)
 493             (let* ((wdir (plist-get (cdr prolist) :working-directory))
 494                    (strip-suffix (plist-get (cdr prolist) :online-suffix))
 495                    (add-suffix (plist-get (cdr prolist) :working-suffix))
 496                    (start-pos (+ (string-match wsearch f) (length base-url)))
 497                    (end-pos (string-match
 498                              (concat (regexp-quote strip-suffix) "\\([?#].*\\)?$") f))
 499                    (the-file (concat wdir (substring f start-pos end-pos) add-suffix)))
 500               (if (file-readable-p the-file)
 501                   (throw 'result the-file))
 502               (if (file-exists-p the-file)
 503                   (message "%s: permission denied!" the-file)
 504                 (message "%s: no such file or directory." the-file))))))
 505       result)))
 506
 507
 508 ;;; Core functions:
 509
 510 (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
 511   "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
 512 Sub-protocols are registered in `org-protocol-protocol-alist' and
 513 `org-protocol-protocol-alist-default'.
 514 This is, how the matching is done:
 515
 516   (string-match \"protocol:/+sub-protocol:/+\" ...)
 517
 518 protocol and sub-protocol are regexp-quoted.
 519
 520 If a matching protcol is found, the protcol is stripped from fname and the
 521 result is passed to the protocols function as the only parameter. If the
 522 function returns nil, the filename is removed from the list of filenames
 523 passed from emacsclient to the server.
 524 If the function returns a non nil value, that value is passed to the server
 525 as filename."
 526   (let ((sub-protocols (append org-protocol-protocol-alist org-protocol-protocol-alist-default)))
 527     (catch 'fname
 528       (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
 529         (when (string-match the-protocol fname)
 530           (dolist (prolist sub-protocols)
 531             (let ((proto (concat the-protocol (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
 532               (when (string-match proto fname)
 533                 (let* ((func (plist-get (cdr prolist) :function))
 534                        (greedy (plist-get (cdr prolist) :greedy))
 535                        (splitted (split-string fname proto))
 536                        (result (if greedy restoffiles (cadr splitted))))
 537                   (when (plist-get (cdr prolist) :kill-client)
 538                     (message "Greedy org-protocol handler. Killing client.")
 539                     (server-edit))
 540                   (when (fboundp func)
 541                     (unless greedy
 542                       (throw 'fname (funcall func result)))
 543                     (funcall func result)
 544                     (throw 'fname t))))))))
 545       ;; (message "fname: %s" fname)
 546       fname)))
 547
 548
 549 (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
 550   "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
 551   (let ((flist (if org-protocol-reverse-list-of-files
 552                    (reverse  (ad-get-arg 0))
 553                  (ad-get-arg 0)))
 554         (client (ad-get-arg 1)))
 555     (catch 'greedy
 556       (dolist (var flist)
 557         (let ((fname  (expand-file-name (car var)))) ;; `\' to `/' on windows. FIXME: could this be done any better?
 558           (setq fname (org-protocol-check-filename-for-protocol fname (member var flist)  client))
 559           (if (eq fname t) ;; greedy? We need the `t' return value.
 560               (progn
 561                 (ad-set-arg 0 nil)
 562                 (throw 'greedy t))
 563             (if (stringp fname) ;; probably filename
 564                 (setcar var fname)
 565               (ad-set-arg 0 (delq var (ad-get-arg 0))))))
 566         ))))
 567
 568 ;;; Org specific functions:
 569
 570 (defun org-protocol-create-for-org ()
 571   "Create a org-protocol project for the current file's Org-mode project.
 572 This works, if the file visited is part of a publishing project in
 573 `org-publish-project-alist'. This functions calls `org-protocol-create' to do
 574 most of the work."
 575   (interactive)
 576   (require 'org-publish)
 577   (org-publish-initialize-files-alist)
 578   (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
 579     (if all (org-protocol-create (cdr all))
 580       (message "Not in an org-project. Did mean %s?"
 581                (substitute-command-keys"\\[org-protocol-create]")))))
 582
 583
 584
 585 (defun org-protocol-create(&optional project-plist)
 586   "Create a new org-protocol project interactively.
 587 An org-protocol project is an entry in `org-protocol-project-alist'
 588 which is used by `org-protocol-open-source'.
 589 Optionally use project-plist to initialize the defaults for this worglet. If
 590 project-plist is the CDR of an element in `org-publish-project-alist', reuse
 591 :base-directory, :html-extension and :base-extension."
 592   (interactive)
 593   (let ((working-dir (expand-file-name(or (plist-get project-plist :base-directory) default-directory)))
 594         (base-url "http://orgmode.org/worg/")
 595         (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
 596         (working-suffix (if (plist-get project-plist :base-extension)
 597                             (concat "." (plist-get project-plist :base-extension))
 598                           ".org"))
 599
 600         (worglet-buffer nil)
 601
 602         (insert-default-directory t)
 603         (minibuffer-allow-text-properties nil))
 604
 605     (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
 606     (if (not (string-match "\\/$" base-url))
 607         (setq base-url (concat base-url "/")))
 608
 609     (setq working-dir
 610           (expand-file-name
 611            (read-directory-name "Local working directory: " working-dir working-dir t)))
 612     (if (not (string-match "\\/$" working-dir))
 613         (setq working-dir (concat working-dir "/")))
 614
 615     (setq strip-suffix
 616           (read-string
 617            (concat "Extension to strip from published URLs ("strip-suffix"): ")
 618                    strip-suffix nil strip-suffix t))
 619
 620     (setq working-suffix
 621           (read-string
 622            (concat "Extension of editable files ("working-suffix"): ")
 623                    working-suffix nil working-suffix t))
 624
 625     (when (yes-or-no-p "Save the new worglet to your init file? ")
 626       (setq org-protocol-project-alist
 627             (cons `(,base-url . (:base-url ,base-url
 628                                  :working-directory ,working-dir
 629                                  :online-suffix ,strip-suffix
 630                                  :working-suffix ,working-suffix))
 631                   org-protocol-project-alist))
 632       (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))
 633 ))
 634
 635 (provide 'org-protocol)
 636 ;;; org-protocol.el ends here