lisp/ob-sh.el

   1 ;;; ob-sh.el --- org-babel functions for shell evaluation
   2
   3 ;; Copyright (C) 2009-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating shell source code.
  27
  28 ;;; Code:
  29 (require 'ob)
  30 (require 'ob-ref)
  31 (require 'ob-comint)
  32 (require 'ob-eval)
  33 (require 'shell)
  34 (eval-when-compile (require 'cl))
  35
  36 (declare-function org-babel-comint-in-buffer "ob-comint" (buffer &rest body))
  37 (declare-function org-babel-comint-wait-for-output "ob-comint" (buffer))
  38 (declare-function org-babel-comint-buffer-livep "ob-comint" (buffer))
  39 (declare-function org-babel-comint-with-output "ob-comint" (meta &rest body))
  40 (declare-function orgtbl-to-generic "org-table" (table params))
  41
  42 (defvar org-babel-default-header-args:sh '())
  43
  44 (defvar org-babel-sh-command "sh"
  45   "Command used to invoke a shell.
  46 This will be passed to  `shell-command-on-region'")
  47
  48 (defcustom org-babel-sh-var-quote-fmt
  49   "$(cat <<'BABEL_TABLE'\n%s\nBABEL_TABLE\n)"
  50   "Format string used to escape variables when passed to shell scripts."
  51   :group 'org-babel
  52   :type 'string)
  53
  54 (defun org-babel-execute:sh (body params)
  55   "Execute a block of Shell commands with Babel.
  56 This function is called by `org-babel-execute-src-block'."
  57   (let* ((session (org-babel-sh-initiate-session
  58                    (cdr (assoc :session params))))
  59          (result-params (cdr (assoc :result-params params)))
  60          (stdin ((lambda (stdin) (when stdin (org-babel-sh-var-to-string
  61                                          (org-babel-ref-resolve stdin))))
  62                  (cdr (assoc :stdin params))))
  63          (full-body (org-babel-expand-body:generic
  64                      body params (org-babel-variable-assignments:sh params))))
  65     (org-babel-reassemble-table
  66      (org-babel-sh-evaluate session full-body result-params stdin)
  67      (org-babel-pick-name
  68       (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
  69      (org-babel-pick-name
  70       (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params))))))
  71
  72 (defun org-babel-prep-session:sh (session params)
  73   "Prepare SESSION according to the header arguments specified in PARAMS."
  74   (let* ((session (org-babel-sh-initiate-session session))
  75          (var-lines (org-babel-variable-assignments:sh params)))
  76     (org-babel-comint-in-buffer session
  77       (mapc (lambda (var)
  78               (insert var) (comint-send-input nil t)
  79               (org-babel-comint-wait-for-output session)) var-lines))
  80     session))
  81
  82 (defun org-babel-load-session:sh (session body params)
  83   "Load BODY into SESSION."
  84   (save-window-excursion
  85     (let ((buffer (org-babel-prep-session:sh session params)))
  86       (with-current-buffer buffer
  87         (goto-char (process-mark (get-buffer-process (current-buffer))))
  88         (insert (org-babel-chomp body)))
  89       buffer)))
  90
  91 ;; helper functions
  92
  93 (defun org-babel-variable-assignments:sh (params)
  94   "Return list of shell statements assigning the block's variables"
  95   (let ((sep (cdr (assoc :separator params))))
  96     (mapcar
  97      (lambda (pair)
  98        (format "%s=%s"
  99                (car pair)
 100                (org-babel-sh-var-to-sh (cdr pair) sep)))
 101      (mapcar #'cdr (org-babel-get-header params :var)))))
 102
 103 (defun org-babel-sh-var-to-sh (var &optional sep)
 104   "Convert an elisp value to a shell variable.
 105 Convert an elisp var into a string of shell commands specifying a
 106 var of the same value."
 107   (format org-babel-sh-var-quote-fmt (org-babel-sh-var-to-string var sep)))
 108
 109 (defun org-babel-sh-var-to-string (var &optional sep)
 110   "Convert an elisp value to a string."
 111   (flet ((echo-var (v) (if (stringp v) v (format "%S" v))))
 112     (cond
 113      ((and (listp var) (listp (car var)))
 114       (orgtbl-to-generic var  (list :sep (or sep "\t") :fmt #'echo-var)))
 115      ((listp var)
 116       (mapconcat #'echo-var var "\n"))
 117      (t (echo-var var)))))
 118
 119 (defun org-babel-sh-table-or-results (results)
 120   "Convert RESULTS to an appropriate elisp value.
 121 If the results look like a table, then convert them into an
 122 Emacs-lisp table, otherwise return the results as a string."
 123   (org-babel-script-escape results))
 124
 125 (defun org-babel-sh-initiate-session (&optional session params)
 126   "Initiate a session named SESSION according to PARAMS."
 127   (when (and session (not (string= session "none")))
 128     (save-window-excursion
 129       (or (org-babel-comint-buffer-livep session)
 130           (progn (shell session) (get-buffer (current-buffer)))))))
 131
 132 (defvar org-babel-sh-eoe-indicator "echo 'org_babel_sh_eoe'"
 133   "String to indicate that evaluation has completed.")
 134 (defvar org-babel-sh-eoe-output "org_babel_sh_eoe"
 135   "String to indicate that evaluation has completed.")
 136
 137 (defun org-babel-sh-evaluate (session body &optional result-params stdin)
 138   "Pass BODY to the Shell process in BUFFER.
 139 If RESULT-TYPE equals 'output then return a list of the outputs
 140 of the statements in BODY, if RESULT-TYPE equals 'value then
 141 return the value of the last statement in BODY."
 142   ((lambda (results)
 143      (when results
 144        (if (or (member "scalar" result-params)
 145                (member "verbatim" result-params)
 146                (member "output" result-params))
 147            results
 148          (let ((tmp-file (org-babel-temp-file "sh-")))
 149            (with-temp-file tmp-file (insert results))
 150            (org-babel-import-elisp-from-file tmp-file)))))
 151    (cond
 152     (stdin                              ; external shell script w/STDIN
 153      (let ((script-file (org-babel-temp-file "sh-script-"))
 154            (stdin-file (org-babel-temp-file "sh-stdin-")))
 155        (with-temp-file script-file (insert body))
 156        (with-temp-file stdin-file (insert stdin))
 157        (with-temp-buffer
 158          (call-process-shell-command
 159           (format "%s %s" org-babel-sh-command script-file)
 160           stdin-file
 161           (current-buffer))
 162          (buffer-string))))
 163     (session                            ; session evaluation
 164      (mapconcat
 165       #'org-babel-sh-strip-weird-long-prompt
 166       (mapcar
 167        #'org-babel-trim
 168        (butlast
 169         (org-babel-comint-with-output
 170             (session org-babel-sh-eoe-output t body)
 171           (mapc
 172            (lambda (line)
 173              (insert line)
 174              (comint-send-input nil t)
 175              (while (save-excursion
 176                       (goto-char comint-last-input-end)
 177                       (not (re-search-forward
 178                             comint-prompt-regexp nil t)))
 179                (accept-process-output (get-buffer-process (current-buffer)))))
 180            (append
 181             (split-string (org-babel-trim body) "\n")
 182             (list org-babel-sh-eoe-indicator))))
 183         2)) "\n"))
 184     ('otherwise                         ; external shell script
 185      (org-babel-eval org-babel-sh-command (org-babel-trim body))))))
 186
 187 (defun org-babel-sh-strip-weird-long-prompt (string)
 188   "Remove prompt cruft from a string of shell output."
 189   (while (string-match "^% +[\r\n$]+ *" string)
 190     (setq string (substring string (match-end 0))))
 191   string)
 192
 193 (provide 'ob-sh)
 194
 195
 196
 197 ;;; ob-sh.el ends here