lisp/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008-2012 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements globally unique identifiers for Org-mode entries.
  28 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  29 ;; are provided that create and retrieve such identifiers, and that find
  30 ;; entries based on the identifier.
  31
  32 ;; Identifiers consist of a prefix (default "Org" given by the variable
  33 ;; `org-id-prefix') and a unique part that can be created by a number
  34 ;; of different methods, see the variable `org-id-method'.
  35 ;; Org has a builtin method that uses a compact encoding of the creation
  36 ;; time of the ID, with microsecond accuracy.  This virtually
  37 ;; guarantees globally unique identifiers, even if several people are
  38 ;; creating IDs at the same time in files that will eventually be used
  39 ;; together.
  40 ;;
  41 ;; By default Org uses UUIDs as global unique identifiers.
  42 ;;
  43 ;; This file defines the following API:
  44 ;;
  45 ;; org-id-get-create
  46 ;;        Create an ID for the entry at point if it does not yet have one.
  47 ;;        Returns the ID (old or new).  This function can be used
  48 ;;        interactively, with prefix argument the creation of a new ID is
  49 ;;        forced, even if there was an old one.
  50 ;;
  51 ;; org-id-get
  52 ;;        Get the ID property of an entry.  Using appropriate arguments
  53 ;;        to the function, it can also create the ID for this entry.
  54 ;;
  55 ;; org-id-goto
  56 ;;        Command to go to a specific ID, this command can be used
  57 ;;        interactively.
  58 ;;
  59 ;; org-id-get-with-outline-path-completion
  60 ;;        Retrieve the ID of an entry, using outline path completion.
  61 ;;        This function can work for multiple files.
  62 ;;
  63 ;; org-id-get-with-outline-drilling
  64 ;;        Retrieve the ID of an entry, using outline path completion.
  65 ;;        This function only works for the current file.
  66 ;;
  67 ;; org-id-find
  68 ;;        Find the location of an entry with specific id.
  69 ;;
  70
  71 ;;; Code:
  72
  73 (require 'org)
  74
  75 (declare-function message-make-fqdn "message" ())
  76 (declare-function org-pop-to-buffer-same-window
  77                   "org-compat" (&optional buffer-or-name norecord label))
  78
  79 ;;; Customization
  80
  81 (defgroup org-id nil
  82   "Options concerning global entry identifiers in Org-mode."
  83   :tag "Org ID"
  84   :group 'org)
  85
  86 (defcustom org-id-uuid-program "uuidgen"
  87   "The uuidgen program."
  88   :group 'org-id
  89   :type 'string)
  90
  91 (defcustom org-id-method 'uuid
  92   "The method that should be used to create new IDs.
  93
  94 An ID will consist of the optional prefix specified in `org-id-prefix',
  95 and a unique part created by the method this variable specifies.
  96
  97 Allowed values are:
  98
  99 org        Org's own internal method, using an encoding of the current time to
 100            microsecond accuracy, and optionally the current domain of the
 101            computer.  See the variable `org-id-include-domain'.
 102
 103 uuid       Create random (version 4) UUIDs.  If the program defined in
 104            `org-id-uuid-program' is available it is used to create the ID.
 105            Otherwise an internal functions is used."
 106   :group 'org-id
 107   :type '(choice
 108           (const :tag "Org's internal method" org)
 109           (const :tag "external: uuidgen" uuid)))
 110
 111 (defcustom org-id-prefix nil
 112   "The prefix for IDs.
 113
 114 This may be a string, or it can be nil to indicate that no prefix is required.
 115 When a string, the string should have no space characters as IDs are expected
 116 to have no space characters in them."
 117   :group 'org-id
 118   :type '(choice
 119           (const :tag "No prefix")
 120           (string :tag "Prefix")))
 121
 122 (defcustom org-id-include-domain nil
 123   "Non-nil means add the domain name to new IDs.
 124 This ensures global uniqueness of IDs, and is also suggested by
 125 RFC 2445 in combination with RFC 822.  This is only relevant if
 126 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 127 be added.
 128 The default is to not use this because we have no really good way to get
 129 the true domain, and Org entries will normally not be shared with enough
 130 people to make this necessary."
 131   :group 'org-id
 132   :type 'boolean)
 133
 134 (defcustom org-id-track-globally t
 135   "Non-nil means track IDs through files, so that links work globally.
 136 This work by maintaining a hash table for IDs and writing this table
 137 to disk when exiting Emacs.  Because of this, it works best if you use
 138 a single Emacs process, not many.
 139
 140 When nil, IDs are not tracked.  Links to IDs will still work within
 141 a buffer, but not if the entry is located in another file.
 142 IDs can still be used if the entry with the id is in the same file as
 143 the link."
 144   :group 'org-id
 145   :type 'boolean)
 146
 147 (defcustom org-id-locations-file (convert-standard-filename
 148                                   "~/.emacs.d/.org-id-locations")
 149   "The file for remembering in which file an ID was defined.
 150 This variable is only relevant when `org-id-track-globally' is set."
 151   :group 'org-id
 152   :type 'file)
 153
 154 (defvar org-id-locations nil
 155   "List of files with IDs in those files.")
 156
 157 (defvar org-id-files nil
 158   "List of files that contain IDs.")
 159
 160 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 161   "Files to be searched for IDs, besides the agenda files.
 162 When Org reparses files to remake the list of files and IDs it is tracking,
 163 it will normally scan the agenda files, the archives related to agenda files,
 164 any files that are listed as ID containing in the current register, and
 165 any Org-mode files currently visited by Emacs.
 166 You can list additional files here.
 167 This variable is only relevant when `org-id-track-globally' is set."
 168   :group 'org-id
 169   :type
 170   '(choice
 171     (symbol :tag "Variable")
 172     (repeat :tag "List of files"
 173             (file))))
 174
 175 (defcustom org-id-search-archives t
 176   "Non-nil means search also the archive files of agenda files for entries.
 177 This is a possibility to reduce overhead, but it means that entries moved
 178 to the archives can no longer be found by ID.
 179 This variable is only relevant when `org-id-track-globally' is set."
 180   :group 'org-id
 181   :type 'boolean)
 182
 183 ;;; The API functions
 184
 185 ;;;###autoload
 186 (defun org-id-get-create (&optional force)
 187   "Create an ID for the current entry and return it.
 188 If the entry already has an ID, just return it.
 189 With optional argument FORCE, force the creation of a new ID."
 190   (interactive "P")
 191   (when force
 192     (org-entry-put (point) "ID" nil))
 193   (org-id-get (point) 'create))
 194
 195 ;;;###autoload
 196 (defun org-id-copy ()
 197   "Copy the ID of the entry at point to the kill ring.
 198 Create an ID if necessary."
 199   (interactive)
 200   (org-kill-new (org-id-get nil 'create)))
 201
 202 ;;;###autoload
 203 (defun org-id-get (&optional pom create prefix)
 204   "Get the ID property of the entry at point-or-marker POM.
 205 If POM is nil, refer to the entry at point.
 206 If the entry does not have an ID, the function returns nil.
 207 However, when CREATE is non nil, create an ID if none is present already.
 208 PREFIX will be passed through to `org-id-new'.
 209 In any case, the ID of the entry is returned."
 210   (org-with-point-at pom
 211     (let ((id (org-entry-get nil "ID")))
 212       (cond
 213        ((and id (stringp id) (string-match "\\S-" id))
 214         id)
 215        (create
 216         (setq id (org-id-new prefix))
 217         (org-entry-put pom "ID" id)
 218         (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 219         id)))))
 220
 221 ;;;###autoload
 222 (defun org-id-get-with-outline-path-completion (&optional targets)
 223   "Use outline-path-completion to retrieve the ID of an entry.
 224 TARGETS may be a setting for `org-refile-targets' to define the eligible
 225 headlines.  When omitted, all headlines in all agenda files are
 226 eligible.
 227 It returns the ID of the entry.  If necessary, the ID is created."
 228   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 229          (org-refile-use-outline-path
 230           (if (caar org-refile-targets) 'file t))
 231          (org-refile-target-verify-function nil)
 232          (spos (org-refile-get-location "Entry"))
 233          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 234                                      (get-file-buffer (nth 1 spos))))))
 235     (prog1 (org-id-get pom 'create)
 236       (move-marker pom nil))))
 237
 238 ;;;###autoload
 239 (defun org-id-get-with-outline-drilling (&optional targets)
 240   "Use an outline-cycling interface to retrieve the ID of an entry.
 241 This only finds entries in the current buffer, using `org-get-location'.
 242 It returns the ID of the entry.  If necessary, the ID is created."
 243   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 244          (pom (and spos (move-marker (make-marker) (car spos)))))
 245     (prog1 (org-id-get pom 'create)
 246       (move-marker pom nil))))
 247
 248 ;;;###autoload
 249 (defun org-id-goto (id)
 250   "Switch to the buffer containing the entry with id ID.
 251 Move the cursor to that entry in that buffer."
 252   (interactive "sID: ")
 253   (let ((m (org-id-find id 'marker)))
 254     (unless m
 255       (error "Cannot find entry with ID \"%s\"" id))
 256     (org-pop-to-buffer-same-window (marker-buffer m))
 257     (goto-char m)
 258     (move-marker m nil)
 259     (org-show-context)))
 260
 261 ;;;###autoload
 262 (defun org-id-find (id &optional markerp)
 263   "Return the location of the entry with the id ID.
 264 The return value is a cons cell (file-name . position), or nil
 265 if there is no entry with that ID.
 266 With optional argument MARKERP, return the position as a new marker."
 267   (cond
 268    ((symbolp id) (setq id (symbol-name id)))
 269    ((numberp id) (setq id (number-to-string id))))
 270   (let ((file (org-id-find-id-file id))
 271         org-agenda-new-buffers where)
 272     (when file
 273       (setq where (org-id-find-id-in-file id file markerp)))
 274     (unless where
 275       (org-id-update-id-locations nil t)
 276       (setq file (org-id-find-id-file id))
 277       (when file
 278         (setq where (org-id-find-id-in-file id file markerp))))
 279     where))
 280
 281 ;;; Internal functions
 282
 283 ;; Creating new IDs
 284
 285 (defun org-id-new (&optional prefix)
 286   "Create a new globally unique ID.
 287
 288 An ID consists of two parts separated by a colon:
 289 - a prefix
 290 - a unique part that will be created according to `org-id-method'.
 291
 292 PREFIX can specify the prefix, the default is given by the variable
 293 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 294 prefix even if `org-id-prefix' specifies one.
 295
 296 So a typical ID could look like \"Org:4nd91V40HI\"."
 297   (let* ((prefix (if (eq prefix 'none)
 298                      ""
 299                    (concat (or prefix org-id-prefix) ":")))
 300          unique)
 301     (if (equal prefix ":") (setq prefix ""))
 302     (cond
 303      ((memq org-id-method '(uuidgen uuid))
 304       (setq unique (org-trim (shell-command-to-string org-id-uuid-program)))
 305       (unless (org-uuidgen-p unique)
 306         (setq unique (org-id-uuid))))
 307      ((eq org-id-method 'org)
 308       (let* ((etime (org-id-reverse-string (org-id-time-to-b36)))
 309              (postfix (if org-id-include-domain
 310                           (progn
 311                             (require 'message)
 312                             (concat "@" (message-make-fqdn))))))
 313         (setq unique (concat etime postfix))))
 314      (t (error "Invalid `org-id-method'")))
 315     (concat prefix unique)))
 316
 317 (defun org-id-uuid ()
 318   "Return string with random (version 4) UUID."
 319   (let ((rnd (md5 (format "%s%s%s%s%s%s%s"
 320                           (org-random)
 321                           (current-time)
 322                           (user-uid)
 323                           (emacs-pid)
 324                           (user-full-name)
 325                           user-mail-address
 326                           (recent-keys)))))
 327     (format "%s-%s-4%s-%s%s-%s"
 328             (substring rnd 0 8)
 329             (substring rnd 8 12)
 330             (substring rnd 13 16)
 331             (format "%x"
 332                     (logior
 333                      #b10000000
 334                      (logand
 335                       #b10111111
 336                       (string-to-number
 337                        (substring rnd 16 18) 16))))
 338             (substring rnd 18 20)
 339             (substring rnd 20 32))))
 340
 341 (defun org-id-reverse-string (s)
 342   (mapconcat 'char-to-string (nreverse (string-to-list s)) ""))
 343
 344 (defun org-id-int-to-b36-one-digit (i)
 345   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 346   (cond
 347    ((< i 10) (+ ?0 i))
 348    ((< i 36) (+ ?a i -10))
 349    (t (error "Larger that 35"))))
 350
 351 (defun org-id-b36-to-int-one-digit (i)
 352   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 353 The input I may be a character, or a single-letter string."
 354   (and (stringp i) (setq i (string-to-char i)))
 355   (cond
 356    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 357    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 358    (t (error "Invalid b36 letter"))))
 359
 360 (defun org-id-int-to-b36 (i &optional length)
 361   "Convert an integer to a base-36 number represented as a string."
 362   (let ((s ""))
 363     (while (> i 0)
 364       (setq s (concat (char-to-string
 365                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 366             i (/ i 36)))
 367     (setq length (max 1 (or length 1)))
 368     (if (< (length s) length)
 369         (setq s (concat (make-string (- length (length s)) ?0) s)))
 370     s))
 371
 372 (defun org-id-b36-to-int (s)
 373   "Convert a base-36 string into the corresponding integer."
 374   (let ((r 0))
 375     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 376           s)
 377     r))
 378
 379 (defun org-id-time-to-b36 (&optional time)
 380   "Encode TIME as a 10-digit string.
 381 This string holds the time to micro-second accuracy, and can be decoded
 382 using `org-id-decode'."
 383   (setq time (or time (current-time)))
 384   (concat (org-id-int-to-b36 (nth 0 time) 4)
 385           (org-id-int-to-b36 (nth 1 time) 4)
 386           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 387
 388 (defun org-id-decode (id)
 389   "Split ID into the prefix and the time value that was used to create it.
 390 The return value is (prefix . time) where PREFIX is nil or a string,
 391 and time is the usual three-integer representation of time."
 392   (let (prefix time parts)
 393     (setq parts (org-split-string id ":"))
 394     (if (= 2 (length parts))
 395         (setq prefix (car parts) time (nth 1 parts))
 396       (setq prefix nil time (nth 0 parts)))
 397     (setq time (org-id-reverse-string time))
 398     (setq time (list (org-id-b36-to-int (substring time 0 4))
 399                      (org-id-b36-to-int (substring time 4 8))
 400                      (org-id-b36-to-int (substring time 8 12))))
 401     (cons prefix time)))
 402
 403 ;; Storing ID locations (files)
 404
 405 (defun org-id-update-id-locations (&optional files silent)
 406   "Scan relevant files for IDs.
 407 Store the relation between files and corresponding IDs.
 408 This will scan all agenda files, all associated archives, and all
 409 files currently mentioned in `org-id-locations'.
 410 When FILES is given, scan these files instead.
 411 When CHECK is given, prepare detailed information about duplicate IDs."
 412   (interactive)
 413   (if (not org-id-track-globally)
 414       (error "Please turn on `org-id-track-globally' if you want to track IDs")
 415     (let* ((org-id-search-archives
 416             (or org-id-search-archives
 417                 (and (symbolp org-id-extra-files)
 418                      (symbol-value org-id-extra-files)
 419                      (member 'agenda-archives org-id-extra-files))))
 420            (files
 421             (or files
 422                 (append
 423                  ;; Agenda files and all associated archives
 424                  (org-agenda-files t org-id-search-archives)
 425                  ;; Explicit extra files
 426                  (if (symbolp org-id-extra-files)
 427                      (symbol-value org-id-extra-files)
 428                    org-id-extra-files)
 429                  ;; Files associated with live org-mode buffers
 430                  (delq nil
 431                        (mapcar (lambda (b)
 432                                  (with-current-buffer b
 433                                    (and (derived-mode-p 'org-mode) (buffer-file-name))))
 434                                (buffer-list)))
 435                  ;; All files known to have IDs
 436                  org-id-files)))
 437            org-agenda-new-buffers
 438            file nfiles tfile ids reg found id seen (ndup 0))
 439       (when (member 'agenda-archives files)
 440         (setq files (delq 'agenda-archives (copy-sequence files))))
 441       (setq nfiles (length files))
 442       (while (setq file (pop files))
 443         (unless silent
 444           (message "Finding ID locations (%d/%d files): %s"
 445                    (- nfiles (length files)) nfiles file))
 446         (setq tfile (file-truename file))
 447         (when (and (file-exists-p file) (not (member tfile seen)))
 448           (push tfile seen)
 449           (setq ids nil)
 450           (with-current-buffer (org-get-agenda-file-buffer file)
 451             (save-excursion
 452               (save-restriction
 453                 (widen)
 454                 (goto-char (point-min))
 455                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 456                                           nil t)
 457                   (setq id (org-match-string-no-properties 1))
 458                   (if (member id found)
 459                       (progn
 460                         (message "Duplicate ID \"%s\", also in file %s"
 461                                  id (or (car (delq
 462                                               nil
 463                                               (mapcar
 464                                                (lambda (x)
 465                                                  (if (member id (cdr x))
 466                                                      (car x)))
 467                                                reg)))
 468                                         (buffer-file-name)))
 469                         (when (= ndup 0)
 470                           (ding)
 471                           (sit-for 2))
 472                         (setq ndup (1+ ndup)))
 473                     (push id found)
 474                     (push id ids)))
 475                 (push (cons (abbreviate-file-name file) ids) reg))))))
 476       (org-release-buffers org-agenda-new-buffers)
 477       (setq org-agenda-new-buffers nil)
 478       (setq org-id-locations reg)
 479       (setq org-id-files (mapcar 'car org-id-locations))
 480       (org-id-locations-save) ;; this function can also handle the alist form
 481       ;; now convert to a hash
 482       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 483       (if (> ndup 0)
 484           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 485         (message "%d unique files scanned for IDs" (length org-id-files)))
 486       org-id-locations)))
 487
 488 (defun org-id-locations-save ()
 489   "Save `org-id-locations' in `org-id-locations-file'."
 490   (when (and org-id-track-globally org-id-locations)
 491     (let ((out (if (hash-table-p org-id-locations)
 492                    (org-id-hash-to-alist org-id-locations)
 493                  org-id-locations)))
 494       (with-temp-file org-id-locations-file
 495         (print out (current-buffer))))))
 496
 497 (defun org-id-locations-load ()
 498   "Read the data from `org-id-locations-file'."
 499   (setq org-id-locations nil)
 500   (when org-id-track-globally
 501     (with-temp-buffer
 502       (condition-case nil
 503           (progn
 504             (insert-file-contents-literally org-id-locations-file)
 505             (goto-char (point-min))
 506             (setq org-id-locations (read (current-buffer))))
 507         (error
 508          (message "Could not read org-id-values from %s.  Setting it to nil."
 509                   org-id-locations-file))))
 510     (setq org-id-files (mapcar 'car org-id-locations))
 511     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 512
 513 (defun org-id-add-location (id file)
 514   "Add the ID with location FILE to the database of ID locations."
 515   ;; Only if global tracking is on, and when the buffer has a file
 516   (when (and org-id-track-globally id file)
 517     (unless org-id-locations (org-id-locations-load))
 518     (puthash id (abbreviate-file-name file) org-id-locations)
 519     (add-to-list 'org-id-files (abbreviate-file-name file))))
 520
 521 (unless noninteractive
 522   (add-hook 'kill-emacs-hook 'org-id-locations-save))
 523
 524 (defun org-id-hash-to-alist (hash)
 525   "Turn an org-id hash into an alist, so that it can be written to a file."
 526   (let (res x)
 527     (maphash
 528      (lambda (k v)
 529        (if (setq x (member v res))
 530            (setcdr x (cons k (cdr x)))
 531          (push (list v k) res)))
 532      hash)
 533     res))
 534
 535 (defun org-id-alist-to-hash (list)
 536   "Turn an org-id location list into a hash table."
 537   (let ((res (make-hash-table
 538               :test 'equal
 539               :size (apply '+ (mapcar 'length list))))
 540         f)
 541     (mapc
 542      (lambda (x)
 543        (setq f (car x))
 544        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 545      list)
 546     res))
 547
 548 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 549   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 550   (when org-id-track-globally
 551     (save-match-data
 552       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 553       (when (bufferp buffer-or-file)
 554         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 555                                  buffer-or-file))
 556         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 557       (when buffer-or-file
 558         (let ((fname (abbreviate-file-name buffer-or-file))
 559               (s 0))
 560           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 561             (setq s (match-end 0))
 562             (org-id-add-location (match-string 1 txt) fname)))))))
 563
 564 ;; Finding entries with specified id
 565
 566 ;;;###autoload
 567 (defun org-id-find-id-file (id)
 568   "Query the id database for the file in which this ID is located."
 569   (unless org-id-locations (org-id-locations-load))
 570   (or (and org-id-locations
 571            (hash-table-p org-id-locations)
 572            (gethash id org-id-locations))
 573       ;; ball back on current buffer
 574       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 575                             (current-buffer)))))
 576
 577 (defun org-id-find-id-in-file (id file &optional markerp)
 578   "Return the position of the entry ID in FILE.
 579 If that files does not exist, or if it does not contain this ID,
 580 return nil.
 581 The position is returned as a cons cell (file-name . position).  With
 582 optional argument MARKERP, return the position as a new marker."
 583   (let (org-agenda-new-buffers buf pos)
 584     (cond
 585      ((not file) nil)
 586      ((not (file-exists-p file)) nil)
 587      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 588           (setq pos (org-find-entry-with-id id))
 589           (when pos
 590             (if markerp
 591                 (move-marker (make-marker) pos buf)
 592               (cons file pos))))))))
 593
 594 ;; id link type
 595
 596 ;; Calling the following function is hard-coded into `org-store-link',
 597 ;; so we do have to add it to `org-store-link-functions'.
 598
 599 ;;;###autoload
 600 (defun org-id-store-link ()
 601   "Store a link to the current entry, using its ID."
 602   (interactive)
 603   (when (and (buffer-file-name (buffer-base-buffer)) (derived-mode-p 'org-mode))
 604     (let* ((link (concat "id:" (org-id-get-create)))
 605            (case-fold-search nil)
 606            (desc (save-excursion
 607                    (org-back-to-heading t)
 608                    (or (and (looking-at org-complex-heading-regexp)
 609                             (if (match-end 4)
 610                                 (match-string 4)
 611                               (match-string 0)))
 612                        link))))
 613       (org-store-link-props :link link :description desc :type "id")
 614       link)))
 615
 616 (defun org-id-open (id)
 617   "Go to the entry with id ID."
 618   (org-mark-ring-push)
 619   (let ((m (org-id-find id 'marker))
 620         cmd)
 621     (unless m
 622       (error "Cannot find entry with ID \"%s\"" id))
 623     ;; Use a buffer-switching command in analogy to finding files
 624     (setq cmd
 625           (or
 626            (cdr
 627             (assq
 628              (cdr (assq 'file org-link-frame-setup))
 629              '((find-file . switch-to-buffer)
 630                (find-file-other-window . switch-to-buffer-other-window)
 631                (find-file-other-frame . switch-to-buffer-other-frame))))
 632            'switch-to-buffer-other-window))
 633     (if (not (equal (current-buffer) (marker-buffer m)))
 634         (funcall cmd (marker-buffer m)))
 635     (goto-char m)
 636     (move-marker m nil)
 637     (org-show-context)))
 638
 639 (org-add-link-type "id" 'org-id-open)
 640
 641 (provide 'org-id)
 642
 643 ;;; org-id.el ends here