lisp/org-compat.el

   1 ;;; org-compat.el --- Compatibility code for Org-mode
   2
   3 ;; Copyright (C) 2004-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains code needed for compatibility with XEmacs and older
  28 ;; versions of GNU Emacs.
  29
  30 ;;; Code:
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'org-macs)
  36
  37 (declare-function w32-focus-frame "term/w32-win" (frame))
  38
  39 ;; The following constant is for backward compatibility.  We do not use
  40 ;; it in org-mode, because the Byte compiler evaluates (featurep 'xemacs)
  41 ;; at compilation time and can therefore optimize code better.
  42 (defconst org-xemacs-p (featurep 'xemacs))
  43 (defconst org-format-transports-properties-p
  44   (let ((x "a"))
  45     (add-text-properties 0 1 '(test t) x)
  46     (get-text-property 0 'test (format "%s" x)))
  47   "Does format transport text properties?")
  48
  49 (defun org-compatible-face (inherits specs)
  50   "Make a compatible face specification.
  51 If INHERITS is an existing face and if the Emacs version supports it,
  52 just inherit the face.  If INHERITS is set and the Emacs version does
  53 not support it, copy the face specification from the inheritance face.
  54 If INHERITS is not given and SPECS is, use SPECS to define the face.
  55 XEmacs and Emacs 21 do not know about the `min-colors' attribute.
  56 For them we convert a (min-colors 8) entry to a `tty' entry and move it
  57 to the top of the list.  The `min-colors' attribute will be removed from
  58 any other entries, and any resulting duplicates will be removed entirely."
  59   (when (and inherits (facep inherits) (not specs))
  60     (setq specs (or specs
  61                     (get inherits 'saved-face)
  62                     (get inherits 'face-defface-spec))))
  63   (cond
  64    ((and inherits (facep inherits)
  65          (not (featurep 'xemacs))
  66          (>= emacs-major-version 22)
  67          ;; do not inherit outline faces before Emacs 23
  68          (or (>= emacs-major-version 23)
  69              (not (string-match "\\`outline-[0-9]+"
  70                                 (symbol-name inherits)))))
  71     (list (list t :inherit inherits)))
  72    ((or (featurep 'xemacs) (< emacs-major-version 22))
  73     ;; These do not understand the `min-colors' attribute.
  74     (let (r e a)
  75       (while (setq e (pop specs))
  76         (cond
  77          ((memq (car e) '(t default)) (push e r))
  78          ((setq a (member '(min-colors 8) (car e)))
  79           (nconc r (list (cons (cons '(type tty) (delq (car a) (car e)))
  80                                (cdr e)))))
  81          ((setq a (assq 'min-colors (car e)))
  82           (setq e (cons (delq a (car e)) (cdr e)))
  83           (or (assoc (car e) r) (push e r)))
  84          (t (or (assoc (car e) r) (push e r)))))
  85       (nreverse r)))
  86    (t specs)))
  87 (put 'org-compatible-face 'lisp-indent-function 1)
  88
  89 (defun org-version-check (version feature level)
  90   (let* ((v1 (mapcar 'string-to-number (split-string version "[.]")))
  91          (v2 (mapcar 'string-to-number (split-string emacs-version "[.]")))
  92          (rmaj (or (nth 0 v1) 99))
  93          (rmin (or (nth 1 v1) 99))
  94          (rbld (or (nth 2 v1) 99))
  95          (maj (or (nth 0 v2) 0))
  96          (min (or (nth 1 v2) 0))
  97          (bld (or (nth 2 v2) 0)))
  98     (if (or (< maj rmaj)
  99             (and (= maj rmaj)
 100                  (< min rmin))
 101             (and (= maj rmaj)
 102                  (= min rmin)
 103                  (< bld rbld)))
 104         (if (eq level :predicate)
 105             ;; just return if we have the version
 106             nil
 107           (let ((msg (format "Emacs %s or greater is recommended for %s"
 108                              version feature)))
 109             (display-warning 'org msg level)
 110             t))
 111       t)))
 112
 113 \f
 114 ;;;; Emacs/XEmacs compatibility
 115
 116 ;; Keys
 117 (defconst org-xemacs-key-equivalents
 118   '(([mouse-1] . [button1])
 119     ([mouse-2] . [button2])
 120     ([mouse-3] . [button3])
 121     ([C-mouse-4] . [(control mouse-4)])
 122     ([C-mouse-5] . [(control mouse-5)]))
 123   "Translation alist for a couple of keys.")
 124
 125 ;; Overlay compatibility functions
 126 (defun org-detach-overlay (ovl)
 127   (if (featurep 'xemacs) (detach-extent ovl) (delete-overlay ovl)))
 128 (defun org-overlay-display (ovl text &optional face evap)
 129   "Make overlay OVL display TEXT with face FACE."
 130   (if (featurep 'xemacs)
 131       (let ((gl (make-glyph text)))
 132         (and face (set-glyph-face gl face))
 133         (set-extent-property ovl 'invisible t)
 134         (set-extent-property ovl 'end-glyph gl))
 135     (overlay-put ovl 'display text)
 136     (if face (overlay-put ovl 'face face))
 137     (if evap (overlay-put ovl 'evaporate t))))
 138 (defun org-overlay-before-string (ovl text &optional face evap)
 139   "Make overlay OVL display TEXT with face FACE."
 140   (if (featurep 'xemacs)
 141       (let ((gl (make-glyph text)))
 142         (and face (set-glyph-face gl face))
 143         (set-extent-property ovl 'begin-glyph gl))
 144     (if face (org-add-props text nil 'face face))
 145     (overlay-put ovl 'before-string text)
 146     (if evap (overlay-put ovl 'evaporate t))))
 147 (defun org-find-overlays (prop &optional pos delete)
 148   "Find all overlays specifying PROP at POS or point.
 149 If DELETE is non-nil, delete all those overlays."
 150   (let ((overlays (overlays-at (or pos (point))))
 151         ov found)
 152     (while (setq ov (pop overlays))
 153       (if (overlay-get ov prop)
 154           (if delete (delete-overlay ov) (push ov found))))
 155     found))
 156
 157 (defun org-get-x-clipboard (value)
 158   "Get the value of the x clipboard, compatible with XEmacs, and GNU Emacs 21."
 159   (if (eq window-system 'x)
 160       (let ((x (org-get-x-clipboard-compat value)))
 161         (if x (org-no-properties x)))))
 162
 163 (defsubst org-decompose-region (beg end)
 164   "Decompose from BEG to END."
 165   (if (featurep 'xemacs)
 166       (let ((modified-p (buffer-modified-p))
 167             (buffer-read-only nil))
 168         (remove-text-properties beg end '(composition nil))
 169         (set-buffer-modified-p modified-p))
 170     (decompose-region beg end)))
 171
 172 ;; Miscellaneous functions
 173
 174 (defun org-add-hook (hook function &optional append local)
 175   "Add-hook, compatible with both Emacsen."
 176   (if (and local (featurep 'xemacs))
 177       (add-local-hook hook function append)
 178     (add-hook hook function append local)))
 179
 180 (defun org-add-props (string plist &rest props)
 181   "Add text properties to entire string, from beginning to end.
 182 PLIST may be a list of properties, PROPS are individual properties and values
 183 that will be added to PLIST.  Returns the string that was modified."
 184   (add-text-properties
 185    0 (length string) (if props (append plist props) plist) string)
 186   string)
 187 (put 'org-add-props 'lisp-indent-function 2)
 188
 189 (defun org-fit-window-to-buffer (&optional window max-height min-height
 190                                            shrink-only)
 191   "Fit WINDOW to the buffer, but only if it is not a side-by-side window.
 192 WINDOW defaults to the selected window.  MAX-HEIGHT and MIN-HEIGHT are
 193 passed through to `fit-window-to-buffer'.  If SHRINK-ONLY is set, call
 194 `shrink-window-if-larger-than-buffer' instead, the height limit is
 195 ignored in this case."
 196   (cond ((if (fboundp 'window-full-width-p)
 197              (not (window-full-width-p window))
 198            (> (frame-width) (window-width window)))
 199          ;; do nothing if another window would suffer
 200          )
 201         ((and (fboundp 'fit-window-to-buffer) (not shrink-only))
 202          (fit-window-to-buffer window max-height min-height))
 203         ((fboundp 'shrink-window-if-larger-than-buffer)
 204          (shrink-window-if-larger-than-buffer window)))
 205   (or window (selected-window)))
 206
 207 (defun org-number-sequence (from &optional to inc)
 208   "Call `number-sequence or emulate it."
 209   (if (fboundp 'number-sequence)
 210       (number-sequence from to inc)
 211     (if (or (not to) (= from to))
 212         (list from)
 213       (or inc (setq inc 1))
 214       (when (zerop inc) (error "The increment can not be zero"))
 215       (let (seq (n 0) (next from))
 216         (if (> inc 0)
 217             (while (<= next to)
 218               (setq seq (cons next seq)
 219                     n (1+ n)
 220                     next (+ from (* n inc))))
 221           (while (>= next to)
 222             (setq seq (cons next seq)
 223                   n (1+ n)
 224                   next (+ from (* n inc)))))
 225         (nreverse seq)))))
 226
 227 ;; Region compatibility
 228
 229 (defvar org-ignore-region nil
 230   "To temporarily disable the active region.")
 231
 232 (defun org-region-active-p ()
 233   "Is `transient-mark-mode' on and the region active?
 234 Works on both Emacs and XEmacs."
 235   (if org-ignore-region
 236       nil
 237     (if (featurep 'xemacs)
 238         (and zmacs-regions (region-active-p))
 239       (if (fboundp 'use-region-p)
 240           (use-region-p)
 241         (and transient-mark-mode mark-active))))) ; Emacs 22 and before
 242
 243 (defun org-cursor-to-region-beginning ()
 244   (when (and (org-region-active-p)
 245              (> (point) (region-beginning)))
 246     (exchange-point-and-mark)))
 247
 248 ;; Emacs 22 misses `activate-mark'
 249 (if (fboundp 'activate-mark)
 250     (defalias 'org-activate-mark 'activate-mark)
 251   (defun org-activate-mark ()
 252     (when (mark t)
 253       (setq mark-active t)
 254       (when (and (boundp 'transient-mark-mode)
 255                  (not transient-mark-mode))
 256         (setq transient-mark-mode 'lambda))
 257       (when (boundp 'zmacs-regions)
 258         (setq zmacs-regions t)))))
 259
 260
 261 ;; Invisibility compatibility
 262
 263 (defun org-remove-from-invisibility-spec (arg)
 264   "Remove elements from `buffer-invisibility-spec'."
 265   (if (fboundp 'remove-from-invisibility-spec)
 266       (remove-from-invisibility-spec arg)
 267     (if (consp buffer-invisibility-spec)
 268         (setq buffer-invisibility-spec
 269               (delete arg buffer-invisibility-spec)))))
 270
 271 (defun org-in-invisibility-spec-p (arg)
 272   "Is ARG a member of `buffer-invisibility-spec'?"
 273   (if (consp buffer-invisibility-spec)
 274       (member arg buffer-invisibility-spec)
 275     nil))
 276
 277 (defmacro org-xemacs-without-invisibility (&rest body)
 278   "Turn off extents with invisibility while executing BODY."
 279   `(let ((ext-inv (extent-list nil (point-at-bol) (point-at-eol)
 280                                'all-extents-closed-open 'invisible))
 281          ext-inv-specs)
 282      (dolist (ext ext-inv)
 283        (when (extent-property ext 'invisible)
 284          (add-to-list 'ext-inv-specs (list ext (extent-property
 285                                                 ext 'invisible)))
 286          (set-extent-property ext 'invisible nil)))
 287      ,@body
 288      (dolist (ext-inv-spec ext-inv-specs)
 289        (set-extent-property (car ext-inv-spec) 'invisible
 290                             (cadr ext-inv-spec)))))
 291 (def-edebug-spec org-xemacs-without-invisibility (body))
 292
 293 (defun org-indent-to-column (column &optional minimum buffer)
 294   "Work around a bug with extents with invisibility in XEmacs."
 295   (if (featurep 'xemacs)
 296       (org-xemacs-without-invisibility (indent-to-column column minimum buffer))
 297     (indent-to-column column minimum)))
 298
 299 (defun org-indent-line-to (column)
 300   "Work around a bug with extents with invisibility in XEmacs."
 301   (if (featurep 'xemacs)
 302       (org-xemacs-without-invisibility (indent-line-to column))
 303     (indent-line-to column)))
 304
 305 (defun org-move-to-column (column &optional force buffer)
 306   (if (featurep 'xemacs)
 307       (org-xemacs-without-invisibility (move-to-column column force buffer))
 308     (move-to-column column force)))
 309
 310 (defun org-get-x-clipboard-compat (value)
 311   "Get the clipboard value on XEmacs or Emacs 21."
 312   (cond ((featurep 'xemacs)
 313          (org-no-warnings (get-selection-no-error value)))
 314         ((fboundp 'x-get-selection)
 315          (condition-case nil
 316              (or (x-get-selection value 'UTF8_STRING)
 317                  (x-get-selection value 'COMPOUND_TEXT)
 318                  (x-get-selection value 'STRING)
 319                  (x-get-selection value 'TEXT))
 320            (error nil)))))
 321
 322 (defun org-propertize (string &rest properties)
 323   (if (featurep 'xemacs)
 324       (progn
 325         (add-text-properties 0 (length string) properties string)
 326         string)
 327     (apply 'propertize string properties)))
 328
 329 (defmacro org-find-library-dir (library)
 330   `(file-name-directory (or (locate-library ,library) "")))
 331
 332 (defun org-count-lines (s)
 333   "How many lines in string S?"
 334   (let ((start 0) (n 1))
 335     (while (string-match "\n" s start)
 336       (setq start (match-end 0) n (1+ n)))
 337     (if (and (> (length s) 0) (= (aref s (1- (length s))) ?\n))
 338         (setq n (1- n)))
 339     n))
 340
 341 (defun org-kill-new (string &rest args)
 342   (remove-text-properties 0 (length string) '(line-prefix t wrap-prefix t)
 343                           string)
 344   (apply 'kill-new string args))
 345
 346 (defun org-select-frame-set-input-focus (frame)
 347   "Select FRAME, raise it, and set input focus, if possible."
 348   (cond ((featurep 'xemacs)
 349          (if (fboundp 'select-frame-set-input-focus)
 350              (select-frame-set-input-focus frame)
 351            (raise-frame frame)
 352            (select-frame frame)
 353            (focus-frame frame)))
 354         ;; `select-frame-set-input-focus' defined in Emacs 21 will not
 355         ;; set the input focus.
 356         ((>= emacs-major-version 22)
 357          (select-frame-set-input-focus frame))
 358         (t
 359          (raise-frame frame)
 360          (select-frame frame)
 361          (cond ((memq window-system '(x ns mac))
 362                 (x-focus-frame frame))
 363                ((eq window-system 'w32)
 364                 (w32-focus-frame frame)))
 365          (when focus-follows-mouse
 366            (set-mouse-position frame (1- (frame-width frame)) 0)))))
 367
 368 (defun org-float-time (&optional time)
 369   "Convert time value TIME to a floating point number.
 370 TIME defaults to the current time."
 371   (if (featurep 'xemacs)
 372       (time-to-seconds (or time (current-time)))
 373     (float-time time)))
 374
 375 (if (fboundp 'string-match-p)
 376     (defalias 'org-string-match-p 'string-match-p)
 377   (defun org-string-match-p (regexp string &optional start)
 378     (save-match-data
 379       (funcall 'string-match regexp string start))))
 380
 381 (if (fboundp 'looking-at-p)
 382     (defalias 'org-looking-at-p 'looking-at-p)
 383   (defun org-looking-at-p (&rest args)
 384     (save-match-data
 385       (apply 'looking-at args))))
 386
 387                                         ; XEmacs does not have `looking-back'.
 388 (if (fboundp 'looking-back)
 389     (defalias 'org-looking-back 'looking-back)
 390   (defun org-looking-back (regexp &optional limit greedy)
 391     "Return non-nil if text before point matches regular expression REGEXP.
 392 Like `looking-at' except matches before point, and is slower.
 393 LIMIT if non-nil speeds up the search by specifying a minimum
 394 starting position, to avoid checking matches that would start
 395 before LIMIT.
 396
 397 If GREEDY is non-nil, extend the match backwards as far as
 398 possible, stopping when a single additional previous character
 399 cannot be part of a match for REGEXP.  When the match is
 400 extended, its starting position is allowed to occur before
 401 LIMIT."
 402     (let ((start (point))
 403           (pos
 404            (save-excursion
 405              (and (re-search-backward (concat "\\(?:" regexp "\\)\\=") limit t)
 406                   (point)))))
 407       (if (and greedy pos)
 408           (save-restriction
 409             (narrow-to-region (point-min) start)
 410             (while (and (> pos (point-min))
 411                         (save-excursion
 412                           (goto-char pos)
 413                           (backward-char 1)
 414                           (looking-at (concat "\\(?:"  regexp "\\)\\'"))))
 415               (setq pos (1- pos)))
 416             (save-excursion
 417               (goto-char pos)
 418               (looking-at (concat "\\(?:"  regexp "\\)\\'")))))
 419       (not (null pos)))))
 420
 421 (defun org-floor* (x &optional y)
 422   "Return a list of the floor of X and the fractional part of X.
 423 With two arguments, return floor and remainder of their quotient."
 424   (let ((q (floor x y)))
 425     (list q (- x (if y (* y q) q)))))
 426
 427 ;; `pop-to-buffer-same-window' has been introduced in Emacs 24.1.
 428 (defun org-pop-to-buffer-same-window
 429   (&optional buffer-or-name norecord label)
 430   "Pop to buffer specified by BUFFER-OR-NAME in the selected window."
 431   (if (fboundp 'pop-to-buffer-same-window)
 432       (funcall
 433        'pop-to-buffer-same-window buffer-or-name norecord)
 434     (funcall 'switch-to-buffer buffer-or-name norecord)))
 435
 436 ;; `condition-case-unless-debug' has been introduced in Emacs 24.1
 437 ;; `condition-case-no-debug' has been introduced in Emacs 23.1
 438 (defalias 'org-condition-case-unless-debug
 439   (or (and (fboundp 'condition-case-unless-debug)
 440            'condition-case-unless-debug)
 441       (and (fboundp 'condition-case-no-debug)
 442            'condition-case-no-debug)
 443       'condition-case))
 444
 445 ;;;###autoload
 446 (defmacro org-check-version ()
 447   "Try very hard to provide sensible version strings."
 448   (let* ((org-dir        (org-find-library-dir "org"))
 449          (org-version.el (concat org-dir "org-version.el"))
 450          (org-fixup.el   (concat org-dir "../mk/org-fixup.el")))
 451     (if (require 'org-version org-version.el 'noerror)
 452         '(progn
 453            (autoload 'org-release     "org-version.el")
 454            (autoload 'org-git-version "org-version.el"))
 455       (if (require 'org-fixup org-fixup.el 'noerror)
 456           '(org-fixup)
 457         ;; provide fallback definitions and complain
 458         (warn "Could not define org version correctly.  Check installation!")
 459         '(progn
 460            (defun org-release () "N/A")
 461            (defun org-git-version () "N/A !!check installation!!"))))))
 462
 463 (provide 'org-compat)
 464
 465 ;;; org-compat.el ends here