lisp/ob-comint.el

   1 ;;; ob-comint.el --- org-babel functions for interaction with comint buffers
   2
   3 ;; Copyright (C) 2009-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research, comint
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.7
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; These functions build on comint to ease the sending and receiving
  28 ;; of commands and results from comint buffers.
  29
  30 ;; Note that the buffers in this file are analogous to sessions in
  31 ;; org-babel at large.
  32
  33 ;;; Code:
  34 (require 'ob)
  35 (require 'comint)
  36 (eval-when-compile (require 'cl))
  37 (declare-function with-parsed-tramp-file-name "tramp" (filename var &rest body))
  38 (declare-function tramp-flush-directory-property "tramp" (vec directory))
  39
  40 (defun org-babel-comint-buffer-livep (buffer)
  41   "Check if BUFFER is a comint buffer with a live process."
  42   (let ((buffer (if buffer (get-buffer buffer))))
  43     (and buffer (buffer-live-p buffer) (get-buffer-process buffer) buffer)))
  44
  45 (defmacro org-babel-comint-in-buffer (buffer &rest body)
  46   "Check BUFFER and execute BODY.
  47 BUFFER is checked with `org-babel-comint-buffer-livep'.  BODY is
  48 executed inside the protection of `save-excursion' and
  49 `save-match-data'."
  50   (declare (indent 1))
  51   `(save-excursion
  52      (save-match-data
  53        (unless (org-babel-comint-buffer-livep ,buffer)
  54          (error "buffer %s doesn't exist or has no process" ,buffer))
  55        (set-buffer ,buffer)
  56        ,@body)))
  57 (def-edebug-spec org-babel-comint-in-buffer (form body))
  58
  59 (defmacro org-babel-comint-with-output (meta &rest body)
  60   "Evaluate BODY in BUFFER and return process output.
  61 Will wait until EOE-INDICATOR appears in the output, then return
  62 all process output.  If REMOVE-ECHO and FULL-BODY are present and
  63 non-nil, then strip echo'd body from the returned output.  META
  64 should be a list containing the following where the last two
  65 elements are optional.
  66
  67  (BUFFER EOE-INDICATOR REMOVE-ECHO FULL-BODY)
  68
  69 This macro ensures that the filter is removed in case of an error
  70 or user `keyboard-quit' during execution of body."
  71   (declare (indent 1))
  72   (let ((buffer (car meta))
  73         (eoe-indicator (cadr meta))
  74         (remove-echo (cadr (cdr meta)))
  75         (full-body (cadr (cdr (cdr meta)))))
  76     `(org-babel-comint-in-buffer ,buffer
  77        (let ((string-buffer "") dangling-text raw)
  78          (flet ((my-filt (text)
  79                          (setq string-buffer (concat string-buffer text))))
  80            ;; setup filter
  81            (add-hook 'comint-output-filter-functions 'my-filt)
  82            (unwind-protect
  83                (progn
  84                  ;; got located, and save dangling text
  85                  (goto-char (process-mark (get-buffer-process (current-buffer))))
  86                  (let ((start (point))
  87                        (end (point-max)))
  88                    (setq dangling-text (buffer-substring start end))
  89                    (delete-region start end))
  90                  ;; pass FULL-BODY to process
  91                  ,@body
  92                  ;; wait for end-of-evaluation indicator
  93                  (while (progn
  94                           (goto-char comint-last-input-end)
  95                           (not (save-excursion
  96                                  (and (re-search-forward
  97                                        (regexp-quote ,eoe-indicator) nil t)
  98                                       (re-search-forward
  99                                        comint-prompt-regexp nil t)))))
 100                    (accept-process-output (get-buffer-process (current-buffer)))
 101                    ;; thought the following this would allow async
 102                    ;; background running, but I was wrong...
 103                    ;; (run-with-timer .5 .5 'accept-process-output
 104                    ;;            (get-buffer-process (current-buffer)))
 105                    )
 106                  ;; replace cut dangling text
 107                  (goto-char (process-mark (get-buffer-process (current-buffer))))
 108                  (insert dangling-text))
 109              ;; remove filter
 110              (remove-hook 'comint-output-filter-functions 'my-filt)))
 111          ;; remove echo'd FULL-BODY from input
 112          (if (and ,remove-echo ,full-body
 113                   (string-match
 114                    (replace-regexp-in-string
 115                     "\n" "[\r\n]+" (regexp-quote (or ,full-body "")))
 116                    string-buffer))
 117              (setq raw (substring string-buffer (match-end 0))))
 118          (split-string string-buffer comint-prompt-regexp)))))
 119 (def-edebug-spec org-babel-comint-with-output (form body))
 120
 121 (defun org-babel-comint-input-command (buffer cmd)
 122   "Pass CMD to BUFFER.
 123 The input will not be echoed."
 124   (org-babel-comint-in-buffer buffer
 125     (goto-char (process-mark (get-buffer-process buffer)))
 126     (insert cmd)
 127     (comint-send-input)
 128     (org-babel-comint-wait-for-output buffer)))
 129
 130 (defun org-babel-comint-wait-for-output (buffer)
 131   "Wait until output arrives from BUFFER.
 132 Note: this is only safe when waiting for the result of a single
 133 statement (not large blocks of code)."
 134   (org-babel-comint-in-buffer buffer
 135     (while (progn
 136              (goto-char comint-last-input-end)
 137              (not (and (re-search-forward comint-prompt-regexp nil t)
 138                        (goto-char (match-beginning 0))
 139                        (string= (face-name (face-at-point))
 140                                 "comint-highlight-prompt"))))
 141       (accept-process-output (get-buffer-process buffer)))))
 142
 143 (defun org-babel-comint-eval-invisibly-and-wait-for-file
 144   (buffer file string &optional period)
 145   "Evaluate STRING in BUFFER invisibly.
 146 Don't return until FILE exists. Code in STRING must ensure that
 147 FILE exists at end of evaluation."
 148   (unless (org-babel-comint-buffer-livep buffer)
 149     (error "buffer %s doesn't exist or has no process" buffer))
 150   (if (file-exists-p file) (delete-file file))
 151   (process-send-string
 152    (get-buffer-process buffer)
 153    (if (string-match "\n$" string) string (concat string "\n")))
 154   ;; From Tramp 2.1.19 the following cache flush is not necessary
 155   (if (file-remote-p default-directory)
 156       (let (v)
 157         (with-parsed-tramp-file-name default-directory nil
 158           (tramp-flush-directory-property v ""))))
 159   (while (not (file-exists-p file)) (sit-for (or period 0.25))))
 160
 161 (provide 'ob-comint)
 162
 163
 164
 165 ;;; ob-comint.el ends here