lisp/ob-python.el

   1 ;;; ob-python.el --- org-babel functions for python evaluation
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (eval-when-compile (require 'cl))
  32
  33 (declare-function org-remove-indentation "org" )
  34 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  35 (declare-function py-toggle-shells "ext:python-mode" (arg))
  36 (declare-function run-python "ext:python" (&optional cmd noshow new))
  37
  38 (defvar org-babel-tangle-lang-exts)
  39 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  40
  41 (defvar org-babel-default-header-args:python '())
  42
  43 (defcustom org-babel-python-command "python"
  44   "Name of the command for executing Python code."
  45   :version "24.4"
  46   :package-version '(Org . "8.0")
  47   :group 'org-babel
  48   :type 'string)
  49
  50 (defcustom org-babel-python-mode
  51   (if (or (featurep 'xemacs) (featurep 'python-mode)) 'python-mode 'python)
  52   "Preferred python mode for use in running python interactively.
  53 This will typically be either 'python or 'python-mode."
  54   :group 'org-babel
  55   :version "24.4"
  56   :package-version '(Org . "8.0")
  57   :type 'function)
  58
  59 (defvar org-src-preserve-indentation)
  60
  61 (defcustom org-babel-python-hline-to "None"
  62   "Replace hlines in incoming tables with this when translating to python."
  63   :group 'org-babel
  64   :version "24.4"
  65   :package-version '(Org . "8.0")
  66   :type 'string)
  67
  68 (defcustom org-babel-python-None-to 'hline
  69   "Replace 'None' in python tables with this before returning."
  70   :group 'org-babel
  71   :version "24.4"
  72   :package-version '(Org . "8.0")
  73   :type 'string)
  74
  75 (defun org-babel-execute:python (body params)
  76   "Execute a block of Python code with Babel.
  77 This function is called by `org-babel-execute-src-block'."
  78   (let* ((session (org-babel-python-initiate-session
  79                    (cdr (assoc :session params))))
  80          (result-params (cdr (assoc :result-params params)))
  81          (result-type (cdr (assoc :result-type params)))
  82          (return-val (when (and (eq result-type 'value) (not session))
  83                        (cdr (assoc :return params))))
  84          (preamble (cdr (assoc :preamble params)))
  85          (full-body
  86           (org-babel-expand-body:generic
  87            (concat body (if return-val (format "\nreturn %s" return-val) ""))
  88            params (org-babel-variable-assignments:python params)))
  89          (result (org-babel-python-evaluate
  90                   session full-body result-type result-params preamble)))
  91     (org-babel-reassemble-table
  92      result
  93      (org-babel-pick-name (cdr (assoc :colname-names params))
  94                           (cdr (assoc :colnames params)))
  95      (org-babel-pick-name (cdr (assoc :rowname-names params))
  96                           (cdr (assoc :rownames params))))))
  97
  98 (defun org-babel-prep-session:python (session params)
  99   "Prepare SESSION according to the header arguments in PARAMS.
 100 VARS contains resolved variable references"
 101   (let* ((session (org-babel-python-initiate-session session))
 102          (var-lines
 103           (org-babel-variable-assignments:python params)))
 104     (org-babel-comint-in-buffer session
 105       (mapc (lambda (var)
 106               (end-of-line 1) (insert var) (comint-send-input)
 107               (org-babel-comint-wait-for-output session)) var-lines))
 108     session))
 109
 110 (defun org-babel-load-session:python (session body params)
 111   "Load BODY into SESSION."
 112   (save-window-excursion
 113     (let ((buffer (org-babel-prep-session:python session params)))
 114       (with-current-buffer buffer
 115         (goto-char (process-mark (get-buffer-process (current-buffer))))
 116         (insert (org-babel-chomp body)))
 117       buffer)))
 118
 119 ;; helper functions
 120
 121 (defun org-babel-variable-assignments:python (params)
 122   "Return a list of Python statements assigning the block's variables."
 123   (mapcar
 124    (lambda (pair)
 125      (format "%s=%s"
 126              (car pair)
 127              (org-babel-python-var-to-python (cdr pair))))
 128    (mapcar #'cdr (org-babel-get-header params :var))))
 129
 130 (defun org-babel-python-var-to-python (var)
 131   "Convert an elisp value to a python variable.
 132 Convert an elisp value, VAR, into a string of python source code
 133 specifying a variable of the same value."
 134   (if (listp var)
 135       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 136     (if (equal var 'hline)
 137         org-babel-python-hline-to
 138       (format
 139        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 140        var))))
 141
 142 (defun org-babel-python-table-or-string (results)
 143   "Convert RESULTS into an appropriate elisp value.
 144 If the results look like a list or tuple, then convert them into an
 145 Emacs-lisp table, otherwise return the results as a string."
 146   ((lambda (res)
 147      (if (listp res)
 148          (mapcar (lambda (el) (if (equal el 'None)
 149                              org-babel-python-None-to el))
 150                  res)
 151        res))
 152    (org-babel-script-escape results)))
 153
 154 (defvar org-babel-python-buffers '((:default . nil)))
 155
 156 (defun org-babel-python-session-buffer (session)
 157   "Return the buffer associated with SESSION."
 158   (cdr (assoc session org-babel-python-buffers)))
 159
 160 (defvar py-default-interpreter)
 161 (defun org-babel-python-initiate-session-by-key (&optional session)
 162   "Initiate a python session.
 163 If there is not a current inferior-process-buffer in SESSION
 164 then create.  Return the initialized session."
 165   (require org-babel-python-mode)
 166   (save-window-excursion
 167     (let* ((session (if session (intern session) :default))
 168            (python-buffer (org-babel-python-session-buffer session)))
 169       (cond
 170        ((and (eq 'python org-babel-python-mode)
 171              (fboundp 'run-python)) ; python.el
 172         (if (version< "24.1" emacs-version)
 173             (run-python org-babel-python-command)
 174           (run-python)))
 175        ((and (eq 'python-mode org-babel-python-mode)
 176              (fboundp 'py-shell)) ; python-mode.el
 177         ;; Make sure that py-which-bufname is initialized, as otherwise
 178         ;; it will be overwritten the first time a Python buffer is
 179         ;; created.
 180         (py-toggle-shells py-default-interpreter)
 181         ;; `py-shell' creates a buffer whose name is the value of
 182         ;; `py-which-bufname' with '*'s at the beginning and end
 183         (let* ((bufname (if (and python-buffer (buffer-live-p python-buffer))
 184                             (replace-regexp-in-string ;; zap surrounding *
 185                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 186                           (concat "Python-" (symbol-name session))))
 187                (py-which-bufname bufname))
 188           (py-shell)
 189           (setq python-buffer (concat "*" bufname "*"))))
 190        (t
 191         (error "No function available for running an inferior Python")))
 192       (setq org-babel-python-buffers
 193             (cons (cons session python-buffer)
 194                   (assq-delete-all session org-babel-python-buffers)))
 195       session)))
 196
 197 (defun org-babel-python-initiate-session (&optional session params)
 198   "Create a session named SESSION according to PARAMS."
 199   (unless (string= session "none")
 200     (org-babel-python-session-buffer
 201      (org-babel-python-initiate-session-by-key session))))
 202
 203 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 204   "A string to indicate that evaluation has completed.")
 205 (defvar org-babel-python-wrapper-method
 206   "
 207 def main():
 208 %s
 209
 210 open('%s', 'w').write( str(main()) )")
 211 (defvar org-babel-python-pp-wrapper-method
 212   "
 213 import pprint
 214 def main():
 215 %s
 216
 217 open('%s', 'w').write( pprint.pformat(main()) )")
 218
 219 (defun org-babel-python-evaluate
 220   (session body &optional result-type result-params preamble)
 221   "Evaluate BODY as Python code."
 222   (if session
 223       (org-babel-python-evaluate-session
 224        session body result-type result-params)
 225     (org-babel-python-evaluate-external-process
 226      body result-type result-params preamble)))
 227
 228 (defun org-babel-python-evaluate-external-process
 229   (body &optional result-type result-params preamble)
 230   "Evaluate BODY in external python process.
 231 If RESULT-TYPE equals 'output then return standard output as a
 232 string.  If RESULT-TYPE equals 'value then return the value of the
 233 last statement in BODY, as elisp."
 234   ((lambda (raw)
 235      (org-babel-result-cond result-params
 236        raw
 237        (org-babel-python-table-or-string (org-babel-trim raw))))
 238    (case result-type
 239      (output (org-babel-eval org-babel-python-command
 240                              (concat (if preamble (concat preamble "\n") "")
 241                                      body)))
 242      (value (let ((tmp-file (org-babel-temp-file "python-")))
 243               (org-babel-eval
 244                org-babel-python-command
 245                (concat
 246                 (if preamble (concat preamble "\n") "")
 247                 (format
 248                  (if (member "pp" result-params)
 249                      org-babel-python-pp-wrapper-method
 250                    org-babel-python-wrapper-method)
 251                  (mapconcat
 252                   (lambda (line) (format "\t%s" line))
 253                   (split-string
 254                    (org-remove-indentation
 255                     (org-babel-trim body))
 256                    "[\r\n]") "\n")
 257                  (org-babel-process-file-name tmp-file 'noquote))))
 258               (org-babel-eval-read-file tmp-file))))))
 259
 260 (defun org-babel-python-evaluate-session
 261   (session body &optional result-type result-params)
 262   "Pass BODY to the Python process in SESSION.
 263 If RESULT-TYPE equals 'output then return standard output as a
 264 string.  If RESULT-TYPE equals 'value then return the value of the
 265 last statement in BODY, as elisp."
 266   (let* ((send-wait (lambda () (comint-send-input nil t) (sleep-for 0 5)))
 267          (dump-last-value
 268           (lambda
 269             (tmp-file pp)
 270             (mapc
 271              (lambda (statement) (insert statement) (funcall send-wait))
 272              (if pp
 273                  (list
 274                   "import pprint"
 275                   (format "open('%s', 'w').write(pprint.pformat(_))"
 276                           (org-babel-process-file-name tmp-file 'noquote)))
 277                (list (format "open('%s', 'w').write(str(_))"
 278                              (org-babel-process-file-name tmp-file 'noquote)))))))
 279          (input-body (lambda (body)
 280                        (mapc (lambda (line) (insert line) (funcall send-wait))
 281                              (split-string body "[\r\n]"))
 282                        (funcall send-wait))))
 283     ((lambda (results)
 284        (unless (string= (substring org-babel-python-eoe-indicator 1 -1) results)
 285          (org-babel-result-cond result-params
 286            results
 287            (org-babel-python-table-or-string results))))
 288      (case result-type
 289        (output
 290         (mapconcat
 291          #'org-babel-trim
 292          (butlast
 293           (org-babel-comint-with-output
 294               (session org-babel-python-eoe-indicator t body)
 295             (funcall input-body body)
 296             (funcall send-wait) (funcall send-wait)
 297             (insert org-babel-python-eoe-indicator)
 298             (funcall send-wait))
 299           2) "\n"))
 300        (value
 301         (let ((tmp-file (org-babel-temp-file "python-")))
 302           (org-babel-comint-with-output
 303               (session org-babel-python-eoe-indicator nil body)
 304             (let ((comint-process-echoes nil))
 305               (funcall input-body body)
 306               (funcall dump-last-value tmp-file (member "pp" result-params))
 307               (funcall send-wait) (funcall send-wait)
 308               (insert org-babel-python-eoe-indicator)
 309               (funcall send-wait)))
 310           (org-babel-eval-read-file tmp-file)))))))
 311
 312 (defun org-babel-python-read-string (string)
 313   "Strip 's from around Python string."
 314   (if (string-match "^'\\([^\000]+\\)'$" string)
 315       (match-string 1 string)
 316     string))
 317
 318 (provide 'ob-python)
 319
 320
 321
 322 ;;; ob-python.el ends here