lisp/org-src.el

   1 ;;; org-src.el --- Source code examples in Org
   2 ;;
   3 ;; Copyright (C) 2004-2011 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;         Bastien Guerry <bzg AT gnu DOT org>
   7 ;;         Dan Davison <davison at stats dot ox dot ac dot uk>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the code dealing with source code examples in Org-mode.
  30
  31 ;;; Code:
  32
  33 (require 'org-macs)
  34 (require 'org-compat)
  35 (require 'ob-keys)
  36 (require 'ob-comint)
  37 (eval-when-compile
  38   (require 'cl))
  39
  40 (declare-function org-do-remove-indentation "org" (&optional n))
  41 (declare-function org-at-table.el-p "org" ())
  42 (declare-function org-get-indentation "org" (&optional line))
  43 (declare-function org-switch-to-buffer-other-window "org" (&rest args))
  44 (declare-function org-strip-protective-commas "org" (beg end))
  45 (declare-function org-pop-to-buffer-same-window
  46                   "org-compat" (&optional buffer-or-name norecord label))
  47
  48 (defcustom org-edit-src-region-extra nil
  49   "Additional regexps to identify regions for editing with `org-edit-src-code'.
  50 For examples see the function `org-edit-src-find-region-and-lang'.
  51 The regular expression identifying the begin marker should end with a newline,
  52 and the regexp marking the end line should start with a newline, to make sure
  53 there are kept outside the narrowed region."
  54   :group 'org-edit-structure
  55   :type '(repeat
  56           (list
  57            (regexp :tag "begin regexp")
  58            (regexp :tag "end regexp")
  59            (choice :tag "language"
  60                    (string :tag "specify")
  61                    (integer :tag "from match group")
  62                    (const :tag "from `lang' element")
  63                    (const :tag "from `style' element")))))
  64
  65 (defcustom org-coderef-label-format "(ref:%s)"
  66   "The default coderef format.
  67 This format string will be used to search for coderef labels in literal
  68 examples (EXAMPLE and SRC blocks).  The format can be overwritten in
  69 an individual literal example with the -l option, like
  70
  71 #+BEGIN_SRC pascal +n -r -l \"((%s))\"
  72 ...
  73 #+END_SRC
  74
  75 If you want to use this for HTML export, make sure that the format does
  76 not introduce special font-locking, and avoid the HTML special
  77 characters `<', `>', and `&'.  The reason for this restriction is that
  78 the labels are searched for only after htmlize has done its job."
  79   :group 'org-edit-structure ; FIXME this is not in the right group
  80   :type 'string)
  81
  82 (defcustom org-edit-fixed-width-region-mode 'artist-mode
  83   "The mode that should be used to edit fixed-width regions.
  84 These are the regions where each line starts with a colon."
  85   :group 'org-edit-structure
  86   :type '(choice
  87           (const artist-mode)
  88           (const picture-mode)
  89           (const fundamental-mode)
  90           (function :tag "Other (specify)")))
  91
  92 (defcustom org-src-preserve-indentation nil
  93   "If non-nil preserve leading whitespace characters on export.
  94 If non-nil leading whitespace characters in source code blocks
  95 are preserved on export, and when switching between the org
  96 buffer and the language mode edit buffer.  If this variable is nil
  97 then, after editing with \\[org-edit-src-code], the
  98 minimum (across-lines) number of leading whitespace characters
  99 are removed from all lines, and the code block is uniformly
 100 indented according to the value of `org-edit-src-content-indentation'."
 101   :group 'org-edit-structure
 102   :type 'boolean)
 103
 104 (defcustom org-edit-src-content-indentation 2
 105   "Indentation for the content of a source code block.
 106 This should be the number of spaces added to the indentation of the #+begin
 107 line in order to compute the indentation of the block content after
 108 editing it with \\[org-edit-src-code].  Has no effect if
 109 `org-src-preserve-indentation' is non-nil."
 110   :group 'org-edit-structure
 111   :type 'integer)
 112
 113 (defvar org-src-strip-leading-and-trailing-blank-lines nil
 114   "If non-nil, blank lines are removed when exiting the code edit
 115 buffer.")
 116
 117 (defcustom org-edit-src-persistent-message t
 118   "Non-nil means show persistent exit help message while editing src examples.
 119 The message is shown in the header-line, which will be created in the
 120 first line of the window showing the editing buffer."
 121   :group 'org-edit-structure
 122   :type 'boolean)
 123
 124 (defcustom org-src-window-setup 'reorganize-frame
 125   "How the source code edit buffer should be displayed.
 126 Possible values for this option are:
 127
 128 current-window    Show edit buffer in the current window, keeping all other
 129                   windows.
 130 other-window      Use `switch-to-buffer-other-window' to display edit buffer.
 131 reorganize-frame  Show only two windows on the current frame, the current
 132                   window and the edit buffer. When exiting the edit buffer,
 133                   return to one window.
 134 other-frame       Use `switch-to-buffer-other-frame' to display edit buffer.
 135                   Also, when exiting the edit buffer, kill that frame."
 136   :group 'org-edit-structure
 137   :type '(choice
 138           (const current-window)
 139           (const other-frame)
 140           (const other-window)
 141           (const reorganize-frame)))
 142
 143 (defvar org-src-mode-hook nil
 144   "Hook  run after Org switched a source code snippet to its Emacs mode.
 145 This hook will run
 146
 147 - when editing a source code snippet with \"C-c '\".
 148 - When formatting a source code snippet for export with htmlize.
 149
 150 You may want to use this hook for example to turn off `outline-minor-mode'
 151 or similar things which you want to have when editing a source code file,
 152 but which mess up the display of a snippet in Org exported files.")
 153
 154 (defcustom org-src-lang-modes
 155   '(("ocaml" . tuareg) ("elisp" . emacs-lisp) ("ditaa" . artist)
 156     ("asymptote" . asy) ("dot" . fundamental) ("sqlite" . sql)
 157     ("calc" . fundamental) ("C" . c) ("cpp" . c++)
 158     ("screen" . shell-script))
 159   "Alist mapping languages to their major mode.
 160 The key is the language name, the value is the string that should
 161 be inserted as the name of the major mode.  For many languages this is
 162 simple, but for language where this is not the case, this variable
 163 provides a way to simplify things on the user side.
 164 For example, there is no ocaml-mode in Emacs, but the mode to use is
 165 `tuareg-mode'."
 166   :group 'org-edit-structure
 167   :type '(repeat
 168           (cons
 169            (string "Language name")
 170            (symbol "Major mode"))))
 171
 172 ;;; Editing source examples
 173
 174 (defvar org-src-mode-map (make-sparse-keymap))
 175 (define-key org-src-mode-map "\C-c'" 'org-edit-src-exit)
 176
 177 (defvar org-edit-src-force-single-line nil)
 178 (defvar org-edit-src-from-org-mode nil)
 179 (defvar org-edit-src-allow-write-back-p t)
 180 (defvar org-edit-src-picture nil)
 181 (defvar org-edit-src-beg-marker nil)
 182 (defvar org-edit-src-end-marker nil)
 183 (defvar org-edit-src-overlay nil)
 184 (defvar org-edit-src-block-indentation nil)
 185 (defvar org-edit-src-saved-temp-window-config nil)
 186
 187 (defvar org-src-ask-before-returning-to-edit-buffer t
 188   "If nil, when org-edit-src code is used on a block that already
 189   has an active edit buffer, it will switch to that edit buffer
 190   immediately; otherwise it will ask whether you want to return
 191   to the existing edit buffer.")
 192
 193 (defvar org-src-babel-info nil)
 194
 195 (define-minor-mode org-src-mode
 196   "Minor mode for language major mode buffers generated by org.
 197 This minor mode is turned on in two situations:
 198 - when editing a source code snippet with \"C-c '\".
 199 - When formatting a source code snippet for export with htmlize.
 200 There is a mode hook, and keybindings for `org-edit-src-exit' and
 201 `org-edit-src-save'")
 202
 203 (defun org-edit-src-code (&optional context code edit-buffer-name)
 204   "Edit the source code example at point.
 205 The example is copied to a separate buffer, and that buffer is
 206 switched to the correct language mode.  When done, exit with
 207 \\[org-edit-src-exit].  This will remove the original code in the
 208 Org buffer, and replace it with the edited version. Optional
 209 argument CONTEXT is used by \\[org-edit-src-save] when calling
 210 this function. See \\[org-src-window-setup] to configure the
 211 display of windows containing the Org buffer and the code
 212 buffer."
 213   (interactive)
 214   (unless (eq context 'save)
 215     (setq org-edit-src-saved-temp-window-config (current-window-configuration)))
 216   (let ((mark (and (org-region-active-p) (mark)))
 217         (case-fold-search t)
 218         (info (org-edit-src-find-region-and-lang))
 219         (full-info (org-babel-get-src-block-info 'light))
 220         (org-mode-p (derived-mode-p 'org-mode)) ;; derived-mode-p is reflexive
 221         (beg (make-marker))
 222         (end (make-marker))
 223         (allow-write-back-p (null code))
 224         block-nindent total-nindent ovl lang lang-f single lfmt buffer msg
 225         begline markline markcol line col transmitted-variables)
 226     (if (not info)
 227         nil
 228       (setq beg (move-marker beg (nth 0 info))
 229             end (move-marker end (nth 1 info))
 230             msg (if allow-write-back-p
 231                     (substitute-command-keys
 232                      "Edit, then exit with C-c ' (C-c and single quote)")
 233                   "Exit with C-c ' (C-c and single quote)")
 234             code (or code (buffer-substring-no-properties beg end))
 235             lang (or (cdr (assoc (nth 2 info) org-src-lang-modes))
 236                      (nth 2 info))
 237             lang (if (symbolp lang) (symbol-name lang) lang)
 238             single (nth 3 info)
 239             block-nindent (nth 5 info)
 240             lang-f (intern (concat lang "-mode"))
 241             begline (save-excursion (goto-char beg) (org-current-line))
 242             transmitted-variables
 243             `((org-edit-src-content-indentation
 244                ,org-edit-src-content-indentation)
 245               (org-edit-src-force-single-line ,single)
 246               (org-edit-src-from-org-mode ,org-mode-p)
 247               (org-edit-src-allow-write-back-p ,allow-write-back-p)
 248               (org-src-preserve-indentation ,org-src-preserve-indentation)
 249               (org-src-babel-info ,(org-babel-get-src-block-info 'light))
 250               (org-coderef-label-format
 251                ,(or (nth 4 info) org-coderef-label-format))
 252               (org-edit-src-beg-marker ,beg)
 253               (org-edit-src-end-marker ,end)
 254               (org-edit-src-block-indentation ,block-nindent)))
 255       (if (and mark (>= mark beg) (<= mark (1+ end)))
 256           (save-excursion (goto-char (min mark end))
 257                           (setq markline (org-current-line)
 258                                 markcol (current-column))))
 259       (if (equal lang-f 'table.el-mode)
 260           (setq lang-f (lambda ()
 261                          (text-mode)
 262                          (if (org-bound-and-true-p flyspell-mode)
 263                              (flyspell-mode -1))
 264                          (table-recognize)
 265                          (org-set-local 'org-edit-src-content-indentation 0))))
 266       (unless (functionp lang-f)
 267         (error "No such language mode: %s" lang-f))
 268       (save-excursion
 269         (if (> (point) end) (goto-char end))
 270         (setq line (org-current-line)
 271               col (current-column)))
 272       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 273                (if org-src-ask-before-returning-to-edit-buffer
 274                    (y-or-n-p "Return to existing edit buffer? [n] will revert changes: ") t))
 275           (org-src-switch-to-buffer buffer 'return)
 276         (when buffer
 277           (with-current-buffer buffer
 278             (if (boundp 'org-edit-src-overlay)
 279                 (delete-overlay org-edit-src-overlay)))
 280           (kill-buffer buffer))
 281         (setq buffer (generate-new-buffer
 282                       (or edit-buffer-name
 283                           (org-src-construct-edit-buffer-name (buffer-name) lang))))
 284         (setq ovl (make-overlay beg end))
 285         (overlay-put ovl 'edit-buffer buffer)
 286         (overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 287         (overlay-put ovl 'face 'secondary-selection)
 288         (overlay-put ovl
 289                      'keymap
 290                      (let ((map (make-sparse-keymap)))
 291                        (define-key map [mouse-1] 'org-edit-src-continue)
 292                        map))
 293         (overlay-put ovl :read-only "Leave me alone")
 294         (setq transmitted-variables
 295               (append transmitted-variables `((org-edit-src-overlay ,ovl))))
 296         (org-src-switch-to-buffer buffer 'edit)
 297         (if (eq single 'macro-definition)
 298             (setq code (replace-regexp-in-string "\\\\n" "\n" code t t)))
 299         (insert code)
 300         (remove-text-properties (point-min) (point-max)
 301                                 '(display nil invisible nil intangible nil))
 302         (unless (cadr (assq 'org-src-preserve-indentation transmitted-variables))
 303           (setq total-nindent (or (org-do-remove-indentation) 0)))
 304         (let ((org-inhibit-startup t))
 305           (condition-case e
 306               (funcall lang-f)
 307             (error
 308              (error "Language mode `%s' fails with: %S" lang-f (nth 1 e)))))
 309         (dolist (pair transmitted-variables)
 310           (org-set-local (car pair) (cadr pair)))
 311         (if (eq major-mode 'org-mode)
 312             (progn
 313               (goto-char (point-min))
 314               (while (re-search-forward "^," nil t)
 315                 (if (eq (org-current-line) line) (setq total-nindent (1+ total-nindent)))
 316                 (replace-match "")))
 317           (org-strip-protective-commas (point-min) (point-max)))
 318         (when markline
 319           (org-goto-line (1+ (- markline begline)))
 320           (org-move-to-column
 321            (if org-src-preserve-indentation markcol
 322              (max 0 (- markcol total-nindent))))
 323           (push-mark (point) 'no-message t)
 324           (setq deactivate-mark nil))
 325         (org-goto-line (1+ (- line begline)))
 326         (org-move-to-column
 327          (if org-src-preserve-indentation col (max 0 (- col total-nindent))))
 328         (org-src-mode)
 329         (set-buffer-modified-p nil)
 330         (and org-edit-src-persistent-message
 331              (org-set-local 'header-line-format msg))
 332         (let ((edit-prep-func (intern (concat "org-babel-edit-prep:" lang))))
 333           (when (fboundp edit-prep-func)
 334             (funcall edit-prep-func full-info))))
 335       t)))
 336
 337 (defun org-edit-src-continue (e)
 338   (interactive "e")
 339   (mouse-set-point e)
 340   (let ((buf (get-char-property (point) 'edit-buffer)))
 341     (if buf (org-src-switch-to-buffer buf 'continue)
 342       (error "Something is wrong here"))))
 343
 344 (defun org-src-switch-to-buffer (buffer context)
 345   (case org-src-window-setup
 346     ('current-window
 347      (org-pop-to-buffer-same-window buffer))
 348     ('other-window
 349      (switch-to-buffer-other-window buffer))
 350     ('other-frame
 351      (case context
 352        ('exit
 353         (let ((frame (selected-frame)))
 354           (switch-to-buffer-other-frame buffer)
 355           (delete-frame frame)))
 356        ('save
 357         (kill-buffer (current-buffer))
 358         (org-pop-to-buffer-same-window buffer))
 359        (t
 360         (switch-to-buffer-other-frame buffer))))
 361     ('reorganize-frame
 362      (if (eq context 'edit) (delete-other-windows))
 363      (org-switch-to-buffer-other-window buffer)
 364      (if (eq context 'exit) (delete-other-windows)))
 365     ('switch-invisibly
 366      (set-buffer buffer))
 367     (t
 368      (message "Invalid value %s for org-src-window-setup"
 369               (symbol-name org-src-window-setup))
 370      (org-pop-to-buffer-same-window buffer))))
 371
 372 (defun org-src-construct-edit-buffer-name (org-buffer-name lang)
 373   "Construct the buffer name for a source editing buffer."
 374   (concat "*Org Src " org-buffer-name "[ " lang " ]*"))
 375
 376 (defun org-edit-src-find-buffer (beg end)
 377   "Find a source editing buffer that is already editing the region BEG to END."
 378   (catch 'exit
 379     (mapc
 380      (lambda (b)
 381        (with-current-buffer b
 382          (if (and (string-match "\\`*Org Src " (buffer-name))
 383                   (local-variable-p 'org-edit-src-beg-marker (current-buffer))
 384                   (local-variable-p 'org-edit-src-end-marker (current-buffer))
 385                   (equal beg org-edit-src-beg-marker)
 386                   (equal end org-edit-src-end-marker))
 387              (throw 'exit (current-buffer)))))
 388      (buffer-list))
 389     nil))
 390
 391 (defun org-edit-fixed-width-region ()
 392   "Edit the fixed-width ascii drawing at point.
 393 This must be a region where each line starts with a colon followed by
 394 a space character.
 395 An new buffer is created and the fixed-width region is copied into it,
 396 and the buffer is switched into `artist-mode' for editing.  When done,
 397 exit with \\[org-edit-src-exit].  The edited text will then replace
 398 the fragment in the Org-mode buffer."
 399   (interactive)
 400   (let ((line (org-current-line))
 401         (col (current-column))
 402         (case-fold-search t)
 403         (msg (substitute-command-keys
 404               "Edit, then exit with C-c ' (C-c and single quote)"))
 405         (org-mode-p (eq major-mode 'org-mode))
 406         (beg (make-marker))
 407         (end (make-marker))
 408         (preserve-indentation org-src-preserve-indentation)
 409         block-nindent ovl beg1 end1 code begline buffer)
 410     (beginning-of-line 1)
 411     (if (looking-at "[ \t]*[^:\n \t]")
 412         nil
 413       (if (looking-at "[ \t]*\\(\n\\|\\'\\)")
 414           (setq beg1 (point) end1 beg1)
 415         (save-excursion
 416           (if (re-search-backward "^[ \t]*[^: \t]" nil 'move)
 417               (setq beg1 (point-at-bol 2))
 418             (setq beg1 (point))))
 419         (save-excursion
 420           (if (re-search-forward "^[ \t]*[^: \t]" nil 'move)
 421               (setq end1 (1- (match-beginning 0)))
 422             (setq end1 (point))))
 423         (org-goto-line line))
 424       (setq beg (move-marker beg beg1)
 425             end (move-marker end end1)
 426             code (buffer-substring-no-properties beg end)
 427             begline (save-excursion (goto-char beg) (org-current-line)))
 428       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 429                (y-or-n-p "Return to existing edit buffer? [n] will revert changes: "))
 430           (org-pop-to-buffer-same-window buffer)
 431         (when buffer
 432           (with-current-buffer buffer
 433             (if (boundp 'org-edit-src-overlay)
 434                 (delete-overlay org-edit-src-overlay)))
 435           (kill-buffer buffer))
 436         (setq buffer (generate-new-buffer
 437                       (org-src-construct-edit-buffer-name
 438                        (buffer-name) "Fixed Width")))
 439         (setq ovl (make-overlay beg end))
 440         (overlay-put ovl 'face 'secondary-selection)
 441         (overlay-put ovl 'edit-buffer buffer)
 442         (overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 443         (overlay-put ovl 'face 'secondary-selection)
 444         (overlay-put ovl
 445                          'keymap
 446                          (let ((map (make-sparse-keymap)))
 447                            (define-key map [mouse-1] 'org-edit-src-continue)
 448                            map))
 449         (overlay-put ovl :read-only "Leave me alone")
 450         (org-pop-to-buffer-same-window buffer)
 451         (insert code)
 452         (remove-text-properties (point-min) (point-max)
 453                                 '(display nil invisible nil intangible nil))
 454         (setq block-nindent (or (org-do-remove-indentation) 0))
 455         (cond
 456          ((eq org-edit-fixed-width-region-mode 'artist-mode)
 457           (fundamental-mode)
 458           (artist-mode 1))
 459          (t (funcall org-edit-fixed-width-region-mode)))
 460         (set (make-local-variable 'org-edit-src-force-single-line) nil)
 461         (set (make-local-variable 'org-edit-src-from-org-mode) org-mode-p)
 462         (set (make-local-variable 'org-edit-src-picture) t)
 463         (goto-char (point-min))
 464         (while (re-search-forward "^[ \t]*: ?" nil t)
 465           (replace-match ""))
 466         (org-goto-line (1+ (- line begline)))
 467         (org-move-to-column (max 0 (- col block-nindent 2)))
 468         (org-set-local 'org-edit-src-beg-marker beg)
 469         (org-set-local 'org-edit-src-end-marker end)
 470         (org-set-local 'org-edit-src-overlay ovl)
 471         (org-set-local 'org-edit-src-block-indentation block-nindent)
 472         (org-set-local 'org-edit-src-content-indentation 0)
 473         (org-set-local 'org-src-preserve-indentation nil)
 474         (org-src-mode)
 475         (set-buffer-modified-p nil)
 476         (and org-edit-src-persistent-message
 477              (org-set-local 'header-line-format msg)))
 478       (message "%s" msg)
 479       t)))
 480
 481 (defun org-edit-src-find-region-and-lang ()
 482   "Find the region and language for a local edit.
 483 Return a list with beginning and end of the region, a string representing
 484 the language, a switch telling if the content should be in a single line."
 485   (let ((re-list
 486          (append
 487           org-edit-src-region-extra
 488           '(
 489             ("<src\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</src>" lang)
 490             ("<literal\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</literal>" style)
 491             ("<example>[ \t]*\n?" "\n?[ \t]*</example>" "fundamental")
 492             ("<lisp>[ \t]*\n?" "\n?[ \t]*</lisp>" "emacs-lisp")
 493             ("<perl>[ \t]*\n?" "\n?[ \t]*</perl>" "perl")
 494             ("<python>[ \t]*\n?" "\n?[ \t]*</python>" "python")
 495             ("<ruby>[ \t]*\n?" "\n?[ \t]*</ruby>" "ruby")
 496             ("^[ \t]*#\\+begin_src\\( \\([^ \t\n]+\\)\\)?.*\n" "\n[ \t]*#\\+end_src" 2)
 497             ("^[ \t]*#\\+begin_example.*\n" "\n[ \t]*#\\+end_example" "fundamental")
 498             ("^[ \t]*#\\+html:" "\n" "html" single-line)
 499             ("^[ \t]*#\\+begin_html.*\n" "\n[ \t]*#\\+end_html" "html")
 500             ("^[ \t]*#\\+latex:" "\n" "latex" single-line)
 501             ("^[ \t]*#\\+begin_latex.*\n" "\n[ \t]*#\\+end_latex" "latex")
 502             ("^[ \t]*#\\+ascii:" "\n" "fundamental" single-line)
 503             ("^[ \t]*#\\+begin_ascii.*\n" "\n[ \t]*#\\+end_ascii" "fundamental")
 504             ("^[ \t]*#\\+docbook:" "\n" "xml" single-line)
 505             ("^[ \t]*#\\+macro:[ \t]+\\S-+\\( \\|$\\)"
 506              "\n" "fundamental" macro-definition)
 507             ("^[ \t]*#\\+begin_docbook.*\n" "\n[ \t]*#\\+end_docbook" "xml")
 508             )))
 509         (pos (point))
 510         re1 re2 single beg end lang lfmt match-re1 ind entry)
 511     (catch 'exit
 512       (while (setq entry (pop re-list))
 513         (setq re1 (car entry) re2 (nth 1 entry) lang (nth 2 entry)
 514               single (nth 3 entry))
 515         (save-excursion
 516           (if (or (looking-at re1)
 517                   (re-search-backward re1 nil t))
 518               (progn
 519                 (setq match-re1 (match-string 0))
 520                 (setq beg (match-end 0)
 521                       lang (org-edit-src-get-lang lang)
 522                       lfmt (org-edit-src-get-label-format match-re1)
 523                       ind (org-edit-src-get-indentation (match-beginning 0)))
 524                 (if (and (re-search-forward re2 nil t)
 525                          (>= (match-end 0) pos))
 526                     (throw 'exit (list beg (match-beginning 0)
 527                                        lang single lfmt ind))))
 528             (if (or (looking-at re2)
 529                     (re-search-forward re2 nil t))
 530                 (progn
 531                   (setq end (match-beginning 0))
 532                   (if (and (re-search-backward re1 nil t)
 533                            (<= (match-beginning 0) pos))
 534                       (progn
 535                         (setq lfmt (org-edit-src-get-label-format
 536                                     (match-string 0))
 537                               ind (org-edit-src-get-indentation
 538                                    (match-beginning 0)))
 539                         (throw 'exit
 540                                (list (match-end 0) end
 541                                      (org-edit-src-get-lang lang)
 542                                      single lfmt ind)))))))))
 543       (when (org-at-table.el-p)
 544         (re-search-backward "^[\t]*[^ \t|\\+]" nil t)
 545         (setq beg (1+ (point-at-eol)))
 546         (goto-char beg)
 547         (or (re-search-forward "^[\t]*[^ \t|\\+]" nil t)
 548             (progn (goto-char (point-max)) (newline)))
 549         (setq end (point-at-bol))
 550         (setq ind (org-edit-src-get-indentation beg))
 551         (throw 'exit (list beg end 'table.el nil nil ind))))))
 552
 553 (defun org-edit-src-get-lang (lang)
 554   "Extract the src language."
 555   (let ((m (match-string 0)))
 556     (cond
 557      ((stringp lang) lang)
 558      ((integerp lang) (match-string lang))
 559      ((and (eq lang 'lang)
 560            (string-match "\\<lang=\"\\([^ \t\n\"]+\\)\"" m))
 561       (match-string 1 m))
 562      ((and (eq lang 'style)
 563            (string-match "\\<style=\"\\([^ \t\n\"]+\\)\"" m))
 564       (match-string 1 m))
 565      (t "fundamental"))))
 566
 567 (defun org-edit-src-get-label-format (s)
 568   "Extract the label format."
 569   (save-match-data
 570     (if (string-match "-l[ \t]+\\\\?\"\\([^\t\r\n\"]+\\)\\\\?\"" s)
 571         (match-string 1 s))))
 572
 573 (defun org-edit-src-get-indentation (pos)
 574   "Count leading whitespace characters on line."
 575   (save-match-data
 576     (goto-char pos)
 577     (org-get-indentation)))
 578
 579 (defun org-edit-src-exit (&optional context)
 580   "Exit special edit and protect problematic lines."
 581   (interactive)
 582   (unless (org-bound-and-true-p org-edit-src-from-org-mode)
 583     (error "This is not a sub-editing buffer, something is wrong"))
 584   (widen)
 585   (let* ((beg org-edit-src-beg-marker)
 586          (end org-edit-src-end-marker)
 587          (ovl org-edit-src-overlay)
 588          (buffer (current-buffer))
 589          (single (org-bound-and-true-p org-edit-src-force-single-line))
 590          (macro (eq single 'macro-definition))
 591          (total-nindent (+ (or org-edit-src-block-indentation 0)
 592                            org-edit-src-content-indentation))
 593          (preserve-indentation org-src-preserve-indentation)
 594          (allow-write-back-p (org-bound-and-true-p org-edit-src-allow-write-back-p))
 595          (delta 0) code line col indent)
 596     (when allow-write-back-p
 597       (unless preserve-indentation (untabify (point-min) (point-max)))
 598       (if org-src-strip-leading-and-trailing-blank-lines
 599           (save-excursion
 600             (goto-char (point-min))
 601             (if (looking-at "[ \t\n]*\n") (replace-match ""))
 602             (unless macro
 603               (if (re-search-forward "\n[ \t\n]*\\'" nil t) (replace-match ""))))))
 604     (setq line (if (org-bound-and-true-p org-edit-src-force-single-line)
 605                    1
 606                  (org-current-line))
 607           col (current-column))
 608     (when allow-write-back-p
 609       (when single
 610         (goto-char (point-min))
 611         (if (re-search-forward "\\s-+\\'" nil t) (replace-match ""))
 612         (goto-char (point-min))
 613         (let ((cnt 0))
 614           (while (re-search-forward "\n" nil t)
 615             (setq cnt (1+ cnt))
 616             (replace-match (if macro "\\n" " ") t t))
 617           (when (and macro (> cnt 0))
 618             (goto-char (point-max)) (insert "\\n")))
 619         (goto-char (point-min))
 620         (if (looking-at "\\s-*") (replace-match " ")))
 621       (when (org-bound-and-true-p org-edit-src-from-org-mode)
 622         (goto-char (point-min))
 623         (while (re-search-forward
 624                 (if (eq major-mode 'org-mode) "^\\(.\\)" "^\\([*]\\|[ \t]*#\\+\\)") nil t)
 625           (if (eq (org-current-line) line) (setq delta (1+ delta)))
 626           (replace-match ",\\1")))
 627       (when (org-bound-and-true-p org-edit-src-picture)
 628         (setq preserve-indentation nil)
 629         (untabify (point-min) (point-max))
 630         (goto-char (point-min))
 631         (while (re-search-forward "^" nil t)
 632           (replace-match ": ")))
 633       (unless (or single preserve-indentation (= total-nindent 0))
 634         (setq indent (make-string total-nindent ?\ ))
 635         (goto-char (point-min))
 636         (while (re-search-forward "^" nil t)
 637           (replace-match indent)))
 638       (if (org-bound-and-true-p org-edit-src-picture)
 639           (setq total-nindent (+ total-nindent 2)))
 640       (setq code (buffer-string))
 641       (set-buffer-modified-p nil))
 642     (org-src-switch-to-buffer (marker-buffer beg) (or context 'exit))
 643     (kill-buffer buffer)
 644     (goto-char beg)
 645     (when allow-write-back-p
 646       (delete-region beg end)
 647       (insert code)
 648       (goto-char beg)
 649       (if single (just-one-space)))
 650     (if (memq t (mapcar (lambda (overlay)
 651                           (eq (overlay-get overlay 'invisible)
 652                               'org-hide-block))
 653                         (overlays-at (point))))
 654         ;; Block is hidden; put point at start of block
 655         (beginning-of-line 0)
 656       ;; Block is visible, put point where it was in the code buffer
 657       (org-goto-line (1- (+ (org-current-line) line)))
 658       (org-move-to-column (if preserve-indentation col (+ col total-nindent delta))))
 659     (move-marker beg nil)
 660     (move-marker end nil))
 661   (unless (eq context 'save)
 662     (when org-edit-src-saved-temp-window-config
 663       (set-window-configuration org-edit-src-saved-temp-window-config)
 664       (setq org-edit-src-saved-temp-window-config nil))))
 665
 666 (defun org-edit-src-save ()
 667   "Save parent buffer with current state source-code buffer."
 668   (interactive)
 669   (let ((p (point)) (m (mark)) msg)
 670     (save-window-excursion
 671       (org-edit-src-exit 'save)
 672       (save-buffer)
 673       (setq msg (current-message))
 674       (if (eq org-src-window-setup 'other-frame)
 675           (let ((org-src-window-setup 'current-window))
 676             (org-edit-src-code 'save))
 677         (org-edit-src-code 'save)))
 678     (push-mark m 'nomessage)
 679     (goto-char (min p (point-max)))
 680     (message (or msg ""))))
 681
 682 (defun org-src-mode-configure-edit-buffer ()
 683   (when (org-bound-and-true-p org-edit-src-from-org-mode)
 684     (org-add-hook 'kill-buffer-hook
 685                   #'(lambda () (delete-overlay org-edit-src-overlay)) nil 'local)
 686     (if (org-bound-and-true-p org-edit-src-allow-write-back-p)
 687         (progn
 688           (setq buffer-offer-save t)
 689           (setq buffer-file-name
 690                 (concat (buffer-file-name (marker-buffer org-edit-src-beg-marker))
 691                         "[" (buffer-name) "]"))
 692           (if (featurep 'xemacs)
 693               (progn
 694                 (make-variable-buffer-local 'write-contents-hooks) ; needed only for 21.4
 695                 (setq write-contents-hooks '(org-edit-src-save)))
 696             (setq write-contents-functions '(org-edit-src-save))))
 697       (setq buffer-read-only t))))
 698
 699 (org-add-hook 'org-src-mode-hook 'org-src-mode-configure-edit-buffer)
 700
 701
 702 (defun org-src-associate-babel-session (info)
 703   "Associate edit buffer with comint session."
 704   (interactive)
 705   (let ((session (cdr (assoc :session (nth 2 info)))))
 706     (and session (not (string= session "none"))
 707          (org-babel-comint-buffer-livep session)
 708          ((lambda (f) (and (fboundp f) (funcall f session)))
 709           (intern (format "org-babel-%s-associate-session" (nth 0 info)))))))
 710
 711 (defun org-src-babel-configure-edit-buffer ()
 712   (when org-src-babel-info
 713     (org-src-associate-babel-session org-src-babel-info)))
 714
 715 (org-add-hook 'org-src-mode-hook 'org-src-babel-configure-edit-buffer)
 716 (defmacro org-src-do-at-code-block (&rest body)
 717   "Execute a command from an edit buffer in the Org-mode buffer."
 718   `(let ((beg-marker org-edit-src-beg-marker))
 719      (if beg-marker
 720          (with-current-buffer (marker-buffer beg-marker)
 721            (goto-char (marker-position beg-marker))
 722            ,@body))))
 723 (def-edebug-spec org-src-do-at-code-block (body))
 724
 725 (defun org-src-do-key-sequence-at-code-block (&optional key)
 726   "Execute key sequence at code block in the source Org buffer.
 727 The command bound to KEY in the Org-babel key map is executed
 728 remotely with point temporarily at the start of the code block in
 729 the Org buffer.
 730
 731 This command is not bound to a key by default, to avoid conflicts
 732 with language major mode bindings. To bind it to C-c @ in all
 733 language major modes, you could use
 734
 735   (add-hook 'org-src-mode-hook
 736             (lambda () (define-key org-src-mode-map \"\\C-c@\"
 737                     'org-src-do-key-sequence-at-code-block)))
 738
 739 In that case, for example, C-c @ t issued in code edit buffers
 740 would tangle the current Org code block, C-c @ e would execute
 741 the block and C-c @ h would display the other available
 742 Org-babel commands."
 743   (interactive "kOrg-babel key: ")
 744   (if (equal key (kbd "C-g")) (keyboard-quit)
 745     (org-edit-src-save)
 746     (org-src-do-at-code-block
 747      (call-interactively
 748       (lookup-key org-babel-map key)))))
 749
 750 (defcustom org-src-tab-acts-natively nil
 751   "If non-nil, the effect of TAB in a code block is as if it were
 752 issued in the language major mode buffer."
 753   :type 'boolean
 754   :group 'org-babel)
 755
 756 (defun org-src-native-tab-command-maybe ()
 757   "Perform language-specific TAB action.
 758 Alter code block according to effect of TAB in the language major
 759 mode."
 760   (and org-src-tab-acts-natively
 761        (let ((org-src-strip-leading-and-trailing-blank-lines nil))
 762          (org-babel-do-key-sequence-in-edit-buffer (kbd "TAB")))))
 763
 764 (add-hook 'org-tab-first-hook 'org-src-native-tab-command-maybe)
 765
 766 (defun org-src-font-lock-fontify-block (lang start end)
 767   "Fontify code block.
 768 This function is called by emacs automatic fontification, as long
 769 as `org-src-fontify-natively' is non-nil. For manual
 770 fontification of code blocks see `org-src-fontify-block' and
 771 `org-src-fontify-buffer'"
 772   (let ((lang-mode (org-src-get-lang-mode lang)))
 773     (if (fboundp lang-mode)
 774         (let ((string (buffer-substring-no-properties start end))
 775               (modified (buffer-modified-p))
 776               (org-buffer (current-buffer)) pos next)
 777           (remove-text-properties start end '(face nil))
 778           (with-current-buffer
 779               (get-buffer-create
 780                (concat " org-src-fontification:" (symbol-name lang-mode)))
 781             (delete-region (point-min) (point-max))
 782             (insert (concat string " ")) ;; so there's a final property change
 783             (unless (eq major-mode lang-mode) (funcall lang-mode))
 784             (font-lock-fontify-buffer)
 785             (setq pos (point-min))
 786             (while (setq next (next-single-property-change pos 'face))
 787               (put-text-property
 788                (+ start (1- pos)) (+ start next) 'face
 789                (get-text-property pos 'face) org-buffer)
 790               (setq pos next)))
 791           (add-text-properties
 792            start end
 793            '(font-lock-fontified t fontified t font-lock-multiline t))
 794           (set-buffer-modified-p modified)))))
 795
 796 (defun org-src-fontify-block ()
 797   "Fontify code block at point."
 798   (interactive)
 799   (save-excursion
 800     (let ((org-src-fontify-natively t)
 801           (info (org-edit-src-find-region-and-lang)))
 802       (font-lock-fontify-region (nth 0 info) (nth 1 info)))))
 803
 804 (defun org-src-fontify-buffer ()
 805   "Fontify all code blocks in the current buffer"
 806   (interactive)
 807   (org-babel-map-src-blocks nil
 808     (org-src-fontify-block)))
 809
 810 (defun org-src-get-lang-mode (lang)
 811   "Return major mode that should be used for LANG.
 812 LANG is a string, and the returned major mode is a symbol."
 813   (intern
 814    (concat
 815     ((lambda (l) (if (symbolp l) (symbol-name l) l))
 816      (or (cdr (assoc lang org-src-lang-modes)) lang)) "-mode")))
 817
 818 (provide 'org-src)
 819
 820 ;;; org-src.el ends here