lisp/org-clock.el

   1 ;;; org-clock.el --- The time clocking code for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.26a
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the time clocking code for Org-mode
  30
  31 (require 'org)
  32 (eval-when-compile
  33   (require 'cl)
  34   (require 'calendar))
  35
  36 (declare-function calendar-absolute-from-iso    "cal-iso"    (&optional date))
  37 (defvar org-time-stamp-formats)
  38
  39 (defgroup org-clock nil
  40   "Options concerning clocking working time in Org-mode."
  41   :tag "Org Clock"
  42   :group 'org-progress)
  43
  44 (defcustom org-clock-into-drawer org-log-into-drawer
  45   "Should clocking info be wrapped into a drawer?
  46 When t, clocking info will always be inserted into a :LOGBOOK: drawer.
  47 If necessary, the drawer will be created.
  48 When nil, the drawer will not be created, but used when present.
  49 When an integer and the number of clocking entries in an item
  50 reaches or exceeds this number, a drawer will be created.
  51 When a string, it names the drawer to be used.
  52
  53 The default for this variable is the value of `org-log-into-drawer',
  54 which see."
  55   :group 'org-todo
  56   :group 'org-clock
  57   :type '(choice
  58           (const :tag "Always" t)
  59           (const :tag "Only when drawer exists" nil)
  60           (integer :tag "When at least N clock entries")
  61           (const :tag "Into LOGBOOK drawer" "LOGBOOK")
  62           (string :tag "Into Drawer named...")))
  63
  64 (defcustom org-clock-out-when-done t
  65   "When non-nil, clock will be stopped when the clocked entry is marked DONE.
  66 A nil value means, clock will keep running until stopped explicitly with
  67 `C-c C-x C-o', or until the clock is started in a different item."
  68   :group 'org-clock
  69   :type 'boolean)
  70
  71 (defcustom org-clock-out-remove-zero-time-clocks nil
  72   "Non-nil means, remove the clock line when the resulting time is zero."
  73   :group 'org-clock
  74   :type 'boolean)
  75
  76 (defcustom org-clock-in-switch-to-state nil
  77   "Set task to a special todo state while clocking it.
  78 The value should be the state to which the entry should be
  79 switched. If the value is a function, it must take one
  80 parameter (the current TODO state of the item) and return the
  81 state to switch it to."
  82   :group 'org-clock
  83   :group 'org-todo
  84   :type '(choice
  85           (const :tag "Don't force a state" nil)
  86           (string :tag "State")
  87           (symbol :tag "Function")))
  88
  89 (defcustom org-clock-history-length 5
  90   "Number of clock tasks to remember in history."
  91   :group 'org-clock
  92   :type 'integer)
  93
  94 (defcustom org-clock-heading-function nil
  95   "When non-nil, should be a function to create `org-clock-heading'.
  96 This is the string shown in the mode line when a clock is running.
  97 The function is called with point at the beginning of the headline."
  98   :group 'org-clock
  99   :type 'function)
 100
 101 (defcustom org-clock-string-limit 0
 102   "Maximum length of clock strings in the modeline. 0 means no limit."
 103   :group 'org-clock
 104   :type 'integer)
 105
 106 (defcustom org-clock-in-resume nil
 107   "If non-nil, resume clock when clocking into task with open clock.
 108 When clocking into a task with a clock entry which has not been closed,
 109 the clock can be resumed from that point."
 110   :group 'org-clock
 111   :type 'boolean)
 112
 113 (defcustom org-clock-persist nil
 114   "When non-nil, save the running clock when emacs is closed.
 115 The clock is resumed when emacs restarts.
 116 When this is t, both the running clock, and the entire clock
 117 history are saved.  When this is the symbol `clock', only the
 118 running clock is saved.
 119
 120 When Emacs restarts with saved clock information, the file containing the
 121 running clock as well as all files mentioned in the clock history will
 122 be visited.
 123 All this depends on running `org-clock-persistence-insinuate' in .emacs"
 124   :group 'org-clock
 125   :type '(choice
 126           (const :tag "Just the running clock" clock)
 127           (const :tag "Clock and history" t)
 128           (const :tag "No persistence" nil)))
 129
 130 (defcustom org-clock-persist-file (convert-standard-filename
 131                                    "~/.emacs.d/org-clock-save.el")
 132   "File to save clock data to."
 133   :group 'org-clock
 134   :type 'string)
 135
 136 (defcustom org-clock-persist-query-save nil
 137   "When non-nil, ask before saving the current clock on exit."
 138   :group 'org-clock
 139   :type 'boolean)
 140
 141 (defcustom org-clock-persist-query-resume t
 142   "When non-nil, ask before resuming any stored clock during load."
 143   :group 'org-clock
 144   :type 'boolean)
 145
 146 ;;; The clock for measuring work time.
 147
 148 (defvar org-mode-line-string "")
 149 (put 'org-mode-line-string 'risky-local-variable t)
 150
 151 (defvar org-clock-mode-line-timer nil)
 152 (defvar org-clock-heading "")
 153 (defvar org-clock-heading-for-remember "")
 154 (defvar org-clock-start-time "")
 155
 156 (defvar org-clock-history nil
 157   "List of marker pointing to recent clocked tasks.")
 158
 159 (defvar org-clock-default-task (make-marker)
 160   "Marker pointing to the default task that should clock time.
 161 The clock can be made to switch to this task after clocking out
 162 of a different task.")
 163
 164 (defvar org-clock-interrupted-task (make-marker)
 165   "Marker pointing to the task that has been interrupted by the current clock.")
 166
 167 (defvar org-clock-mode-line-map (make-sparse-keymap))
 168 (define-key org-clock-mode-line-map [mode-line mouse-2] 'org-clock-goto)
 169
 170 (defun org-clock-history-push (&optional pos buffer)
 171   "Push a marker to the clock history."
 172   (setq org-clock-history-length (max 1 (min 35 org-clock-history-length)))
 173   (let ((m (move-marker (make-marker) (or pos (point)) buffer)) n l)
 174     (while (setq n (member m org-clock-history))
 175       (move-marker (car n) nil))
 176     (setq org-clock-history
 177           (delq nil
 178                 (mapcar (lambda (x) (if (marker-buffer x) x nil))
 179                         org-clock-history)))
 180     (when (>= (setq l (length org-clock-history)) org-clock-history-length)
 181       (setq org-clock-history
 182             (nreverse
 183              (nthcdr (- l org-clock-history-length -1)
 184                      (nreverse org-clock-history)))))
 185     (push m org-clock-history)))
 186
 187 (defun org-clock-save-markers-for-cut-and-paste (beg end)
 188   "Save relative positions of markers in region."
 189   (org-check-and-save-marker org-clock-marker beg end)
 190   (org-check-and-save-marker org-clock-default-task beg end)
 191   (org-check-and-save-marker org-clock-interrupted-task beg end)
 192   (mapc (lambda (m) (org-check-and-save-marker m beg end))
 193         org-clock-history))
 194
 195 (defun org-clock-select-task (&optional prompt)
 196   "Select a task that recently was associated with clocking."
 197   (interactive)
 198   (let (sel-list rpl (i 0) s)
 199     (save-window-excursion
 200       (org-switch-to-buffer-other-window
 201        (get-buffer-create "*Clock Task Select*"))
 202       (erase-buffer)
 203       (when (marker-buffer org-clock-default-task)
 204         (insert (org-add-props "Default Task\n" nil 'face 'bold))
 205         (setq s (org-clock-insert-selection-line ?d org-clock-default-task))
 206         (push s sel-list))
 207       (when (marker-buffer org-clock-interrupted-task)
 208         (insert (org-add-props "The task interrupted by starting the last one\n" nil 'face 'bold))
 209         (setq s (org-clock-insert-selection-line ?i org-clock-interrupted-task))
 210         (push s sel-list))
 211       (when (marker-buffer org-clock-marker)
 212         (insert (org-add-props "Current Clocking Task\n" nil 'face 'bold))
 213         (setq s (org-clock-insert-selection-line ?c org-clock-marker))
 214         (push s sel-list))
 215       (insert (org-add-props "Recent Tasks\n" nil 'face 'bold))
 216       (mapc
 217        (lambda (m)
 218          (when (marker-buffer m)
 219            (setq i (1+ i)
 220                  s (org-clock-insert-selection-line
 221                     (if (< i 10)
 222                         (+ i ?0)
 223                       (+ i (- ?A 10))) m))
 224            (push s sel-list)))
 225        org-clock-history)
 226       (org-fit-window-to-buffer)
 227       (message (or prompt "Select task for clocking:"))
 228       (setq rpl (read-char-exclusive))
 229       (cond
 230        ((eq rpl ?q) nil)
 231        ((eq rpl ?x) nil)
 232        ((assoc rpl sel-list) (cdr (assoc rpl sel-list)))
 233        (t (error "Invalid task choice %c" rpl))))))
 234
 235 (defun org-clock-insert-selection-line (i marker)
 236   (when (marker-buffer marker)
 237     (let (file cat task)
 238       (with-current-buffer (org-base-buffer (marker-buffer marker))
 239         (save-excursion
 240           (save-restriction
 241             (widen)
 242             (goto-char marker)
 243             (setq file (buffer-file-name (marker-buffer marker))
 244                   cat (or (org-get-category)
 245                           (progn (org-refresh-category-properties)
 246                                  (org-get-category)))
 247                   task (org-get-heading 'notags)))))
 248       (when (and cat task)
 249         (insert (format "[%c] %-15s %s\n" i cat task))
 250         (cons i marker)))))
 251
 252 (defun org-clock-update-mode-line ()
 253   (let* ((delta (- (time-to-seconds (current-time))
 254                    (time-to-seconds org-clock-start-time)))
 255          (h (floor delta 3600))
 256          (m (floor (- delta (* 3600 h)) 60)))
 257     (setq org-mode-line-string
 258           (org-propertize
 259            (let ((clock-string (format (concat "-[" org-time-clocksum-format " (%s)]")
 260                                        h m org-clock-heading))
 261                  (help-text "Org-mode clock is running. Mouse-2 to go there."))
 262              (if (and (> org-clock-string-limit 0)
 263                       (> (length clock-string) org-clock-string-limit))
 264                  (org-propertize (substring clock-string 0 org-clock-string-limit)
 265                              'help-echo (concat help-text ": " org-clock-heading))
 266                (org-propertize clock-string 'help-echo help-text)))
 267            'local-map org-clock-mode-line-map
 268            'mouse-face (if (featurep 'xemacs) 'highlight 'mode-line-highlight)))
 269     (force-mode-line-update)))
 270
 271 (defvar org-clock-mode-line-entry nil
 272   "Information for the modeline about the running clock.")
 273
 274 (defun org-clock-in (&optional select)
 275   "Start the clock on the current item.
 276 If necessary, clock-out of the currently active clock.
 277 With prefix arg SELECT, offer a list of recently clocked tasks to
 278 clock into.  When SELECT is `C-u C-u', clock into the current task and mark
 279 is as the default task, a special task that will always be offered in
 280 the clocking selection, associated with the letter `d'."
 281   (interactive "P")
 282   (catch 'abort
 283     (let ((interrupting (marker-buffer org-clock-marker))
 284           ts selected-task target-pos)
 285       (when (equal select '(4))
 286         (setq selected-task (org-clock-select-task "Clock-in on task: "))
 287         (if selected-task
 288             (setq selected-task (copy-marker selected-task))
 289           (error "Abort")))
 290       (when interrupting
 291         ;; We are interrupting the clocking of a different task.
 292         ;; Save a marker to this task, so that we can go back.
 293         (move-marker org-clock-interrupted-task
 294                      (marker-position org-clock-marker)
 295                      (marker-buffer org-clock-marker))
 296         (org-clock-out t))
 297
 298       (when (equal select '(16))
 299         ;; Mark as default clocking task
 300         (save-excursion
 301           (org-back-to-heading t)
 302           (move-marker org-clock-default-task (point))))
 303
 304       (setq target-pos (point))  ;; we want to clock in at this location
 305       (save-excursion
 306         (when (and selected-task (marker-buffer selected-task))
 307           ;; There is a selected task, move to the correct buffer
 308           ;; and set the new target position.
 309           (set-buffer (org-base-buffer (marker-buffer selected-task)))
 310           (setq target-pos (marker-position selected-task))
 311           (move-marker selected-task nil))
 312         (save-excursion
 313           (save-restriction
 314             (widen)
 315             (goto-char target-pos)
 316             (org-back-to-heading t)
 317             (or interrupting (move-marker org-clock-interrupted-task nil))
 318             (org-clock-history-push)
 319             (cond ((functionp org-clock-in-switch-to-state)
 320                    (looking-at org-complex-heading-regexp)
 321                    (let ((newstate (funcall org-clock-in-switch-to-state
 322                                             (match-string 2))))
 323                      (if newstate (org-todo newstate))))
 324                   ((and org-clock-in-switch-to-state
 325                         (not (looking-at (concat outline-regexp "[ \t]*"
 326                                                  org-clock-in-switch-to-state
 327                                                  "\\>"))))
 328                    (org-todo org-clock-in-switch-to-state)))
 329             (setq org-clock-heading-for-remember
 330                   (and (looking-at org-complex-heading-regexp)
 331                        (match-end 4)
 332                        (org-trim (buffer-substring (match-end 1)
 333                                                    (match-end 4)))))
 334             (setq org-clock-heading
 335                   (cond ((and org-clock-heading-function
 336                               (functionp org-clock-heading-function))
 337                          (funcall org-clock-heading-function))
 338                         ((looking-at org-complex-heading-regexp)
 339                          (match-string 4))
 340                         (t "???")))
 341             (setq org-clock-heading (org-propertize org-clock-heading
 342                                                     'face nil))
 343             (org-clock-find-position org-clock-in-resume)
 344             (cond
 345              ((and org-clock-in-resume
 346                    (looking-at
 347                     (concat "^[ \t]* " org-clock-string
 348                             " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 349                             " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")))
 350               (message "Matched %s" (match-string 1))
 351               (setq ts (concat "[" (match-string 1) "]"))
 352               (goto-char (match-end 1))
 353               (setq org-clock-start-time
 354                     (apply 'encode-time
 355                            (org-parse-time-string (match-string 1)))))
 356              ((eq org-clock-in-resume 'auto-restart)
 357               ;; called from org-clock-load during startup,
 358               ;; do not interrupt, but warn!
 359               (message "Cannot restart clock because task does not contain unfinished clock")
 360               (ding)
 361               (sit-for 2)
 362               (throw 'abort nil))
 363              (t
 364               (insert-before-markers "\n")
 365               (backward-char 1)
 366               (org-indent-line-function)
 367               (when (and (save-excursion
 368                            (end-of-line 0)
 369                            (org-in-item-p)))
 370                 (beginning-of-line 1)
 371                 (org-indent-line-to (- (org-get-indentation) 2)))
 372               (insert org-clock-string " ")
 373               (setq org-clock-start-time (current-time))
 374               (setq ts (org-insert-time-stamp org-clock-start-time 'with-hm 'inactive))))
 375             (move-marker org-clock-marker (point) (buffer-base-buffer))
 376             (or global-mode-string (setq global-mode-string '("")))
 377             (or (memq 'org-mode-line-string global-mode-string)
 378                 (setq global-mode-string
 379                       (append global-mode-string '(org-mode-line-string))))
 380             (org-clock-update-mode-line)
 381             (setq org-clock-mode-line-timer
 382                   (run-with-timer 60 60 'org-clock-update-mode-line))
 383             (message "Clock started at %s" ts)))))
 384     (org-clock-goto nil)))
 385
 386 (defun org-clock-find-position (find-unclosed)
 387   "Find the location where the next clock line should be inserted.
 388 When FIND-UNCLOSED is non-nil, first check if there is an unclosed clock
 389 line and position cursor in that line."
 390   (org-back-to-heading t)
 391   (catch 'exit
 392     (let ((beg (save-excursion
 393                  (beginning-of-line 2)
 394                  (or (bolp) (newline))
 395                  (point)))
 396           (end (progn (outline-next-heading) (point)))
 397           (re (concat "^[ \t]*" org-clock-string))
 398           (cnt 0)
 399           (drawer (if (stringp org-clock-into-drawer)
 400                       org-clock-into-drawer "LOGBOOK"))
 401           first last ind-last)
 402       (goto-char beg)
 403       (when (and find-unclosed
 404                  (re-search-forward
 405                   (concat "^[ \t]* " org-clock-string
 406                           " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 407                           " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")
 408                   end t))
 409         (beginning-of-line 1)
 410         (throw 'exit t))
 411       (when (eobp) (newline) (setq end (max (point) end)))
 412       (when (re-search-forward (concat "^[ \t]*:" drawer ":") end t)
 413         ;; we seem to have a CLOCK drawer, so go there.
 414         (beginning-of-line 2)
 415         (or org-log-states-order-reversed
 416             (and (re-search-forward org-property-end-re nil t)
 417                  (goto-char (match-beginning 0))))
 418         (throw 'exit t))
 419       ;; Lets count the CLOCK lines
 420       (goto-char beg)
 421       (while (re-search-forward re end t)
 422         (setq first (or first (match-beginning 0))
 423               last (match-beginning 0)
 424               cnt (1+ cnt)))
 425       (when (and (integerp org-clock-into-drawer)
 426                  last
 427                  (>= (1+ cnt) org-clock-into-drawer))
 428         ;; Wrap current entries into a new drawer
 429         (goto-char last)
 430         (setq ind-last (org-get-indentation))
 431         (beginning-of-line 2)
 432         (if (and (>= (org-get-indentation) ind-last)
 433                  (org-at-item-p))
 434             (org-end-of-item))
 435         (insert ":END:\n")
 436         (beginning-of-line 0)
 437         (org-indent-line-to ind-last)
 438         (goto-char first)
 439         (insert ":" drawer ":\n")
 440         (beginning-of-line 0)
 441         (org-indent-line-function)
 442         (org-flag-drawer t)
 443         (beginning-of-line 2)
 444         (or org-log-states-order-reversed
 445             (and (re-search-forward org-property-end-re nil t)
 446                  (goto-char (match-beginning 0))))
 447         (throw 'exit nil))
 448
 449       (goto-char beg)
 450       (while (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 451                   (not (equal (match-string 1) org-clock-string)))
 452         ;; Planning info, skip to after it
 453         (beginning-of-line 2)
 454         (or (bolp) (newline)))
 455       (when (or (eq org-clock-into-drawer t)
 456                 (stringp org-clock-into-drawer)
 457                 (and (integerp org-clock-into-drawer)
 458                      (< org-clock-into-drawer 2)))
 459         (insert ":" drawer ":\n:END:\n")
 460         (beginning-of-line -1)
 461         (org-indent-line-function)
 462         (org-flag-drawer t)
 463         (beginning-of-line 2)
 464         (org-indent-line-function)
 465         (beginning-of-line)
 466         (or org-log-states-order-reversed
 467             (and (re-search-forward org-property-end-re nil t)
 468                  (goto-char (match-beginning 0))))))))
 469
 470 (defun org-clock-out (&optional fail-quietly)
 471   "Stop the currently running clock.
 472 If there is no running clock, throw an error, unless FAIL-QUIETLY is set."
 473   (interactive)
 474   (catch 'exit
 475   (if (not (marker-buffer org-clock-marker))
 476       (if fail-quietly (throw 'exit t) (error "No active clock")))
 477   (let (ts te s h m remove)
 478     (save-excursion
 479       (set-buffer (marker-buffer org-clock-marker))
 480       (save-restriction
 481         (widen)
 482         (goto-char org-clock-marker)
 483         (beginning-of-line 1)
 484         (if (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 485                  (equal (match-string 1) org-clock-string))
 486             (setq ts (match-string 2))
 487           (if fail-quietly (throw 'exit nil) (error "Clock start time is gone")))
 488         (goto-char (match-end 0))
 489         (delete-region (point) (point-at-eol))
 490         (insert "--")
 491         (setq te (org-insert-time-stamp (current-time) 'with-hm 'inactive))
 492         (setq s (- (time-to-seconds (apply 'encode-time (org-parse-time-string te)))
 493                    (time-to-seconds (apply 'encode-time (org-parse-time-string ts))))
 494               h (floor (/ s 3600))
 495               s (- s (* 3600 h))
 496               m (floor (/ s 60))
 497               s (- s (* 60 s)))
 498         (insert " => " (format "%2d:%02d" h m))
 499         (when (setq remove (and org-clock-out-remove-zero-time-clocks
 500                                 (= (+ h m) 0)))
 501           (beginning-of-line 1)
 502           (delete-region (point) (point-at-eol))
 503           (and (looking-at "\n") (> (point-max) (1+ (point)))
 504                (delete-char 1)))
 505         (move-marker org-clock-marker nil)
 506         (when org-log-note-clock-out
 507           (org-add-log-setup 'clock-out nil nil nil nil
 508                              (concat "# Task: " (org-get-heading t) "\n\n")))
 509         (when org-clock-mode-line-timer
 510           (cancel-timer org-clock-mode-line-timer)
 511           (setq org-clock-mode-line-timer nil))
 512         (setq global-mode-string
 513               (delq 'org-mode-line-string global-mode-string))
 514         (force-mode-line-update)
 515         (message (concat "Clock stopped at %s after HH:MM = " org-time-clocksum-format "%s") te h m
 516                  (if remove " => LINE REMOVED" "")))))))
 517
 518 (defun org-clock-cancel ()
 519   "Cancel the running clock be removing the start timestamp."
 520   (interactive)
 521   (if (not (marker-buffer org-clock-marker))
 522       (error "No active clock"))
 523   (save-excursion
 524     (set-buffer (marker-buffer org-clock-marker))
 525     (goto-char org-clock-marker)
 526     (delete-region (1- (point-at-bol)) (point-at-eol)))
 527   (setq global-mode-string
 528         (delq 'org-mode-line-string global-mode-string))
 529   (force-mode-line-update)
 530   (message "Clock canceled"))
 531
 532 (defun org-clock-goto (&optional select)
 533   "Go to the currently clocked-in entry.
 534 With prefix arg SELECT, offer recently clocked tasks."
 535   (interactive "P")
 536   (let ((m (if select
 537                (org-clock-select-task "Select task to go to: ")
 538              org-clock-marker)))
 539     (if (not (marker-buffer m))
 540         (if select
 541             (error "No task selected")
 542           (error "No active clock")))
 543     (switch-to-buffer (marker-buffer m))
 544     (if (or (< m (point-min)) (> m (point-max))) (widen))
 545     (goto-char m)
 546     (org-show-entry)
 547     (org-back-to-heading)
 548     (org-cycle-hide-drawers 'children)
 549     (recenter)))
 550
 551 (defvar org-clock-file-total-minutes nil
 552   "Holds the file total time in minutes, after a call to `org-clock-sum'.")
 553   (make-variable-buffer-local 'org-clock-file-total-minutes)
 554
 555 (defun org-clock-sum (&optional tstart tend)
 556   "Sum the times for each subtree.
 557 Puts the resulting times in minutes as a text property on each headline."
 558   (interactive)
 559   (let* ((bmp (buffer-modified-p))
 560          (re (concat "^\\(\\*+\\)[ \t]\\|^[ \t]*"
 561                      org-clock-string
 562                      "[ \t]*\\(?:\\(\\[.*?\\]\\)-+\\(\\[.*?\\]\\)\\|=>[ \t]+\\([0-9]+\\):\\([0-9]+\\)\\)"))
 563          (lmax 30)
 564          (ltimes (make-vector lmax 0))
 565          (t1 0)
 566          (level 0)
 567          ts te dt
 568          time)
 569     (remove-text-properties (point-min) (point-max) '(:org-clock-minutes t))
 570     (save-excursion
 571       (goto-char (point-max))
 572       (while (re-search-backward re nil t)
 573         (cond
 574          ((match-end 2)
 575           ;; Two time stamps
 576           (setq ts (match-string 2)
 577                 te (match-string 3)
 578                 ts (time-to-seconds
 579                     (apply 'encode-time (org-parse-time-string ts)))
 580                 te (time-to-seconds
 581                     (apply 'encode-time (org-parse-time-string te)))
 582                 ts (if tstart (max ts tstart) ts)
 583                 te (if tend (min te tend) te)
 584                 dt (- te ts)
 585                 t1 (if (> dt 0) (+ t1 (floor (/ dt 60))) t1)))
 586          ((match-end 4)
 587           ;; A naked time
 588           (setq t1 (+ t1 (string-to-number (match-string 5))
 589                       (* 60 (string-to-number (match-string 4))))))
 590          (t ;; A headline
 591           (setq level (- (match-end 1) (match-beginning 1)))
 592           (when (or (> t1 0) (> (aref ltimes level) 0))
 593             (loop for l from 0 to level do
 594                   (aset ltimes l (+ (aref ltimes l) t1)))
 595             (setq t1 0 time (aref ltimes level))
 596             (loop for l from level to (1- lmax) do
 597                   (aset ltimes l 0))
 598             (goto-char (match-beginning 0))
 599             (put-text-property (point) (point-at-eol) :org-clock-minutes time)))))
 600       (setq org-clock-file-total-minutes (aref ltimes 0)))
 601     (set-buffer-modified-p bmp)))
 602
 603 (defun org-clock-display (&optional total-only)
 604   "Show subtree times in the entire buffer.
 605 If TOTAL-ONLY is non-nil, only show the total time for the entire file
 606 in the echo area."
 607   (interactive)
 608   (org-clock-remove-overlays)
 609   (let (time h m p)
 610     (org-clock-sum)
 611     (unless total-only
 612       (save-excursion
 613         (goto-char (point-min))
 614         (while (or (and (equal (setq p (point)) (point-min))
 615                         (get-text-property p :org-clock-minutes))
 616                    (setq p (next-single-property-change
 617                             (point) :org-clock-minutes)))
 618           (goto-char p)
 619           (when (setq time (get-text-property p :org-clock-minutes))
 620             (org-clock-put-overlay time (funcall outline-level))))
 621         (setq h (/ org-clock-file-total-minutes 60)
 622               m (- org-clock-file-total-minutes (* 60 h)))
 623         ;; Arrange to remove the overlays upon next change.
 624         (when org-remove-highlights-with-change
 625           (org-add-hook 'before-change-functions 'org-clock-remove-overlays
 626                         nil 'local))))
 627     (message (concat "Total file time: " org-time-clocksum-format " (%d hours and %d minutes)") h m h m)))
 628
 629 (defvar org-clock-overlays nil)
 630 (make-variable-buffer-local 'org-clock-overlays)
 631
 632 (defun org-clock-put-overlay (time &optional level)
 633   "Put an overlays on the current line, displaying TIME.
 634 If LEVEL is given, prefix time with a corresponding number of stars.
 635 This creates a new overlay and stores it in `org-clock-overlays', so that it
 636 will be easy to remove."
 637   (let* ((c 60) (h (floor (/ time 60))) (m (- time (* 60 h)))
 638          (l (if level (org-get-valid-level level 0) 0))
 639          (fmt (concat "%s " org-time-clocksum-format "%s"))
 640          (off 0)
 641          ov tx)
 642     (org-move-to-column c)
 643     (unless (eolp) (skip-chars-backward "^ \t"))
 644     (skip-chars-backward " \t")
 645     (setq ov (org-make-overlay (1- (point)) (point-at-eol))
 646           tx (concat (buffer-substring (1- (point)) (point))
 647                      (make-string (+ off (max 0 (- c (current-column)))) ?.)
 648                      (org-add-props (format fmt
 649                                             (make-string l ?*) h m
 650                                             (make-string (- 16 l) ?\ ))
 651                          (list 'face 'org-clock-overlay))
 652                      ""))
 653     (if (not (featurep 'xemacs))
 654         (org-overlay-put ov 'display tx)
 655       (org-overlay-put ov 'invisible t)
 656       (org-overlay-put ov 'end-glyph (make-glyph tx)))
 657     (push ov org-clock-overlays)))
 658
 659 (defun org-clock-remove-overlays (&optional beg end noremove)
 660   "Remove the occur highlights from the buffer.
 661 BEG and END are ignored.  If NOREMOVE is nil, remove this function
 662 from the `before-change-functions' in the current buffer."
 663   (interactive)
 664   (unless org-inhibit-highlight-removal
 665     (mapc 'org-delete-overlay org-clock-overlays)
 666     (setq org-clock-overlays nil)
 667     (unless noremove
 668       (remove-hook 'before-change-functions
 669                    'org-clock-remove-overlays 'local))))
 670
 671 (defvar state) ;; dynamically scoped into this function
 672 (defun org-clock-out-if-current ()
 673   "Clock out if the current entry contains the running clock.
 674 This is used to stop the clock after a TODO entry is marked DONE,
 675 and is only done if the variable `org-clock-out-when-done' is not nil."
 676   (when (and org-clock-out-when-done
 677              (member state org-done-keywords)
 678              (equal (or (buffer-base-buffer (marker-buffer org-clock-marker))
 679                         (marker-buffer org-clock-marker))
 680                     (or (buffer-base-buffer (current-buffer))
 681                         (current-buffer)))
 682              (< (point) org-clock-marker)
 683              (> (save-excursion (outline-next-heading) (point))
 684                 org-clock-marker))
 685     ;; Clock out, but don't accept a logging message for this.
 686     (let ((org-log-note-clock-out nil))
 687       (org-clock-out))))
 688
 689 (add-hook 'org-after-todo-state-change-hook
 690           'org-clock-out-if-current)
 691
 692 ;;;###autoload
 693 (defun org-get-clocktable (&rest props)
 694   "Get a formatted clocktable with parameters according to PROPS.
 695 The table is created in a temporary buffer, fully formatted and
 696 fontified, and then returned."
 697   ;; Set the defaults
 698   (setq props (plist-put props :name "clocktable"))
 699   (unless (plist-member props :maxlevel)
 700     (setq props (plist-put props :maxlevel 2)))
 701   (unless (plist-member props :scope)
 702     (setq props (plist-put props :scope 'agenda)))
 703   (with-temp-buffer
 704     (org-mode)
 705     (org-create-dblock props)
 706     (org-update-dblock)
 707     (font-lock-fontify-buffer)
 708     (forward-line 2)
 709     (buffer-substring (point) (progn
 710                                 (re-search-forward "^#\\+END" nil t)
 711                                 (point-at-bol)))))
 712
 713 (defun org-clock-report (&optional arg)
 714   "Create a table containing a report about clocked time.
 715 If the cursor is inside an existing clocktable block, then the table
 716 will be updated.  If not, a new clocktable will be inserted.
 717 When called with a prefix argument, move to the first clock table in the
 718 buffer and update it."
 719   (interactive "P")
 720   (org-clock-remove-overlays)
 721   (when arg
 722     (org-find-dblock "clocktable")
 723     (org-show-entry))
 724   (if (org-in-clocktable-p)
 725       (goto-char (org-in-clocktable-p))
 726     (org-create-dblock (list :name "clocktable"
 727                              :maxlevel 2 :scope 'file)))
 728   (org-update-dblock))
 729
 730 (defun org-in-clocktable-p ()
 731   "Check if the cursor is in a clocktable."
 732   (let ((pos (point)) start)
 733     (save-excursion
 734       (end-of-line 1)
 735       (and (re-search-backward "^#\\+BEGIN:[ \t]+clocktable" nil t)
 736            (setq start (match-beginning 0))
 737            (re-search-forward "^#\\+END:.*" nil t)
 738            (>= (match-end 0) pos)
 739            start))))
 740
 741 (defun org-clock-special-range (key &optional time as-strings)
 742   "Return two times bordering a special time range.
 743 Key is a symbol specifying the range and can be one of `today', `yesterday',
 744 `thisweek', `lastweek', `thismonth', `lastmonth', `thisyear', `lastyear'.
 745 A week starts Monday 0:00 and ends Sunday 24:00.
 746 The range is determined relative to TIME.  TIME defaults to the current time.
 747 The return value is a cons cell with two internal times like the ones
 748 returned by `current time' or `encode-time'. if AS-STRINGS is non-nil,
 749 the returned times will be formatted strings."
 750   (if (integerp key) (setq key (intern (number-to-string key))))
 751   (let* ((tm (decode-time (or time (current-time))))
 752          (s 0) (m (nth 1 tm)) (h (nth 2 tm))
 753          (d (nth 3 tm)) (month (nth 4 tm)) (y (nth 5 tm))
 754          (dow (nth 6 tm))
 755          (skey (symbol-name key))
 756          (shift 0)
 757          s1 m1 h1 d1 month1 y1 diff ts te fm txt w date)
 758     (cond
 759      ((string-match "^[0-9]+$" skey)
 760       (setq y (string-to-number skey) m 1 d 1 key 'year))
 761      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)$" skey)
 762       (setq y (string-to-number (match-string 1 skey))
 763             month (string-to-number (match-string 2 skey))
 764             d 1 key 'month))
 765      ((string-match "^\\([0-9]+\\)-[wW]\\([0-9]\\{1,2\\}\\)$" skey)
 766       (require 'cal-iso)
 767       (setq y (string-to-number (match-string 1 skey))
 768             w (string-to-number (match-string 2 skey)))
 769       (setq date (calendar-gregorian-from-absolute
 770                   (calendar-absolute-from-iso (list w 1 y))))
 771       (setq d (nth 1 date) month (car date) y (nth 2 date)
 772             dow 1
 773             key 'week))
 774      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)-\\([0-9]\\{1,2\\}\\)$" skey)
 775       (setq y (string-to-number (match-string 1 skey))
 776             month (string-to-number (match-string 2 skey))
 777             d (string-to-number (match-string 3 skey))
 778             key 'day))
 779      ((string-match "\\([-+][0-9]+\\)$" skey)
 780       (setq shift (string-to-number (match-string 1 skey))
 781             key (intern (substring skey 0 (match-beginning 1))))))
 782     (when (= shift 0)
 783       (cond ((eq key 'yesterday) (setq key 'today shift -1))
 784             ((eq key 'lastweek)  (setq key 'week  shift -1))
 785             ((eq key 'lastmonth) (setq key 'month shift -1))
 786             ((eq key 'lastyear)  (setq key 'year  shift -1))))
 787     (cond
 788      ((memq key '(day today))
 789       (setq d (+ d shift) h 0 m 0 h1 24 m1 0))
 790      ((memq key '(week thisweek))
 791       (setq diff (+ (* -7 shift) (if (= dow 0) 6 (1- dow)))
 792             m 0 h 0 d (- d diff) d1 (+ 7 d)))
 793      ((memq key '(month thismonth))
 794       (setq d 1 h 0 m 0 d1 1 month (+ month shift) month1 (1+ month) h1 0 m1 0))
 795      ((memq key '(year thisyear))
 796       (setq m 0 h 0 d 1 month 1 y (+ y shift) y1 (1+ y)))
 797      (t (error "No such time block %s" key)))
 798     (setq ts (encode-time s m h d month y)
 799           te (encode-time (or s1 s) (or m1 m) (or h1 h)
 800                           (or d1 d) (or month1 month) (or y1 y)))
 801     (setq fm (cdr org-time-stamp-formats))
 802     (cond
 803      ((memq key '(day today))
 804       (setq txt (format-time-string "%A, %B %d, %Y" ts)))
 805      ((memq key '(week thisweek))
 806       (setq txt (format-time-string "week %G-W%V" ts)))
 807      ((memq key '(month thismonth))
 808       (setq txt (format-time-string "%B %Y" ts)))
 809      ((memq key '(year thisyear))
 810       (setq txt (format-time-string "the year %Y" ts))))
 811     (if as-strings
 812         (list (format-time-string fm ts) (format-time-string fm te) txt)
 813       (list ts te txt))))
 814
 815 (defun org-clocktable-shift (dir n)
 816   "Try to shift the :block date of the clocktable at point.
 817 Point must be in the #+BEGIN: line of a clocktable, or this function
 818 will throw an error.
 819 DIR is a direction, a symbol `left', `right', `up', or `down'.
 820 Both `left' and `down' shift the block toward the past, `up' and `right'
 821 push it toward the future.
 822 N is the number of shift steps to take.  The size of the step depends on
 823 the currently selected interval size."
 824   (setq n (prefix-numeric-value n))
 825   (and (memq dir '(left down)) (setq n (- n)))
 826   (save-excursion
 827     (goto-char (point-at-bol))
 828     (if (not (looking-at "#\\+BEGIN: clocktable\\>.*?:block[ \t]+\\(\\S-+\\)"))
 829         (error "Line needs a :block definition before this command works")
 830       (let* ((b (match-beginning 1)) (e (match-end 1))
 831              (s (match-string 1))
 832              block shift ins y mw d date wp m)
 833         (cond
 834          ((equal s "yesterday") (setq s "today-1"))
 835          ((equal s "lastweek") (setq s "thisweek-1"))
 836          ((equal s "lastmonth") (setq s "thismonth-1"))
 837          ((equal s "lastyear") (setq s "thisyear-1")))
 838         (cond
 839          ((string-match "^\\(today\\|thisweek\\|thismonth\\|thisyear\\)\\([-+][0-9]+\\)?$" s)
 840           (setq block (match-string 1 s)
 841                 shift (if (match-end 2)
 842                           (string-to-number (match-string 2 s))
 843                         0))
 844           (setq shift (+ shift n))
 845           (setq ins (if (= shift 0) block (format "%s%+d" block shift))))
 846          ((string-match "\\([0-9]+\\)\\(-\\([wW]?\\)\\([0-9]\\{1,2\\}\\)\\(-\\([0-9]\\{1,2\\}\\)\\)?\\)?" s)
 847           ;;               1        1  2   3       3  4                4  5   6                6  5   2
 848           (setq y (string-to-number (match-string 1 s))
 849                 wp (and (match-end 3) (match-string 3 s))
 850                 mw (and (match-end 4) (string-to-number (match-string 4 s)))
 851                 d (and (match-end 6) (string-to-number (match-string 6 s))))
 852           (cond
 853            (d (setq ins (format-time-string
 854                          "%Y-%m-%d"
 855                          (encode-time 0 0 0 (+ d n) m y))))
 856            ((and wp mw (> (length wp) 0))
 857             (require 'cal-iso)
 858             (setq date (calendar-gregorian-from-absolute (calendar-absolute-from-iso (list (+ mw n) 1 y))))
 859             (setq ins (format-time-string
 860                        "%G-W%V"
 861                        (encode-time 0 0 0 (nth 1 date) (car date) (nth 2 date)))))
 862            (mw
 863             (setq ins (format-time-string
 864                        "%Y-%m"
 865                        (encode-time 0 0 0 1 (+ mw n) y))))
 866            (y
 867             (setq ins (number-to-string (+ y n))))))
 868          (t (error "Cannot shift clocktable block")))
 869         (when ins
 870           (goto-char b)
 871           (insert ins)
 872           (delete-region (point) (+ (point) (- e b)))
 873           (beginning-of-line 1)
 874           (org-update-dblock)
 875           t)))))
 876
 877 (defun org-dblock-write:clocktable (params)
 878   "Write the standard clocktable."
 879   (catch 'exit
 880     (let* ((hlchars '((1 . "*") (2 . "/")))
 881            (ins (make-marker))
 882            (total-time nil)
 883            (scope (plist-get params :scope))
 884            (tostring (plist-get  params :tostring))
 885            (multifile (plist-get  params :multifile))
 886            (header (plist-get  params :header))
 887            (maxlevel (or (plist-get params :maxlevel) 3))
 888            (step (plist-get params :step))
 889            (emph (plist-get params :emphasize))
 890            (ts (plist-get params :tstart))
 891            (te (plist-get params :tend))
 892            (block (plist-get params :block))
 893            (link (plist-get params :link))
 894            ipos time p level hlc hdl content recalc formula pcol
 895            cc beg end pos tbl tbl1 range-text rm-file-column scope-is-list st)
 896       (setq org-clock-file-total-minutes nil)
 897       (when step
 898         (unless (or block (and ts te))
 899           (error "Clocktable `:step' can only be used with `:block' or `:tstart,:end'"))
 900         (org-clocktable-steps params)
 901         (throw 'exit nil))
 902       (when block
 903         (setq cc (org-clock-special-range block nil t)
 904               ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
 905       (when (integerp ts) (setq ts (calendar-gregorian-from-absolute ts)))
 906       (when (integerp te) (setq te (calendar-gregorian-from-absolute te)))
 907       (when (and ts (listp ts))
 908         (setq ts (format "%4d-%02d-%02d" (nth 2 ts) (car ts) (nth 1 ts))))
 909       (when (and te (listp te))
 910         (setq te (format "%4d-%02d-%02d" (nth 2 te) (car te) (nth 1 te))))
 911       ;; Now the times are strings we can parse.
 912       (if ts (setq ts (time-to-seconds
 913                        (apply 'encode-time (org-parse-time-string ts)))))
 914       (if te (setq te (time-to-seconds
 915                        (apply 'encode-time (org-parse-time-string te)))))
 916       (move-marker ins (point))
 917       (setq ipos (point))
 918
 919       ;; Get the right scope
 920       (setq pos (point))
 921       (cond
 922        ((and scope (listp scope) (symbolp (car scope)))
 923         (setq scope (eval scope)))
 924        ((eq scope 'agenda)
 925         (setq scope (org-agenda-files t)))
 926        ((eq scope 'agenda-with-archives)
 927         (setq scope (org-agenda-files t))
 928         (setq scope (org-add-archive-files scope)))
 929        ((eq scope 'file-with-archives)
 930         (setq scope (org-add-archive-files (list (buffer-file-name)))
 931               rm-file-column t)))
 932       (setq scope-is-list (and scope (listp scope)))
 933       (save-restriction
 934         (cond
 935          ((not scope))
 936          ((eq scope 'file) (widen))
 937          ((eq scope 'subtree) (org-narrow-to-subtree))
 938          ((eq scope 'tree)
 939           (while (org-up-heading-safe))
 940           (org-narrow-to-subtree))
 941          ((and (symbolp scope) (string-match "^tree\\([0-9]+\\)$"
 942                                              (symbol-name scope)))
 943           (setq level (string-to-number (match-string 1 (symbol-name scope))))
 944           (catch 'exit
 945             (while (org-up-heading-safe)
 946               (looking-at outline-regexp)
 947               (if (<= (org-reduced-level (funcall outline-level)) level)
 948                   (throw 'exit nil))))
 949           (org-narrow-to-subtree))
 950          (scope-is-list
 951           (let* ((files scope)
 952                  (scope 'agenda)
 953                  (p1 (copy-sequence params))
 954                  file)
 955             (setq p1 (plist-put p1 :tostring t))
 956             (setq p1 (plist-put p1 :multifile t))
 957             (setq p1 (plist-put p1 :scope 'file))
 958             (org-prepare-agenda-buffers files)
 959             (while (setq file (pop files))
 960               (with-current-buffer (find-buffer-visiting file)
 961                 (setq tbl1 (org-dblock-write:clocktable p1))
 962                 (when tbl1
 963                   (push (org-clocktable-add-file
 964                          file
 965                          (concat "| |*File time*|*"
 966                                  (org-minutes-to-hh:mm-string
 967                                   org-clock-file-total-minutes)
 968                                  "*|\n"
 969                                  tbl1)) tbl)
 970                   (setq total-time (+ (or total-time 0)
 971                                       org-clock-file-total-minutes))))))))
 972         (goto-char pos)
 973
 974         (unless scope-is-list
 975           (org-clock-sum ts te)
 976           (goto-char (point-min))
 977           (setq st t)
 978           (while (or (and (bobp) (prog1 st (setq st nil))
 979                           (get-text-property (point) :org-clock-minutes)
 980                           (setq p (point-min)))
 981                      (setq p (next-single-property-change (point) :org-clock-minutes)))
 982             (goto-char p)
 983             (when (setq time (get-text-property p :org-clock-minutes))
 984               (save-excursion
 985                 (beginning-of-line 1)
 986                 (when (and (looking-at (org-re "\\(\\*+\\)[ \t]+\\(.*?\\)\\([ \t]+:[[:alnum:]_@:]+:\\)?[ \t]*$"))
 987                            (setq level (org-reduced-level
 988                                         (- (match-end 1) (match-beginning 1))))
 989                            (<= level maxlevel))
 990                   (setq hlc (if emph (or (cdr (assoc level hlchars)) "") "")
 991                         hdl (if (not link)
 992                                 (match-string 2)
 993                               (org-make-link-string
 994                                (format "file:%s::%s"
 995                                        (buffer-file-name)
 996                                        (save-match-data
 997                                          (org-make-org-heading-search-string
 998                                           (match-string 2))))
 999                                (match-string 2))))
1000                   (if (and (not multifile) (= level 1)) (push "|-" tbl))
1001                   (push (concat
1002                          "| " (int-to-string level) "|" hlc hdl hlc " |"
1003                          (make-string (1- level) ?|)
1004                          hlc (org-minutes-to-hh:mm-string time) hlc
1005                          " |") tbl))))))
1006         (setq tbl (nreverse tbl))
1007         (if tostring
1008             (if tbl (mapconcat 'identity tbl "\n") nil)
1009           (goto-char ins)
1010           (insert-before-markers
1011            (or header
1012                (concat
1013                 "Clock summary at ["
1014                 (substring
1015                  (format-time-string (cdr org-time-stamp-formats))
1016                  1 -1)
1017                 "]"
1018                 (if block (concat ", for " range-text ".") "")
1019                 "\n\n"))
1020            (if scope-is-list "|File" "")
1021            "|L|Headline|Time|\n")
1022           (setq total-time (or total-time org-clock-file-total-minutes))
1023           (insert-before-markers
1024            "|-\n|"
1025            (if scope-is-list "|" "")
1026            "|"
1027            "*Total time*| *"
1028            (org-minutes-to-hh:mm-string (or total-time 0))
1029            "*|\n|-\n")
1030           (setq tbl (delq nil tbl))
1031           (if (and (stringp (car tbl)) (> (length (car tbl)) 1)
1032                    (equal (substring (car tbl) 0 2) "|-"))
1033               (pop tbl))
1034           (insert-before-markers (mapconcat
1035                                   'identity (delq nil tbl)
1036                                   (if scope-is-list "\n|-\n" "\n")))
1037           (backward-delete-char 1)
1038           (if (setq formula (plist-get params :formula))
1039               (cond
1040                ((eq formula '%)
1041                 (setq pcol (+ (if scope-is-list 1 0) maxlevel 3))
1042                 (insert
1043                  (format
1044                   "\n#+TBLFM: $%d='(org-clock-time%% @%d$%d $%d..$%d);%%.1f"
1045                   pcol
1046                   2
1047                   (+ 3 (if scope-is-list 1 0))
1048                   (+ (if scope-is-list 1 0) 3)
1049                   (1- pcol)))
1050                 (setq recalc t))
1051                ((stringp formula)
1052                 (insert "\n#+TBLFM: " formula)
1053                 (setq recalc t))
1054                (t (error "invalid formula in clocktable")))
1055             ;; Should we rescue an old formula?
1056             (when (stringp (setq content (plist-get params :content)))
1057               (when (string-match "^\\(#\\+TBLFM:.*\\)" content)
1058                 (setq recalc t)
1059                 (insert "\n" (match-string 1 (plist-get params :content)))
1060                 (beginning-of-line 0))))
1061           (goto-char ipos)
1062           (skip-chars-forward "^|")
1063           (org-table-align)
1064           (when recalc
1065             (if (eq formula '%)
1066                 (save-excursion (org-table-goto-column pcol nil 'force)
1067                                 (insert "%")))
1068             (org-table-recalculate 'all))
1069           (when rm-file-column
1070             (forward-char 1)
1071             (org-table-delete-column)))))))
1072
1073 (defun org-clocktable-steps (params)
1074   (let* ((p1 (copy-sequence params))
1075          (ts (plist-get p1 :tstart))
1076          (te (plist-get p1 :tend))
1077          (step0 (plist-get p1 :step))
1078          (step (cdr (assoc step0 '((day . 86400) (week . 604800)))))
1079          (block (plist-get p1 :block))
1080          cc range-text)
1081     (when block
1082       (setq cc (org-clock-special-range block nil t)
1083             ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1084     (if ts (setq ts (time-to-seconds
1085                      (apply 'encode-time (org-parse-time-string ts)))))
1086     (if te (setq te (time-to-seconds
1087                      (apply 'encode-time (org-parse-time-string te)))))
1088     (setq p1 (plist-put p1 :header ""))
1089     (setq p1 (plist-put p1 :step nil))
1090     (setq p1 (plist-put p1 :block nil))
1091     (while (< ts te)
1092       (or (bolp) (insert "\n"))
1093       (setq p1 (plist-put p1 :tstart (format-time-string
1094                                       (org-time-stamp-format nil t)
1095                                       (seconds-to-time ts))))
1096       (setq p1 (plist-put p1 :tend (format-time-string
1097                                     (org-time-stamp-format nil t)
1098                                     (seconds-to-time (setq ts (+ ts step))))))
1099       (insert "\n" (if (eq step0 'day) "Daily report: " "Weekly report starting on: ")
1100               (plist-get p1 :tstart) "\n")
1101       (org-dblock-write:clocktable p1)
1102       (re-search-forward "#\\+END:")
1103       (end-of-line 0))))
1104
1105 (defun org-clocktable-add-file (file table)
1106   (if table
1107       (let ((lines (org-split-string table "\n"))
1108             (ff (file-name-nondirectory file)))
1109         (mapconcat 'identity
1110                    (mapcar (lambda (x)
1111                              (if (string-match org-table-dataline-regexp x)
1112                                  (concat "|" ff x)
1113                                x))
1114                            lines)
1115                    "\n"))))
1116
1117 (defun org-clock-time% (total &rest strings)
1118   "Compute a time fraction in percent.
1119 TOTAL s a time string like 10:21 specifying the total times.
1120 STRINGS is a list of strings that should be checked for a time.
1121 The first string that does have a time will be used.
1122 This function is made for clock tables."
1123   (let ((re "\\([0-9]+\\):\\([0-9]+\\)")
1124         tot s)
1125     (save-match-data
1126       (catch 'exit
1127         (if (not (string-match re total))
1128             (throw 'exit 0.)
1129           (setq tot (+ (string-to-number (match-string 2 total))
1130                        (* 60 (string-to-number (match-string 1 total)))))
1131           (if (= tot 0.) (throw 'exit 0.)))
1132         (while (setq s (pop strings))
1133           (if (string-match "\\([0-9]+\\):\\([0-9]+\\)" s)
1134               (throw 'exit
1135                      (/ (* 100.0 (+ (string-to-number (match-string 2 s))
1136                                     (* 60 (string-to-number (match-string 1 s)))))
1137                         tot))))
1138         0))))
1139
1140 (defun org-clock-save ()
1141   "Persist various clock-related data to disk.
1142 The details of what will be saved are regulated by the variable
1143 `org-clock-persist'."
1144   (when org-clock-persist
1145     (let (b)
1146       (with-current-buffer (find-file (expand-file-name org-clock-persist-file))
1147         (progn
1148           (delete-region (point-min) (point-max))
1149           ;;Store clock
1150           (insert (format ";; org-persist.el - %s at %s\n"
1151                           system-name (format-time-string
1152                                        (cdr org-time-stamp-formats))))
1153           (if (and (setq b (marker-buffer org-clock-marker))
1154                    (setq b (or (buffer-base-buffer b) b))
1155                    (buffer-live-p b)
1156                    (buffer-file-name b)
1157                    (or (not org-clock-persist-query-save)
1158                        (y-or-n-p (concat "Save current clock ("
1159                                          (substring-no-properties org-clock-heading)
1160                                          ") "))))
1161               (insert "(setq resume-clock '(\""
1162                       (buffer-file-name (marker-buffer org-clock-marker))
1163                       "\" . " (int-to-string (marker-position org-clock-marker))
1164                       "))\n"))
1165           ;; Store clocked task history. Tasks are stored reversed to make
1166           ;; reading simpler
1167           (when (and org-clock-history (eq org-clock-persist t))
1168             (insert
1169              "(setq stored-clock-history '("
1170              (mapconcat
1171               (lambda (m)
1172                 (when (and (setq b (marker-buffer m))
1173                            (setq b (or (buffer-base-buffer b) b))
1174                            (buffer-live-p b)
1175                            (buffer-file-name b))
1176                   (concat "(\"" (buffer-file-name b)
1177                           "\" . " (int-to-string (marker-position m))
1178                           ")")))
1179               (reverse org-clock-history) " ") "))\n"))
1180           (save-buffer)
1181           (kill-buffer (current-buffer)))))))
1182
1183 (defvar org-clock-loaded nil
1184   "Was the clock file loaded?")
1185
1186 (defun org-clock-load ()
1187   "Load clock-related data from disk, maybe resuming a stored clock."
1188   (when (and org-clock-persist (not org-clock-loaded))
1189     (let ((filename (expand-file-name org-clock-persist-file))
1190           (org-clock-in-resume 'auto-restart)
1191           resume-clock stored-clock-history)
1192       (if (not (file-readable-p filename))
1193           (message "Not restoring clock data; %s not found"
1194                    org-clock-persist-file)
1195         (message "%s" "Restoring clock data")
1196         (setq org-clock-loaded t)
1197         (load-file filename)
1198         ;; load history
1199         (when stored-clock-history
1200           (save-window-excursion
1201             (mapc (lambda (task)
1202                     (if (file-exists-p (car task))
1203                         (org-clock-history-push (cdr task)
1204                                                 (find-file (car task)))))
1205                   stored-clock-history)))
1206         ;; resume clock
1207         (when (and resume-clock org-clock-persist
1208                    (file-exists-p (car resume-clock))
1209                    (or (not org-clock-persist-query-resume)
1210                        (y-or-n-p
1211                         (concat
1212                          "Resume clock ("
1213                          (with-current-buffer (find-file (car resume-clock))
1214                            (save-excursion
1215                              (goto-char (cdr resume-clock))
1216                              (org-back-to-heading t)
1217                              (and (looking-at org-complex-heading-regexp)
1218                                   (match-string 4))))
1219                          ") "))))
1220           (when (file-exists-p (car resume-clock))
1221             (with-current-buffer (find-file (car resume-clock))
1222               (goto-char (cdr resume-clock))
1223               (org-clock-in)
1224               (if (org-invisible-p)
1225                   (org-show-context)))))))))
1226
1227 ;;;###autoload
1228 (defun org-clock-persistence-insinuate ()
1229   "Set up hooks for clock persistence"
1230   (add-hook 'org-mode-hook 'org-clock-load)
1231   (add-hook 'kill-emacs-hook 'org-clock-save))
1232
1233 (provide 'org-clock)
1234
1235 ;; arch-tag: 7b42c5d4-9b36-48be-97c0-66a869daed4c
1236
1237 ;;; org-clock.el ends here