lisp/ob-python.el

   1 ;;; ob-python.el --- org-babel functions for python evaluation
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'ob-ref)
  32 (require 'ob-comint)
  33 (require 'ob-eval)
  34 (eval-when-compile (require 'cl))
  35
  36 (declare-function org-remove-indentation "org" )
  37 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  38 (declare-function py-toggle-shells "ext:python-mode" (arg))
  39 (declare-function run-python "ext:python" (&optional cmd noshow new))
  40
  41 (defvar org-babel-tangle-lang-exts)
  42 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  43
  44 (defvar org-babel-default-header-args:python '())
  45
  46 (defvar org-babel-python-command "python"
  47   "Name of the command for executing Python code.")
  48
  49 (defvar org-babel-python-mode (if (featurep 'xemacs) 'python-mode 'python)
  50   "Preferred python mode for use in running python interactively.
  51 This will typically be either 'python or 'python-mode.")
  52
  53 (defvar org-src-preserve-indentation)
  54
  55 (defun org-babel-execute:python (body params)
  56   "Execute a block of Python code with Babel.
  57 This function is called by `org-babel-execute-src-block'."
  58   (let* ((session (org-babel-python-initiate-session
  59                    (cdr (assoc :session params))))
  60          (result-params (cdr (assoc :result-params params)))
  61          (result-type (cdr (assoc :result-type params)))
  62          (return-val (when (and (eq result-type 'value) (not session))
  63                        (cdr (assoc :return params))))
  64          (preamble (cdr (assoc :preamble params)))
  65          (full-body
  66           (org-babel-expand-body:generic
  67            (concat body (if return-val (format "\nreturn %s" return-val) ""))
  68            params (org-babel-variable-assignments:python params)))
  69          (result (org-babel-python-evaluate
  70                   session full-body result-type result-params preamble)))
  71     (org-babel-reassemble-table
  72      result
  73      (org-babel-pick-name (cdr (assoc :colname-names params))
  74                           (cdr (assoc :colnames params)))
  75      (org-babel-pick-name (cdr (assoc :rowname-names params))
  76                           (cdr (assoc :rownames params))))))
  77
  78 (defun org-babel-prep-session:python (session params)
  79   "Prepare SESSION according to the header arguments in PARAMS.
  80 VARS contains resolved variable references"
  81   (let* ((session (org-babel-python-initiate-session session))
  82          (var-lines
  83           (org-babel-variable-assignments:python params)))
  84     (org-babel-comint-in-buffer session
  85       (mapc (lambda (var)
  86               (end-of-line 1) (insert var) (comint-send-input)
  87               (org-babel-comint-wait-for-output session)) var-lines))
  88     session))
  89
  90 (defun org-babel-load-session:python (session body params)
  91   "Load BODY into SESSION."
  92   (save-window-excursion
  93     (let ((buffer (org-babel-prep-session:python session params)))
  94       (with-current-buffer buffer
  95         (goto-char (process-mark (get-buffer-process (current-buffer))))
  96         (insert (org-babel-chomp body)))
  97       buffer)))
  98
  99 ;; helper functions
 100
 101 (defun org-babel-variable-assignments:python (params)
 102   "Return a list of Python statements assigning the block's variables."
 103   (mapcar
 104    (lambda (pair)
 105      (format "%s=%s"
 106              (car pair)
 107              (org-babel-python-var-to-python (cdr pair))))
 108    (mapcar #'cdr (org-babel-get-header params :var))))
 109
 110 (defun org-babel-python-var-to-python (var)
 111   "Convert an elisp value to a python variable.
 112 Convert an elisp value, VAR, into a string of python source code
 113 specifying a variable of the same value."
 114   (if (listp var)
 115       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 116     (if (equal var 'hline)
 117         "None"
 118       (format
 119        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 120        var))))
 121
 122 (defun org-babel-python-table-or-string (results)
 123   "Convert RESULTS into an appropriate elisp value.
 124 If the results look like a list or tuple, then convert them into an
 125 Emacs-lisp table, otherwise return the results as a string."
 126   (org-babel-script-escape results))
 127
 128 (defvar org-babel-python-buffers '((:default . nil)))
 129
 130 (defun org-babel-python-session-buffer (session)
 131   "Return the buffer associated with SESSION."
 132   (cdr (assoc session org-babel-python-buffers)))
 133
 134 (defvar py-default-interpreter)
 135 (defun org-babel-python-initiate-session-by-key (&optional session)
 136   "Initiate a python session.
 137 If there is not a current inferior-process-buffer in SESSION
 138 then create.  Return the initialized session."
 139   (require org-babel-python-mode)
 140   (save-window-excursion
 141     (let* ((session (if session (intern session) :default))
 142            (python-buffer (org-babel-python-session-buffer session)))
 143       (cond
 144        ((and (eq 'python org-babel-python-mode)
 145              (fboundp 'run-python)) ; python.el
 146         (if (version< "24.1" emacs-version)
 147             (run-python org-babel-python-command)
 148           (run-python)))
 149        ((and (eq 'python-mode org-babel-python-mode)
 150              (fboundp 'py-shell)) ; python-mode.el
 151         ;; Make sure that py-which-bufname is initialized, as otherwise
 152         ;; it will be overwritten the first time a Python buffer is
 153         ;; created.
 154         (py-toggle-shells py-default-interpreter)
 155         ;; `py-shell' creates a buffer whose name is the value of
 156         ;; `py-which-bufname' with '*'s at the beginning and end
 157         (let* ((bufname (if (and python-buffer (buffer-live-p python-buffer))
 158                             (replace-regexp-in-string ;; zap surrounding *
 159                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 160                           (concat "Python-" (symbol-name session))))
 161                (py-which-bufname bufname))
 162           (py-shell)
 163           (setq python-buffer (concat "*" bufname "*"))))
 164        (t
 165         (error "No function available for running an inferior Python")))
 166       (setq org-babel-python-buffers
 167             (cons (cons session python-buffer)
 168                   (assq-delete-all session org-babel-python-buffers)))
 169       session)))
 170
 171 (defun org-babel-python-initiate-session (&optional session params)
 172   "Create a session named SESSION according to PARAMS."
 173   (unless (string= session "none")
 174     (org-babel-python-session-buffer
 175      (org-babel-python-initiate-session-by-key session))))
 176
 177 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 178   "A string to indicate that evaluation has completed.")
 179 (defvar org-babel-python-wrapper-method
 180   "
 181 def main():
 182 %s
 183
 184 open('%s', 'w').write( str(main()) )")
 185 (defvar org-babel-python-pp-wrapper-method
 186   "
 187 import pprint
 188 def main():
 189 %s
 190
 191 open('%s', 'w').write( pprint.pformat(main()) )")
 192
 193 (defun org-babel-python-evaluate
 194   (session body &optional result-type result-params preamble)
 195   "Evaluate BODY as Python code."
 196   (if session
 197       (org-babel-python-evaluate-session
 198        session body result-type result-params)
 199     (org-babel-python-evaluate-external-process
 200      body result-type result-params preamble)))
 201
 202 (defun org-babel-python-evaluate-external-process
 203   (body &optional result-type result-params preamble)
 204   "Evaluate BODY in external python process.
 205 If RESULT-TYPE equals 'output then return standard output as a
 206 string.  If RESULT-TYPE equals 'value then return the value of the
 207 last statement in BODY, as elisp."
 208   ((lambda (raw)
 209      (if (or (member "code" result-params)
 210              (member "pp" result-params)
 211              (and (member "output" result-params)
 212                   (not (member "table" result-params))))
 213          raw
 214        (org-babel-python-table-or-string (org-babel-trim raw))))
 215    (case result-type
 216      (output (org-babel-eval org-babel-python-command
 217                              (concat (if preamble (concat preamble "\n") "")
 218                                      body)))
 219      (value (let ((tmp-file (org-babel-temp-file "python-")))
 220               (org-babel-eval
 221                org-babel-python-command
 222                (concat
 223                 (if preamble (concat preamble "\n") "")
 224                 (format
 225                  (if (member "pp" result-params)
 226                      org-babel-python-pp-wrapper-method
 227                    org-babel-python-wrapper-method)
 228                  (mapconcat
 229                   (lambda (line) (format "\t%s" line))
 230                   (split-string
 231                    (org-remove-indentation
 232                     (org-babel-trim body))
 233                    "[\r\n]") "\n")
 234                  (org-babel-process-file-name tmp-file 'noquote))))
 235               (org-babel-eval-read-file tmp-file))))))
 236
 237 (defun org-babel-python-evaluate-session
 238   (session body &optional result-type result-params)
 239   "Pass BODY to the Python process in SESSION.
 240 If RESULT-TYPE equals 'output then return standard output as a
 241 string.  If RESULT-TYPE equals 'value then return the value of the
 242 last statement in BODY, as elisp."
 243   (let* ((send-wait (lambda () (comint-send-input nil t) (sleep-for 0 5)))
 244          (dump-last-value
 245           (lambda
 246             (tmp-file pp)
 247             (mapc
 248              (lambda (statement) (insert statement) (funcall send-wait))
 249              (if pp
 250                  (list
 251                   "import pprint"
 252                   (format "open('%s', 'w').write(pprint.pformat(_))"
 253                           (org-babel-process-file-name tmp-file 'noquote)))
 254                (list (format "open('%s', 'w').write(str(_))"
 255                              (org-babel-process-file-name tmp-file 'noquote)))))))
 256          (input-body (lambda (body)
 257                        (mapc (lambda (line) (insert line) (funcall send-wait))
 258                              (split-string body "[\r\n]"))
 259                        (funcall send-wait))))
 260     ((lambda (results)
 261        (unless (string= (substring org-babel-python-eoe-indicator 1 -1) results)
 262          (if (or (member "code" result-params)
 263                  (member "pp" result-params)
 264                  (and (member "output" result-params)
 265                       (not (member "table" result-params))))
 266              results
 267            (org-babel-python-table-or-string results))))
 268      (case result-type
 269        (output
 270         (mapconcat
 271          #'org-babel-trim
 272          (butlast
 273           (org-babel-comint-with-output
 274               (session org-babel-python-eoe-indicator t body)
 275             (funcall input-body body)
 276             (funcall send-wait) (funcall send-wait)
 277             (insert org-babel-python-eoe-indicator)
 278             (funcall send-wait))
 279           2) "\n"))
 280        (value
 281         (let ((tmp-file (org-babel-temp-file "python-")))
 282           (org-babel-comint-with-output
 283               (session org-babel-python-eoe-indicator nil body)
 284             (let ((comint-process-echoes nil))
 285               (funcall input-body body)
 286               (funcall dump-last-value tmp-file (member "pp" result-params))
 287               (funcall send-wait) (funcall send-wait)
 288               (insert org-babel-python-eoe-indicator)
 289               (funcall send-wait)))
 290           (org-babel-eval-read-file tmp-file)))))))
 291
 292 (defun org-babel-python-read-string (string)
 293   "Strip 's from around Python string."
 294   (if (string-match "^'\\([^\000]+\\)'$" string)
 295       (match-string 1 string)
 296     string))
 297
 298 (provide 'ob-python)
 299
 300
 301
 302 ;;; ob-python.el ends here