lisp/org-gnus.el

   1 ;;; org-gnus.el --- Support for links to Gnus groups and messages from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;;         Tassilo Horn <tassilo at member dot fsf dot org>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;; Version: 6.29trans
  11 ;;
  12 ;; This file is part of GNU Emacs.
  13 ;;
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29
  30 ;; This file implements links to Gnus groups and messages from within Org-mode.
  31 ;; Org-mode loads this module by default - if this is not what you want,
  32 ;; configure the variable `org-modules'.
  33
  34 ;;; Code:
  35
  36 (require 'org)
  37 (eval-when-compile
  38   (require 'gnus-sum))
  39
  40 ;; Customization variables
  41
  42 (when (fboundp 'defvaralias)
  43   (defvaralias 'org-usenet-links-prefer-google 'org-gnus-prefer-web-links))
  44
  45 (defcustom org-gnus-prefer-web-links nil
  46   "Non-nil means, `org-store-link' will create web links to Google groups.
  47 When nil, Gnus will be used for such links.
  48 Using a prefix arg to the command \\[org-store-link] (`org-store-link')
  49 negates this setting for the duration of the command."
  50   :group 'org-link-store
  51   :type 'boolean)
  52
  53 ;; Declare external functions and variables
  54 (declare-function gnus-summary-article-header "gnus-sum" (&optional number))
  55 (declare-function message-fetch-field "message" (header &optional not-all))
  56 (declare-function message-narrow-to-head-1 "message" nil)
  57
  58 (defvar gnus-other-frame-object)
  59 (defvar gnus-group-name)
  60 (defvar gnus-article-current)
  61
  62 ;; Install the link type
  63 (org-add-link-type "gnus" 'org-gnus-open)
  64 (add-hook 'org-store-link-functions 'org-gnus-store-link)
  65
  66 ;; Implementation
  67
  68 (defun org-gnus-group-link (group)
  69   "Create a link to the Gnus group GROUP.
  70 If GROUP is a newsgroup and `org-gnus-prefer-web-links' is
  71 non-nil, create a link to groups.google.com or gmane.org.
  72 Otherwise create a link to the group inside Gnus.
  73
  74 If `org-store-link' was called with a prefix arg the meaning of
  75 `org-gnus-prefer-web-links' is reversed."
  76   (let ((unprefixed-group (replace-regexp-in-string "^[^:]+:" "" group)))
  77     (if (and (string-match "^nntp" group) ;; Only for nntp groups
  78              (org-xor current-prefix-arg
  79                       org-gnus-prefer-web-links))
  80         (org-make-link (if (string-match "gmane" unprefixed-group)
  81                            "http://news.gmane.org/"
  82                          "http://groups.google.com/group/")
  83                        unprefixed-group)
  84       (org-make-link "gnus:" group))))
  85
  86 (defun org-gnus-article-link (group newsgroups message-id x-no-archive)
  87   "Create a link to a Gnus article.
  88 The article is specified by its MESSAGE-ID.  Additional
  89 parameters are the Gnus GROUP, the NEWSGROUPS the article was
  90 posted to and the X-NO-ARCHIVE header value of that article.
  91
  92 If GROUP is a newsgroup and `org-gnus-prefer-web-links' is
  93 non-nil, create a link to groups.google.com or gmane.org.
  94 Otherwise create a link to the article inside Gnus.
  95
  96 If `org-store-link' was called with a prefix arg the meaning of
  97 `org-gnus-prefer-web-links' is reversed."
  98   (if (and (org-xor current-prefix-arg org-gnus-prefer-web-links)
  99            newsgroups     ;; Make web links only for nntp groups
 100            (not x-no-archive)) ;; and if X-No-Archive isn't set.
 101       (format (if (string-match "gmane\\." newsgroups)
 102                   "http://mid.gmane.org/%s"
 103                 "http://groups.google.com/groups/search?as_umsgid=%s")
 104               (org-fixup-message-id-for-http message-id))
 105     (org-make-link "gnus:" group "#" message-id)))
 106
 107 (defun org-gnus-store-link ()
 108   "Store a link to a Gnus folder or message."
 109   (cond
 110    ((eq major-mode 'gnus-group-mode)
 111     (let* ((group (cond ((fboundp 'gnus-group-group-name) ; depending on Gnus
 112                          (gnus-group-group-name))         ; version
 113                         ((fboundp 'gnus-group-name)
 114                          (gnus-group-name))
 115                         (t "???")))
 116            desc link)
 117       (when group
 118         (org-store-link-props :type "gnus" :group group)
 119         (setq desc (org-gnus-group-link group)
 120               link desc)
 121         (org-add-link-props :link link :description desc)
 122         link)))
 123
 124    ((memq major-mode '(gnus-summary-mode gnus-article-mode))
 125     (let* ((group gnus-newsgroup-name)
 126            (header (with-current-buffer gnus-summary-buffer
 127                      (gnus-summary-article-header)))
 128            (extra (mail-header-extra header))
 129            (from (mail-header-from header))
 130            (message-id (org-remove-angle-brackets (mail-header-id header)))
 131            (date (mail-header-date header))
 132            (to (cdr (assoc 'To extra)))
 133            (newsgroups (cdr (assoc 'newsgroup extra)))
 134            (x-no-archive (cdr (assoc 'x-no-archive extra)))
 135            (subject (mail-header-subject header))
 136            desc link)
 137       (org-store-link-props :type "gnus" :from from :subject subject
 138                             :message-id message-id :group group :to to)
 139       (setq desc (org-email-link-description)
 140             link (org-gnus-article-link
 141                   group newsgroups message-id x-no-archive))
 142       (org-add-link-props :link link :description desc)
 143       link))))
 144
 145 (defun org-gnus-open (path)
 146   "Follow the Gnus message or folder link specified by PATH."
 147   (let (group article)
 148     (if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
 149         (error "Error in Gnus link"))
 150     (setq group (match-string 1 path)
 151           article (match-string 3 path))
 152     (when group
 153       (setq group (org-substring-no-properties group)))
 154     (when article
 155       (setq article (org-substring-no-properties article)))
 156     (org-gnus-follow-link group article)))
 157
 158 (defun org-gnus-follow-link (&optional group article)
 159   "Follow a Gnus link to GROUP and ARTICLE."
 160   (require 'gnus)
 161   (funcall (cdr (assq 'gnus org-link-frame-setup)))
 162   (if gnus-other-frame-object (select-frame gnus-other-frame-object))
 163   (when group
 164     (setq group (org-substring-no-properties group)))
 165   (when article
 166     (setq article (org-substring-no-properties article)))
 167   (cond ((and group article)
 168          (gnus-activate-group group t)
 169          (condition-case nil
 170              (let ((articles 1)
 171                    group-opened)
 172                (while (and (not group-opened)
 173                            ;; stop on integer overflows
 174                            (> articles 0))
 175                  (setq group-opened (gnus-group-read-group articles nil group)
 176                        articles (if (< articles 16)
 177                                     (1+ articles)
 178                                   (* articles 2))))
 179                (if group-opened
 180                    (gnus-summary-goto-article article nil t)
 181                  (message "Couldn't follow gnus link.  %s"
 182                           "The summary couldn't be opened.")))
 183            (quit (message "Couldn't follow gnus link.  %s"
 184                           "The linked group is empty."))))
 185         (group (gnus-group-jump-to-group group))))
 186
 187 (defun org-gnus-no-new-news ()
 188   "Like `M-x gnus' but doesn't check for new news."
 189   (if (not (gnus-alive-p)) (gnus)))
 190
 191 (provide 'org-gnus)
 192
 193 ;; arch-tag: 512e0840-58fa-45b3-b456-71e10fa2376d
 194
 195 ;;; org-gnus.el ends here