lisp/org-clock.el

   1 ;;; org-clock.el --- The time clocking code for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.23a
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the time clocking code for Org-mode
  30
  31 (require 'org)
  32 (eval-when-compile
  33   (require 'cl)
  34   (require 'calendar))
  35
  36 (declare-function calendar-absolute-from-iso    "cal-iso"    (&optional date))
  37 (defvar org-time-stamp-formats)
  38
  39 (defgroup org-clock nil
  40   "Options concerning clocking working time in Org-mode."
  41   :tag "Org Clock"
  42   :group 'org-progress)
  43
  44 (defcustom org-clock-into-drawer org-log-into-drawer
  45   "Should clocking info be wrapped into a drawer?
  46 When t, clocking info will always be inserted into a :LOGBOOK: drawer.
  47 If necessary, the drawer will be created.
  48 When nil, the drawer will not be created, but used when present.
  49 When an integer and the number of clocking entries in an item
  50 reaches or exceeds this number, a drawer will be created.
  51 When a string, it names the drawer to be used.
  52
  53 The default for this variable is the value of `org-log-into-drawer',
  54 which see."
  55   :group 'org-todo
  56   :group 'org-clock
  57   :type '(choice
  58           (const :tag "Always" t)
  59           (const :tag "Only when drawer exists" nil)
  60           (integer :tag "When at least N clock entries")
  61           (const :tag "Into LOGBOOK drawer" "LOGBOOK")
  62           (string :tag "Into Drawer named...")))
  63
  64 (defcustom org-clock-out-when-done t
  65   "When non-nil, the clock will be stopped when the relevant entry is marked DONE.
  66 A nil value means, clock will keep running until stopped explicitly with
  67 `C-c C-x C-o', or until the clock is started in a different item."
  68   :group 'org-clock
  69   :type 'boolean)
  70
  71 (defcustom org-clock-out-remove-zero-time-clocks nil
  72   "Non-nil means, remove the clock line when the resulting time is zero."
  73   :group 'org-clock
  74   :type 'boolean)
  75
  76 (defcustom org-clock-in-switch-to-state nil
  77   "Set task to a special todo state while clocking it.
  78 The value should be the state to which the entry should be
  79 switched. If the value is a function, it must take one
  80 parameter (the current TODO state of the item) and return the
  81 state to switch it to."
  82   :group 'org-clock
  83   :group 'org-todo
  84   :type '(choice
  85           (const :tag "Don't force a state" nil)
  86           (string :tag "State")
  87           (symbol :tag "Function")))
  88
  89 (defcustom org-clock-history-length 5
  90   "Number of clock tasks to remember in history."
  91   :group 'org-clock
  92   :type 'integer)
  93
  94 (defcustom org-clock-heading-function nil
  95   "When non-nil, should be a function to create `org-clock-heading'.
  96 This is the string shown in the mode line when a clock is running.
  97 The function is called with point at the beginning of the headline."
  98   :group 'org-clock
  99   :type 'function)
 100
 101 (defcustom org-clock-string-limit 0
 102   "Maximum length of clock strings in the modeline. 0 means no limit"
 103   :group 'org-clock
 104   :type 'integer)
 105
 106 (defcustom org-clock-in-resume nil
 107   "If non-nil, when clocking into a task with a clock entry which
 108 has not been closed, resume the clock from that point"
 109   :group 'org-clock
 110   :type 'boolean)
 111
 112 (defcustom org-clock-persist nil
 113   "When non-nil, save the running clock when emacs is closed, and
 114   resume it next time emacs is started.
 115 When this is t, both the running clock, and the entire clock
 116 history are saved.  When this is the symbol `clock', only the
 117 running clock is saved.
 118
 119 When Emacs restarts with saved clock information, the file containing the
 120 running clock as well as all files mentioned in the clock history will
 121 be visited."
 122   :group 'org-clock
 123   :type '(choice
 124           (const :tag "Just the running clock" clock)
 125           (const :tag "Clock and history" t)
 126           (const :tag "No persistence" nil)))
 127
 128 (defcustom org-clock-persist-file (convert-standard-filename
 129                                    "~/.emacs.d/org-clock-save.el")
 130   "File to save clock data to"
 131   :group 'org-clock
 132   :type 'string)
 133
 134 (defcustom org-clock-persist-query-save nil
 135   "When non-nil, ask before saving the current clock on exit"
 136   :group 'org-clock
 137   :type 'boolean)
 138
 139 (defcustom org-clock-persist-query-resume t
 140   "When non-nil, ask before resuming any stored clock during
 141 load."
 142   :group 'org-clock
 143   :type 'boolean)
 144
 145 ;;; The clock for measuring work time.
 146
 147 (defvar org-mode-line-string "")
 148 (put 'org-mode-line-string 'risky-local-variable t)
 149
 150 (defvar org-clock-mode-line-timer nil)
 151 (defvar org-clock-heading "")
 152 (defvar org-clock-heading-for-remember "")
 153 (defvar org-clock-start-time "")
 154
 155 (defvar org-clock-history nil
 156   "List of marker pointing to recent clocked tasks.")
 157
 158 (defvar org-clock-default-task (make-marker)
 159   "Marker pointing to the default task that should clock time.
 160 The clock can be made to switch to this task after clocking out
 161 of a different task.")
 162
 163 (defvar org-clock-interrupted-task (make-marker)
 164   "Marker pointing to the task that has been interrupted by the current clock.")
 165
 166 (defvar org-clock-mode-line-map (make-sparse-keymap))
 167 (define-key org-clock-mode-line-map [mode-line mouse-2] 'org-clock-goto)
 168
 169 (defun org-clock-history-push (&optional pos buffer)
 170   "Push a marker to the clock history."
 171   (setq org-clock-history-length (max 1 (min 35 org-clock-history-length)))
 172   (let ((m (move-marker (make-marker) (or pos (point)) buffer)) n l)
 173     (while (setq n (member m org-clock-history))
 174       (move-marker (car n) nil))
 175     (setq org-clock-history
 176           (delq nil
 177                 (mapcar (lambda (x) (if (marker-buffer x) x nil))
 178                         org-clock-history)))
 179     (when (>= (setq l (length org-clock-history)) org-clock-history-length)
 180       (setq org-clock-history
 181             (nreverse
 182              (nthcdr (- l org-clock-history-length -1)
 183                      (nreverse org-clock-history)))))
 184     (push m org-clock-history)))
 185
 186 (defun org-clock-save-markers-for-cut-and-paste (beg end)
 187   "Save relative positions of markers in region."
 188   (org-check-and-save-marker org-clock-marker beg end)
 189   (org-check-and-save-marker org-clock-default-task beg end)
 190   (org-check-and-save-marker org-clock-interrupted-task beg end)
 191   (mapc (lambda (m) (org-check-and-save-marker m beg end))
 192         org-clock-history))
 193
 194 (defun org-clock-select-task (&optional prompt)
 195   "Select a task that recently was associated with clocking."
 196   (interactive)
 197   (let (sel-list rpl (i 0) s)
 198     (save-window-excursion
 199       (org-switch-to-buffer-other-window
 200        (get-buffer-create "*Clock Task Select*"))
 201       (erase-buffer)
 202       (when (marker-buffer org-clock-default-task)
 203         (insert (org-add-props "Default Task\n" nil 'face 'bold))
 204         (setq s (org-clock-insert-selection-line ?d org-clock-default-task))
 205         (push s sel-list))
 206       (when (marker-buffer org-clock-interrupted-task)
 207         (insert (org-add-props "The task interrupted by starting the last one\n" nil 'face 'bold))
 208         (setq s (org-clock-insert-selection-line ?i org-clock-interrupted-task))
 209         (push s sel-list))
 210       (when (marker-buffer org-clock-marker)
 211         (insert (org-add-props "Current Clocking Task\n" nil 'face 'bold))
 212         (setq s (org-clock-insert-selection-line ?c org-clock-marker))
 213         (push s sel-list))
 214       (insert (org-add-props "Recent Tasks\n" nil 'face 'bold))
 215       (mapc
 216        (lambda (m)
 217          (when (marker-buffer m)
 218            (setq i (1+ i)
 219                  s (org-clock-insert-selection-line
 220                     (if (< i 10)
 221                         (+ i ?0)
 222                       (+ i (- ?A 10))) m))
 223            (push s sel-list)))
 224        org-clock-history)
 225       (org-fit-window-to-buffer)
 226       (message (or prompt "Select task for clocking:"))
 227       (setq rpl (read-char-exclusive))
 228       (cond
 229        ((eq rpl ?q) nil)
 230        ((eq rpl ?x) nil)
 231        ((assoc rpl sel-list) (cdr (assoc rpl sel-list)))
 232        (t (error "Invalid task choice %c" rpl))))))
 233
 234 (defun org-clock-insert-selection-line (i marker)
 235   (when (marker-buffer marker)
 236     (let (file cat task)
 237       (with-current-buffer (org-base-buffer (marker-buffer marker))
 238         (save-excursion
 239           (save-restriction
 240             (widen)
 241             (goto-char marker)
 242             (setq file (buffer-file-name (marker-buffer marker))
 243                   cat (or (org-get-category)
 244                           (progn (org-refresh-category-properties)
 245                                  (org-get-category)))
 246                   task (org-get-heading 'notags)))))
 247       (when (and cat task)
 248         (insert (format "[%c] %-15s %s\n" i cat task))
 249         (cons i marker)))))
 250
 251 (defun org-clock-update-mode-line ()
 252   (let* ((delta (- (time-to-seconds (current-time))
 253                    (time-to-seconds org-clock-start-time)))
 254          (h (floor delta 3600))
 255          (m (floor (- delta (* 3600 h)) 60)))
 256     (setq org-mode-line-string
 257           (org-propertize
 258            (let ((clock-string (format (concat "-[" org-time-clocksum-format " (%s)]")
 259                                        h m org-clock-heading))
 260                  (help-text "Org-mode clock is running. Mouse-2 to go there."))
 261              (if (and (> org-clock-string-limit 0)
 262                       (> (length clock-string) org-clock-string-limit))
 263                  (org-propertize (substring clock-string 0 org-clock-string-limit)
 264                              'help-echo (concat help-text ": " org-clock-heading))
 265                (org-propertize clock-string 'help-echo help-text)))
 266            'local-map org-clock-mode-line-map
 267            'mouse-face (if (featurep 'xemacs) 'highlight 'mode-line-highlight)))
 268     (force-mode-line-update)))
 269
 270 (defvar org-clock-mode-line-entry nil
 271   "Information for the modeline about the running clock.")
 272
 273 (defun org-clock-in (&optional select)
 274   "Start the clock on the current item.
 275 If necessary, clock-out of the currently active clock.
 276 With prefix arg SELECT, offer a list of recently clocked tasks to
 277 clock into.  When SELECT is `C-u C-u', clock into the current task and mark
 278 is as the default task, a special task that will always be offered in
 279 the clocking selection, associated with the letter `d'."
 280   (interactive "P")
 281   (catch 'abort
 282     (let ((interrupting (marker-buffer org-clock-marker))
 283           ts selected-task target-pos)
 284       (when (equal select '(4))
 285         (setq selected-task (org-clock-select-task "Clock-in on task: "))
 286         (if selected-task
 287             (setq selected-task (copy-marker selected-task))
 288           (error "Abort")))
 289       (when interrupting
 290         ;; We are interrupting the clocking of a different task.
 291         ;; Save a marker to this task, so that we can go back.
 292         (move-marker org-clock-interrupted-task
 293                      (marker-position org-clock-marker)
 294                      (marker-buffer org-clock-marker))
 295         (org-clock-out t))
 296
 297       (when (equal select '(16))
 298         ;; Mark as default clocking task
 299         (save-excursion
 300           (org-back-to-heading t)
 301           (move-marker org-clock-default-task (point))))
 302
 303       (setq target-pos (point))  ;; we want to clock in at this location
 304       (save-excursion
 305         (when (and selected-task (marker-buffer selected-task))
 306           ;; There is a selected task, move to the correct buffer
 307           ;; and set the new target position.
 308           (set-buffer (org-base-buffer (marker-buffer selected-task)))
 309           (setq target-pos (marker-position selected-task))
 310           (move-marker selected-task nil))
 311         (save-excursion
 312           (save-restriction
 313             (widen)
 314             (goto-char target-pos)
 315             (org-back-to-heading t)
 316             (or interrupting (move-marker org-clock-interrupted-task nil))
 317             (org-clock-history-push)
 318             (cond ((functionp org-clock-in-switch-to-state)
 319                    (looking-at org-complex-heading-regexp)
 320                    (let ((newstate (funcall org-clock-in-switch-to-state
 321                                             (match-string 2))))
 322                      (if newstate (org-todo newstate))))
 323                   ((and org-clock-in-switch-to-state
 324                         (not (looking-at (concat outline-regexp "[ \t]*"
 325                                                  org-clock-in-switch-to-state
 326                                                  "\\>"))))
 327                    (org-todo org-clock-in-switch-to-state)))
 328             (setq org-clock-heading-for-remember
 329                   (and (looking-at org-complex-heading-regexp)
 330                        (match-end 4)
 331                        (org-trim (buffer-substring (match-end 1)
 332                                                    (match-end 4)))))
 333             (setq org-clock-heading
 334                   (cond ((and org-clock-heading-function
 335                               (functionp org-clock-heading-function))
 336                          (funcall org-clock-heading-function))
 337                         ((looking-at org-complex-heading-regexp)
 338                          (match-string 4))
 339                         (t "???")))
 340             (setq org-clock-heading (org-propertize org-clock-heading
 341                                                     'face nil))
 342             (org-clock-find-position)
 343             (cond
 344              ((and org-clock-in-resume
 345                    (looking-at
 346                     (concat "^[ \\t]* " org-clock-string
 347                             " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 348                             " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")))
 349               (message "Matched %s" (match-string 1))
 350               (setq ts (concat "[" (match-string 1) "]"))
 351               (goto-char (match-end 1))
 352               (setq org-clock-start-time
 353                     (apply 'encode-time
 354                            (org-parse-time-string (match-string 1)))))
 355              ((eq org-clock-in-resume 'auto-restart)
 356               ;; called from org-clock-load during startup,
 357               ;; do not interrupt, but warn!
 358               (message "Cannot restart clock because task does not contain unfinished clock")
 359               (ding)
 360               (sit-for 2)
 361               (throw 'abort nil))
 362              (t
 363               (insert-before-markers "\n")
 364               (backward-char 1)
 365               (org-indent-line-function)
 366               (when (and (save-excursion
 367                            (end-of-line 0)
 368                            (org-in-item-p)))
 369                 (beginning-of-line 1)
 370                 (org-indent-line-to (- (org-get-indentation) 2)))
 371               (insert org-clock-string " ")
 372               (setq org-clock-start-time (current-time))
 373               (setq ts (org-insert-time-stamp org-clock-start-time 'with-hm 'inactive))))
 374             (move-marker org-clock-marker (point) (buffer-base-buffer))
 375             (or global-mode-string (setq global-mode-string '("")))
 376             (or (memq 'org-mode-line-string global-mode-string)
 377                 (setq global-mode-string
 378                       (append global-mode-string '(org-mode-line-string))))
 379             (org-clock-update-mode-line)
 380             (setq org-clock-mode-line-timer
 381                   (run-with-timer 60 60 'org-clock-update-mode-line))
 382             (message "Clock started at %s" ts)))))))
 383
 384 (defun org-clock-find-position ()
 385   "Find the location where the next clock line should be inserted."
 386   (org-back-to-heading t)
 387   (catch 'exit
 388     (let ((beg (save-excursion
 389                  (beginning-of-line 2)
 390                  (or (bolp) (newline))
 391                  (point)))
 392           (end (progn (outline-next-heading) (point)))
 393           (re (concat "^[ \t]*" org-clock-string))
 394           (cnt 0)
 395           (drawer (if (stringp org-clock-into-drawer)
 396                       org-clock-into-drawer "LOGBOOK"))
 397           first last ind-last)
 398       (goto-char beg)
 399       (when (eobp) (newline) (setq end (max (point) end)))
 400       (when (re-search-forward (concat "^[ \t]*:" drawer ":") end t)
 401         ;; we seem to have a CLOCK drawer, so go there.
 402         (beginning-of-line 2)
 403         (or org-log-states-order-reversed
 404             (and (re-search-forward org-property-end-re nil t)
 405                  (goto-char (match-beginning 0))))
 406         (throw 'exit t))
 407       ;; Lets count the CLOCK lines
 408       (goto-char beg)
 409       (while (re-search-forward re end t)
 410         (setq first (or first (match-beginning 0))
 411               last (match-beginning 0)
 412               cnt (1+ cnt)))
 413       (when (and (integerp org-clock-into-drawer)
 414                  last
 415                  (>= (1+ cnt) org-clock-into-drawer))
 416         ;; Wrap current entries into a new drawer
 417         (goto-char last)
 418         (setq ind-last (org-get-indentation))
 419         (beginning-of-line 2)
 420         (if (and (>= (org-get-indentation) ind-last)
 421                  (org-at-item-p))
 422             (org-end-of-item))
 423         (insert ":END:\n")
 424         (beginning-of-line 0)
 425         (org-indent-line-to ind-last)
 426         (goto-char first)
 427         (insert ":" drawer ":\n")
 428         (beginning-of-line 0)
 429         (org-indent-line-function)
 430         (org-flag-drawer t)
 431         (beginning-of-line 2)
 432         (or org-log-states-order-reversed
 433             (and (re-search-forward org-property-end-re nil t)
 434                  (goto-char (match-beginning 0))))
 435         (throw 'exit nil))
 436
 437       (goto-char beg)
 438       (while (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 439                   (not (equal (match-string 1) org-clock-string)))
 440         ;; Planning info, skip to after it
 441         (beginning-of-line 2)
 442         (or (bolp) (newline)))
 443       (when (or (eq org-clock-into-drawer t)
 444                 (stringp org-clock-into-drawer)
 445                 (and (integerp org-clock-into-drawer)
 446                      (< org-clock-into-drawer 2)))
 447         (insert ":" drawer ":\n:END:\n")
 448         (beginning-of-line 0)
 449         (org-indent-line-function)
 450         (beginning-of-line 0)
 451         (org-flag-drawer t)
 452         (org-indent-line-function)
 453         (beginning-of-line 2)
 454         (or org-log-states-order-reversed
 455             (and (re-search-forward org-property-end-re nil t)
 456                  (goto-char (match-beginning 0))))))))
 457
 458 (defun org-clock-out (&optional fail-quietly)
 459   "Stop the currently running clock.
 460 If there is no running clock, throw an error, unless FAIL-QUIETLY is set."
 461   (interactive)
 462   (catch 'exit
 463   (if (not (marker-buffer org-clock-marker))
 464       (if fail-quietly (throw 'exit t) (error "No active clock")))
 465   (let (ts te s h m remove)
 466     (save-excursion
 467       (set-buffer (marker-buffer org-clock-marker))
 468       (save-restriction
 469         (widen)
 470         (goto-char org-clock-marker)
 471         (beginning-of-line 1)
 472         (if (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 473                  (equal (match-string 1) org-clock-string))
 474             (setq ts (match-string 2))
 475           (if fail-quietly (throw 'exit nil) (error "Clock start time is gone")))
 476         (goto-char (match-end 0))
 477         (delete-region (point) (point-at-eol))
 478         (insert "--")
 479         (setq te (org-insert-time-stamp (current-time) 'with-hm 'inactive))
 480         (setq s (- (time-to-seconds (apply 'encode-time (org-parse-time-string te)))
 481                    (time-to-seconds (apply 'encode-time (org-parse-time-string ts))))
 482               h (floor (/ s 3600))
 483               s (- s (* 3600 h))
 484               m (floor (/ s 60))
 485               s (- s (* 60 s)))
 486         (insert " => " (format "%2d:%02d" h m))
 487         (when (setq remove (and org-clock-out-remove-zero-time-clocks
 488                                 (= (+ h m) 0)))
 489           (beginning-of-line 1)
 490           (delete-region (point) (point-at-eol))
 491           (and (looking-at "\n") (> (point-max) (1+ (point)))
 492                (delete-char 1)))
 493         (move-marker org-clock-marker nil)
 494         (when org-log-note-clock-out
 495           (org-add-log-setup 'clock-out nil nil nil nil
 496                              (concat "# Task: " (org-get-heading t) "\n\n")))
 497         (when org-clock-mode-line-timer
 498           (cancel-timer org-clock-mode-line-timer)
 499           (setq org-clock-mode-line-timer nil))
 500         (setq global-mode-string
 501               (delq 'org-mode-line-string global-mode-string))
 502         (force-mode-line-update)
 503         (message (concat "Clock stopped at %s after HH:MM = " org-time-clocksum-format "%s") te h m
 504                  (if remove " => LINE REMOVED" "")))))))
 505
 506 (defun org-clock-cancel ()
 507   "Cancel the running clock be removing the start timestamp."
 508   (interactive)
 509   (if (not (marker-buffer org-clock-marker))
 510       (error "No active clock"))
 511   (save-excursion
 512     (set-buffer (marker-buffer org-clock-marker))
 513     (goto-char org-clock-marker)
 514     (delete-region (1- (point-at-bol)) (point-at-eol)))
 515   (setq global-mode-string
 516         (delq 'org-mode-line-string global-mode-string))
 517   (force-mode-line-update)
 518   (message "Clock canceled"))
 519
 520 (defun org-clock-goto (&optional select)
 521   "Go to the currently clocked-in entry.
 522 With prefix arg SELECT, offer recently clocked tasks."
 523   (interactive "P")
 524   (let ((m (if select
 525                (org-clock-select-task "Select task to go to: ")
 526              org-clock-marker)))
 527     (if (not (marker-buffer m))
 528         (if select
 529             (error "No task selected")
 530           (error "No active clock")))
 531     (switch-to-buffer (marker-buffer m))
 532     (if (or (< m (point-min)) (> m (point-max))) (widen))
 533     (goto-char m)
 534     (org-show-entry)
 535     (org-back-to-heading)
 536     (org-cycle-hide-drawers 'children)
 537     (recenter)))
 538
 539 (defvar org-clock-file-total-minutes nil
 540   "Holds the file total time in minutes, after a call to `org-clock-sum'.")
 541   (make-variable-buffer-local 'org-clock-file-total-minutes)
 542
 543 (defun org-clock-sum (&optional tstart tend)
 544   "Sum the times for each subtree.
 545 Puts the resulting times in minutes as a text property on each headline."
 546   (interactive)
 547   (let* ((bmp (buffer-modified-p))
 548          (re (concat "^\\(\\*+\\)[ \t]\\|^[ \t]*"
 549                      org-clock-string
 550                      "[ \t]*\\(?:\\(\\[.*?\\]\\)-+\\(\\[.*?\\]\\)\\|=>[ \t]+\\([0-9]+\\):\\([0-9]+\\)\\)"))
 551          (lmax 30)
 552          (ltimes (make-vector lmax 0))
 553          (t1 0)
 554          (level 0)
 555          ts te dt
 556          time)
 557     (remove-text-properties (point-min) (point-max) '(:org-clock-minutes t))
 558     (save-excursion
 559       (goto-char (point-max))
 560       (while (re-search-backward re nil t)
 561         (cond
 562          ((match-end 2)
 563           ;; Two time stamps
 564           (setq ts (match-string 2)
 565                 te (match-string 3)
 566                 ts (time-to-seconds
 567                     (apply 'encode-time (org-parse-time-string ts)))
 568                 te (time-to-seconds
 569                     (apply 'encode-time (org-parse-time-string te)))
 570                 ts (if tstart (max ts tstart) ts)
 571                 te (if tend (min te tend) te)
 572                 dt (- te ts)
 573                 t1 (if (> dt 0) (+ t1 (floor (/ dt 60))) t1)))
 574          ((match-end 4)
 575           ;; A naked time
 576           (setq t1 (+ t1 (string-to-number (match-string 5))
 577                       (* 60 (string-to-number (match-string 4))))))
 578          (t ;; A headline
 579           (setq level (- (match-end 1) (match-beginning 1)))
 580           (when (or (> t1 0) (> (aref ltimes level) 0))
 581             (loop for l from 0 to level do
 582                   (aset ltimes l (+ (aref ltimes l) t1)))
 583             (setq t1 0 time (aref ltimes level))
 584             (loop for l from level to (1- lmax) do
 585                   (aset ltimes l 0))
 586             (goto-char (match-beginning 0))
 587             (put-text-property (point) (point-at-eol) :org-clock-minutes time)))))
 588       (setq org-clock-file-total-minutes (aref ltimes 0)))
 589     (set-buffer-modified-p bmp)))
 590
 591 (defun org-clock-display (&optional total-only)
 592   "Show subtree times in the entire buffer.
 593 If TOTAL-ONLY is non-nil, only show the total time for the entire file
 594 in the echo area."
 595   (interactive)
 596   (org-clock-remove-overlays)
 597   (let (time h m p)
 598     (org-clock-sum)
 599     (unless total-only
 600       (save-excursion
 601         (goto-char (point-min))
 602         (while (or (and (equal (setq p (point)) (point-min))
 603                         (get-text-property p :org-clock-minutes))
 604                    (setq p (next-single-property-change
 605                             (point) :org-clock-minutes)))
 606           (goto-char p)
 607           (when (setq time (get-text-property p :org-clock-minutes))
 608             (org-clock-put-overlay time (funcall outline-level))))
 609         (setq h (/ org-clock-file-total-minutes 60)
 610               m (- org-clock-file-total-minutes (* 60 h)))
 611         ;; Arrange to remove the overlays upon next change.
 612         (when org-remove-highlights-with-change
 613           (org-add-hook 'before-change-functions 'org-clock-remove-overlays
 614                         nil 'local))))
 615     (message (concat "Total file time: " org-time-clocksum-format " (%d hours and %d minutes)") h m h m)))
 616
 617 (defvar org-clock-overlays nil)
 618 (make-variable-buffer-local 'org-clock-overlays)
 619
 620 (defun org-clock-put-overlay (time &optional level)
 621   "Put an overlays on the current line, displaying TIME.
 622 If LEVEL is given, prefix time with a corresponding number of stars.
 623 This creates a new overlay and stores it in `org-clock-overlays', so that it
 624 will be easy to remove."
 625   (let* ((c 60) (h (floor (/ time 60))) (m (- time (* 60 h)))
 626          (l (if level (org-get-valid-level level 0) 0))
 627          (fmt (concat "%s " org-time-clocksum-format "%s"))
 628          (off 0)
 629          ov tx)
 630     (org-move-to-column c)
 631     (unless (eolp) (skip-chars-backward "^ \t"))
 632     (skip-chars-backward " \t")
 633     (setq ov (org-make-overlay (1- (point)) (point-at-eol))
 634           tx (concat (buffer-substring (1- (point)) (point))
 635                      (make-string (+ off (max 0 (- c (current-column)))) ?.)
 636                      (org-add-props (format fmt
 637                                             (make-string l ?*) h m
 638                                             (make-string (- 16 l) ?\ ))
 639                          (list 'face 'org-clock-overlay))
 640                      ""))
 641     (if (not (featurep 'xemacs))
 642         (org-overlay-put ov 'display tx)
 643       (org-overlay-put ov 'invisible t)
 644       (org-overlay-put ov 'end-glyph (make-glyph tx)))
 645     (push ov org-clock-overlays)))
 646
 647 (defun org-clock-remove-overlays (&optional beg end noremove)
 648   "Remove the occur highlights from the buffer.
 649 BEG and END are ignored.  If NOREMOVE is nil, remove this function
 650 from the `before-change-functions' in the current buffer."
 651   (interactive)
 652   (unless org-inhibit-highlight-removal
 653     (mapc 'org-delete-overlay org-clock-overlays)
 654     (setq org-clock-overlays nil)
 655     (unless noremove
 656       (remove-hook 'before-change-functions
 657                    'org-clock-remove-overlays 'local))))
 658
 659 (defvar state) ;; dynamically scoped into this function
 660 (defun org-clock-out-if-current ()
 661   "Clock out if the current entry contains the running clock.
 662 This is used to stop the clock after a TODO entry is marked DONE,
 663 and is only done if the variable `org-clock-out-when-done' is not nil."
 664   (when (and org-clock-out-when-done
 665              (member state org-done-keywords)
 666              (equal (marker-buffer org-clock-marker) (current-buffer))
 667              (< (point) org-clock-marker)
 668              (> (save-excursion (outline-next-heading) (point))
 669                 org-clock-marker))
 670     ;; Clock out, but don't accept a logging message for this.
 671     (let ((org-log-note-clock-out nil))
 672       (org-clock-out))))
 673
 674 (add-hook 'org-after-todo-state-change-hook
 675           'org-clock-out-if-current)
 676
 677 ;;;###autoload
 678 (defun org-get-clocktable (&rest props)
 679   "Get a formatted clocktable with parameters according to PROPS.
 680 The table is created in a temporary buffer, fully formatted and
 681 fontified, and then returned."
 682   ;; Set the defaults
 683   (setq props (plist-put props :name "clocktable"))
 684   (unless (plist-member props :maxlevel)
 685     (setq props (plist-put props :maxlevel 2)))
 686   (unless (plist-member props :scope)
 687     (setq props (plist-put props :scope 'agenda)))
 688   (with-temp-buffer
 689     (org-mode)
 690     (org-create-dblock props)
 691     (org-update-dblock)
 692     (font-lock-fontify-buffer)
 693     (forward-line 2)
 694     (buffer-substring (point) (progn
 695                                 (re-search-forward "^#\\+END" nil t)
 696                                 (point-at-bol)))))
 697
 698 (defun org-clock-report (&optional arg)
 699   "Create a table containing a report about clocked time.
 700 If the cursor is inside an existing clocktable block, then the table
 701 will be updated.  If not, a new clocktable will be inserted.
 702 When called with a prefix argument, move to the first clock table in the
 703 buffer and update it."
 704   (interactive "P")
 705   (org-clock-remove-overlays)
 706   (when arg
 707     (org-find-dblock "clocktable")
 708     (org-show-entry))
 709   (if (org-in-clocktable-p)
 710       (goto-char (org-in-clocktable-p))
 711     (org-create-dblock (list :name "clocktable"
 712                              :maxlevel 2 :scope 'file)))
 713   (org-update-dblock))
 714
 715 (defun org-in-clocktable-p ()
 716   "Check if the cursor is in a clocktable."
 717   (let ((pos (point)) start)
 718     (save-excursion
 719       (end-of-line 1)
 720       (and (re-search-backward "^#\\+BEGIN:[ \t]+clocktable" nil t)
 721            (setq start (match-beginning 0))
 722            (re-search-forward "^#\\+END:.*" nil t)
 723            (>= (match-end 0) pos)
 724            start))))
 725
 726 (defun org-clock-special-range (key &optional time as-strings)
 727   "Return two times bordering a special time range.
 728 Key is a symbol specifying the range and can be one of `today', `yesterday',
 729 `thisweek', `lastweek', `thismonth', `lastmonth', `thisyear', `lastyear'.
 730 A week starts Monday 0:00 and ends Sunday 24:00.
 731 The range is determined relative to TIME.  TIME defaults to the current time.
 732 The return value is a cons cell with two internal times like the ones
 733 returned by `current time' or `encode-time'. if AS-STRINGS is non-nil,
 734 the returned times will be formatted strings."
 735   (if (integerp key) (setq key (intern (number-to-string key))))
 736   (let* ((tm (decode-time (or time (current-time))))
 737          (s 0) (m (nth 1 tm)) (h (nth 2 tm))
 738          (d (nth 3 tm)) (month (nth 4 tm)) (y (nth 5 tm))
 739          (dow (nth 6 tm))
 740          (skey (symbol-name key))
 741          (shift 0)
 742          s1 m1 h1 d1 month1 y1 diff ts te fm txt w date)
 743     (cond
 744      ((string-match "^[0-9]+$" skey)
 745       (setq y (string-to-number skey) m 1 d 1 key 'year))
 746      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)$" skey)
 747       (setq y (string-to-number (match-string 1 skey))
 748             month (string-to-number (match-string 2 skey))
 749             d 1 key 'month))
 750      ((string-match "^\\([0-9]+\\)-[wW]\\([0-9]\\{1,2\\}\\)$" skey)
 751       (require 'cal-iso)
 752       (setq y (string-to-number (match-string 1 skey))
 753             w (string-to-number (match-string 2 skey)))
 754       (setq date (calendar-gregorian-from-absolute
 755                   (calendar-absolute-from-iso (list w 1 y))))
 756       (setq d (nth 1 date) month (car date) y (nth 2 date)
 757             dow 1
 758             key 'week))
 759      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)-\\([0-9]\\{1,2\\}\\)$" skey)
 760       (setq y (string-to-number (match-string 1 skey))
 761             month (string-to-number (match-string 2 skey))
 762             d (string-to-number (match-string 3 skey))
 763             key 'day))
 764      ((string-match "\\([-+][0-9]+\\)$" skey)
 765       (setq shift (string-to-number (match-string 1 skey))
 766             key (intern (substring skey 0 (match-beginning 1))))))
 767     (when (= shift 0)
 768       (cond ((eq key 'yesterday) (setq key 'today shift -1))
 769             ((eq key 'lastweek)  (setq key 'week  shift -1))
 770             ((eq key 'lastmonth) (setq key 'month shift -1))
 771             ((eq key 'lastyear)  (setq key 'year  shift -1))))
 772     (cond
 773      ((memq key '(day today))
 774       (setq d (+ d shift) h 0 m 0 h1 24 m1 0))
 775      ((memq key '(week thisweek))
 776       (setq diff (+ (* -7 shift) (if (= dow 0) 6 (1- dow)))
 777             m 0 h 0 d (- d diff) d1 (+ 7 d)))
 778      ((memq key '(month thismonth))
 779       (setq d 1 h 0 m 0 d1 1 month (+ month shift) month1 (1+ month) h1 0 m1 0))
 780      ((memq key '(year thisyear))
 781       (setq m 0 h 0 d 1 month 1 y (+ y shift) y1 (1+ y)))
 782      (t (error "No such time block %s" key)))
 783     (setq ts (encode-time s m h d month y)
 784           te (encode-time (or s1 s) (or m1 m) (or h1 h)
 785                           (or d1 d) (or month1 month) (or y1 y)))
 786     (setq fm (cdr org-time-stamp-formats))
 787     (cond
 788      ((memq key '(day today))
 789       (setq txt (format-time-string "%A, %B %d, %Y" ts)))
 790      ((memq key '(week thisweek))
 791       (setq txt (format-time-string "week %G-W%V" ts)))
 792      ((memq key '(month thismonth))
 793       (setq txt (format-time-string "%B %Y" ts)))
 794      ((memq key '(year thisyear))
 795       (setq txt (format-time-string "the year %Y" ts))))
 796     (if as-strings
 797         (list (format-time-string fm ts) (format-time-string fm te) txt)
 798       (list ts te txt))))
 799
 800 (defun org-clocktable-shift (dir n)
 801   "Try to shift the :block date of the clocktable at point.
 802 Point must be in the #+BEGIN: line of a clocktable, or this function
 803 will throw an error.
 804 DIR is a direction, a symbol `left', `right', `up', or `down'.
 805 Both `left' and `down' shift the block toward the past, `up' and `right'
 806 push it toward the future.
 807 N is the number of shift steps to take.  The size of the step depends on
 808 the currently selected interval size."
 809   (setq n (prefix-numeric-value n))
 810   (and (memq dir '(left down)) (setq n (- n)))
 811   (save-excursion
 812     (goto-char (point-at-bol))
 813     (if (not (looking-at "#\\+BEGIN: clocktable\\>.*?:block[ \t]+\\(\\S-+\\)"))
 814         (error "Line needs a :block definition before this command works")
 815       (let* ((b (match-beginning 1)) (e (match-end 1))
 816              (s (match-string 1))
 817              block shift ins y mw d date wp m)
 818         (cond
 819          ((equal s "yesterday") (setq s "today-1"))
 820          ((equal s "lastweek") (setq s "thisweek-1"))
 821          ((equal s "lastmonth") (setq s "thismonth-1"))
 822          ((equal s "lastyear") (setq s "thisyear-1")))
 823         (cond
 824          ((string-match "^\\(today\\|thisweek\\|thismonth\\|thisyear\\)\\([-+][0-9]+\\)?$" s)
 825           (setq block (match-string 1 s)
 826                 shift (if (match-end 2)
 827                           (string-to-number (match-string 2 s))
 828                         0))
 829           (setq shift (+ shift n))
 830           (setq ins (if (= shift 0) block (format "%s%+d" block shift))))
 831          ((string-match "\\([0-9]+\\)\\(-\\([wW]?\\)\\([0-9]\\{1,2\\}\\)\\(-\\([0-9]\\{1,2\\}\\)\\)?\\)?" s)
 832           ;;               1        1  2   3       3  4                4  5   6                6  5   2
 833           (setq y (string-to-number (match-string 1 s))
 834                 wp (and (match-end 3) (match-string 3 s))
 835                 mw (and (match-end 4) (string-to-number (match-string 4 s)))
 836                 d (and (match-end 6) (string-to-number (match-string 6 s))))
 837           (cond
 838            (d (setq ins (format-time-string
 839                          "%Y-%m-%d"
 840                          (encode-time 0 0 0 (+ d n) m y))))
 841            ((and wp mw (> (length wp) 0))
 842             (require 'cal-iso)
 843             (setq date (calendar-gregorian-from-absolute (calendar-absolute-from-iso (list (+ mw n) 1 y))))
 844             (setq ins (format-time-string
 845                        "%G-W%V"
 846                        (encode-time 0 0 0 (nth 1 date) (car date) (nth 2 date)))))
 847            (mw
 848             (setq ins (format-time-string
 849                        "%Y-%m"
 850                        (encode-time 0 0 0 1 (+ mw n) y))))
 851            (y
 852             (setq ins (number-to-string (+ y n))))))
 853          (t (error "Cannot shift clocktable block")))
 854         (when ins
 855           (goto-char b)
 856           (insert ins)
 857           (delete-region (point) (+ (point) (- e b)))
 858           (beginning-of-line 1)
 859           (org-update-dblock)
 860           t)))))
 861
 862 (defun org-dblock-write:clocktable (params)
 863   "Write the standard clocktable."
 864   (catch 'exit
 865     (let* ((hlchars '((1 . "*") (2 . "/")))
 866            (ins (make-marker))
 867            (total-time nil)
 868            (scope (plist-get params :scope))
 869            (tostring (plist-get  params :tostring))
 870            (multifile (plist-get  params :multifile))
 871            (header (plist-get  params :header))
 872            (maxlevel (or (plist-get params :maxlevel) 3))
 873            (step (plist-get params :step))
 874            (emph (plist-get params :emphasize))
 875            (ts (plist-get params :tstart))
 876            (te (plist-get params :tend))
 877            (block (plist-get params :block))
 878            (link (plist-get params :link))
 879            ipos time p level hlc hdl content recalc formula pcol
 880            cc beg end pos tbl tbl1 range-text rm-file-column scope-is-list st)
 881       (setq org-clock-file-total-minutes nil)
 882       (when step
 883         (unless (or block (and ts te))
 884           (error "Clocktable `:step' can only be used with `:block' or `:tstart,:end'"))
 885         (org-clocktable-steps params)
 886         (throw 'exit nil))
 887       (when block
 888         (setq cc (org-clock-special-range block nil t)
 889               ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
 890       (when (integerp ts) (setq ts (calendar-gregorian-from-absolute ts)))
 891       (when (integerp te) (setq te (calendar-gregorian-from-absolute te)))
 892       (when (and ts (listp ts))
 893         (setq ts (format "%4d-%02d-%02d" (nth 2 ts) (car ts) (nth 1 ts))))
 894       (when (and te (listp te))
 895         (setq te (format "%4d-%02d-%02d" (nth 2 te) (car te) (nth 1 te))))
 896       ;; Now the times are strings we can parse.
 897       (if ts (setq ts (time-to-seconds
 898                        (apply 'encode-time (org-parse-time-string ts)))))
 899       (if te (setq te (time-to-seconds
 900                        (apply 'encode-time (org-parse-time-string te)))))
 901       (move-marker ins (point))
 902       (setq ipos (point))
 903
 904       ;; Get the right scope
 905       (setq pos (point))
 906       (cond
 907        ((and scope (listp scope) (symbolp (car scope)))
 908         (setq scope (eval scope)))
 909        ((eq scope 'agenda)
 910         (setq scope (org-agenda-files t)))
 911        ((eq scope 'agenda-with-archives)
 912         (setq scope (org-agenda-files t))
 913         (setq scope (org-add-archive-files scope)))
 914        ((eq scope 'file-with-archives)
 915         (setq scope (org-add-archive-files (list (buffer-file-name)))
 916               rm-file-column t)))
 917       (setq scope-is-list (and scope (listp scope)))
 918       (save-restriction
 919         (cond
 920          ((not scope))
 921          ((eq scope 'file) (widen))
 922          ((eq scope 'subtree) (org-narrow-to-subtree))
 923          ((eq scope 'tree)
 924           (while (org-up-heading-safe))
 925           (org-narrow-to-subtree))
 926          ((and (symbolp scope) (string-match "^tree\\([0-9]+\\)$"
 927                                              (symbol-name scope)))
 928           (setq level (string-to-number (match-string 1 (symbol-name scope))))
 929           (catch 'exit
 930             (while (org-up-heading-safe)
 931               (looking-at outline-regexp)
 932               (if (<= (org-reduced-level (funcall outline-level)) level)
 933                   (throw 'exit nil))))
 934           (org-narrow-to-subtree))
 935          (scope-is-list
 936           (let* ((files scope)
 937                  (scope 'agenda)
 938                  (p1 (copy-sequence params))
 939                  file)
 940             (setq p1 (plist-put p1 :tostring t))
 941             (setq p1 (plist-put p1 :multifile t))
 942             (setq p1 (plist-put p1 :scope 'file))
 943             (org-prepare-agenda-buffers files)
 944             (while (setq file (pop files))
 945               (with-current-buffer (find-buffer-visiting file)
 946                 (setq tbl1 (org-dblock-write:clocktable p1))
 947                 (when tbl1
 948                   (push (org-clocktable-add-file
 949                          file
 950                          (concat "| |*File time*|*"
 951                                  (org-minutes-to-hh:mm-string
 952                                   org-clock-file-total-minutes)
 953                                  "*|\n"
 954                                  tbl1)) tbl)
 955                   (setq total-time (+ (or total-time 0)
 956                                       org-clock-file-total-minutes))))))))
 957         (goto-char pos)
 958
 959         (unless scope-is-list
 960           (org-clock-sum ts te)
 961           (goto-char (point-min))
 962           (setq st t)
 963           (while (or (and (bobp) (prog1 st (setq st nil))
 964                           (get-text-property (point) :org-clock-minutes)
 965                           (setq p (point-min)))
 966                      (setq p (next-single-property-change (point) :org-clock-minutes)))
 967             (goto-char p)
 968             (when (setq time (get-text-property p :org-clock-minutes))
 969               (save-excursion
 970                 (beginning-of-line 1)
 971                 (when (and (looking-at (org-re "\\(\\*+\\)[ \t]+\\(.*?\\)\\([ \t]+:[[:alnum:]_@:]+:\\)?[ \t]*$"))
 972                            (setq level (org-reduced-level
 973                                         (- (match-end 1) (match-beginning 1))))
 974                            (<= level maxlevel))
 975                   (setq hlc (if emph (or (cdr (assoc level hlchars)) "") "")
 976                         hdl (if (not link)
 977                                 (match-string 2)
 978                               (org-make-link-string
 979                                (format "file:%s::%s"
 980                                        (buffer-file-name)
 981                                        (save-match-data
 982                                          (org-make-org-heading-search-string
 983                                           (match-string 2))))
 984                                (match-string 2))))
 985                   (if (and (not multifile) (= level 1)) (push "|-" tbl))
 986                   (push (concat
 987                          "| " (int-to-string level) "|" hlc hdl hlc " |"
 988                          (make-string (1- level) ?|)
 989                          hlc (org-minutes-to-hh:mm-string time) hlc
 990                          " |") tbl))))))
 991         (setq tbl (nreverse tbl))
 992         (if tostring
 993             (if tbl (mapconcat 'identity tbl "\n") nil)
 994           (goto-char ins)
 995           (insert-before-markers
 996            (or header
 997                (concat
 998                 "Clock summary at ["
 999                 (substring
1000                  (format-time-string (cdr org-time-stamp-formats))
1001                  1 -1)
1002                 "]"
1003                 (if block (concat ", for " range-text ".") "")
1004                 "\n\n"))
1005            (if scope-is-list "|File" "")
1006            "|L|Headline|Time|\n")
1007           (setq total-time (or total-time org-clock-file-total-minutes))
1008           (insert-before-markers
1009            "|-\n|"
1010            (if scope-is-list "|" "")
1011            "|"
1012            "*Total time*| *"
1013            (org-minutes-to-hh:mm-string (or total-time 0))
1014            "*|\n|-\n")
1015           (setq tbl (delq nil tbl))
1016           (if (and (stringp (car tbl)) (> (length (car tbl)) 1)
1017                    (equal (substring (car tbl) 0 2) "|-"))
1018               (pop tbl))
1019           (insert-before-markers (mapconcat
1020                                   'identity (delq nil tbl)
1021                                   (if scope-is-list "\n|-\n" "\n")))
1022           (backward-delete-char 1)
1023           (if (setq formula (plist-get params :formula))
1024               (cond
1025                ((eq formula '%)
1026                 (setq pcol (+ (if scope-is-list 1 0) maxlevel 3))
1027                 (insert
1028                  (format
1029                   "\n#+TBLFM: $%d='(org-clock-time%% @%d$%d $%d..$%d);%%.1f"
1030                   pcol
1031                   2
1032                   (+ 3 (if scope-is-list 1 0))
1033                   (+ (if scope-is-list 1 0) 3)
1034                   (1- pcol)))
1035                 (setq recalc t))
1036                ((stringp formula)
1037                 (insert "\n#+TBLFM: " formula)
1038                 (setq recalc t))
1039                (t (error "invalid formula in clocktable")))
1040             ;; Should we rescue an old formula?
1041             (when (stringp (setq content (plist-get params :content)))
1042               (when (string-match "^\\(#\\+TBLFM:.*\\)" content)
1043                 (setq recalc t)
1044                 (insert "\n" (match-string 1 (plist-get params :content)))
1045                 (beginning-of-line 0))))
1046           (goto-char ipos)
1047           (skip-chars-forward "^|")
1048           (org-table-align)
1049           (when recalc
1050             (if (eq formula '%)
1051                 (save-excursion (org-table-goto-column pcol nil 'force)
1052                                 (insert "%")))
1053             (org-table-recalculate 'all))
1054           (when rm-file-column
1055             (forward-char 1)
1056             (org-table-delete-column)))))))
1057
1058 (defun org-clocktable-steps (params)
1059   (let* ((p1 (copy-sequence params))
1060          (ts (plist-get p1 :tstart))
1061          (te (plist-get p1 :tend))
1062          (step0 (plist-get p1 :step))
1063          (step (cdr (assoc step0 '((day . 86400) (week . 604800)))))
1064          (block (plist-get p1 :block))
1065          cc range-text)
1066     (when block
1067       (setq cc (org-clock-special-range block nil t)
1068             ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1069     (if ts (setq ts (time-to-seconds
1070                      (apply 'encode-time (org-parse-time-string ts)))))
1071     (if te (setq te (time-to-seconds
1072                      (apply 'encode-time (org-parse-time-string te)))))
1073     (setq p1 (plist-put p1 :header ""))
1074     (setq p1 (plist-put p1 :step nil))
1075     (setq p1 (plist-put p1 :block nil))
1076     (while (< ts te)
1077       (or (bolp) (insert "\n"))
1078       (setq p1 (plist-put p1 :tstart (format-time-string
1079                                       (car org-time-stamp-formats)
1080                                       (seconds-to-time ts))))
1081       (setq p1 (plist-put p1 :tend (format-time-string
1082                                     (car org-time-stamp-formats)
1083                                     (seconds-to-time (setq ts (+ ts step))))))
1084       (insert "\n" (if (eq step0 'day) "Daily report: " "Weekly report starting on: ")
1085               (plist-get p1 :tstart) "\n")
1086       (org-dblock-write:clocktable p1)
1087       (re-search-forward "#\\+END:")
1088       (end-of-line 0))))
1089
1090 (defun org-clocktable-add-file (file table)
1091   (if table
1092       (let ((lines (org-split-string table "\n"))
1093             (ff (file-name-nondirectory file)))
1094         (mapconcat 'identity
1095                    (mapcar (lambda (x)
1096                              (if (string-match org-table-dataline-regexp x)
1097                                  (concat "|" ff x)
1098                                x))
1099                            lines)
1100                    "\n"))))
1101
1102 (defun org-clock-time% (total &rest strings)
1103   "Compute a time fraction in percent.
1104 TOTAL s a time string like 10:21 specifying the total times.
1105 STRINGS is a list of strings that should be checked for a time.
1106 The first string that does have a time will be used.
1107 This function is made for clock tables."
1108   (let ((re "\\([0-9]+\\):\\([0-9]+\\)")
1109         tot s)
1110     (save-match-data
1111       (catch 'exit
1112         (if (not (string-match re total))
1113             (throw 'exit 0.)
1114           (setq tot (+ (string-to-number (match-string 2 total))
1115                        (* 60 (string-to-number (match-string 1 total)))))
1116           (if (= tot 0.) (throw 'exit 0.)))
1117         (while (setq s (pop strings))
1118           (if (string-match "\\([0-9]+\\):\\([0-9]+\\)" s)
1119               (throw 'exit
1120                      (/ (* 100.0 (+ (string-to-number (match-string 2 s))
1121                                     (* 60 (string-to-number (match-string 1 s)))))
1122                         tot))))
1123         0))))
1124
1125 (defun org-clock-save ()
1126   "Persist various clock-related data to disk.
1127 The details of what will be saved are regulated by the variable
1128 `org-clock-persist'."
1129   (when org-clock-persist
1130     (let (b)
1131       (with-current-buffer (find-file (expand-file-name org-clock-persist-file))
1132         (progn
1133           (delete-region (point-min) (point-max))
1134           ;;Store clock
1135           (insert (format ";; org-persist.el - %s at %s\n"
1136                           system-name (format-time-string
1137                                        (cdr org-time-stamp-formats))))
1138           (if (and (setq b (marker-buffer org-clock-marker))
1139                    (setq b (or (buffer-base-buffer b) b))
1140                    (buffer-live-p b)
1141                    (buffer-file-name b)
1142                    (or (not org-clock-persist-query-save)
1143                        (y-or-n-p (concat "Save current clock ("
1144                                          (substring-no-properties org-clock-heading)
1145                                          ") "))))
1146               (insert "(setq resume-clock '(\""
1147                       (buffer-file-name (marker-buffer org-clock-marker))
1148                       "\" . " (int-to-string (marker-position org-clock-marker))
1149                       "))\n"))
1150           ;; Store clocked task history. Tasks are stored reversed to make
1151           ;; reading simpler
1152           (when (and org-clock-history (eq org-clock-persist t))
1153             (insert
1154              "(setq stored-clock-history '("
1155              (mapconcat
1156               (lambda (m)
1157                 (when (and (setq b (marker-buffer m))
1158                            (setq b (or (buffer-base-buffer b) b))
1159                            (buffer-live-p b)
1160                            (buffer-file-name b))
1161                   (concat "(\"" (buffer-file-name b)
1162                           "\" . " (int-to-string (marker-position m))
1163                           ")")))
1164               (reverse org-clock-history) " ") "))\n"))
1165           (save-buffer)
1166           (kill-buffer (current-buffer)))))))
1167
1168 (defvar org-clock-loaded nil
1169   "Was the clock file loaded?")
1170
1171 (defun org-clock-load ()
1172   "Load various clock-related data from disk, optionally resuming
1173 a stored clock"
1174   (when (and org-clock-persist (not org-clock-loaded))
1175     (let ((filename (expand-file-name org-clock-persist-file))
1176           (org-clock-in-resume 'auto-restart)
1177           resume-clock stored-clock-history)
1178       (if (not (file-readable-p filename))
1179           (message "Not restoring clock data; %s not found"
1180                    org-clock-persist-file)
1181         (message "%s" "Restoring clock data")
1182         (setq org-clock-loaded t)
1183         (load-file filename)
1184         ;; load history
1185         (when stored-clock-history
1186           (save-window-excursion
1187             (mapc (lambda (task)
1188                     (if (file-exists-p (car task))
1189                         (org-clock-history-push (cdr task)
1190                                                 (find-file (car task)))))
1191                   stored-clock-history)))
1192         ;; resume clock
1193         (when (and resume-clock org-clock-persist
1194                    (file-exists-p (car resume-clock))
1195                    (or (not org-clock-persist-query-resume)
1196                        (y-or-n-p
1197                         (concat
1198                          "Resume clock ("
1199                          (with-current-buffer (find-file (car resume-clock))
1200                            (save-excursion
1201                              (goto-char (cdr resume-clock))
1202                              (org-back-to-heading t)
1203                              (and (looking-at org-complex-heading-regexp)
1204                                   (match-string 4))))
1205                          ") "))))
1206           (when (file-exists-p (car resume-clock))
1207             (with-current-buffer (find-file (car resume-clock))
1208               (goto-char (cdr resume-clock))
1209               (org-clock-in)
1210               (if (org-invisible-p)
1211                   (org-show-context)))))))))
1212
1213 ;;;###autoload
1214 (defun org-clock-persistence-insinuate ()
1215   "Set up hooks for clock persistence"
1216   (add-hook 'org-mode-hook 'org-clock-load)
1217   (add-hook 'kill-emacs-hook 'org-clock-save))
1218
1219 (provide 'org-clock)
1220
1221 ;; arch-tag: 7b42c5d4-9b36-48be-97c0-66a869daed4c
1222
1223 ;;; org-clock.el ends here