lisp/org-protocol.el

   1 ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
   2 ;;
   3 ;; Copyright (C) 2008-2013 Free Software Foundation, Inc.
   4 ;;
   5 ;; Authors: Bastien Guerry <bzg AT gnu DOT org>
   6 ;;       Daniel M German <dmg AT uvic DOT org>
   7 ;;       Sebastian Rose <sebastian_rose AT gmx DOT de>
   8 ;;       Ross Patterson <me AT rpatterson DOT net>
   9 ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  10 ;; Keywords: org, emacsclient, wp
  11
  12 ;; This file is part of GNU Emacs.
  13 ;;
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  28 ;;; Commentary:
  29 ;;
  30 ;; Intercept calls from emacsclient to trigger custom actions.
  31 ;;
  32 ;; This is done by advising `server-visit-files' to scan the list of filenames
  33 ;; for `org-protocol-the-protocol' and sub-protocols defined in
  34 ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  35 ;;
  36 ;; Any application that supports calling external programs with an URL
  37 ;; as argument may be used with this functionality.
  38 ;;
  39 ;;
  40 ;; Usage:
  41 ;; ------
  42 ;;
  43 ;;   1.) Add this to your init file (.emacs probably):
  44 ;;
  45 ;;       (add-to-list 'load-path "/path/to/org-protocol/")
  46 ;;       (require 'org-protocol)
  47 ;;
  48 ;;   3.) Ensure emacs-server is up and running.
  49 ;;   4.) Try this from the command line (adjust the URL as needed):
  50 ;;
  51 ;;       $ emacsclient \
  52 ;;         org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  53 ;;
  54 ;;   5.) Optionally add custom sub-protocols and handlers:
  55 ;;
  56 ;;       (setq org-protocol-protocol-alist
  57 ;;             '(("my-protocol"
  58 ;;                :protocol "my-protocol"
  59 ;;                :function my-protocol-handler-function)))
  60 ;;
  61 ;;       A "sub-protocol" will be found in URLs like this:
  62 ;;
  63 ;;           org-protocol://sub-protocol://data
  64 ;;
  65 ;; If it works, you can now setup other applications for using this feature.
  66 ;;
  67 ;;
  68 ;; As of March 2009 Firefox users follow the steps documented on
  69 ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  70 ;; http://www.opera.com/support/kb/view/535/
  71 ;;
  72 ;;
  73 ;; Documentation
  74 ;; -------------
  75 ;;
  76 ;; org-protocol.el comes with and installs handlers to open sources of published
  77 ;; online content, store and insert the browser's URLs and cite online content
  78 ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  79 ;; applications:
  80 ;;
  81 ;;   * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  82 ;;     URLs to local filenames defined in `org-protocol-project-alist'.
  83 ;;
  84 ;;   * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  85 ;;     pushes the browsers URL to the `kill-ring' for yanking.  This handler is
  86 ;;     triggered through the sub-protocol \"store-link\".
  87 ;;
  88 ;;   * Call `org-protocol-capture' by using the sub-protocol \"capture\".  If
  89 ;;     Org-mode is loaded, Emacs will pop-up a capture buffer and fill the
  90 ;;     template with the data provided.  I.e. the browser's URL is inserted as an
  91 ;;     Org-link of which the page title will be the description part.  If text
  92 ;;     was select in the browser, that text will be the body of the entry.
  93 ;;
  94 ;; You may use the same bookmark URL for all those standard handlers and just
  95 ;; adjust the sub-protocol used:
  96 ;;
  97 ;;     location.href='org-protocol://sub-protocol://'+
  98 ;;           encodeURIComponent(location.href)+'/'+
  99 ;;           encodeURIComponent(document.title)+'/'+
 100 ;;           encodeURIComponent(window.getSelection())
 101 ;;
 102 ;; The handler for the sub-protocol \"capture\" detects an optional template
 103 ;; char that, if present, triggers the use of a special template.
 104 ;; Example:
 105 ;;
 106 ;;     location.href='org-protocol://sub-protocol://x/'+ ...
 107 ;;
 108 ;;  use template ?x.
 109 ;;
 110 ;; Note, that using double slashes is optional from org-protocol.el's point of
 111 ;; view because emacsclient squashes the slashes to one.
 112 ;;
 113 ;;
 114 ;; provides: 'org-protocol
 115 ;;
 116 ;;; Code:
 117
 118 (require 'org)
 119 (eval-when-compile
 120   (require 'cl))
 121
 122 (declare-function org-publish-get-project-from-filename "org-publish"
 123                   (filename &optional up))
 124 (declare-function server-edit "server" (&optional arg))
 125
 126 (define-obsolete-function-alias
 127   'org-protocol-unhex-compound 'org-link-unescape-compound
 128   "2011-02-17")
 129
 130 (define-obsolete-function-alias
 131   'org-protocol-unhex-string 'org-link-unescape
 132   "2011-02-17")
 133
 134 (define-obsolete-function-alias
 135   'org-protocol-unhex-single-byte-sequence
 136   'org-link-unescape-single-byte-sequence
 137   "2011-02-17")
 138
 139 (defgroup org-protocol nil
 140   "Intercept calls from emacsclient to trigger custom actions.
 141
 142 This is done by advising `server-visit-files' to scan the list of filenames
 143 for `org-protocol-the-protocol' and sub-protocols defined in
 144 `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
 145   :version "22.1"
 146   :group 'convenience
 147   :group 'org)
 148
 149
 150 ;;; Variables:
 151
 152 (defconst org-protocol-protocol-alist-default
 153   '(("org-capture"     :protocol "capture"     :function org-protocol-capture  :kill-client t)
 154     ("org-store-link"  :protocol "store-link"  :function org-protocol-store-link)
 155     ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
 156   "Default protocols to use.
 157 See `org-protocol-protocol-alist' for a description of this variable.")
 158
 159 (defconst org-protocol-the-protocol "org-protocol"
 160   "This is the protocol to detect if org-protocol.el is loaded.
 161 `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold
 162 the sub-protocols that trigger the required action.  You will have to define
 163 just one protocol handler OS-wide (MS-Windows) or per application (Linux).
 164 That protocol handler should call emacsclient.")
 165
 166 ;;; User variables:
 167
 168 (defcustom org-protocol-reverse-list-of-files t
 169   "Non-nil means re-reverse the list of filenames passed on the command line.
 170 The filenames passed on the command line are passed to the emacs-server in
 171 reverse order.  Set to t (default) to re-reverse the list, i.e. use the
 172 sequence on the command line.  If nil, the sequence of the filenames is
 173 unchanged."
 174   :group 'org-protocol
 175   :type 'boolean)
 176
 177 (defcustom org-protocol-project-alist nil
 178   "Map URLs to local filenames for `org-protocol-open-source' (open-source).
 179
 180 Each element of this list must be of the form:
 181
 182   (module-name :property value property: value ...)
 183
 184 where module-name is an arbitrary name.  All the values are strings.
 185
 186 Possible properties are:
 187
 188   :online-suffix     - the suffix to strip from the published URLs
 189   :working-suffix    - the replacement for online-suffix
 190   :base-url          - the base URL, e.g. http://www.example.com/project/
 191                        Last slash required.
 192   :working-directory - the local working directory.  This is, what base-url will
 193                        be replaced with.
 194   :redirects         - A list of cons cells, each of which maps a regular
 195                        expression to match to a path relative to :working-directory.
 196
 197 Example:
 198
 199    (setq org-protocol-project-alist
 200        '((\"http://orgmode.org/worg/\"
 201           :online-suffix \".php\"
 202           :working-suffix \".org\"
 203           :base-url \"http://orgmode.org/worg/\"
 204           :working-directory \"/home/user/org/Worg/\")
 205          (\"http://localhost/org-notes/\"
 206           :online-suffix \".html\"
 207           :working-suffix \".org\"
 208           :base-url \"http://localhost/org/\"
 209           :working-directory \"/home/user/org/\"
 210           :rewrites ((\"org/?$\" . \"index.php\")))))
 211
 212    The last line tells `org-protocol-open-source' to open
 213    /home/user/org/index.php, if the URL cannot be mapped to an existing
 214    file, and ends with either \"org\" or \"org/\".
 215
 216 Consider using the interactive functions `org-protocol-create' and
 217 `org-protocol-create-for-org' to help you filling this variable with valid contents."
 218   :group 'org-protocol
 219   :type 'alist)
 220
 221 (defcustom org-protocol-protocol-alist nil
 222   "Register custom handlers for org-protocol.
 223
 224 Each element of this list must be of the form:
 225
 226   (module-name :protocol protocol :function func :kill-client nil)
 227
 228 protocol - protocol to detect in a filename without trailing colon and slashes.
 229            See rfc1738 section 2.1 for more on this.
 230            If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
 231            will search filenames for \"org-protocol:/my-protocol:/\"
 232            and trigger your action for every match. `org-protocol' is defined in
 233            `org-protocol-the-protocol'.  Double and triple slashes are compressed
 234            to one by emacsclient.
 235
 236 function - function that handles requests with protocol and takes exactly one
 237            argument: the filename with all protocols stripped.  If the function
 238            returns nil, emacsclient and -server do nothing.  Any non-nil return
 239            value is considered a valid filename and thus passed to the server.
 240
 241            `org-protocol.el provides some support for handling those filenames,
 242            if you stay with the conventions used for the standard handlers in
 243            `org-protocol-protocol-alist-default'.  See `org-protocol-split-data'.
 244
 245 kill-client - If t, kill the client immediately, once the sub-protocol is
 246            detected.  This is necessary for actions that can be interrupted by
 247            `C-g' to avoid dangling emacsclients.  Note, that all other command
 248            line arguments but the this one will be discarded, greedy handlers
 249            still receive the whole list of arguments though.
 250
 251 Here is an example:
 252
 253   (setq org-protocol-protocol-alist
 254       '((\"my-protocol\"
 255          :protocol \"my-protocol\"
 256          :function my-protocol-handler-function)
 257         (\"your-protocol\"
 258          :protocol \"your-protocol\"
 259          :function your-protocol-handler-function)))"
 260   :group 'org-protocol
 261   :type '(alist))
 262
 263 (defcustom org-protocol-default-template-key nil
 264   "The default template key to use.
 265 This is usually a single character string but can also be a
 266 string with two characters."
 267   :group 'org-protocol
 268   :type 'string)
 269
 270 (defcustom org-protocol-data-separator "/+"
 271   "The default data separator to use.
 272    This should be a single regexp string."
 273   :group 'org-protocol
 274   :type 'string)
 275
 276 ;;; Helper functions:
 277
 278 (defun org-protocol-sanitize-uri (uri)
 279   "emacsclient compresses double and triple slashes.
 280 Slashes are sanitized to double slashes here."
 281   (when (string-match "^\\([a-z]+\\):/" uri)
 282     (let* ((splitparts (split-string uri "/+")))
 283       (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
 284   uri)
 285
 286 (defun org-protocol-split-data (data &optional unhexify separator)
 287   "Split what an org-protocol handler function gets as only argument.
 288 DATA is that one argument.  DATA is split at each occurrence of
 289 SEPARATOR (regexp).  If no SEPARATOR is specified or SEPARATOR is
 290 nil, assume \"/+\".  The results of that splitting are returned
 291 as a list.  If UNHEXIFY is non-nil, hex-decode each split part.
 292 If UNHEXIFY is a function, use that function to decode each split
 293 part."
 294   (let* ((sep (or separator "/+"))
 295          (split-parts (split-string data sep)))
 296     (if unhexify
 297         (if (fboundp unhexify)
 298             (mapcar unhexify split-parts)
 299           (mapcar 'org-link-unescape split-parts))
 300       split-parts)))
 301
 302 (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
 303   "Greedy handlers might receive a list like this from emacsclient:
 304  '((\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 305 where \"/dir/\" is the absolute path to emacsclients working directory.  This
 306 function transforms it into a flat list using `org-protocol-flatten' and
 307 transforms the elements of that list as follows:
 308
 309 If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
 310 param-list.
 311
 312 If replacement is string, replace the \"/dir/\" prefix with it.
 313
 314 The first parameter, the one that contains the protocols, is always changed.
 315 Everything up to the end of the protocols is stripped.
 316
 317 Note, that this function will always behave as if
 318 `org-protocol-reverse-list-of-files' was set to t and the returned list will
 319 reflect that.  I.e. emacsclients first parameter will be the first one in the
 320 returned list."
 321   (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
 322                                       param-list
 323                                     (reverse param-list))))
 324          (trigger (car l))
 325          (len 0)
 326          dir
 327          ret)
 328     (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
 329       (setq dir (match-string 1 trigger))
 330       (setq len (length dir))
 331       (setcar l (concat dir (match-string 3 trigger))))
 332     (if strip-path
 333         (progn
 334           (dolist (e l ret)
 335             (setq ret
 336                   (append ret
 337                           (list
 338                            (if (stringp e)
 339                                (if (stringp replacement)
 340                                    (setq e (concat replacement (substring e len)))
 341                                  (setq e (substring e len)))
 342                              e)))))
 343           ret)
 344       l)))
 345
 346 (defun org-protocol-flatten (l)
 347   "Greedy handlers might receive a list like this from emacsclient:
 348  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 349 where \"/dir/\" is the absolute path to emacsclients working directory.
 350 This function transforms it into a flat list."
 351   (if (null l) ()
 352     (if (listp l)
 353         (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
 354       (list l))))
 355
 356
 357 ;;; Standard protocol handlers:
 358
 359 (defun org-protocol-store-link (fname)
 360   "Process an org-protocol://store-link:// style url.
 361 Additionally store a browser URL as an org link.  Also pushes the
 362 link's URL to the `kill-ring'.
 363
 364 The location for a browser's bookmark has to look like this:
 365
 366   javascript:location.href='org-protocol://store-link://'+ \\
 367         encodeURIComponent(location.href)
 368         encodeURIComponent(document.title)+'/'+ \\
 369
 370 Don't use `escape()'! Use `encodeURIComponent()' instead.  The title of the page
 371 could contain slashes and the location definitely will.
 372
 373 The sub-protocol used to reach this function is set in
 374 `org-protocol-protocol-alist'."
 375   (let* ((splitparts (org-protocol-split-data fname t org-protocol-data-separator))
 376          (uri (org-protocol-sanitize-uri (car splitparts)))
 377          (title (cadr splitparts))
 378          orglink)
 379     (if (boundp 'org-stored-links)
 380         (setq org-stored-links (cons (list uri title) org-stored-links)))
 381     (kill-new uri)
 382     (message "`%s' to insert new org-link, `%s' to insert `%s'"
 383              (substitute-command-keys"\\[org-insert-link]")
 384              (substitute-command-keys"\\[yank]")
 385              uri))
 386   nil)
 387
 388 (defun org-protocol-capture (info)
 389   "Process an org-protocol://capture:// style url.
 390
 391 The sub-protocol used to reach this function is set in
 392 `org-protocol-protocol-alist'.
 393
 394 This function detects an URL, title and optional text, separated by '/'
 395 The location for a browser's bookmark has to look like this:
 396
 397   javascript:location.href='org-protocol://capture://'+ \\
 398         encodeURIComponent(location.href)+'/' \\
 399         encodeURIComponent(document.title)+'/'+ \\
 400         encodeURIComponent(window.getSelection())
 401
 402 By default, it uses the character `org-protocol-default-template-key',
 403 which should be associated with a template in `org-capture-templates'.
 404 But you may prepend the encoded URL with a character and a slash like so:
 405
 406   javascript:location.href='org-protocol://capture://b/'+ ...
 407
 408 Now template ?b will be used."
 409   (if (and (boundp 'org-stored-links)
 410            (org-protocol-do-capture info))
 411       (message "Item captured."))
 412   nil)
 413
 414 (defun org-protocol-do-capture (info)
 415   "Support `org-capture'."
 416   (let* ((parts (org-protocol-split-data info t org-protocol-data-separator))
 417          (template (or (and (>= 2 (length (car parts))) (pop parts))
 418                        org-protocol-default-template-key))
 419          (url (org-protocol-sanitize-uri (car parts)))
 420          (type (if (string-match "^\\([a-z]+\\):" url)
 421                    (match-string 1 url)))
 422          (title (or (cadr parts) ""))
 423          (region (or (caddr parts) ""))
 424          (orglink (org-make-link-string
 425                    url (if (string-match "[^[:space:]]" title) title url)))
 426          (org-capture-link-is-already-stored t)) ;; avoid call to org-store-link
 427     (setq org-stored-links
 428           (cons (list url title) org-stored-links))
 429     (kill-new orglink)
 430     (org-store-link-props :type type
 431                           :link url
 432                           :description title
 433                           :annotation orglink
 434                           :initial region)
 435     (raise-frame)
 436     (funcall 'org-capture nil template)))
 437
 438 (defun org-protocol-open-source (fname)
 439   "Process an org-protocol://open-source:// style url.
 440
 441 Change a filename by mapping URLs to local filenames as set
 442 in `org-protocol-project-alist'.
 443
 444 The location for a browser's bookmark should look like this:
 445
 446   javascript:location.href='org-protocol://open-source://'+ \\
 447         encodeURIComponent(location.href)"
 448   ;; As we enter this function for a match on our protocol, the return value
 449   ;; defaults to nil.
 450   (let ((result nil)
 451         (f (org-link-unescape fname)))
 452     (catch 'result
 453       (dolist (prolist org-protocol-project-alist)
 454         (let* ((base-url (plist-get (cdr prolist) :base-url))
 455                (wsearch (regexp-quote base-url)))
 456
 457           (when (string-match wsearch f)
 458             (let* ((wdir (plist-get (cdr prolist) :working-directory))
 459                    (strip-suffix (plist-get (cdr prolist) :online-suffix))
 460                    (add-suffix (plist-get (cdr prolist) :working-suffix))
 461                    ;; Strip "[?#].*$" if `f' is a redirect with another
 462                    ;; ending than strip-suffix here:
 463                    (f1 (substring f 0 (string-match "\\([\\?#].*\\)?$" f)))
 464                    (start-pos (+ (string-match wsearch f1) (length base-url)))
 465                    (end-pos (string-match
 466                              (regexp-quote strip-suffix) f1))
 467                    ;; We have to compare redirects without suffix below:
 468                    (f2 (concat wdir (substring f1 start-pos end-pos)))
 469                    (the-file (concat f2 add-suffix)))
 470
 471               ;; Note: the-file may still contain `%C3' et al here because browsers
 472               ;; tend to encode `&auml;' in URLs to `%25C3' - `%25' being `%'.
 473               ;; So the results may vary.
 474
 475               ;; -- start redirects --
 476               (unless (file-exists-p the-file)
 477                 (message "File %s does not exist.\nTesting for rewritten URLs." the-file)
 478                 (let ((rewrites (plist-get (cdr prolist) :rewrites)))
 479                   (when rewrites
 480                     (message "Rewrites found: %S" rewrites)
 481                     (mapc
 482                      (lambda (rewrite)
 483                        "Try to match a rewritten URL and map it to a real file."
 484                        ;; Compare redirects without suffix:
 485                        (if (string-match (car rewrite) f2)
 486                            (throw 'result (concat wdir (cdr rewrite)))))
 487                      rewrites))))
 488               ;; -- end of redirects --
 489
 490               (if (file-readable-p the-file)
 491                   (throw 'result the-file))
 492               (if (file-exists-p the-file)
 493                   (message "%s: permission denied!" the-file)
 494                 (message "%s: no such file or directory." the-file))))))
 495       result)))
 496
 497
 498 ;;; Core functions:
 499
 500 (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
 501   "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
 502 Sub-protocols are registered in `org-protocol-protocol-alist' and
 503 `org-protocol-protocol-alist-default'.
 504 This is, how the matching is done:
 505
 506   (string-match \"protocol:/+sub-protocol:/+\" ...)
 507
 508 protocol and sub-protocol are regexp-quoted.
 509
 510 If a matching protocol is found, the protocol is stripped from fname and the
 511 result is passed to the protocols function as the only parameter.  If the
 512 function returns nil, the filename is removed from the list of filenames
 513 passed from emacsclient to the server.
 514 If the function returns a non nil value, that value is passed to the server
 515 as filename."
 516   (let ((sub-protocols (append org-protocol-protocol-alist
 517                                org-protocol-protocol-alist-default)))
 518     (catch 'fname
 519       (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
 520         (when (string-match the-protocol fname)
 521           (dolist (prolist sub-protocols)
 522             (let ((proto (concat the-protocol
 523                                  (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
 524               (when (string-match proto fname)
 525                 (let* ((func (plist-get (cdr prolist) :function))
 526                        (greedy (plist-get (cdr prolist) :greedy))
 527                        (split (split-string fname proto))
 528                        (result (if greedy restoffiles (cadr split))))
 529                   (when (plist-get (cdr prolist) :kill-client)
 530                     (message "Greedy org-protocol handler.  Killing client.")
 531                     (server-edit))
 532                   (when (fboundp func)
 533                     (unless greedy
 534                       (throw 'fname (funcall func result)))
 535                     (funcall func result)
 536                     (throw 'fname t))))))))
 537       ;; (message "fname: %s" fname)
 538       fname)))
 539
 540 (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
 541   "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
 542   (let ((flist (if org-protocol-reverse-list-of-files
 543                    (reverse  (ad-get-arg 0))
 544                  (ad-get-arg 0)))
 545         (client (ad-get-arg 1)))
 546     (catch 'greedy
 547       (dolist (var flist)
 548         ;; `\' to `/' on windows.  FIXME: could this be done any better?
 549         (let ((fname  (expand-file-name (car var))))
 550           (setq fname (org-protocol-check-filename-for-protocol
 551                        fname (member var flist)  client))
 552           (if (eq fname t) ;; greedy? We need the `t' return value.
 553               (progn
 554                 (ad-set-arg 0 nil)
 555                 (throw 'greedy t))
 556             (if (stringp fname) ;; probably filename
 557                 (setcar var fname)
 558               (ad-set-arg 0 (delq var (ad-get-arg 0))))))))))
 559
 560 ;;; Org specific functions:
 561
 562 (defun org-protocol-create-for-org ()
 563   "Create a org-protocol project for the current file's Org-mode project.
 564 This works, if the file visited is part of a publishing project in
 565 `org-publish-project-alist'.  This function calls `org-protocol-create' to do
 566 most of the work."
 567   (interactive)
 568   (require 'org-publish)
 569   (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
 570     (if all (org-protocol-create (cdr all))
 571       (message "Not in an org-project.  Did mean %s?"
 572                (substitute-command-keys"\\[org-protocol-create]")))))
 573
 574 (defun org-protocol-create (&optional project-plist)
 575   "Create a new org-protocol project interactively.
 576 An org-protocol project is an entry in `org-protocol-project-alist'
 577 which is used by `org-protocol-open-source'.
 578 Optionally use project-plist to initialize the defaults for this project.  If
 579 project-plist is the CDR of an element in `org-publish-project-alist', reuse
 580 :base-directory, :html-extension and :base-extension."
 581   (interactive)
 582   (let ((working-dir (expand-file-name
 583                       (or (plist-get project-plist :base-directory)
 584                           default-directory)))
 585         (base-url "http://orgmode.org/worg/")
 586         (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
 587         (working-suffix (if (plist-get project-plist :base-extension)
 588                             (concat "." (plist-get project-plist :base-extension))
 589                           ".org"))
 590         (worglet-buffer nil)
 591         (insert-default-directory t)
 592         (minibuffer-allow-text-properties nil))
 593
 594     (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
 595     (if (not (string-match "\\/$" base-url))
 596         (setq base-url (concat base-url "/")))
 597
 598     (setq working-dir
 599           (expand-file-name
 600            (read-directory-name "Local working directory: " working-dir working-dir t)))
 601     (if (not (string-match "\\/$" working-dir))
 602         (setq working-dir (concat working-dir "/")))
 603
 604     (setq strip-suffix
 605           (read-string
 606            (concat "Extension to strip from published URLs (" strip-suffix "): ")
 607            strip-suffix nil strip-suffix t))
 608
 609     (setq working-suffix
 610           (read-string
 611            (concat "Extension of editable files (" working-suffix "): ")
 612            working-suffix nil working-suffix t))
 613
 614     (when (yes-or-no-p "Save the new org-protocol-project to your init file? ")
 615       (setq org-protocol-project-alist
 616             (cons `(,base-url . (:base-url ,base-url
 617                                            :working-directory ,working-dir
 618                                            :online-suffix ,strip-suffix
 619                                            :working-suffix ,working-suffix))
 620                   org-protocol-project-alist))
 621       (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))))
 622
 623 (provide 'org-protocol)
 624
 625 ;;; org-protocol.el ends here