lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- extract source code from org-mode files
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extract the code from source blocks out into raw source-code files.
  27
  28 ;;; Code:
  29 (require 'org-src)
  30 (eval-when-compile
  31   (require 'cl))
  32
  33 (declare-function org-link-escape "org" (text &optional table))
  34 (declare-function org-heading-components "org" ())
  35 (declare-function org-back-to-heading "org" (invisible-ok))
  36 (declare-function org-fill-template "org" (template alist))
  37 (declare-function org-babel-update-block-body "org" (new-body))
  38 (declare-function make-directory "files" (dir &optional parents))
  39
  40 (defcustom org-babel-tangle-lang-exts
  41   '(("emacs-lisp" . "el"))
  42   "Alist mapping languages to their file extensions.
  43 The key is the language name, the value is the string that should
  44 be inserted as the extension commonly used to identify files
  45 written in this language.  If no entry is found in this list,
  46 then the name of the language is used."
  47   :group 'org-babel-tangle
  48   :version "24.1"
  49   :type '(repeat
  50           (cons
  51            (string "Language name")
  52            (string "File Extension"))))
  53
  54 (defcustom org-babel-post-tangle-hook nil
  55   "Hook run in code files tangled by `org-babel-tangle'."
  56   :group 'org-babel
  57   :version "24.1"
  58   :type 'hook)
  59
  60 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  61   "Hook run at the beginning of `org-babel-tangle'."
  62   :group 'org-babel
  63   :version "24.1"
  64   :type 'hook)
  65
  66 (defcustom org-babel-tangle-body-hook nil
  67   "Hook run over the contents of each code block body."
  68   :group 'org-babel
  69   :version "24.1"
  70   :type 'hook)
  71
  72 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  73   "Format of inserted comments in tangled code files.
  74 The following format strings can be used to insert special
  75 information into the output using `org-fill-template'.
  76 %start-line --- the line number at the start of the code block
  77 %file --------- the file from which the code block was tangled
  78 %link --------- Org-mode style link to the code block
  79 %source-name -- name of the code block
  80
  81 Whether or not comments are inserted during tangling is
  82 controlled by the :comments header argument."
  83   :group 'org-babel
  84   :version "24.1"
  85   :type 'string)
  86
  87 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  88   "Format of inserted comments in tangled code files.
  89 The following format strings can be used to insert special
  90 information into the output using `org-fill-template'.
  91 %start-line --- the line number at the start of the code block
  92 %file --------- the file from which the code block was tangled
  93 %link --------- Org-mode style link to the code block
  94 %source-name -- name of the code block
  95
  96 Whether or not comments are inserted during tangling is
  97 controlled by the :comments header argument."
  98   :group 'org-babel
  99   :version "24.1"
 100   :type 'string)
 101
 102 (defcustom org-babel-process-comment-text #'org-babel-trim
 103   "Function called to process raw Org-mode text collected to be
 104 inserted as comments in tangled source-code files.  The function
 105 should take a single string argument and return a string
 106 result.  The default value is `org-babel-trim'."
 107   :group 'org-babel
 108   :version "24.1"
 109   :type 'function)
 110
 111 (defun org-babel-find-file-noselect-refresh (file)
 112   "Find file ensuring that the latest changes on disk are
 113 represented in the file."
 114   (find-file-noselect file)
 115   (with-current-buffer (get-file-buffer file)
 116     (revert-buffer t t t)))
 117
 118 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 119   "Open FILE into a temporary buffer execute BODY there like
 120 `progn', then kill the FILE buffer returning the result of
 121 evaluating BODY."
 122   (declare (indent 1))
 123   (let ((temp-path (make-symbol "temp-path"))
 124         (temp-result (make-symbol "temp-result"))
 125         (temp-file (make-symbol "temp-file"))
 126         (visited-p (make-symbol "visited-p")))
 127     `(let* ((,temp-path ,file)
 128             (,visited-p (get-file-buffer ,temp-path))
 129             ,temp-result ,temp-file)
 130        (org-babel-find-file-noselect-refresh ,temp-path)
 131        (setf ,temp-file (get-file-buffer ,temp-path))
 132        (with-current-buffer ,temp-file
 133          (setf ,temp-result (progn ,@body)))
 134        (unless ,visited-p (kill-buffer ,temp-file))
 135        ,temp-result)))
 136 (def-edebug-spec org-babel-with-temp-filebuffer (form body))
 137
 138 ;;;###autoload
 139 (defun org-babel-load-file (file &optional compile)
 140   "Load Emacs Lisp source code blocks in the Org-mode FILE.
 141 This function exports the source code using `org-babel-tangle'
 142 and then loads the resulting file using `load-file'.  With prefix
 143 arg (noninteractively: 2nd arg) COMPILE the tangled Emacs Lisp
 144 file to byte-code before it is loaded."
 145   (interactive "fFile to load: \nP")
 146   (let* ((age (lambda (file)
 147                 (float-time
 148                  (time-subtract (current-time)
 149                                 (nth 5 (or (file-attributes (file-truename file))
 150                                            (file-attributes file)))))))
 151          (base-name (file-name-sans-extension file))
 152          (exported-file (concat base-name ".el")))
 153     ;; tangle if the org-mode file is newer than the elisp file
 154     (unless (and (file-exists-p exported-file)
 155                  (> (funcall age file) (funcall age exported-file)))
 156       (org-babel-tangle-file file exported-file "emacs-lisp"))
 157     (message "%s %s"
 158              (if compile
 159                  (progn (byte-compile-file exported-file 'load)
 160                         "Compiled and loaded")
 161                (progn (load-file exported-file) "Loaded"))
 162              exported-file)))
 163
 164 ;;;###autoload
 165 (defun org-babel-tangle-file (file &optional target-file lang)
 166   "Extract the bodies of source code blocks in FILE.
 167 Source code blocks are extracted with `org-babel-tangle'.
 168 Optional argument TARGET-FILE can be used to specify a default
 169 export file for all source blocks.  Optional argument LANG can be
 170 used to limit the exported source code blocks by language."
 171   (interactive "fFile to tangle: \nP")
 172   (let ((visited-p (get-file-buffer (expand-file-name file)))
 173         to-be-removed)
 174     (save-window-excursion
 175       (find-file file)
 176       (setq to-be-removed (current-buffer))
 177       (org-babel-tangle nil target-file lang))
 178     (unless visited-p
 179       (kill-buffer to-be-removed))))
 180
 181 (defun org-babel-tangle-publish (_ filename pub-dir)
 182   "Tangle FILENAME and place the results in PUB-DIR."
 183   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 184
 185 ;;;###autoload
 186 (defun org-babel-tangle (&optional only-this-block target-file lang)
 187   "Write code blocks to source-specific files.
 188 Extract the bodies of all source code blocks from the current
 189 file into their own source-specific files.  Optional argument
 190 TARGET-FILE can be used to specify a default export file for all
 191 source blocks.  Optional argument LANG can be used to limit the
 192 exported source code blocks by language."
 193   (interactive "P")
 194   (run-hooks 'org-babel-pre-tangle-hook)
 195   ;; possibly restrict the buffer to the current code block
 196   (save-restriction
 197     (when only-this-block
 198       (unless (org-babel-where-is-src-block-head)
 199         (error "Point is not currently inside of a code block"))
 200       (save-match-data
 201         (unless (or (cdr (assoc :tangle (nth 2 (org-babel-get-src-block-info))))
 202                     target-file)
 203           (setq target-file
 204                 (read-from-minibuffer "Tangle to: " (buffer-file-name)))))
 205       (narrow-to-region (match-beginning 0) (match-end 0)))
 206     (save-excursion
 207       (let ((block-counter 0)
 208             (org-babel-default-header-args
 209              (if target-file
 210                  (org-babel-merge-params org-babel-default-header-args
 211                                          (list (cons :tangle target-file)))
 212                org-babel-default-header-args))
 213             path-collector)
 214         (mapc ;; map over all languages
 215          (lambda (by-lang)
 216            (let* ((lang (car by-lang))
 217                   (specs (cdr by-lang))
 218                   (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 219                   (lang-f (intern
 220                            (concat
 221                             (or (and (cdr (assoc lang org-src-lang-modes))
 222                                      (symbol-name
 223                                       (cdr (assoc lang org-src-lang-modes))))
 224                                 lang)
 225                             "-mode")))
 226                   she-banged)
 227              (mapc
 228               (lambda (spec)
 229                 (let ((get-spec (lambda (name) (cdr (assoc name (nth 4 spec))))))
 230                   (let* ((tangle (funcall get-spec :tangle))
 231                          (she-bang ((lambda (sheb) (when (> (length sheb) 0) sheb))
 232                                     (funcall get-spec :shebang)))
 233                          (base-name (cond
 234                                      ((string= "yes" tangle)
 235                                       (file-name-sans-extension
 236                                        (buffer-file-name)))
 237                                      ((string= "no" tangle) nil)
 238                                      ((> (length tangle) 0) tangle)))
 239                          (file-name (when base-name
 240                                       ;; decide if we want to add ext to base-name
 241                                       (if (and ext (string= "yes" tangle))
 242                                           (concat base-name "." ext) base-name))))
 243                     (when file-name
 244                       ;; possibly create the parent directories for file
 245                       (when ((lambda (m) (and m (not (string= m "no"))))
 246                              (funcall get-spec :mkdirp))
 247                         (make-directory (file-name-directory file-name) 'parents))
 248                       ;; delete any old versions of file
 249                       (when (and (file-exists-p file-name)
 250                                  (not (member file-name path-collector)))
 251                         (delete-file file-name))
 252                       ;; drop source-block to file
 253                       (with-temp-buffer
 254                         (when (fboundp lang-f) (ignore-errors (funcall lang-f)))
 255                         (when (and she-bang (not (member file-name she-banged)))
 256                           (insert (concat she-bang "\n"))
 257                           (setq she-banged (cons file-name she-banged)))
 258                         (org-babel-spec-to-string spec)
 259                         ;; We avoid append-to-file as it does not work with tramp.
 260                         (let ((content (buffer-string)))
 261                           (with-temp-buffer
 262                             (if (file-exists-p file-name)
 263                                 (insert-file-contents file-name))
 264                             (goto-char (point-max))
 265                             (insert content)
 266                             (write-region nil nil file-name))))
 267                       ;; if files contain she-bangs, then make the executable
 268                       (when she-bang (set-file-modes file-name #o755))
 269                       ;; update counter
 270                       (setq block-counter (+ 1 block-counter))
 271                       (add-to-list 'path-collector file-name)))))
 272               specs)))
 273          (org-babel-tangle-collect-blocks lang))
 274         (message "Tangled %d code block%s from %s" block-counter
 275                  (if (= block-counter 1) "" "s")
 276                  (file-name-nondirectory
 277                   (buffer-file-name (or (buffer-base-buffer) (current-buffer)))))
 278         ;; run `org-babel-post-tangle-hook' in all tangled files
 279         (when org-babel-post-tangle-hook
 280           (mapc
 281            (lambda (file)
 282              (org-babel-with-temp-filebuffer file
 283                (run-hooks 'org-babel-post-tangle-hook)))
 284            path-collector))
 285         path-collector))))
 286
 287 (defun org-babel-tangle-clean ()
 288   "Remove comments inserted by `org-babel-tangle'.
 289 Call this function inside of a source-code file generated by
 290 `org-babel-tangle' to remove all comments inserted automatically
 291 by `org-babel-tangle'.  Warning, this comment removes any lines
 292 containing constructs which resemble org-mode file links or noweb
 293 references."
 294   (interactive)
 295   (goto-char (point-min))
 296   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 297              (re-search-forward (org-babel-noweb-wrap) nil t))
 298     (delete-region (save-excursion (beginning-of-line 1) (point))
 299                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 300
 301 (defvar org-stored-links)
 302 (defvar org-bracket-link-regexp)
 303 (defun org-babel-spec-to-string (spec)
 304   "Insert SPEC into the current file.
 305 Insert the source-code specified by SPEC into the current
 306 source code file.  This function uses `comment-region' which
 307 assumes that the appropriate major-mode is set.  SPEC has the
 308 form
 309
 310   (start-line file link source-name params body comment)"
 311   (let* ((start-line (nth 0 spec))
 312          (file (nth 1 spec))
 313          (link (nth 2 spec))
 314          (source-name (nth 3 spec))
 315          (body (nth 5 spec))
 316          (comment (nth 6 spec))
 317          (comments (cdr (assoc :comments (nth 4 spec))))
 318          (padline (not (string= "no" (cdr (assoc :padline (nth 4 spec))))))
 319          (link-p (or (string= comments "both") (string= comments "link")
 320                      (string= comments "yes") (string= comments "noweb")))
 321          (link-data (mapcar (lambda (el)
 322                               (cons (symbol-name el)
 323                                     ((lambda (le)
 324                                        (if (stringp le) le (format "%S" le)))
 325                                      (eval el))))
 326                             '(start-line file link source-name)))
 327          (insert-comment (lambda (text)
 328                            (when (and comments (not (string= comments "no"))
 329                                       (> (length text) 0))
 330                              (when padline (insert "\n"))
 331                              (comment-region (point) (progn (insert text) (point)))
 332                              (end-of-line nil) (insert "\n")))))
 333     (when comment (funcall insert-comment comment))
 334     (when link-p
 335       (funcall
 336        insert-comment
 337        (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 338     (when padline (insert "\n"))
 339     (insert
 340      (format
 341       "%s\n"
 342       (replace-regexp-in-string
 343        "^," ""
 344        (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
 345     (when link-p
 346       (funcall
 347        insert-comment
 348        (org-fill-template org-babel-tangle-comment-format-end link-data)))))
 349
 350 (defun org-babel-tangle-collect-blocks (&optional language)
 351   "Collect source blocks in the current Org-mode file.
 352 Return an association list of source-code block specifications of
 353 the form used by `org-babel-spec-to-string' grouped by language.
 354 Optional argument LANG can be used to limit the collected source
 355 code blocks by language."
 356   (let ((block-counter 1) (current-heading "") blocks)
 357     (org-babel-map-src-blocks (buffer-file-name)
 358       ((lambda (new-heading)
 359          (if (not (string= new-heading current-heading))
 360              (progn
 361                (setq block-counter 1)
 362                (setq current-heading new-heading))
 363            (setq block-counter (+ 1 block-counter))))
 364        (replace-regexp-in-string "[ \t]" "-"
 365                                  (condition-case nil
 366                                      (or (nth 4 (org-heading-components))
 367                                          "(dummy for heading without text)")
 368                                    (error (buffer-file-name)))))
 369       (let* ((start-line (save-restriction (widen)
 370                                            (+ 1 (line-number-at-pos (point)))))
 371              (file (buffer-file-name))
 372              (info (org-babel-get-src-block-info 'light))
 373              (src-lang (nth 0 info)))
 374         (unless (string= (cdr (assoc :tangle (nth 2 info))) "no")
 375           (unless (and language (not (string= language src-lang)))
 376             (let* ((info (org-babel-get-src-block-info))
 377                    (params (nth 2 info))
 378                    (link ((lambda (link)
 379                             (and (string-match org-bracket-link-regexp link)
 380                                  (match-string 1 link)))
 381                           (org-no-properties
 382                            (org-store-link nil))))
 383                    (source-name
 384                     (intern (or (nth 4 info)
 385                                 (format "%s:%d"
 386                                         current-heading block-counter))))
 387                    (expand-cmd
 388                     (intern (concat "org-babel-expand-body:" src-lang)))
 389                    (assignments-cmd
 390                     (intern (concat "org-babel-variable-assignments:" src-lang)))
 391                    (body
 392                     ((lambda (body) ;; run the tangle-body-hook
 393                        (with-temp-buffer
 394                          (insert body)
 395                          (run-hooks 'org-babel-tangle-body-hook)
 396                          (buffer-string)))
 397                      ((lambda (body) ;; expand the body in language specific manner
 398                         (if (assoc :no-expand params)
 399                             body
 400                           (if (fboundp expand-cmd)
 401                               (funcall expand-cmd body params)
 402                             (org-babel-expand-body:generic
 403                              body params
 404                              (and (fboundp assignments-cmd)
 405                                   (funcall assignments-cmd params))))))
 406                       (if (org-babel-noweb-p params :tangle)
 407                           (org-babel-expand-noweb-references info)
 408                         (nth 1 info)))))
 409                    (comment
 410                     (when (or (string= "both" (cdr (assoc :comments params)))
 411                               (string= "org" (cdr (assoc :comments params))))
 412                       ;; from the previous heading or code-block end
 413                       (funcall
 414                        org-babel-process-comment-text
 415                        (buffer-substring
 416                         (max (condition-case nil
 417                                  (save-excursion
 418                                    (org-back-to-heading t)  ; sets match data
 419                                    (match-end 0))
 420                                (error (point-min)))
 421                              (save-excursion
 422                                (if (re-search-backward
 423                                     org-babel-src-block-regexp nil t)
 424                                    (match-end 0)
 425                                  (point-min))))
 426                         (point)))))
 427                    by-lang)
 428               ;; add the spec for this block to blocks under it's language
 429               (setq by-lang (cdr (assoc src-lang blocks)))
 430               (setq blocks (delq (assoc src-lang blocks) blocks))
 431               (setq blocks (cons
 432                             (cons src-lang
 433                                   (cons (list start-line file link
 434                                               source-name params body comment)
 435                                         by-lang)) blocks)))))))
 436     ;; ensure blocks in the correct order
 437     (setq blocks
 438           (mapcar
 439            (lambda (by-lang) (cons (car by-lang) (reverse (cdr by-lang))))
 440            blocks))
 441     blocks))
 442
 443 (defun org-babel-tangle-comment-links ( &optional info)
 444   "Return a list of begin and end link comments for the code block at point."
 445   (let* ((start-line (org-babel-where-is-src-block-head))
 446          (file (buffer-file-name))
 447          (link (org-link-escape (progn (call-interactively 'org-store-link)
 448                                        (org-no-properties
 449                                         (car (pop org-stored-links))))))
 450          (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
 451          (link-data (mapcar (lambda (el)
 452                               (cons (symbol-name el)
 453                                     ((lambda (le)
 454                                        (if (stringp le) le (format "%S" le)))
 455                                      (eval el))))
 456                             '(start-line file link source-name))))
 457     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 458           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 459
 460 ;; de-tangling functions
 461 (defvar org-bracket-link-analytic-regexp)
 462 (defun org-babel-detangle (&optional source-code-file)
 463   "Propagate changes in source file back original to Org-mode file.
 464 This requires that code blocks were tangled with link comments
 465 which enable the original code blocks to be found."
 466   (interactive)
 467   (save-excursion
 468     (when source-code-file (find-file source-code-file))
 469     (goto-char (point-min))
 470     (let ((counter 0) new-body end)
 471       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 472         (when (re-search-forward
 473                (concat " " (regexp-quote (match-string 5)) " ends here"))
 474           (setq end (match-end 0))
 475           (forward-line -1)
 476           (save-excursion
 477             (when (setq new-body (org-babel-tangle-jump-to-org))
 478               (org-babel-update-block-body new-body)))
 479           (setq counter (+ 1 counter)))
 480         (goto-char end))
 481       (prog1 counter (message "Detangled %d code blocks" counter)))))
 482
 483 (defun org-babel-tangle-jump-to-org ()
 484   "Jump from a tangled code file to the related Org-mode file."
 485   (interactive)
 486   (let ((mid (point))
 487         start end done
 488         target-buffer target-char link path block-name body)
 489     (save-window-excursion
 490       (save-excursion
 491         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 492                     (not ; ever wider searches until matching block comments
 493                      (and (setq start (point-at-eol))
 494                           (setq link (match-string 0))
 495                           (setq path (match-string 3))
 496                           (setq block-name (match-string 5))
 497                           (save-excursion
 498                             (save-match-data
 499                               (re-search-forward
 500                                (concat " " (regexp-quote block-name)
 501                                        " ends here") nil t)
 502                               (setq end (point-at-bol))))))))
 503         (unless (and start (< start mid) (< mid end))
 504           (error "Not in tangled code"))
 505         (setq body (org-babel-trim (buffer-substring start end))))
 506       (when (string-match "::" path)
 507         (setq path (substring path 0 (match-beginning 0))))
 508       (find-file path) (setq target-buffer (current-buffer))
 509       (goto-char start) (org-open-link-from-string link)
 510       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 511           (org-babel-next-src-block
 512            (string-to-number (match-string 1 block-name)))
 513         (org-babel-goto-named-src-block block-name))
 514       (setq target-char (point)))
 515     (pop-to-buffer target-buffer)
 516     (prog1 body (goto-char target-char))))
 517
 518 (provide 'ob-tangle)
 519
 520 ;; Local variables:
 521 ;; generated-autoload-file: "org-loaddefs.el"
 522 ;; End:
 523
 524 ;;; ob-tangle.el ends here