lisp/org-protocol.el

   1 ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
   2 ;;
   3 ;; Copyright (C) 2008, 2009
   4 ;;          Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Bastien Guerry <bzg AT altern DOT org>
   7 ;; Author: Daniel M German <dmg AT uvic DOT org>
   8 ;; Author: Sebastian Rose <sebastian_rose AT gmx DOT de>
   9 ;; Author: Ross Patterson <me AT rpatterson DOT net>
  10 ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  11 ;; Keywords: org, emacsclient, wp
  12 ;; Version: 6.33c
  13
  14 ;; This file is part of GNU Emacs.
  15 ;;
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  30 ;;; Commentary:
  31 ;;
  32 ;; Intercept calls from emacsclient to trigger custom actions.
  33 ;;
  34 ;; This is done by advising `server-visit-files' to scann the list of filenames
  35 ;; for `org-protocol-the-protocol' and sub-procols defined in
  36 ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  37 ;;
  38 ;; Any application that supports calling external programs with an URL
  39 ;; as argument may be used with this functionality.
  40 ;;
  41 ;;
  42 ;; Usage:
  43 ;; ------
  44 ;;
  45 ;;   1.) Add this to your init file (.emacs probably):
  46 ;;
  47 ;;       (add-to-list 'load-path "/path/to/org-protocol/")
  48 ;;       (require 'org-protocol)
  49 ;;
  50 ;;   3.) Ensure emacs-server is up and running.
  51 ;;   4.) Try this from the command line (adjust the URL as needed):
  52 ;;
  53 ;;       $ emacsclient \
  54 ;;         org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  55 ;;
  56 ;;   5.) Optionally add custom sub-protocols and handlers:
  57 ;;
  58 ;;       (setq org-protocol-protocol-alist
  59 ;;             '(("my-protocol"
  60 ;;                :protocol "my-protocol"
  61 ;;                :function my-protocol-handler-fuction)))
  62 ;;
  63 ;;       A "sub-protocol" will be found in URLs like this:
  64 ;;
  65 ;;           org-protocol://sub-protocol://data
  66 ;;
  67 ;; If it works, you can now setup other applications for using this feature.
  68 ;;
  69 ;;
  70 ;; As of March 2009 Firefox users follow the steps documented on
  71 ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  72 ;; http://www.opera.com/support/kb/view/535/
  73 ;;
  74 ;;
  75 ;; Documentation
  76 ;; -------------
  77 ;;
  78 ;; org-protocol.el comes with and installs handlers to open sources of published
  79 ;; online content, store and insert the browser's URLs and cite online content
  80 ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  81 ;; applications:
  82 ;;
  83 ;;   * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  84 ;;     URLs to local filenames defined in `org-protocol-project-alist'.
  85 ;;
  86 ;;   * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  87 ;;     pushes the browsers URL to the `kill-ring' for yanking. This handler is
  88 ;;     triggered through the sub-protocol \"store-link\".
  89 ;;
  90 ;;   * Call `org-protocol-remember' by using the sub-protocol \"remember\".  If
  91 ;;     Org-mode is loaded, emacs will pop-up a remember buffer and fill the
  92 ;;     template with the data provided. I.e. the browser's URL is inserted as an
  93 ;;     Org-link of which the page title will be the description part. If text
  94 ;;     was select in the browser, that text will be the body of the entry.
  95 ;;
  96 ;; You may use the same bookmark URL for all those standard handlers and just
  97 ;; adjust the sub-protocol used:
  98 ;;
  99 ;;     location.href='org-protocol://sub-protocol://'+
 100 ;;           encodeURIComponent(location.href)+'/'+
 101 ;;           encodeURIComponent(document.title)+'/'+
 102 ;;           encodeURIComponent(window.getSelection())
 103 ;;
 104 ;; The handler for the sub-protocol \"remember\" detects an optional template
 105 ;; char that, if present, triggers the use of a special template.
 106 ;; Example:
 107 ;;
 108 ;;     location.href='org-protocol://sub-protocol://x/'+ ...
 109 ;;
 110 ;;  use template ?x.
 111 ;;
 112 ;; Note, that using double slashes is optional from org-protocol.el's point of
 113 ;; view because emacsclient squashes the slashes to one.
 114 ;;
 115 ;;
 116 ;; provides: 'org-protocol
 117 ;;
 118 ;;; Code:
 119
 120 (require 'org)
 121 (eval-when-compile
 122   (require 'cl))
 123
 124 (declare-function org-publish-initialize-files-alist "org-publish"
 125                   (&optional refresh))
 126 (declare-function org-publish-get-project-from-filename "org-publish"
 127                   (filename &optional up))
 128 (declare-function server-edit "server" (&optional arg))
 129
 130
 131 (defgroup org-protocol nil
 132   "Intercept calls from emacsclient to trigger custom actions.
 133
 134 This is done by advising `server-visit-files' to scann the list of filenames
 135 for `org-protocol-the-protocol' and sub-procols defined in
 136 `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
 137   :version "22.1"
 138   :group 'convenience
 139   :group 'org)
 140
 141
 142 ;;; Variables:
 143
 144 (defconst org-protocol-protocol-alist-default
 145   '(("org-remember"    :protocol "remember"    :function org-protocol-remember :kill-client t)
 146     ("org-store-link"  :protocol "store-link"  :function org-protocol-store-link)
 147     ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
 148   "Default protocols to use.
 149 See `org-protocol-protocol-alist' for a description of this variable.")
 150
 151
 152 (defconst org-protocol-the-protocol "org-protocol"
 153   "This is the protocol to detect if org-protocol.el is loaded.
 154 `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold the
 155 sub-protocols that trigger the required action. You will have to define just one
 156 protocol handler OS-wide (MS-Windows) or per application (Linux). That protocol
 157 handler should call emacsclient.")
 158
 159
 160 ;;; User variables:
 161
 162 (defcustom org-protocol-reverse-list-of-files t
 163   "* The filenames passed on the commandline are passed to the emacs-server in
 164 reversed order. Set to `t' (default) to re-reverse the list, i.e. use the
 165 sequence on the command line. If nil, the sequence of the filenames is
 166 unchanged."
 167   :group 'org-protocol
 168   :type 'boolean)
 169
 170
 171 (defcustom org-protocol-project-alist nil
 172   "* Map URLs to local filenames for `org-protocol-open-source' (open-source).
 173
 174 Each element of this list must be of the form:
 175
 176   (module-name :property value property: value ...)
 177
 178 where module-name is an arbitrary name. All the values are strings.
 179
 180 Possible properties are:
 181
 182   :online-suffix     - the suffix to strip from the published URLs
 183   :working-suffix    - the replacement for online-suffix
 184   :base-url          - the base URL, e.g. http://www.example.com/project/
 185                        Last slash required.
 186   :working-directory - the local working directory. This is, what base-url will
 187                        be replaced with.
 188
 189 Example:
 190
 191    (setq org-protocol-project-alist
 192        '((\"http://orgmode.org/worg/\"
 193           :online-suffix \".php\"
 194           :working-suffix \".org\"
 195           :base-url \"http://orgmode.org/worg/\"
 196           :working-directory \"/home/user/org/Worg/\")
 197          (\"http://localhost/org-notes/\"
 198           :online-suffix \".html\"
 199           :working-suffix \".org\"
 200           :base-url \"http://localhost/org/\"
 201           :working-directory \"/home/user/org/\")))
 202
 203 Consider using the interactive functions `org-protocol-create' and
 204 `org-protocol-create-for-org' to help you filling this variable with valid contents."
 205   :group 'org-protocol
 206   :type 'alist)
 207
 208
 209 (defcustom org-protocol-protocol-alist nil
 210   "* Register custom handlers for org-protocol.
 211
 212 Each element of this list must be of the form:
 213
 214   (module-name :protocol protocol :function func :kill-client nil)
 215
 216 protocol - protocol to detect in a filename without trailing colon and slashes.
 217            See rfc1738 section 2.1 for more on this.
 218            If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
 219            will search filenames for \"org-protocol:/my-protocol:/\"
 220            and trigger your action for every match. `org-protocol' is defined in
 221            `org-protocol-the-protocol'. Double and tripple slashes are compressed
 222            to one by emacsclient.
 223
 224 function - function that handles requests with protocol and takes exactly one
 225            argument: the filename with all protocols stripped. If the function
 226            returns nil, emacsclient and -server do nothing. Any non-nil return
 227            value is considered a valid filename and thus passed to the server.
 228
 229            `org-protocol.el provides some support for handling those filenames,
 230            if you stay with the conventions used for the standard handlers in
 231            `org-protocol-protocol-alist-default'. See `org-protocol-split-data'.
 232
 233 kill-client - If t, kill the client immediately, once the sub-protocol is
 234            detected. This is necessary for actions that can be interrupted by
 235            `C-g' to avoid dangeling emacsclients. Note, that all other command
 236            line arguments but the this one will be discarded, greedy handlers
 237            still receive the whole list of arguments though.
 238
 239 Here is an example:
 240
 241   (setq org-protocol-protocol-alist
 242       '((\"my-protocol\"
 243          :protocol \"my-protocol\"
 244          :function my-protocol-handler-fuction)
 245         (\"your-protocol\"
 246          :protocol \"your-protocol\"
 247          :function your-protocol-handler-fuction)))"
 248   :group 'org-protocol
 249   :type '(alist))
 250
 251 (defcustom org-protocol-default-template-key "w"
 252   "The default org-remember-templates key to use."
 253   :group 'org-protocol
 254   :type 'string)
 255
 256
 257 ;;; Helper functions:
 258
 259 (defun org-protocol-sanitize-uri (uri)
 260   "emacsclient compresses double and tripple slashes.
 261 Slashes are sanitized to double slashes here."
 262   (when (string-match "^\\([a-z]+\\):/" uri)
 263     (let* ((splitparts (split-string uri "/+")))
 264       (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
 265   uri)
 266
 267
 268 (defun org-protocol-split-data(data &optional unhexify separator)
 269   "Split, what a org-protocol handler function gets as only argument.
 270 data is that one argument. Data is splitted at each occurrence of separator
 271  (regexp). If no separator is specified or separator is nil, assume \"/+\".
 272 The results of that splitting are return as a list. If unhexify is non-nil,
 273 hex-decode each split part. If unhexify is a function, use that function to
 274 decode each split part."
 275   (let* ((sep (or separator "/+"))
 276          (split-parts (split-string data sep)))
 277     (if unhexify
 278         (if (fboundp unhexify)
 279             (mapcar unhexify split-parts)
 280           (mapcar 'org-protocol-unhex-string split-parts))
 281       split-parts)))
 282
 283 ;; This inline function is needed in org-protocol-unhex-compound to do
 284 ;; the right thing to decode UTF-8 char integer values.
 285 (eval-when-compile
 286   (if (>= emacs-major-version 23)
 287       (defsubst org-protocol-char-to-string(c)
 288         "Defsubst to decode UTF-8 character values in emacs 23 and beyond."
 289         (char-to-string c))
 290     (defsubst org-protocol-char-to-string (c)
 291       "Defsubst to decode UTF-8 character values in emacs 22."
 292       (string (decode-char 'ucs c)))))
 293
 294 (defun org-protocol-unhex-string(str)
 295   "Unhex hexified unicode strings as returned from the JavaScript function
 296 encodeURIComponent. E.g. `%C3%B6' is the german Umlaut `ü'."
 297   (setq str (or str ""))
 298   (let ((tmp "")
 299         (case-fold-search t))
 300     (while (string-match "\\(%[0-9a-f][0-9a-f]\\)+" str)
 301       (let* ((start (match-beginning 0))
 302              (end (match-end 0))
 303              (hex (match-string 0 str))
 304              (replacement (org-protocol-unhex-compound hex)))
 305         (setq tmp (concat tmp (substring str 0 start) replacement))
 306         (setq str (substring str end))))
 307     (setq tmp (concat tmp str))
 308     tmp))
 309
 310
 311 (defun org-protocol-unhex-compound (hex)
 312   "Unhexify unicode hex-chars. E.g. `%C3%B6' is the german Umlaut `ü'."
 313   (let* ((bytes (remove "" (split-string hex "%")))
 314          (ret "")
 315          (eat 0)
 316          (sum 0))
 317     (while bytes
 318       (let* ((b (pop bytes))
 319              (a (elt b 0))
 320              (b (elt b 1))
 321              (c1 (if (> a ?9) (+ 10 (- a ?A)) (- a ?0)))
 322              (c2 (if (> b ?9) (+ 10 (- b ?A)) (- b ?0)))
 323              (val (+ (lsh c1 4) c2))
 324              (shift
 325               (if (= 0 eat) ;; new byte
 326                   (if (>= val 252) 6
 327                     (if (>= val 248) 5
 328                       (if (>= val 240) 4
 329                         (if (>= val 224) 3
 330                           (if (>= val 192) 2 0)))))
 331                 6))
 332              (xor
 333               (if (= 0 eat) ;; new byte
 334                   (if (>= val 252) 252
 335                     (if (>= val 248) 248
 336                       (if (>= val 240) 240
 337                         (if (>= val 224) 224
 338                           (if (>= val 192) 192 0)))))
 339                 128)))
 340         (if (>= val 192) (setq eat shift))
 341         (setq val (logxor val xor))
 342         (setq sum (+ (lsh sum shift) val))
 343         (if (> eat 0) (setq eat (- eat 1)))
 344         (when (= 0 eat)
 345           (setq ret (concat ret (org-protocol-char-to-string sum)))
 346           (setq sum 0))
 347         )) ;; end (while bytes
 348     ret ))
 349
 350 (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
 351   "Greedy handlers might recieve a list like this from emacsclient:
 352  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 353 where \"/dir/\" is the absolute path to emacsclients working directory. This
 354 function transforms it into a flat list utilizing `org-protocol-flatten' and
 355 transforms the elements of that list as follows:
 356
 357 If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
 358 param-list.
 359
 360 If replacement is string, replace the \"/dir/\" prefix with it.
 361
 362 The first parameter, the one that contains the protocols, is always changed.
 363 Everything up to the end of the protocols is stripped.
 364
 365 Note, that this function will always behave as if
 366 `org-protocol-reverse-list-of-files' was set to t and the returned list will
 367 reflect that. I.e. emacsclients first parameter will be the first one in the
 368 returned list."
 369 (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
 370                                     param-list
 371                                   (reverse param-list))))
 372       (trigger (car l))
 373       (len 0)
 374       dir
 375       ret)
 376   (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
 377     (setq dir (match-string 1 trigger))
 378     (setq len (length dir))
 379     (setcar l (concat dir (match-string 3 trigger))))
 380   (if strip-path
 381       (progn
 382        (dolist (e l ret)
 383          (setq ret
 384                (append ret
 385                        (list
 386                         (if (stringp e)
 387                             (if (stringp replacement)
 388                                 (setq e (concat replacement (substring e len)))
 389                               (setq e (substring e len)))
 390                           e)))))
 391        ret)
 392     l)))
 393
 394
 395 (defun org-protocol-flatten (l)
 396   "Greedy handlers might recieve a list like this from emacsclient:
 397  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 398 where \"/dir/\" is the absolute path to emacsclients working directory. This
 399 function transforms it into a flat list."
 400   (if (null l) ()
 401     (if (listp l)
 402        (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
 403       (list l))))
 404
 405 ;;; Standard protocol handlers:
 406
 407 (defun org-protocol-store-link (fname)
 408   "Process an org-protocol://store-link:// style url
 409 and store a browser URL as an org link. Also pushes the links URL to the
 410 `kill-ring'.
 411
 412 The location for a browser's bookmark has to look like this:
 413
 414   javascript:location.href='org-protocol://store-link://'+ \\
 415         encodeURIComponent(location.href)
 416         encodeURIComponent(document.title)+'/'+ \\
 417
 418 Don't use `escape()'! Use `encodeURIComponent()' instead. The title of the page
 419 could contain slashes and the location definitely will.
 420
 421 The sub-protocol used to reach this function is set in
 422 `org-protocol-protocol-alist'."
 423   (let* ((splitparts (org-protocol-split-data fname t))
 424          (uri (org-protocol-sanitize-uri (car splitparts)))
 425          (title (cadr splitparts))
 426          orglink)
 427     (if (boundp 'org-stored-links)
 428       (setq org-stored-links (cons (list uri title) org-stored-links)))
 429     (kill-new uri)
 430     (message "`%s' to insert new org-link, `%s' to insert `%s'"
 431              (substitute-command-keys"\\[org-insert-link]")
 432              (substitute-command-keys"\\[yank]")
 433              uri))
 434   nil)
 435
 436 (defun org-protocol-remember  (info)
 437   "Process an org-protocol://remember:// style url.
 438
 439 The sub-protocol used to reach this function is set in
 440 `org-protocol-protocol-alist'.
 441
 442 This function detects an URL, title and optional text, separated by '/'
 443 The location for a browser's bookmark has to look like this:
 444
 445   javascript:location.href='org-protocol://remember://'+ \\
 446         encodeURIComponent(location.href)+'/' \\
 447         encodeURIComponent(document.title)+'/'+ \\
 448         encodeURIComponent(window.getSelection())
 449
 450 By default, it uses the character `org-protocol-default-template-key',
 451 which should be associated with a template in `org-remember-templates'.
 452 But you may prepend the encoded URL with a character and a slash like so:
 453
 454   javascript:location.href='org-protocol://org-store-link://b/'+ ...
 455
 456 Now template ?b will be used."
 457
 458   (if (and (boundp 'org-stored-links)
 459            (fboundp 'org-remember))
 460       (let* ((parts (org-protocol-split-data info t))
 461              (template (or (and (= 1 (length (car parts))) (pop parts))
 462                            org-protocol-default-template-key))
 463              (url (org-protocol-sanitize-uri (car parts)))
 464              (type (if (string-match "^\\([a-z]+\\):" url)
 465                        (match-string 1 url)))
 466              (title (cadr parts))
 467              (region (caddr parts))
 468              (orglink (org-make-link-string url title))
 469              remember-annotation-functions)
 470         (setq org-stored-links
 471               (cons (list url title) org-stored-links))
 472         (kill-new orglink)
 473         (org-store-link-props :type type
 474                               :link url
 475                               :description title
 476                               :initial region)
 477         (raise-frame)
 478         (org-remember nil (string-to-char template)))
 479
 480     (message "Org-mode not loaded."))
 481   nil)
 482
 483 (defun org-protocol-open-source (fname)
 484   "Process an org-protocol://open-source:// style url.
 485
 486 Change a filename by mapping URLs to local filenames as set
 487 in `org-protocol-project-alist'.
 488
 489 The location for a browser's bookmark should look like this:
 490
 491   javascript:location.href='org-protocol://open-source://'+ \\
 492         encodeURIComponent(location.href)"
 493
 494   ;; As we enter this function for a match on our protocol, the return value
 495   ;; defaults to nil.
 496   (let ((result nil)
 497         (f (org-protocol-unhex-string fname)))
 498     (catch 'result
 499       (dolist (prolist org-protocol-project-alist)
 500         (let* ((base-url (plist-get (cdr prolist) :base-url))
 501                (wsearch (regexp-quote base-url)))
 502
 503           (when (string-match wsearch f)
 504             (let* ((wdir (plist-get (cdr prolist) :working-directory))
 505                    (strip-suffix (plist-get (cdr prolist) :online-suffix))
 506                    (add-suffix (plist-get (cdr prolist) :working-suffix))
 507                    (start-pos (+ (string-match wsearch f) (length base-url)))
 508                    (end-pos (string-match
 509                              (concat (regexp-quote strip-suffix) "\\([?#].*\\)?$") f))
 510                    (the-file (concat wdir (substring f start-pos end-pos) add-suffix)))
 511               (if (file-readable-p the-file)
 512                   (throw 'result the-file))
 513               (if (file-exists-p the-file)
 514                   (message "%s: permission denied!" the-file)
 515                 (message "%s: no such file or directory." the-file))))))
 516       result)))
 517
 518
 519 ;;; Core functions:
 520
 521 (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
 522   "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
 523 Sub-protocols are registered in `org-protocol-protocol-alist' and
 524 `org-protocol-protocol-alist-default'.
 525 This is, how the matching is done:
 526
 527   (string-match \"protocol:/+sub-protocol:/+\" ...)
 528
 529 protocol and sub-protocol are regexp-quoted.
 530
 531 If a matching protcol is found, the protcol is stripped from fname and the
 532 result is passed to the protocols function as the only parameter. If the
 533 function returns nil, the filename is removed from the list of filenames
 534 passed from emacsclient to the server.
 535 If the function returns a non nil value, that value is passed to the server
 536 as filename."
 537   (let ((sub-protocols (append org-protocol-protocol-alist org-protocol-protocol-alist-default)))
 538     (catch 'fname
 539       (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
 540         (when (string-match the-protocol fname)
 541           (dolist (prolist sub-protocols)
 542             (let ((proto (concat the-protocol (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
 543               (when (string-match proto fname)
 544                 (let* ((func (plist-get (cdr prolist) :function))
 545                        (greedy (plist-get (cdr prolist) :greedy))
 546                        (splitted (split-string fname proto))
 547                        (result (if greedy restoffiles (cadr splitted))))
 548                   (when (plist-get (cdr prolist) :kill-client)
 549                     (message "Greedy org-protocol handler. Killing client.")
 550                     (server-edit))
 551                   (when (fboundp func)
 552                     (unless greedy
 553                       (throw 'fname (funcall func result)))
 554                     (funcall func result)
 555                     (throw 'fname t))))))))
 556       ;; (message "fname: %s" fname)
 557       fname)))
 558
 559
 560 (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
 561   "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
 562   (let ((flist (if org-protocol-reverse-list-of-files
 563                    (reverse  (ad-get-arg 0))
 564                  (ad-get-arg 0)))
 565         (client (ad-get-arg 1)))
 566     (catch 'greedy
 567       (dolist (var flist)
 568         (let ((fname  (expand-file-name (car var)))) ;; `\' to `/' on windows. FIXME: could this be done any better?
 569           (setq fname (org-protocol-check-filename-for-protocol fname (member var flist)  client))
 570           (if (eq fname t) ;; greedy? We need the `t' return value.
 571               (progn
 572                 (ad-set-arg 0 nil)
 573                 (throw 'greedy t))
 574             (if (stringp fname) ;; probably filename
 575                 (setcar var fname)
 576               (ad-set-arg 0 (delq var (ad-get-arg 0))))))
 577         ))))
 578
 579 ;;; Org specific functions:
 580
 581 (defun org-protocol-create-for-org ()
 582   "Create a org-protocol project for the current file's Org-mode project.
 583 This works, if the file visited is part of a publishing project in
 584 `org-publish-project-alist'. This functions calls `org-protocol-create' to do
 585 most of the work."
 586   (interactive)
 587   (require 'org-publish)
 588   (org-publish-initialize-files-alist)
 589   (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
 590     (if all (org-protocol-create (cdr all))
 591       (message "Not in an org-project. Did mean %s?"
 592                (substitute-command-keys"\\[org-protocol-create]")))))
 593
 594
 595 (defun org-protocol-create(&optional project-plist)
 596   "Create a new org-protocol project interactively.
 597 An org-protocol project is an entry in `org-protocol-project-alist'
 598 which is used by `org-protocol-open-source'.
 599 Optionally use project-plist to initialize the defaults for this worglet. If
 600 project-plist is the CDR of an element in `org-publish-project-alist', reuse
 601 :base-directory, :html-extension and :base-extension."
 602   (interactive)
 603   (let ((working-dir (expand-file-name(or (plist-get project-plist :base-directory) default-directory)))
 604         (base-url "http://orgmode.org/worg/")
 605         (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
 606         (working-suffix (if (plist-get project-plist :base-extension)
 607                             (concat "." (plist-get project-plist :base-extension))
 608                           ".org"))
 609
 610         (worglet-buffer nil)
 611
 612         (insert-default-directory t)
 613         (minibuffer-allow-text-properties nil))
 614
 615     (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
 616     (if (not (string-match "\\/$" base-url))
 617         (setq base-url (concat base-url "/")))
 618
 619     (setq working-dir
 620           (expand-file-name
 621            (read-directory-name "Local working directory: " working-dir working-dir t)))
 622     (if (not (string-match "\\/$" working-dir))
 623         (setq working-dir (concat working-dir "/")))
 624
 625     (setq strip-suffix
 626           (read-string
 627            (concat "Extension to strip from published URLs ("strip-suffix"): ")
 628                    strip-suffix nil strip-suffix t))
 629
 630     (setq working-suffix
 631           (read-string
 632            (concat "Extension of editable files ("working-suffix"): ")
 633                    working-suffix nil working-suffix t))
 634
 635     (when (yes-or-no-p "Save the new worglet to your init file? ")
 636       (setq org-protocol-project-alist
 637             (cons `(,base-url . (:base-url ,base-url
 638                                  :working-directory ,working-dir
 639                                  :online-suffix ,strip-suffix
 640                                  :working-suffix ,working-suffix))
 641                   org-protocol-project-alist))
 642       (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))))
 643
 644 (provide 'org-protocol)
 645
 646 ;; arch-tag: b5c5c2ac-77cf-4a94-a649-2163dff95846
 647 ;;; org-protocol.el ends here