lisp/org-pcomplete.el

   1 ;;; org-pcomplete.el --- In-buffer completion code
   2
   3 ;; Copyright (C) 2004-2013 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;         John Wiegley <johnw at gnu dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Code:
  27
  28 ;;;; Require other packages
  29
  30 (eval-when-compile
  31   (require 'cl))
  32
  33 (require 'org-macs)
  34 (require 'org-compat)
  35 (require 'pcomplete)
  36
  37 (declare-function org-split-string "org" (string &optional separators))
  38 (declare-function org-make-org-heading-search-string "org"
  39                   (&optional string heading))
  40 (declare-function org-get-buffer-tags "org" ())
  41 (declare-function org-get-tags "org" ())
  42 (declare-function org-buffer-property-keys "org"
  43                   (&optional include-specials include-defaults include-columns))
  44 (declare-function org-entry-properties "org" (&optional pom which specific))
  45
  46 ;;;; Customization variables
  47
  48 (defgroup org-complete nil
  49   "Outline-based notes management and organizer."
  50   :tag "Org"
  51   :group 'org)
  52
  53 (defvar org-drawer-regexp)
  54 (defvar org-property-re)
  55
  56 (defun org-thing-at-point ()
  57   "Examine the thing at point and let the caller know what it is.
  58 The return value is a string naming the thing at point."
  59   (let ((beg1 (save-excursion
  60                 (skip-chars-backward (org-re "[:alnum:]-_@"))
  61                 (point)))
  62         (beg (save-excursion
  63                (skip-chars-backward "a-zA-Z0-9-_:$")
  64                (point)))
  65         (line-to-here (buffer-substring (point-at-bol) (point))))
  66     (cond
  67      ((string-match "\\`[ \t]*#\\+begin: clocktable[ \t]+" line-to-here)
  68       (cons "block-option" "clocktable"))
  69      ((string-match "\\`[ \t]*#\\+begin_src[ \t]+" line-to-here)
  70       (cons "block-option" "src"))
  71      ((save-excursion
  72         (re-search-backward "^[ \t]*#\\+\\([A-Z_]+\\):.*"
  73                             (line-beginning-position) t))
  74       (cons "file-option" (match-string-no-properties 1)))
  75      ((string-match "\\`[ \t]*#\\+[a-zA-Z_]*\\'" line-to-here)
  76       (cons "file-option" nil))
  77      ((equal (char-before beg) ?\[)
  78       (cons "link" nil))
  79      ((equal (char-before beg) ?\\)
  80       (cons "tex" nil))
  81      ((string-match "\\`\\*+[ \t]+\\'"
  82                     (buffer-substring (point-at-bol) beg))
  83       (cons "todo" nil))
  84      ((equal (char-before beg) ?*)
  85       (cons "searchhead" nil))
  86      ((and (equal (char-before beg1) ?:)
  87            (equal (char-after (point-at-bol)) ?*))
  88       (cons "tag" nil))
  89      ((and (equal (char-before beg1) ?:)
  90            (not (equal (char-after (point-at-bol)) ?*))
  91            (save-excursion
  92              (move-beginning-of-line 1)
  93              (skip-chars-backward "[ \t\n]")
  94              ;; org-drawer-regexp matches a whole line but while
  95              ;; looking-back, we just ignore trailing whitespaces
  96              (or (org-looking-back (substring org-drawer-regexp 0 -1))
  97                  (org-looking-back org-property-re))))
  98       (cons "prop" nil))
  99      ((and (equal (char-before beg1) ?:)
 100            (not (equal (char-after (point-at-bol)) ?*)))
 101       (cons "drawer" nil))
 102      (t nil))))
 103
 104 (defun org-command-at-point ()
 105   "Return the qualified name of the Org completion entity at point.
 106 When completing for #+STARTUP, for example, this function returns
 107 \"file-option/startup\"."
 108   (let ((thing (org-thing-at-point)))
 109     (cond
 110      ((string= "file-option" (car thing))
 111       (concat (car thing)
 112               (and (cdr thing) (concat "/" (downcase (cdr thing))))))
 113      ((string= "block-option" (car thing))
 114       (concat (car thing) "/" (downcase (cdr thing))))
 115      (t (car thing)))))
 116
 117 (defun org-parse-arguments ()
 118   "Parse whitespace separated arguments in the current region."
 119   (let ((begin (line-beginning-position))
 120         (end (line-end-position))
 121         begins args)
 122     (save-restriction
 123       (narrow-to-region begin end)
 124       (save-excursion
 125         (goto-char (point-min))
 126         (while (not (eobp))
 127           (skip-chars-forward " \t\n[")
 128           (setq begins (cons (point) begins))
 129           (skip-chars-forward "^ \t\n[")
 130           (setq args (cons (buffer-substring-no-properties
 131                             (car begins) (point))
 132                            args)))
 133         (cons (reverse args) (reverse begins))))))
 134
 135 (defun org-pcomplete-initial ()
 136   "Calls the right completion function for first argument completions."
 137   (ignore
 138    (funcall (or (pcomplete-find-completion-function
 139                  (car (org-thing-at-point)))
 140                 pcomplete-default-completion-function))))
 141
 142 (defvar org-options-keywords)            ; From org.el
 143 (defvar org-element-block-name-alist)    ; From org-element.el
 144 (defvar org-element-affiliated-keywords) ; From org-element.el
 145 (declare-function org-get-export-keywords "org" ())
 146 (defun pcomplete/org-mode/file-option ()
 147   "Complete against all valid file options."
 148   (require 'org-element)
 149   (pcomplete-here
 150    (org-pcomplete-case-double
 151     (append (mapcar (lambda (keyword) (concat keyword " "))
 152                     org-options-keywords)
 153             (mapcar (lambda (keyword) (concat keyword ": "))
 154                     org-element-affiliated-keywords)
 155             (let (block-names)
 156               (mapc (lambda (block-name)
 157                       (let ((name (car block-name)))
 158                         (push (format "END_%s: " name) block-names)
 159                         (push (format "BEGIN_%s: " name) block-names)
 160                         (push (format "ATTR_%s: " name) block-names)))
 161                     org-element-block-name-alist)
 162               block-names)
 163             (mapcar (lambda (keyword) (concat keyword ": "))
 164                     (org-get-export-keywords))))
 165    (substring pcomplete-stub 2)))
 166
 167 (defun pcomplete/org-mode/file-option/author ()
 168   "Complete arguments for the #+AUTHOR file option."
 169   (pcomplete-here (list user-full-name)))
 170
 171 (defvar org-time-stamp-formats)
 172 (defun pcomplete/org-mode/file-option/date ()
 173   "Complete arguments for the #+DATE file option."
 174   (pcomplete-here (list (format-time-string (car org-time-stamp-formats)))))
 175
 176 (defun pcomplete/org-mode/file-option/email ()
 177   "Complete arguments for the #+EMAIL file option."
 178   (pcomplete-here (list user-mail-address)))
 179
 180 (defvar org-export-exclude-tags)
 181 (defun pcomplete/org-mode/file-option/exclude_tags ()
 182   "Complete arguments for the #+EXCLUDE_TAGS file option."
 183   (require 'ox)
 184   (pcomplete-here
 185    (and org-export-exclude-tags
 186         (list (mapconcat 'identity org-export-exclude-tags " ")))))
 187
 188 (defvar org-file-tags)
 189 (defun pcomplete/org-mode/file-option/filetags ()
 190   "Complete arguments for the #+FILETAGS file option."
 191   (pcomplete-here (and org-file-tags (mapconcat 'identity org-file-tags " "))))
 192
 193 (defvar org-export-default-language)
 194 (defun pcomplete/org-mode/file-option/language ()
 195   "Complete arguments for the #+LANGUAGE file option."
 196   (require 'ox)
 197   (pcomplete-here
 198    (pcomplete-uniqify-list
 199     (list org-export-default-language "en"))))
 200
 201 (defvar org-default-priority)
 202 (defvar org-highest-priority)
 203 (defvar org-lowest-priority)
 204 (defun pcomplete/org-mode/file-option/priorities ()
 205   "Complete arguments for the #+PRIORITIES file option."
 206   (pcomplete-here (list (format "%c %c %c"
 207                                 org-highest-priority
 208                                 org-lowest-priority
 209                                 org-default-priority))))
 210
 211 (defvar org-export-select-tags)
 212 (defun pcomplete/org-mode/file-option/select_tags ()
 213   "Complete arguments for the #+SELECT_TAGS file option."
 214   (require 'ox)
 215   (pcomplete-here
 216    (and org-export-select-tags
 217         (list (mapconcat 'identity org-export-select-tags " ")))))
 218
 219 (defvar org-startup-options)
 220 (defun pcomplete/org-mode/file-option/startup ()
 221   "Complete arguments for the #+STARTUP file option."
 222   (while (pcomplete-here
 223           (let ((opts (pcomplete-uniqify-list
 224                        (mapcar 'car org-startup-options))))
 225             ;; Some options are mutually exclusive, and shouldn't be completed
 226             ;; against if certain other options have already been seen.
 227             (dolist (arg pcomplete-args)
 228               (cond
 229                ((string= arg "hidestars")
 230                 (setq opts (delete "showstars" opts)))))
 231             opts))))
 232
 233 (defvar org-tag-alist)
 234 (defun pcomplete/org-mode/file-option/tags ()
 235   "Complete arguments for the #+TAGS file option."
 236   (pcomplete-here
 237    (list
 238     (mapconcat (lambda (x)
 239                  (cond
 240                   ((eq :startgroup (car x)) "{")
 241                   ((eq :endgroup (car x)) "}")
 242                   ((eq :newline (car x)) "\\n")
 243                   ((cdr x) (format "%s(%c)" (car x) (cdr x)))
 244                   (t (car x))))
 245                org-tag-alist " "))))
 246
 247 (defun pcomplete/org-mode/file-option/title ()
 248   "Complete arguments for the #+TITLE file option."
 249   (pcomplete-here
 250    (let ((visited-file (buffer-file-name (buffer-base-buffer))))
 251      (list (or (and visited-file
 252                     (file-name-sans-extension
 253                      (file-name-nondirectory visited-file)))
 254                (buffer-name (buffer-base-buffer)))))))
 255
 256 (defun pcomplete/org-mode/file-option/options ()
 257   "Complete arguments for the #+OPTIONS file option."
 258   (while (pcomplete-here
 259           (pcomplete-uniqify-list
 260            (append
 261             ;; Hard-coded OPTION items always available.
 262             '("H:" "\\n:" "num:" "timestamp:" "arch:" "author:" "c:"
 263               "creator:" "date:" "d:" "email:" "*:" "e:" "::" "f:"
 264               "inline:" "tex:" "p:" "pri:" "':" "-:" "stat:" "^:" "toc:"
 265               "|:" "tags:" "tasks:" "<:" "todo:")
 266             ;; OPTION items from registered back-ends.
 267             (let (items)
 268               (dolist (back-end (org-bound-and-true-p
 269                                  org-export-registered-backends))
 270                 (dolist (option (plist-get (cdr back-end) :options-alist))
 271                   (let ((item (nth 2 option)))
 272                     (when item (push (concat item ":") items)))))
 273               items))))))
 274
 275 (defun pcomplete/org-mode/file-option/infojs_opt ()
 276   "Complete arguments for the #+INFOJS_OPT file option."
 277   (while (pcomplete-here
 278           (pcomplete-uniqify-list
 279            (mapcar (lambda (item) (format "%s:" (car item)))
 280                    (org-bound-and-true-p org-infojs-opts-table))))))
 281
 282 (defun pcomplete/org-mode/file-option/bind ()
 283   "Complete arguments for the #+BIND file option, which are variable names."
 284   (let (vars)
 285     (mapatoms
 286      (lambda (a) (if (boundp a) (setq vars (cons (symbol-name a) vars)))))
 287     (pcomplete-here vars)))
 288
 289 (defvar org-link-abbrev-alist-local)
 290 (defvar org-link-abbrev-alist)
 291 (defun pcomplete/org-mode/link ()
 292   "Complete against defined #+LINK patterns."
 293   (pcomplete-here
 294    (pcomplete-uniqify-list
 295     (copy-sequence
 296      (append (mapcar 'car org-link-abbrev-alist-local)
 297              (mapcar 'car org-link-abbrev-alist))))))
 298
 299 (defvar org-entities)
 300 (defun pcomplete/org-mode/tex ()
 301   "Complete against TeX-style HTML entity names."
 302   (require 'org-entities)
 303   (while (pcomplete-here
 304           (pcomplete-uniqify-list (remove nil (mapcar 'car-safe org-entities)))
 305           (substring pcomplete-stub 1))))
 306
 307 (defvar org-todo-keywords-1)
 308 (defun pcomplete/org-mode/todo ()
 309   "Complete against known TODO keywords."
 310   (pcomplete-here (pcomplete-uniqify-list (copy-sequence org-todo-keywords-1))))
 311
 312 (defvar org-todo-line-regexp)
 313 (defun pcomplete/org-mode/searchhead ()
 314   "Complete against all headings.
 315 This needs more work, to handle headings with lots of spaces in them."
 316   (while
 317       (pcomplete-here
 318        (save-excursion
 319          (goto-char (point-min))
 320          (let (tbl)
 321            (while (re-search-forward org-todo-line-regexp nil t)
 322              (push (org-make-org-heading-search-string
 323                     (match-string-no-properties 3) t)
 324                    tbl))
 325            (pcomplete-uniqify-list tbl)))
 326        (substring pcomplete-stub 1))))
 327
 328 (defvar org-tag-alist)
 329 (defun pcomplete/org-mode/tag ()
 330   "Complete a tag name.  Omit tags already set."
 331   (while (pcomplete-here
 332           (mapcar (lambda (x)
 333                     (concat x ":"))
 334                   (let ((lst (pcomplete-uniqify-list
 335                               (or (remove
 336                                    nil
 337                                    (mapcar (lambda (x)
 338                                              (and (stringp (car x)) (car x)))
 339                                            org-tag-alist))
 340                                   (mapcar 'car (org-get-buffer-tags))))))
 341                     (dolist (tag (org-get-tags))
 342                       (setq lst (delete tag lst)))
 343                     lst))
 344           (and (string-match ".*:" pcomplete-stub)
 345                (substring pcomplete-stub (match-end 0))))))
 346
 347 (defun pcomplete/org-mode/prop ()
 348   "Complete a property name.  Omit properties already set."
 349   (pcomplete-here
 350    (mapcar (lambda (x)
 351              (concat x ": "))
 352            (let ((lst (pcomplete-uniqify-list
 353                        (copy-sequence
 354                         (org-buffer-property-keys nil t t)))))
 355              (dolist (prop (org-entry-properties))
 356                (setq lst (delete (car prop) lst)))
 357              lst))
 358    (substring pcomplete-stub 1)))
 359
 360 (defvar org-drawers)
 361
 362 (defun pcomplete/org-mode/drawer ()
 363   "Complete a drawer name."
 364   (let ((spc (save-excursion
 365                (move-beginning-of-line 1)
 366                (looking-at "^\\([ \t]*\\):")
 367                (match-string 1)))
 368         (cpllist (mapcar (lambda (x) (concat x ": ")) org-drawers)))
 369     (pcomplete-here cpllist
 370                     (substring pcomplete-stub 1)
 371                     (unless (or (not (delq
 372                                       nil
 373                                       (mapcar (lambda(x)
 374                                                 (string-match (substring pcomplete-stub 1) x))
 375                                               cpllist)))
 376                                 (looking-at "[ \t]*\n.*:END:"))
 377                       (save-excursion (insert "\n" spc ":END:"))))))
 378
 379 (defun pcomplete/org-mode/block-option/src ()
 380   "Complete the arguments of a begin_src block.
 381 Complete a language in the first field, the header arguments and switches."
 382   (pcomplete-here
 383    (mapcar
 384     (lambda(x) (symbol-name (nth 3 x)))
 385     (cdr (car (cdr (memq :key-type (plist-get
 386                                     (symbol-plist
 387                                      'org-babel-load-languages)
 388                                     'custom-type)))))))
 389   (while (pcomplete-here
 390           '("-n" "-r" "-l"
 391             ":cache" ":colnames" ":comments" ":dir" ":eval" ":exports"
 392             ":file" ":hlines" ":no-expand" ":noweb" ":results" ":rownames"
 393             ":session" ":shebang" ":tangle" ":var"))))
 394
 395 (defun pcomplete/org-mode/block-option/clocktable ()
 396   "Complete keywords in a clocktable line."
 397   (while (pcomplete-here '(":maxlevel" ":scope"
 398                            ":tstart" ":tend" ":block" ":step"
 399                            ":stepskip0" ":fileskip0"
 400                            ":emphasize" ":link" ":narrow" ":indent"
 401                            ":tcolumns" ":level" ":compact" ":timestamp"
 402                            ":formula" ":formatter"))))
 403
 404 (defun org-pcomplete-case-double (list)
 405   "Return list with both upcase and downcase version of all strings in LIST."
 406   (let (e res)
 407     (while (setq e (pop list))
 408       (setq res (cons (downcase e) (cons (upcase e) res))))
 409     (nreverse res)))
 410
 411 ;;;; Finish up
 412
 413 (provide 'org-pcomplete)
 414
 415 ;;; org-pcomplete.el ends here