lisp/ob-python.el

   1 ;;; ob-python.el --- org-babel functions for python evaluation
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (eval-when-compile (require 'cl))
  32
  33 (declare-function org-remove-indentation "org" )
  34 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  35 (declare-function py-toggle-shells "ext:python-mode" (arg))
  36 (declare-function run-python "ext:python" (cmd &optional dedicated show))
  37
  38 (defvar org-babel-tangle-lang-exts)
  39 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  40
  41 (defvar org-babel-default-header-args:python '())
  42
  43 (defcustom org-babel-python-command "python"
  44   "Name of the command for executing Python code."
  45   :version "24.4"
  46   :package-version '(Org . "8.0")
  47   :group 'org-babel
  48   :type 'string)
  49
  50 (defcustom org-babel-python-mode
  51   (if (or (featurep 'xemacs) (featurep 'python-mode)) 'python-mode 'python)
  52   "Preferred python mode for use in running python interactively.
  53 This will typically be either 'python or 'python-mode."
  54   :group 'org-babel
  55   :version "24.4"
  56   :package-version '(Org . "8.0")
  57   :type 'symbol)
  58
  59 (defvar org-src-preserve-indentation)
  60
  61 (defcustom org-babel-python-hline-to "None"
  62   "Replace hlines in incoming tables with this when translating to python."
  63   :group 'org-babel
  64   :version "24.4"
  65   :package-version '(Org . "8.0")
  66   :type 'string)
  67
  68 (defcustom org-babel-python-None-to 'hline
  69   "Replace 'None' in python tables with this before returning."
  70   :group 'org-babel
  71   :version "24.4"
  72   :package-version '(Org . "8.0")
  73   :type 'symbol)
  74
  75 (defun org-babel-execute:python (body params)
  76   "Execute a block of Python code with Babel.
  77 This function is called by `org-babel-execute-src-block'."
  78   (let* ((session (org-babel-python-initiate-session
  79                    (cdr (assoc :session params))))
  80          (result-params (cdr (assoc :result-params params)))
  81          (result-type (cdr (assoc :result-type params)))
  82          (return-val (when (and (eq result-type 'value) (not session))
  83                        (cdr (assoc :return params))))
  84          (preamble (cdr (assoc :preamble params)))
  85          (org-babel-python-command
  86           (or (cdr (assoc :python params)) org-babel-python-command))
  87          (full-body
  88           (org-babel-expand-body:generic
  89            (concat body (if return-val (format "\nreturn %s" return-val) ""))
  90            params (org-babel-variable-assignments:python params)))
  91          (result (org-babel-python-evaluate
  92                   session full-body result-type result-params preamble)))
  93     (org-babel-reassemble-table
  94      result
  95      (org-babel-pick-name (cdr (assoc :colname-names params))
  96                           (cdr (assoc :colnames params)))
  97      (org-babel-pick-name (cdr (assoc :rowname-names params))
  98                           (cdr (assoc :rownames params))))))
  99
 100 (defun org-babel-prep-session:python (session params)
 101   "Prepare SESSION according to the header arguments in PARAMS.
 102 VARS contains resolved variable references"
 103   (let* ((session (org-babel-python-initiate-session session))
 104          (var-lines
 105           (org-babel-variable-assignments:python params)))
 106     (org-babel-comint-in-buffer session
 107       (mapc (lambda (var)
 108               (end-of-line 1) (insert var) (comint-send-input)
 109               (org-babel-comint-wait-for-output session)) var-lines))
 110     session))
 111
 112 (defun org-babel-load-session:python (session body params)
 113   "Load BODY into SESSION."
 114   (save-window-excursion
 115     (let ((buffer (org-babel-prep-session:python session params)))
 116       (with-current-buffer buffer
 117         (goto-char (process-mark (get-buffer-process (current-buffer))))
 118         (insert (org-babel-chomp body)))
 119       buffer)))
 120
 121 ;; helper functions
 122
 123 (defun org-babel-variable-assignments:python (params)
 124   "Return a list of Python statements assigning the block's variables."
 125   (mapcar
 126    (lambda (pair)
 127      (format "%s=%s"
 128              (car pair)
 129              (org-babel-python-var-to-python (cdr pair))))
 130    (mapcar #'cdr (org-babel-get-header params :var))))
 131
 132 (defun org-babel-python-var-to-python (var)
 133   "Convert an elisp value to a python variable.
 134 Convert an elisp value, VAR, into a string of python source code
 135 specifying a variable of the same value."
 136   (if (listp var)
 137       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 138     (if (equal var 'hline)
 139         org-babel-python-hline-to
 140       (format
 141        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 142        (if (stringp var) (substring-no-properties var) var)))))
 143
 144 (defun org-babel-python-table-or-string (results)
 145   "Convert RESULTS into an appropriate elisp value.
 146 If the results look like a list or tuple, then convert them into an
 147 Emacs-lisp table, otherwise return the results as a string."
 148   (let ((res (org-babel-script-escape results)))
 149     (if (listp res)
 150         (mapcar (lambda (el) (if (equal el 'None)
 151                             org-babel-python-None-to el))
 152                 res)
 153       res)))
 154
 155 (defvar org-babel-python-buffers '((:default . "*Python*")))
 156
 157 (defun org-babel-python-session-buffer (session)
 158   "Return the buffer associated with SESSION."
 159   (cdr (assoc session org-babel-python-buffers)))
 160
 161 (defun org-babel-python-with-earmuffs (session)
 162   (let ((name (if (stringp session) session (format "%s" session))))
 163     (if (and (string= "*" (substring name 0 1))
 164              (string= "*" (substring name (- (length name) 1))))
 165         name
 166       (format "*%s*" name))))
 167
 168 (defun org-babel-python-without-earmuffs (session)
 169   (let ((name (if (stringp session) session (format "%s" session))))
 170     (if (and (string= "*" (substring name 0 1))
 171              (string= "*" (substring name (- (length name) 1))))
 172         (substring name 1 (- (length name) 1))
 173       name)))
 174
 175 (defvar py-default-interpreter)
 176 (defvar py-which-bufname)
 177 (defvar python-shell-buffer-name)
 178 (defun org-babel-python-initiate-session-by-key (&optional session)
 179   "Initiate a python session.
 180 If there is not a current inferior-process-buffer in SESSION
 181 then create.  Return the initialized session."
 182   (require org-babel-python-mode)
 183   (save-window-excursion
 184     (let* ((session (if session (intern session) :default))
 185            (python-buffer (org-babel-python-session-buffer session))
 186            (cmd (if (member system-type '(cygwin windows-nt ms-dos))
 187                     (concat org-babel-python-command " -i")
 188                   org-babel-python-command)))
 189       (cond
 190        ((and (eq 'python org-babel-python-mode)
 191              (fboundp 'run-python)) ; python.el
 192         (if (not (version< "24.1" emacs-version))
 193             (run-python cmd)
 194           (unless python-buffer
 195             (setq python-buffer (org-babel-python-with-earmuffs session)))
 196           (let ((python-shell-buffer-name
 197                  (org-babel-python-without-earmuffs python-buffer)))
 198             (run-python cmd))))
 199        ((and (eq 'python-mode org-babel-python-mode)
 200              (fboundp 'py-shell)) ; python-mode.el
 201         ;; Make sure that py-which-bufname is initialized, as otherwise
 202         ;; it will be overwritten the first time a Python buffer is
 203         ;; created.
 204         (py-toggle-shells py-default-interpreter)
 205         ;; `py-shell' creates a buffer whose name is the value of
 206         ;; `py-which-bufname' with '*'s at the beginning and end
 207         (let* ((bufname (if (and python-buffer (buffer-live-p python-buffer))
 208                             (replace-regexp-in-string ;; zap surrounding *
 209                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 210                           (concat "Python-" (symbol-name session))))
 211                (py-which-bufname bufname))
 212           (py-shell)
 213           (setq python-buffer (org-babel-python-with-earmuffs bufname))))
 214        (t
 215         (error "No function available for running an inferior Python")))
 216       (setq org-babel-python-buffers
 217             (cons (cons session python-buffer)
 218                   (assq-delete-all session org-babel-python-buffers)))
 219       session)))
 220
 221 (defun org-babel-python-initiate-session (&optional session params)
 222   "Create a session named SESSION according to PARAMS."
 223   (unless (string= session "none")
 224     (org-babel-python-session-buffer
 225      (org-babel-python-initiate-session-by-key session))))
 226
 227 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 228   "A string to indicate that evaluation has completed.")
 229 (defvar org-babel-python-wrapper-method
 230   "
 231 def main():
 232 %s
 233
 234 open('%s', 'w').write( str(main()) )")
 235 (defvar org-babel-python-pp-wrapper-method
 236   "
 237 import pprint
 238 def main():
 239 %s
 240
 241 open('%s', 'w').write( pprint.pformat(main()) )")
 242
 243 (defun org-babel-python-evaluate
 244   (session body &optional result-type result-params preamble)
 245   "Evaluate BODY as Python code."
 246   (if session
 247       (org-babel-python-evaluate-session
 248        session body result-type result-params)
 249     (org-babel-python-evaluate-external-process
 250      body result-type result-params preamble)))
 251
 252 (defun org-babel-python-evaluate-external-process
 253   (body &optional result-type result-params preamble)
 254   "Evaluate BODY in external python process.
 255 If RESULT-TYPE equals 'output then return standard output as a
 256 string.  If RESULT-TYPE equals 'value then return the value of the
 257 last statement in BODY, as elisp."
 258   (let ((raw
 259          (case result-type
 260            (output (org-babel-eval org-babel-python-command
 261                                    (concat (if preamble (concat preamble "\n"))
 262                                            body)))
 263            (value (let ((tmp-file (org-babel-temp-file "python-")))
 264                     (org-babel-eval
 265                      org-babel-python-command
 266                      (concat
 267                       (if preamble (concat preamble "\n") "")
 268                       (format
 269                        (if (member "pp" result-params)
 270                            org-babel-python-pp-wrapper-method
 271                          org-babel-python-wrapper-method)
 272                        (mapconcat
 273                         (lambda (line) (format "\t%s" line))
 274                         (split-string
 275                          (org-remove-indentation
 276                           (org-babel-trim body))
 277                          "[\r\n]") "\n")
 278                        (org-babel-process-file-name tmp-file 'noquote))))
 279                     (org-babel-eval-read-file tmp-file))))))
 280     (org-babel-result-cond result-params
 281       raw
 282       (org-babel-python-table-or-string (org-babel-trim raw)))))
 283
 284 (defun org-babel-python-evaluate-session
 285     (session body &optional result-type result-params)
 286   "Pass BODY to the Python process in SESSION.
 287 If RESULT-TYPE equals 'output then return standard output as a
 288 string.  If RESULT-TYPE equals 'value then return the value of the
 289 last statement in BODY, as elisp."
 290   (let* ((send-wait (lambda () (comint-send-input nil t) (sleep-for 0 5)))
 291          (dump-last-value
 292           (lambda
 293             (tmp-file pp)
 294             (mapc
 295              (lambda (statement) (insert statement) (funcall send-wait))
 296              (if pp
 297                  (list
 298                   "import pprint"
 299                   (format "open('%s', 'w').write(pprint.pformat(_))"
 300                           (org-babel-process-file-name tmp-file 'noquote)))
 301                (list (format "open('%s', 'w').write(str(_))"
 302                              (org-babel-process-file-name tmp-file
 303                                                           'noquote)))))))
 304          (input-body (lambda (body)
 305                        (mapc (lambda (line) (insert line) (funcall send-wait))
 306                              (split-string body "[\r\n]"))
 307                        (funcall send-wait)))
 308          (results
 309           (case result-type
 310             (output
 311              (mapconcat
 312               #'org-babel-trim
 313               (butlast
 314                (org-babel-comint-with-output
 315                    (session org-babel-python-eoe-indicator t body)
 316                  (funcall input-body body)
 317                  (funcall send-wait) (funcall send-wait)
 318                  (insert org-babel-python-eoe-indicator)
 319                  (funcall send-wait))
 320                2) "\n"))
 321             (value
 322              (let ((tmp-file (org-babel-temp-file "python-")))
 323                (org-babel-comint-with-output
 324                    (session org-babel-python-eoe-indicator nil body)
 325                  (let ((comint-process-echoes nil))
 326                    (funcall input-body body)
 327                    (funcall dump-last-value tmp-file
 328                             (member "pp" result-params))
 329                    (funcall send-wait) (funcall send-wait)
 330                    (insert org-babel-python-eoe-indicator)
 331                    (funcall send-wait)))
 332                (org-babel-eval-read-file tmp-file))))))
 333     (unless (string= (substring org-babel-python-eoe-indicator 1 -1) results)
 334       (org-babel-result-cond result-params
 335         results
 336         (org-babel-python-table-or-string results)))))
 337
 338 (defun org-babel-python-read-string (string)
 339   "Strip 's from around Python string."
 340   (if (string-match "^'\\([^\000]+\\)'$" string)
 341       (match-string 1 string)
 342     string))
 343
 344 (provide 'ob-python)
 345
 346
 347
 348 ;;; ob-python.el ends here