lisp/org-habit.el

   1 ;;; org-habit.el --- The habit tracking code for Org-mode
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: John Wiegley <johnw at gnu dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the habit tracking code for Org-mode
  28
  29 ;;; Code:
  30
  31 (require 'org)
  32 (require 'org-agenda)
  33
  34 (eval-when-compile
  35   (require 'cl))
  36
  37 (defgroup org-habit nil
  38   "Options concerning habit tracking in Org-mode."
  39   :tag "Org Habit"
  40   :group 'org-progress)
  41
  42 (defcustom org-habit-graph-column 40
  43   "The absolute column at which to insert habit consistency graphs.
  44 Note that consistency graphs will overwrite anything else in the buffer."
  45   :group 'org-habit
  46   :type 'integer)
  47
  48 (defcustom org-habit-preceding-days 21
  49   "Number of days before today to appear in consistency graphs."
  50   :group 'org-habit
  51   :type 'integer)
  52
  53 (defcustom org-habit-following-days 7
  54   "Number of days after today to appear in consistency graphs."
  55   :group 'org-habit
  56   :type 'integer)
  57
  58 (defcustom org-habit-show-habits t
  59   "If non-nil, show habits in agenda buffers."
  60   :group 'org-habit
  61   :type 'boolean)
  62
  63 (defcustom org-habit-show-habits-only-for-today t
  64   "If non-nil, only show habits on today's agenda, and not for future days.
  65 Note that even when shown for future days, the graph is always
  66 relative to the current effective date."
  67   :group 'org-habit
  68   :type 'boolean)
  69
  70 (defcustom org-habit-show-all-today nil
  71   "If non-nil, will show the consistency graph of all habits on
  72 today's agenda, even if they are not scheduled."
  73   :group 'org-habit
  74   :type 'boolean)
  75
  76 (defcustom org-habit-today-glyph ?!
  77   "Glyph character used to identify today."
  78   :group 'org-habit
  79   :version "24.1"
  80   :type 'character)
  81
  82 (defcustom org-habit-completed-glyph ?*
  83   "Glyph character used to show completed days on which a task was done."
  84   :group 'org-habit
  85   :version "24.1"
  86   :type 'character)
  87
  88 (defcustom org-habit-show-done-always-green nil
  89   "Non-nil means DONE days will always be green in the consistency graph.
  90 It will be green even if it was done after the deadline."
  91   :group 'org-habit
  92   :type 'boolean)
  93
  94 (defface org-habit-clear-face
  95   '((((background light)) (:background "#8270f9"))
  96     (((background dark)) (:background "blue")))
  97   "Face for days on which a task shouldn't be done yet."
  98   :group 'org-habit
  99   :group 'org-faces)
 100 (defface org-habit-clear-future-face
 101   '((((background light)) (:background "#d6e4fc"))
 102     (((background dark)) (:background "midnightblue")))
 103   "Face for future days on which a task shouldn't be done yet."
 104   :group 'org-habit
 105   :group 'org-faces)
 106
 107 (defface org-habit-ready-face
 108   '((((background light)) (:background "#4df946"))
 109     (((background dark)) (:background "forestgreen")))
 110   "Face for days on which a task should start to be done."
 111   :group 'org-habit
 112   :group 'org-faces)
 113 (defface org-habit-ready-future-face
 114   '((((background light)) (:background "#acfca9"))
 115     (((background dark)) (:background "darkgreen")))
 116   "Face for days on which a task should start to be done."
 117   :group 'org-habit
 118   :group 'org-faces)
 119
 120 (defface org-habit-alert-face
 121   '((((background light)) (:background "#f5f946"))
 122     (((background dark)) (:background "gold")))
 123   "Face for days on which a task is due."
 124   :group 'org-habit
 125   :group 'org-faces)
 126 (defface org-habit-alert-future-face
 127   '((((background light)) (:background "#fafca9"))
 128     (((background dark)) (:background "darkgoldenrod")))
 129   "Face for days on which a task is due."
 130   :group 'org-habit
 131   :group 'org-faces)
 132
 133 (defface org-habit-overdue-face
 134   '((((background light)) (:background "#f9372d"))
 135     (((background dark)) (:background "firebrick")))
 136   "Face for days on which a task is overdue."
 137   :group 'org-habit
 138   :group 'org-faces)
 139 (defface org-habit-overdue-future-face
 140   '((((background light)) (:background "#fc9590"))
 141     (((background dark)) (:background "darkred")))
 142   "Face for days on which a task is overdue."
 143   :group 'org-habit
 144   :group 'org-faces)
 145
 146 (defun org-habit-duration-to-days (ts)
 147   (if (string-match "\\([0-9]+\\)\\([dwmy]\\)" ts)
 148       ;; lead time is specified.
 149       (floor (* (string-to-number (match-string 1 ts))
 150                 (cdr (assoc (match-string 2 ts)
 151                             '(("d" . 1)    ("w" . 7)
 152                               ("m" . 30.4) ("y" . 365.25))))))
 153     (error "Invalid duration string: %s" ts)))
 154
 155 (defun org-is-habit-p (&optional pom)
 156   "Is the task at POM or point a habit?"
 157   (string= "habit" (org-entry-get (or pom (point)) "STYLE")))
 158
 159 (defun org-habit-parse-todo (&optional pom)
 160   "Parse the TODO surrounding point for its habit-related data.
 161 Returns a list with the following elements:
 162
 163   0: Scheduled date for the habit (may be in the past)
 164   1: \".+\"-style repeater for the schedule, in days
 165   2: Optional deadline (nil if not present)
 166   3: If deadline, the repeater for the deadline, otherwise nil
 167   4: A list of all the past dates this todo was mark closed
 168
 169 This list represents a \"habit\" for the rest of this module."
 170   (save-excursion
 171     (if pom (goto-char pom))
 172     (assert (org-is-habit-p (point)))
 173     (let* ((scheduled (org-get-scheduled-time (point)))
 174            (scheduled-repeat (org-get-repeat org-scheduled-string))
 175            (end (org-entry-end-position))
 176            (habit-entry (org-no-properties (nth 4 (org-heading-components))))
 177            closed-dates deadline dr-days sr-days)
 178       (if scheduled
 179           (setq scheduled (time-to-days scheduled))
 180         (error "Habit %s has no scheduled date" habit-entry))
 181       (unless scheduled-repeat
 182         (error
 183          "Habit '%s' has no scheduled repeat period or has an incorrect one"
 184          habit-entry))
 185       (setq sr-days (org-habit-duration-to-days scheduled-repeat))
 186       (unless (> sr-days 0)
 187         (error "Habit %s scheduled repeat period is less than 1d" habit-entry))
 188       (when (string-match "/\\([0-9]+[dwmy]\\)" scheduled-repeat)
 189         (setq dr-days (org-habit-duration-to-days
 190                        (match-string-no-properties 1 scheduled-repeat)))
 191         (if (<= dr-days sr-days)
 192             (error "Habit %s deadline repeat period is less than or equal to scheduled (%s)"
 193                    habit-entry scheduled-repeat))
 194         (setq deadline (+ scheduled (- dr-days sr-days))))
 195       (org-back-to-heading t)
 196       (let* ((maxdays (+ org-habit-preceding-days org-habit-following-days))
 197              (reversed org-log-states-order-reversed)
 198              (search (if reversed 're-search-forward 're-search-backward))
 199              (limit (if reversed end (point)))
 200              (count 0))
 201         (unless reversed (goto-char end))
 202         (while (and (< count maxdays)
 203                     (funcall search
 204                              (concat
 205                               (format "- State \"%s\".*\\[\\([^]]+\\)\\]"
 206                                       (regexp-opt org-done-keywords))
 207                               "\\|"
 208                               (org-replace-escapes
 209                                (regexp-quote
 210                                 (cdr (assq 'done org-log-note-headings)))
 211                                `(("%d" . ,org-ts-regexp-inactive)
 212                                  ("%D" . ,org-ts-regexp)
 213                                  ("%s" . "\"\\S-+\"")
 214                                  ("%S" . "\"\\S-+\"")
 215                                  ("%t" . ,org-ts-regexp-inactive)
 216                                  ("%T" . ,org-ts-regexp)
 217                                  ("%u" . ".*?")
 218                                  ("%U" . ".*?"))))
 219                              limit t))
 220           (push (time-to-days
 221                  (org-time-string-to-time
 222                   (or (org-match-string-no-properties 1)
 223                       (org-match-string-no-properties 2))))
 224                 closed-dates)
 225           (setq count (1+ count))))
 226       (list scheduled sr-days deadline dr-days closed-dates))))
 227
 228 (defsubst org-habit-scheduled (habit)
 229   (nth 0 habit))
 230 (defsubst org-habit-scheduled-repeat (habit)
 231   (nth 1 habit))
 232 (defsubst org-habit-deadline (habit)
 233   (let ((deadline (nth 2 habit)))
 234     (or deadline
 235         (if (nth 3 habit)
 236             (+ (org-habit-scheduled habit)
 237                (1- (org-habit-scheduled-repeat habit)))
 238           (org-habit-scheduled habit)))))
 239 (defsubst org-habit-deadline-repeat (habit)
 240   (or (nth 3 habit)
 241       (org-habit-scheduled-repeat habit)))
 242 (defsubst org-habit-done-dates (habit)
 243   (nth 4 habit))
 244
 245 (defsubst org-habit-get-priority (habit &optional moment)
 246   "Determine the relative priority of a habit.
 247 This must take into account not just urgency, but consistency as well."
 248   (let ((pri 1000)
 249         (now (if moment (time-to-days moment) (org-today)))
 250         (scheduled (org-habit-scheduled habit))
 251         (deadline (org-habit-deadline habit)))
 252     ;; add 10 for every day past the scheduled date, and subtract for every
 253     ;; day before it
 254     (setq pri (+ pri (* (- now scheduled) 10)))
 255     ;; add 50 if the deadline is today
 256     (if (and (/= scheduled deadline)
 257              (= now deadline))
 258         (setq pri (+ pri 50)))
 259     ;; add 100 for every day beyond the deadline date, and subtract 10 for
 260     ;; every day before it
 261     (let ((slip (- now (1- deadline))))
 262       (if (> slip 0)
 263           (setq pri (+ pri (* slip 100)))
 264         (setq pri (+ pri (* slip 10)))))
 265     pri))
 266
 267 (defun org-habit-get-faces (habit &optional now-days scheduled-days donep)
 268   "Return faces for HABIT relative to NOW-DAYS and SCHEDULED-DAYS.
 269 NOW-DAYS defaults to the current time's days-past-the-epoch if nil.
 270 SCHEDULED-DAYS defaults to the habit's actual scheduled days if nil.
 271
 272 Habits are assigned colors on the following basis:
 273   Blue      Task is before the scheduled date.
 274   Green     Task is on or after scheduled date, but before the
 275             end of the schedule's repeat period.
 276   Yellow    If the task has a deadline, then it is after schedule's
 277             repeat period, but before the deadline.
 278   Orange    The task has reached the deadline day, or if there is
 279             no deadline, the end of the schedule's repeat period.
 280   Red       The task has gone beyond the deadline day or the
 281             schedule's repeat period."
 282   (let* ((scheduled (or scheduled-days (org-habit-scheduled habit)))
 283          (s-repeat (org-habit-scheduled-repeat habit))
 284          (scheduled-end (+ scheduled (1- s-repeat)))
 285          (d-repeat (org-habit-deadline-repeat habit))
 286          (deadline (if scheduled-days
 287                        (+ scheduled-days (- d-repeat s-repeat))
 288                      (org-habit-deadline habit)))
 289          (m-days (or now-days (time-to-days (current-time)))))
 290     (cond
 291      ((< m-days scheduled)
 292       '(org-habit-clear-face . org-habit-clear-future-face))
 293      ((< m-days deadline)
 294       '(org-habit-ready-face . org-habit-ready-future-face))
 295      ((= m-days deadline)
 296       (if donep
 297           '(org-habit-ready-face . org-habit-ready-future-face)
 298         '(org-habit-alert-face . org-habit-alert-future-face)))
 299      ((and org-habit-show-done-always-green donep)
 300       '(org-habit-ready-face . org-habit-ready-future-face))
 301      (t '(org-habit-overdue-face . org-habit-overdue-future-face)))))
 302
 303 (defun org-habit-build-graph (habit starting current ending)
 304   "Build a graph for the given HABIT, from STARTING to ENDING.
 305 CURRENT gives the current time between STARTING and ENDING, for
 306 the purpose of drawing the graph.  It need not be the actual
 307 current time."
 308   (let* ((done-dates (sort (org-habit-done-dates habit) '<))
 309          (scheduled (org-habit-scheduled habit))
 310          (s-repeat (org-habit-scheduled-repeat habit))
 311          (start (time-to-days starting))
 312          (now (time-to-days current))
 313          (end (time-to-days ending))
 314          (graph (make-string (1+ (- end start)) ?\ ))
 315          (index 0)
 316          last-done-date)
 317     (while (and done-dates (< (car done-dates) start))
 318       (setq last-done-date (car done-dates)
 319             done-dates (cdr done-dates)))
 320     (while (< start end)
 321       (let* ((in-the-past-p (< start now))
 322              (todayp (= start now))
 323              (donep (and done-dates
 324                          (= start (car done-dates))))
 325              (faces (if (and in-the-past-p
 326                              (not last-done-date)
 327                              (not (< scheduled now)))
 328                         '(org-habit-clear-face . org-habit-clear-future-face)
 329                       (org-habit-get-faces
 330                        habit start (and in-the-past-p
 331                                         (if last-done-date
 332                                             (+ last-done-date s-repeat)
 333                                           scheduled))
 334                        donep)))
 335              markedp face)
 336         (if donep
 337             (let ((done-time (time-add
 338                               starting
 339                               (days-to-time
 340                                (- start (time-to-days starting))))))
 341
 342               (aset graph index org-habit-completed-glyph)
 343               (setq markedp t)
 344               (put-text-property
 345                index (1+ index) 'help-echo
 346                (format-time-string (org-time-stamp-format) done-time) graph)
 347               (while (and done-dates
 348                           (= start (car done-dates)))
 349                 (setq last-done-date (car done-dates)
 350                       done-dates (cdr done-dates))))
 351           (if todayp
 352               (aset graph index org-habit-today-glyph)))
 353         (setq face (if (or in-the-past-p todayp)
 354                        (car faces)
 355                      (cdr faces)))
 356         (if (and in-the-past-p
 357                  (not (eq face 'org-habit-overdue-face))
 358                  (not markedp))
 359             (setq face (cdr faces)))
 360         (put-text-property index (1+ index) 'face face graph))
 361       (setq start (1+ start)
 362             index (1+ index)))
 363     graph))
 364
 365 (defun org-habit-insert-consistency-graphs (&optional line)
 366   "Insert consistency graph for any habitual tasks."
 367   (let ((inhibit-read-only t) l c
 368         (buffer-invisibility-spec '(org-link))
 369         (moment (time-subtract (current-time)
 370                                (list 0 (* 3600 org-extend-today-until) 0))))
 371     (save-excursion
 372       (goto-char (if line (point-at-bol) (point-min)))
 373       (while (not (eobp))
 374         (let ((habit (get-text-property (point) 'org-habit-p)))
 375           (when habit
 376             (move-to-column org-habit-graph-column t)
 377             (delete-char (min (+ 1 org-habit-preceding-days
 378                                  org-habit-following-days)
 379                               (- (line-end-position) (point))))
 380             (insert-before-markers
 381              (org-habit-build-graph
 382               habit
 383               (time-subtract moment (days-to-time org-habit-preceding-days))
 384               moment
 385               (time-add moment (days-to-time org-habit-following-days))))))
 386         (forward-line)))))
 387
 388 (defun org-habit-toggle-habits ()
 389   "Toggle display of habits in an agenda buffer."
 390   (interactive)
 391   (org-agenda-check-type t 'agenda)
 392   (setq org-habit-show-habits (not org-habit-show-habits))
 393   (org-agenda-redo)
 394   (org-agenda-set-mode-name)
 395   (message "Habits turned %s"
 396            (if org-habit-show-habits "on" "off")))
 397
 398 (org-defkey org-agenda-mode-map "K" 'org-habit-toggle-habits)
 399
 400 (provide 'org-habit)
 401
 402 ;;; org-habit.el ends here