lisp/org-docview.el

   1 ;;; org-docview.el --- support for links to doc-view-mode buffers
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Jan Böcker <jan.boecker at jboecker dot de>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements links to open files in doc-view-mode.
  28 ;; Org-mode loads this module by default - if this is not what you want,
  29 ;; configure the variable `org-modules'.
  30
  31 ;; The links take the form
  32 ;;
  33 ;;    docview:<file path>::<page number>
  34 ;;
  35 ;; for example: [[docview:~/.elisp/org/doc/org.pdf::1][Org-Mode Manual]]
  36 ;;
  37 ;; Autocompletion for inserting links is supported; you will be
  38 ;; prompted for a file and a page number.
  39 ;;
  40 ;; If you use org-store-link in a doc-view mode buffer, the stored
  41 ;; link will point to the current page.
  42
  43 ;;; Code:
  44
  45
  46 (require 'org)
  47
  48 (declare-function doc-view-goto-page "ext:doc-view" (page))
  49 (declare-function image-mode-window-get "ext:image-mode"
  50                   (prop &optional winprops))
  51
  52 (org-autoload "doc-view" '(doc-view-goto-page))
  53
  54 (org-add-link-type "docview" 'org-docview-open 'org-docview-export)
  55 (add-hook 'org-store-link-functions 'org-docview-store-link)
  56
  57 (defun org-docview-export (link description format)
  58   "Export a docview link from Org files."
  59   (let* ((path (when (string-match "\\(.+\\)::.+" link)
  60                  (match-string 1 link)))
  61          (desc (or description link)))
  62     (when (stringp path)
  63       (setq path (org-link-escape (expand-file-name path)))
  64       (cond
  65        ((eq format 'html) (format "<a href=\"%s\">%s</a>" path desc))
  66        ((eq format 'latex) (format "\href{%s}{%s}" path desc))
  67        ((eq format 'ascii) (format "%s (%s)" desc path))
  68        (t path)))))
  69
  70 (defun org-docview-open (link)
  71   (when (string-match "\\(.*\\)::\\([0-9]+\\)$"  link)
  72     (let* ((path (match-string 1 link))
  73            (page (string-to-number (match-string 2 link))))
  74       (org-open-file path 1) ;; let org-mode open the file (in-emacs = 1)
  75       ;; to ensure org-link-frame-setup is respected
  76       (doc-view-goto-page page)
  77       )))
  78
  79 (defun org-docview-store-link ()
  80   "Store a link to a docview buffer."
  81   (when (eq major-mode 'doc-view-mode)
  82     ;; This buffer is in doc-view-mode
  83     (let* ((path buffer-file-name)
  84            (page (image-mode-window-get 'page))
  85            (link (concat "docview:" path "::" (number-to-string page)))
  86            (description ""))
  87       (org-store-link-props
  88        :type "docview"
  89        :link link
  90        :description path))))
  91
  92 (defun org-docview-complete-link ()
  93   "Use the existing file name completion for file.
  94 Links to get the file name, then ask the user for the page number
  95 and append it."
  96   (concat (replace-regexp-in-string "^file:" "docview:" (org-file-complete-link))
  97           "::"
  98           (read-from-minibuffer "Page:" "1")))
  99
 100
 101 (provide 'org-docview)
 102
 103 ;;; org-docview.el ends here