lisp/org-bibtex.el

   1 ;;; org-bibtex.el --- Org links to BibTeX entries
   2 ;;
   3 ;; Copyright (C) 2007-2013 Free Software Foundation, Inc.
   4 ;;
   5 ;; Authors: Bastien Guerry <bzg at altern dot org>
   6 ;;       Carsten Dominik <carsten dot dominik at gmail dot com>
   7 ;;       Eric Schulte <schulte dot eric at gmail dot com>
   8 ;; Keywords: org, wp, remember
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;
  25 ;;; Commentary:
  26 ;;
  27 ;; This file implements links to database entries in BibTeX files.
  28 ;; Instead of defining a special link prefix, it uses the normal file
  29 ;; links combined with a custom search mechanism to find entries
  30 ;; by reference key.  And it constructs a nice description tag for
  31 ;; the link that contains the author name, the year and a short title.
  32 ;;
  33 ;; It also stores detailed information about the entry so that
  34 ;; remember templates can access and enter this information easily.
  35 ;;
  36 ;; The available properties for each entry are listed here:
  37 ;;
  38 ;; :author        :publisher      :volume      :pages
  39 ;; :editor        :url            :number      :journal
  40 ;; :title         :year           :series      :address
  41 ;; :booktitle     :month          :annote      :abstract
  42 ;; :key           :btype
  43 ;;
  44 ;; Here is an example of a remember template that use some of this
  45 ;; information (:author :year :title :journal :pages):
  46 ;;
  47 ;; (setq org-remember-templates
  48 ;;   '((?b "* READ %?\n\n%a\n\n%:author (%:year): %:title\n   \
  49 ;;          In %:journal, %:pages.")))
  50 ;;
  51 ;; Let's say you want to remember this BibTeX entry:
  52 ;;
  53 ;; @Article{dolev83,
  54 ;;   author =    {Danny Dolev and Andrew C. Yao},
  55 ;;   title =     {On the security of public-key protocols},
  56 ;;   journal =   {IEEE Transaction on Information Theory},
  57 ;;   year =      1983,
  58 ;;   volume =    2,
  59 ;;   number =    29,
  60 ;;   pages =     {198--208},
  61 ;;   month =     {Mars}
  62 ;; }
  63 ;;
  64 ;; M-x `org-remember' on this entry will produce this buffer:
  65 ;;
  66 ;; =====================================================================
  67 ;; * READ <== [point here]
  68 ;;
  69 ;; [[file:file.bib::dolev83][Dolev & Yao 1983: security of public key protocols]]
  70 ;;
  71 ;; Danny Dolev and Andrew C. Yao (1983): On the security of public-key protocols
  72 ;; In IEEE Transaction on Information Theory, 198--208.
  73 ;; =====================================================================
  74 ;;
  75 ;; Additionally, the following functions are now available for storing
  76 ;; bibtex entries within Org-mode documents.
  77 ;;
  78 ;; - Run `org-bibtex' to export the current file to a .bib.
  79 ;;
  80 ;; - Run `org-bibtex-check' or `org-bibtex-check-all' to check and
  81 ;;   fill in missing field of either the current, or all headlines
  82 ;;
  83 ;; - Run `org-bibtex-create' to add a bibtex entry
  84 ;;
  85 ;; - Use `org-bibtex-read' to read a bibtex entry after `point' or in
  86 ;;   the active region, then call `org-bibtex-write' in a .org file to
  87 ;;   insert a heading for the read bibtex entry
  88 ;;
  89 ;; - All Bibtex information is taken from the document compiled by
  90 ;;   Andrew Roberts from the Bibtex manual, available at
  91 ;;   http://www.andy-roberts.net/res/writing/latex/bibentries.pdf
  92 ;;
  93 ;;; History:
  94 ;;
  95 ;; The link creation part has been part of Org-mode for a long time.
  96 ;;
  97 ;; Creating better remember template information was inspired by a request
  98 ;; of Austin Frank: http://article.gmane.org/gmane.emacs.orgmode/4112
  99 ;; and then implemented by Bastien Guerry.
 100 ;;
 101 ;; Eric Schulte eventually added the functions for translating between
 102 ;; Org-mode headlines and Bibtex entries, and for fleshing out the Bibtex
 103 ;; fields of existing Org-mode headlines.
 104 ;;
 105 ;; Org-mode loads this module by default - if this is not what you want,
 106 ;; configure the variable `org-modules'.
 107
 108 ;;; Code:
 109
 110 (require 'org)
 111 (require 'bibtex)
 112 (eval-when-compile
 113   (require 'cl))
 114 (require 'org-compat)
 115
 116 (defvar org-bibtex-description nil) ; dynamically scoped from org.el
 117 (defvar org-id-locations)
 118
 119 (declare-function bibtex-beginning-of-entry "bibtex" ())
 120 (declare-function bibtex-generate-autokey "bibtex" ())
 121 (declare-function bibtex-parse-entry "bibtex" (&optional content))
 122 (declare-function bibtex-url "bibtex" (&optional pos no-browse))
 123 (declare-function longlines-mode "longlines" (&optional arg))
 124 (declare-function org-babel-trim "ob" (string &optional regexp))
 125
 126 \f
 127 ;;; Bibtex data
 128 (defvar org-bibtex-types
 129   '((:article
 130      (:description . "An article from a journal or magazine")
 131      (:required :author :title :journal :year)
 132      (:optional :volume :number :pages :month :note))
 133     (:book
 134      (:description . "A book with an explicit publisher")
 135      (:required (:editor :author) :title :publisher :year)
 136      (:optional (:volume :number) :series :address :edition :month :note))
 137     (:booklet
 138      (:description . "A work that is printed and bound, but without a named publisher or sponsoring institution.")
 139      (:required :title)
 140      (:optional :author :howpublished :address :month :year :note))
 141     (:conference
 142      (:description . "")
 143      (:required :author :title :booktitle :year)
 144      (:optional :editor :pages :organization :publisher :address :month :note))
 145     (:inbook
 146      (:description . "A part of a book, which may be a chapter (or section or whatever) and/or a range of pages.")
 147      (:required (:author :editor) :title (:chapter :pages) :publisher :year)
 148      (:optional :crossref (:volume :number) :series :type :address :edition :month :note))
 149     (:incollection
 150      (:description . "A part of a book having its own title.")
 151      (:required :author :title :booktitle :publisher :year)
 152      (:optional :crossref :editor (:volume :number) :series :type :chapter :pages :address :edition :month :note))
 153     (:inproceedings
 154      (:description . "An article in a conference proceedings")
 155      (:required :author :title :booktitle :year)
 156      (:optional :crossref :editor (:volume :number) :series :pages :address :month :organization :publisher :note))
 157     (:manual
 158      (:description . "Technical documentation.")
 159      (:required :title)
 160      (:optional :author :organization :address :edition :month :year :note))
 161     (:mastersthesis
 162      (:description . "A Master’s thesis.")
 163      (:required :author :title :school :year)
 164      (:optional :type :address :month :note))
 165     (:misc
 166      (:description . "Use this type when nothing else fits.")
 167      (:required)
 168      (:optional :author :title :howpublished :month :year :note))
 169     (:phdthesis
 170      (:description . "A PhD thesis.")
 171      (:required :author :title :school :year)
 172      (:optional :type :address :month :note))
 173     (:proceedings
 174      (:description . "The proceedings of a conference.")
 175      (:required :title :year)
 176      (:optional :editor (:volume :number) :series :address :month :organization :publisher :note))
 177     (:techreport
 178      (:description . "A report published by a school or other institution.")
 179      (:required :author :title :institution :year)
 180      (:optional :type :address :month :note))
 181     (:unpublished
 182      (:description . "A document having an author and title, but not formally published.")
 183      (:required :author :title :note)
 184      (:optional :month :year)))
 185   "Bibtex entry types with required and optional parameters.")
 186
 187 (defvar org-bibtex-fields
 188   '((:address      . "Usually the address of the publisher or other type of institution.  For major publishing houses, van Leunen recommends omitting the information entirely.  For small publishers, on the other hand, you can help the reader by giving the complete address.")
 189     (:annote       . "An annotation.  It is not used by the standard bibliography styles, but may be used by others that produce an annotated bibliography.")
 190     (:author       . "The name(s) of the author(s), in the format described in the LaTeX book.  Remember, all names are separated with the and keyword, and not commas.")
 191     (:booktitle    . "Title of a book, part of which is being cited.  See the LaTeX book for how to type titles.  For book entries, use the title field instead.")
 192     (:chapter      . "A chapter (or section or whatever) number.")
 193     (:crossref     . "The database key of the entry being cross referenced.")
 194     (:edition      . "The edition of a book for example, 'Second'.  This should be an ordinal, and should have the first letter capitalized, as shown here; the standard styles convert to lower case when necessary.")
 195     (:editor       . "Name(s) of editor(s), typed as indicated in the LaTeX book.  If there is also an author field, then the editor field gives the editor of the book or collection in which the reference appears.")
 196     (:howpublished . "How something strange has been published.  The first word should be capitalized.")
 197     (:institution  . "The sponsoring institution of a technical report.")
 198     (:journal      . "A journal name.")
 199     (:key          . "Used for alphabetizing, cross-referencing, and creating a label when the author information is missing.  This field should not be confused with the key that appears in the \cite command and at the beginning of the database entry.")
 200     (:month        . "The month in which the work was published or, for an unpublished work, in which it was written.  You should use the standard three-letter abbreviation,")
 201     (:note         . "Any additional information that can help the reader.  The first word should be capitalized.")
 202     (:number       . "Any additional information that can help the reader.  The first word should be capitalized.")
 203     (:organization . "The organization that sponsors a conference or that publishes a manual.")
 204     (:pages        . "One or more page numbers or range of numbers, such as 42-111 or 7,41,73-97 or 43+ (the ‘+’ in this last example indicates pages following that don’t form simple range). BibTEX requires double dashes for page ranges (--).")
 205     (:publisher    . "The publisher’s name.")
 206     (:school       . "The name of the school where a thesis was written.")
 207     (:series       . "The name of a series or set of books.  When citing an entire book, the the title field gives its title and an optional series field gives the name of a series or multi-volume set in which the book is published.")
 208     (:title        . "The work’s title, typed as explained in the LaTeX book.")
 209     (:type         . "The type of a technical report for example, 'Research Note'.")
 210     (:volume       . "The volume of a journal or multi-volume book.")
 211     (:year         . "The year of publication or, for an unpublished work, the year it was written.  Generally it should consist of four numerals, such as 1984, although the standard styles can handle any year whose last four nonpunctuation characters are numerals, such as '(about 1984)'"))
 212   "Bibtex fields with descriptions.")
 213
 214 (defvar org-bibtex-entries nil
 215   "List to hold parsed bibtex entries.")
 216
 217 (defcustom org-bibtex-autogen-keys nil
 218   "Set to a truth value to use `bibtex-generate-autokey' to generate keys."
 219   :group 'org-bibtex
 220   :version "24.1"
 221   :type  'boolean)
 222
 223 (defcustom org-bibtex-prefix nil
 224   "Optional prefix for all bibtex property names.
 225 For example setting to 'BIB_' would allow interoperability with fireforg."
 226   :group 'org-bibtex
 227   :version "24.1"
 228   :type  'string)
 229
 230 (defcustom org-bibtex-treat-headline-as-title t
 231   "Treat headline text as title if title property is absent.
 232 If an entry is missing a title property, use the headline text as
 233 the property.  If this value is t, `org-bibtex-check' will ignore
 234 a missing title field."
 235   :group 'org-bibtex
 236   :version "24.1"
 237   :type 'boolean)
 238
 239 (defcustom org-bibtex-export-arbitrary-fields nil
 240   "When converting to bibtex allow fields not defined in `org-bibtex-fields'.
 241 This only has effect if `org-bibtex-prefix' is defined, so as to
 242 ensure that other org-properties, such as CATEGORY or LOGGING are
 243 not placed in the exported bibtex entry."
 244   :group 'org-bibtex
 245   :version "24.1"
 246   :type 'boolean)
 247
 248 (defcustom org-bibtex-key-property "CUSTOM_ID"
 249   "Property that holds the bibtex key.
 250 By default, this is CUSTOM_ID, which enables easy linking to
 251 bibtex headlines from within an org file.  This can be set to ID
 252 to enable global links, but only with great caution, as global
 253 IDs must be unique."
 254   :group 'org-bibtex
 255   :version "24.1"
 256   :type 'string)
 257
 258 (defcustom org-bibtex-tags nil
 259   "List of tag(s) that should be added to new bib entries."
 260   :group 'org-bibtex
 261   :version "24.1"
 262   :type '(repeat  :tag "Tag" (string)))
 263
 264 (defcustom org-bibtex-tags-are-keywords nil
 265   "Convert the value of the keywords field to tags and vice versa.
 266 If set to t, comma-separated entries in a bibtex entry's keywords
 267 field will be converted to org tags.  Note: spaces will be escaped
 268 with underscores, and characters that are not permitted in org
 269 tags will be removed.
 270
 271 If t, local tags in an org entry will be exported as a
 272 comma-separated string of keywords when exported to bibtex.  Tags
 273 defined in `org-bibtex-tags' or `org-bibtex-no-export-tags' will
 274 not be exported."
 275   :group 'org-bibtex
 276   :version "24.1"
 277   :type 'boolean)
 278
 279 (defcustom org-bibtex-no-export-tags nil
 280   "List of tag(s) that should not be converted to keywords.
 281 This variable is relevant only if `org-bibtex-export-tags-as-keywords' is t."
 282   :group 'org-bibtex
 283   :version "24.1"
 284   :type '(repeat :tag "Tag" (string)))
 285
 286 (defcustom org-bibtex-type-property-name "btype"
 287   "Property in which to store bibtex entry type (e.g., article)."
 288   :group 'org-bibtex
 289   :version "24.1"
 290   :type 'string)
 291
 292 \f
 293 ;;; Utility functions
 294 (defun org-bibtex-get (property)
 295   ((lambda (it) (when it (org-babel-trim it)))
 296    (let ((org-special-properties
 297           (delete "FILE" (copy-sequence org-special-properties))))
 298      (or
 299       (org-entry-get (point) (upcase property))
 300       (org-entry-get (point) (concat org-bibtex-prefix (upcase property)))))))
 301
 302 (defun org-bibtex-put (property value)
 303   (let ((prop (upcase (if (keywordp property)
 304                           (substring (symbol-name property) 1)
 305                         property))))
 306     (org-set-property
 307      (concat (unless (string= org-bibtex-key-property prop) org-bibtex-prefix)
 308              prop)
 309      value)))
 310
 311 (defun org-bibtex-headline ()
 312   "Return a bibtex entry of the given headline as a string."
 313   (let* ((val (lambda (key lst) (cdr (assoc key lst))))
 314          (to (lambda (string) (intern (concat ":" string))))
 315          (from (lambda (key) (substring (symbol-name key) 1)))
 316          flatten ; silent compiler warning
 317          (flatten (lambda (&rest lsts)
 318                     (apply #'append (mapcar
 319                                      (lambda (e)
 320                                        (if (listp e) (apply flatten e) (list e)))
 321                                      lsts))))
 322          (notes (buffer-string))
 323          (id (org-bibtex-get org-bibtex-key-property))
 324          (type (org-bibtex-get org-bibtex-type-property-name))
 325          (tags (when org-bibtex-tags-are-keywords
 326                  (delq nil
 327                        (mapcar
 328                         (lambda (tag)
 329                           (unless (member tag
 330                                           (append org-bibtex-tags
 331                                                   org-bibtex-no-export-tags))
 332                             tag))
 333                         (org-get-local-tags-at))))))
 334     (when type
 335       (let ((entry (format
 336                     "@%s{%s,\n%s\n}\n" type id
 337                     (mapconcat
 338                      (lambda (pair)
 339                        (format "  %s={%s}" (car pair) (cdr pair)))
 340                      (remove nil
 341                              (if (and org-bibtex-export-arbitrary-fields
 342                                       org-bibtex-prefix)
 343                                  (mapcar
 344                                   (lambda (kv)
 345                                     (let ((key (car kv)) (val0 (cdr kv)))
 346                                       (when (and
 347                                              (string-match org-bibtex-prefix key)
 348                                              (not (string=
 349                                                    (downcase (concat org-bibtex-prefix
 350                                                                      org-bibtex-type-property-name))
 351                                                    (downcase key))))
 352                                         (cons (downcase (replace-regexp-in-string
 353                                                          org-bibtex-prefix "" key))
 354                                               val0))))
 355                                   (org-entry-properties nil 'standard))
 356                                (mapcar
 357                                 (lambda (field)
 358                                   (let ((value (or (org-bibtex-get (funcall from field))
 359                                                    (and (equal :title field)
 360                                                         (nth 4 (org-heading-components))))))
 361                                     (when value (cons (funcall from field) value))))
 362                                 (funcall flatten
 363                                          (funcall val :required (funcall val (funcall to type) org-bibtex-types))
 364                                          (funcall val :optional (funcall val (funcall to type) org-bibtex-types))))))
 365                      ",\n"))))
 366         (with-temp-buffer
 367           (insert entry)
 368           (when tags
 369             (bibtex-beginning-of-entry)
 370             (if (re-search-forward "keywords.*=.*{\\(.*\\)}" nil t)
 371                 (progn (goto-char (match-end 1)) (insert ", "))
 372               (bibtex-make-field "keywords" t t))
 373             (insert (mapconcat #'identity tags ", ")))
 374           (buffer-string))))))
 375
 376 (defun org-bibtex-ask (field)
 377   (unless (assoc field org-bibtex-fields)
 378     (error "Field:%s is not known" field))
 379   (save-window-excursion
 380     (let* ((name (substring (symbol-name field) 1))
 381            (buf-name (format "*Bibtex Help %s*" name)))
 382       (with-output-to-temp-buffer buf-name
 383         (princ (cdr (assoc field org-bibtex-fields))))
 384       (with-current-buffer buf-name (longlines-mode t))
 385       (org-fit-window-to-buffer (get-buffer-window buf-name))
 386       ((lambda (result) (when (> (length result) 0) result))
 387        (read-from-minibuffer (format "%s: " name))))))
 388
 389 (defun org-bibtex-autokey ()
 390   "Generate an autokey for the current headline."
 391   (org-bibtex-put org-bibtex-key-property
 392                   (if org-bibtex-autogen-keys
 393                       (let* ((entry (org-bibtex-headline))
 394                              (key
 395                               (with-temp-buffer
 396                                 (insert entry)
 397                                 (bibtex-generate-autokey))))
 398                         ;; test for duplicate IDs if using global ID
 399                         (when (and
 400                                (equal org-bibtex-key-property "ID")
 401                                (featurep 'org-id)
 402                                (hash-table-p org-id-locations)
 403                                (gethash key org-id-locations))
 404                           (warn "Another entry has the same ID"))
 405                         key)
 406                     (read-from-minibuffer "id: "))))
 407
 408 (defun org-bibtex-fleshout (type &optional optional)
 409   "Fleshout current heading, ensuring all required fields are present.
 410 With optional argument OPTIONAL, also prompt for optional fields."
 411   (let ((val (lambda (key lst) (cdr (assoc key lst))))
 412         (keyword (lambda (name) (intern (concat ":" (downcase name)))))
 413         (name (lambda (keyword) (substring (symbol-name keyword) 1))))
 414     (dolist (field (append
 415                     (if org-bibtex-treat-headline-as-title
 416                         (remove :title (funcall val :required (funcall val type org-bibtex-types)))
 417                       (funcall val :required (funcall val type org-bibtex-types)))
 418                     (when optional (funcall val :optional (funcall val type org-bibtex-types)))))
 419       (when (consp field) ; or'd pair of fields e.g., (:editor :author)
 420         (let ((present (first (remove
 421                                nil
 422                                (mapcar
 423                                 (lambda (f) (when (org-bibtex-get (funcall name f)) f))
 424                                 field)))))
 425           (setf field (or present (funcall keyword
 426                                            (org-icompleting-read
 427                                             "Field: " (mapcar name field)))))))
 428       (let ((name (funcall name field)))
 429         (unless (org-bibtex-get name)
 430           (let ((prop (org-bibtex-ask field)))
 431             (when prop (org-bibtex-put name prop)))))))
 432   (when (and type (assoc type org-bibtex-types)
 433              (not (org-bibtex-get org-bibtex-key-property)))
 434     (org-bibtex-autokey)))
 435
 436 \f
 437 ;;; Bibtex link functions
 438 (org-add-link-type "bibtex" 'org-bibtex-open)
 439 (add-hook 'org-store-link-functions 'org-bibtex-store-link)
 440
 441 (defun org-bibtex-open (path)
 442   "Visit the bibliography entry on PATH."
 443   (let* ((search (when (string-match "::\\(.+\\)\\'" path)
 444                    (match-string 1 path)))
 445          (path (substring path 0 (match-beginning 0))))
 446     (org-open-file path t nil search)))
 447
 448 (defun org-bibtex-store-link ()
 449   "Store a link to a BibTeX entry."
 450   (when (eq major-mode 'bibtex-mode)
 451     (let* ((search (org-create-file-search-in-bibtex))
 452            (link (concat "file:" (abbreviate-file-name buffer-file-name)
 453                          "::" search))
 454            (entry (mapcar ; repair strings enclosed in "..." or {...}
 455                    (lambda(c)
 456                      (if (string-match
 457                           "^\\(?:{\\|\"\\)\\(.*\\)\\(?:}\\|\"\\)$" (cdr c))
 458                          (cons (car c) (match-string 1 (cdr c))) c))
 459                    (save-excursion
 460                      (bibtex-beginning-of-entry)
 461                      (bibtex-parse-entry)))))
 462       (org-store-link-props
 463        :key (cdr (assoc "=key=" entry))
 464        :author (or (cdr (assoc "author" entry)) "[no author]")
 465        :editor (or (cdr (assoc "editor" entry)) "[no editor]")
 466        :title (or (cdr (assoc "title" entry)) "[no title]")
 467        :booktitle (or (cdr (assoc "booktitle" entry)) "[no booktitle]")
 468        :journal (or (cdr (assoc "journal" entry)) "[no journal]")
 469        :publisher (or (cdr (assoc "publisher" entry)) "[no publisher]")
 470        :pages (or (cdr (assoc "pages" entry)) "[no pages]")
 471        :url (or (cdr (assoc "url" entry)) "[no url]")
 472        :year (or (cdr (assoc "year" entry)) "[no year]")
 473        :month (or (cdr (assoc "month" entry)) "[no month]")
 474        :address (or (cdr (assoc "address" entry)) "[no address]")
 475        :volume (or (cdr (assoc "volume" entry)) "[no volume]")
 476        :number (or (cdr (assoc "number" entry)) "[no number]")
 477        :annote (or (cdr (assoc "annote" entry)) "[no annotation]")
 478        :series (or (cdr (assoc "series" entry)) "[no series]")
 479        :abstract (or (cdr (assoc "abstract" entry)) "[no abstract]")
 480        :btype (or (cdr (assoc "=type=" entry)) "[no type]")
 481        :type "bibtex"
 482        :link link
 483        :description org-bibtex-description))))
 484
 485 (defun org-create-file-search-in-bibtex ()
 486   "Create the search string and description for a BibTeX database entry."
 487   ;; Make a good description for this entry, using names, year and the title
 488   ;; Put it into the `description' variable which is dynamically scoped.
 489   (let ((bibtex-autokey-names 1)
 490         (bibtex-autokey-names-stretch 1)
 491         (bibtex-autokey-name-case-convert-function 'identity)
 492         (bibtex-autokey-name-separator " & ")
 493         (bibtex-autokey-additional-names " et al.")
 494         (bibtex-autokey-year-length 4)
 495         (bibtex-autokey-name-year-separator " ")
 496         (bibtex-autokey-titlewords 3)
 497         (bibtex-autokey-titleword-separator " ")
 498         (bibtex-autokey-titleword-case-convert-function 'identity)
 499         (bibtex-autokey-titleword-length 'infty)
 500         (bibtex-autokey-year-title-separator ": "))
 501     (setq org-bibtex-description (bibtex-generate-autokey)))
 502   ;; Now parse the entry, get the key and return it.
 503   (save-excursion
 504     (bibtex-beginning-of-entry)
 505     (cdr (assoc "=key=" (bibtex-parse-entry)))))
 506
 507 (defun org-execute-file-search-in-bibtex (s)
 508   "Find the link search string S as a key for a database entry."
 509   (when (eq major-mode 'bibtex-mode)
 510     ;; Yes, we want to do the search in this file.
 511     ;; We construct a regexp that searches for "@entrytype{" followed by the key
 512     (goto-char (point-min))
 513     (and (re-search-forward (concat "@[a-zA-Z]+[ \t\n]*{[ \t\n]*"
 514                                     (regexp-quote s) "[ \t\n]*,") nil t)
 515          (goto-char (match-beginning 0)))
 516     (if (and (match-beginning 0) (equal current-prefix-arg '(16)))
 517         ;; Use double prefix to indicate that any web link should be browsed
 518         (let ((b (current-buffer)) (p (point)))
 519           ;; Restore the window configuration because we just use the web link
 520           (set-window-configuration org-window-config-before-follow-link)
 521           (with-current-buffer b
 522             (goto-char p)
 523             (bibtex-url)))
 524       (recenter 0))  ; Move entry start to beginning of window
 525     ;; return t to indicate that the search is done.
 526     t))
 527
 528 ;; Finally add the link search function to the right hook.
 529 (add-hook 'org-execute-file-search-functions 'org-execute-file-search-in-bibtex)
 530
 531 \f
 532 ;;; Bibtex <-> Org-mode headline translation functions
 533 (defun org-bibtex (&optional filename)
 534   "Export each headline in the current file to a bibtex entry.
 535 Headlines are exported using `org-bibtex-export-headline'."
 536   (interactive
 537    (list (read-file-name
 538           "Bibtex file: " nil nil nil
 539           (file-name-nondirectory
 540            (concat (file-name-sans-extension (buffer-file-name)) ".bib")))))
 541   ((lambda (error-point)
 542      (when error-point
 543        (goto-char error-point)
 544        (message "Bibtex error at %S" (nth 4 (org-heading-components)))))
 545    (catch 'bib
 546      (let ((bibtex-entries (remove nil (org-map-entries
 547                                         (lambda ()
 548                                           (condition-case foo
 549                                               (org-bibtex-headline)
 550                                             (error (throw 'bib (point)))))))))
 551        (with-temp-file filename
 552          (insert (mapconcat #'identity bibtex-entries "\n")))
 553        (message "Successfully exported %d BibTeX entries to %s"
 554                 (length bibtex-entries) filename) nil))))
 555
 556 (defun org-bibtex-check (&optional optional)
 557   "Check the current headline for required fields.
 558 With prefix argument OPTIONAL also prompt for optional fields."
 559   (interactive "P")
 560   (save-restriction
 561     (org-narrow-to-subtree)
 562     (let ((type ((lambda (name) (when name (intern (concat ":" name))))
 563                  (org-bibtex-get org-bibtex-type-property-name))))
 564       (when type (org-bibtex-fleshout type optional)))))
 565
 566 (defun org-bibtex-check-all (&optional optional)
 567   "Check all headlines in the current file.
 568 With prefix argument OPTIONAL also prompt for optional fields."
 569   (interactive) (org-map-entries (lambda () (org-bibtex-check optional))))
 570
 571 (defun org-bibtex-create (&optional arg nonew)
 572   "Create a new entry at the given level.
 573 With a prefix arg, query for optional fields as well.
 574 If nonew is t, add data to the headline of the entry at point."
 575   (interactive "P")
 576   (let* ((type (org-icompleting-read
 577                 "Type: " (mapcar (lambda (type)
 578                                    (substring (symbol-name (car type)) 1))
 579                                  org-bibtex-types)
 580                 nil nil (when nonew
 581                           (org-bibtex-get org-bibtex-type-property-name))))
 582          (type (if (keywordp type) type (intern (concat ":" type))))
 583          (org-bibtex-treat-headline-as-title (if nonew nil t)))
 584     (unless (assoc type org-bibtex-types)
 585       (error "Type:%s is not known" type))
 586     (if nonew
 587         (org-back-to-heading)
 588       (org-insert-heading)
 589       (let ((title (org-bibtex-ask :title)))
 590         (insert title)
 591         (org-bibtex-put "TITLE" title)))
 592     (org-bibtex-put org-bibtex-type-property-name
 593                     (substring (symbol-name type) 1))
 594     (org-bibtex-fleshout type arg)
 595     (mapc (lambda (tag) (org-toggle-tag tag 'on)) org-bibtex-tags)))
 596
 597 (defun org-bibtex-create-in-current-entry (&optional arg)
 598   "Add bibliographical data to the current entry.
 599 With a prefix arg, query for optional fields."
 600   (interactive "P")
 601   (org-bibtex-create arg t))
 602
 603 (defun org-bibtex-read ()
 604   "Read a bibtex entry and save to `org-bibtex-entries'.
 605 This uses `bibtex-parse-entry'."
 606   (interactive)
 607   (let ((keyword (lambda (str) (intern (concat ":" (downcase str)))))
 608         (clean-space (lambda (str) (replace-regexp-in-string
 609                                     "[[:space:]\n\r]+" " " str)))
 610         (strip-delim
 611          (lambda (str)       ; strip enclosing "..." and {...}
 612            (dolist (pair '((34 . 34) (123 . 125) (123 . 125)))
 613              (when (and (= (aref str 0) (car pair))
 614                         (= (aref str (1- (length str))) (cdr pair)))
 615                (setf str (substring str 1 (1- (length str)))))) str)))
 616     (push (mapcar
 617            (lambda (pair)
 618              (cons (let ((field (funcall keyword (car pair))))
 619                      (case field
 620                        (:=type= :type)
 621                        (:=key= :key)
 622                        (otherwise field)))
 623                    (funcall clean-space (funcall strip-delim (cdr pair)))))
 624            (save-excursion (bibtex-beginning-of-entry) (bibtex-parse-entry)))
 625           org-bibtex-entries)))
 626
 627 (defun org-bibtex-write ()
 628   "Insert a heading built from the first element of `org-bibtex-entries'."
 629   (interactive)
 630   (when (= (length org-bibtex-entries) 0)
 631     (error "No entries in `org-bibtex-entries'"))
 632   (let* ((entry (pop org-bibtex-entries))
 633          (org-special-properties nil) ; avoids errors with `org-entry-put'
 634          (val (lambda (field) (cdr (assoc field entry))))
 635          (togtag (lambda (tag) (org-toggle-tag tag 'on))))
 636     (org-insert-heading)
 637     (insert (funcall val :title))
 638     (org-bibtex-put "TITLE" (funcall val :title))
 639     (org-bibtex-put org-bibtex-type-property-name
 640                     (downcase (funcall val :type)))
 641     (dolist (pair entry)
 642       (case (car pair)
 643         (:title    nil)
 644         (:type     nil)
 645         (:key      (org-bibtex-put org-bibtex-key-property (cdr pair)))
 646         (:keywords (if org-bibtex-tags-are-keywords
 647                        (mapc
 648                         (lambda (kw)
 649                           (funcall
 650                            togtag
 651                            (replace-regexp-in-string
 652                             "[^[:alnum:]_@#%]" ""
 653                             (replace-regexp-in-string "[ \t]+" "_" kw))))
 654                         (split-string (cdr pair) ", *"))
 655                      (org-bibtex-put (car pair) (cdr pair))))
 656         (otherwise (org-bibtex-put (car pair)  (cdr pair)))))
 657     (mapc togtag org-bibtex-tags)))
 658
 659 (defun org-bibtex-yank ()
 660   "If kill ring holds a bibtex entry yank it as an Org-mode headline."
 661   (interactive)
 662   (let (entry)
 663     (with-temp-buffer (yank 1) (setf entry (org-bibtex-read)))
 664     (if entry
 665         (org-bibtex-write)
 666       (error "Yanked text does not appear to contain a BibTeX entry"))))
 667
 668 (defun org-bibtex-export-to-kill-ring ()
 669   "Export current headline to kill ring as bibtex entry."
 670   (interactive)
 671   (let ((result (org-bibtex-headline)))
 672     (kill-new result) result))
 673
 674 (defun org-bibtex-search (string)
 675   "Search for bibliographical entries in agenda files.
 676 This function relies `org-search-view' to locate results."
 677   (interactive "sSearch string: ")
 678   (let ((org-agenda-overriding-header "Bib search results:")
 679         (org-agenda-search-view-always-boolean t))
 680     (org-search-view nil
 681                      (format "%s +{:%s%s:}"
 682                              string (or org-bibtex-prefix "")
 683                              org-bibtex-type-property-name))))
 684
 685 (provide 'org-bibtex)
 686
 687 ;;; org-bibtex.el ends here