lisp/org-compat.el

   1 ;;; org-compat.el --- Compatibility code for Org-mode
   2
   3 ;; Copyright (C) 2004-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains code needed for compatibility with XEmacs and older
  28 ;; versions of GNU Emacs.
  29
  30 ;;; Code:
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'org-macs)
  36
  37 (declare-function w32-focus-frame "term/w32-win" (frame))
  38
  39 ;; The following constant is for backward compatibility.  We do not use
  40 ;; it in org-mode, because the Byte compiler evaluates (featurep 'xemacs)
  41 ;; at compilation time and can therefore optimize code better.
  42 (defconst org-xemacs-p (featurep 'xemacs))
  43 (defconst org-format-transports-properties-p
  44   (let ((x "a"))
  45     (add-text-properties 0 1 '(test t) x)
  46     (get-text-property 0 'test (format "%s" x)))
  47   "Does format transport text properties?")
  48
  49 (defun org-compatible-face (inherits specs)
  50   "Make a compatible face specification.
  51 If INHERITS is an existing face and if the Emacs version supports it,
  52 just inherit the face.  If INHERITS is set and the Emacs version does
  53 not support it, copy the face specification from the inheritance face.
  54 If INHERITS is not given and SPECS is, use SPECS to define the face.
  55 XEmacs and Emacs 21 do not know about the `min-colors' attribute.
  56 For them we convert a (min-colors 8) entry to a `tty' entry and move it
  57 to the top of the list.  The `min-colors' attribute will be removed from
  58 any other entries, and any resulting duplicates will be removed entirely."
  59   (when (and inherits (facep inherits) (not specs))
  60     (setq specs (or specs
  61                     (get inherits 'saved-face)
  62                     (get inherits 'face-defface-spec))))
  63   (cond
  64    ((and inherits (facep inherits)
  65          (not (featurep 'xemacs))
  66          (>= emacs-major-version 22)
  67          ;; do not inherit outline faces before Emacs 23
  68          (or (>= emacs-major-version 23)
  69              (not (string-match "\\`outline-[0-9]+"
  70                                 (symbol-name inherits)))))
  71     (list (list t :inherit inherits)))
  72    ((or (featurep 'xemacs) (< emacs-major-version 22))
  73     ;; These do not understand the `min-colors' attribute.
  74     (let (r e a)
  75       (while (setq e (pop specs))
  76         (cond
  77          ((memq (car e) '(t default)) (push e r))
  78          ((setq a (member '(min-colors 8) (car e)))
  79           (nconc r (list (cons (cons '(type tty) (delq (car a) (car e)))
  80                                (cdr e)))))
  81          ((setq a (assq 'min-colors (car e)))
  82           (setq e (cons (delq a (car e)) (cdr e)))
  83           (or (assoc (car e) r) (push e r)))
  84          (t (or (assoc (car e) r) (push e r)))))
  85       (nreverse r)))
  86    (t specs)))
  87 (put 'org-compatible-face 'lisp-indent-function 1)
  88
  89 (defun org-version-check (version feature level)
  90   (let* ((v1 (mapcar 'string-to-number (split-string version "[.]")))
  91          (v2 (mapcar 'string-to-number (split-string emacs-version "[.]")))
  92          (rmaj (or (nth 0 v1) 99))
  93          (rmin (or (nth 1 v1) 99))
  94          (rbld (or (nth 2 v1) 99))
  95          (maj (or (nth 0 v2) 0))
  96          (min (or (nth 1 v2) 0))
  97          (bld (or (nth 2 v2) 0)))
  98     (if (or (< maj rmaj)
  99             (and (= maj rmaj)
 100                  (< min rmin))
 101             (and (= maj rmaj)
 102                  (= min rmin)
 103                  (< bld rbld)))
 104         (if (eq level :predicate)
 105             ;; just return if we have the version
 106             nil
 107           (let ((msg (format "Emacs %s or greater is recommended for %s"
 108                              version feature)))
 109             (display-warning 'org msg level)
 110             t))
 111       t)))
 112
 113 \f
 114 ;;;; Emacs/XEmacs compatibility
 115
 116 (eval-and-compile
 117   (when (and (not (boundp 'user-emacs-directory))
 118              (boundp 'user-init-directory))
 119     (defvaralias 'user-emacs-directory 'user-init-directory)))
 120
 121 ;; Keys
 122 (defconst org-xemacs-key-equivalents
 123   '(([mouse-1] . [button1])
 124     ([mouse-2] . [button2])
 125     ([mouse-3] . [button3])
 126     ([C-mouse-4] . [(control mouse-4)])
 127     ([C-mouse-5] . [(control mouse-5)]))
 128   "Translation alist for a couple of keys.")
 129
 130 ;; Overlay compatibility functions
 131 (defun org-detach-overlay (ovl)
 132   (if (featurep 'xemacs) (detach-extent ovl) (delete-overlay ovl)))
 133 (defun org-overlay-display (ovl text &optional face evap)
 134   "Make overlay OVL display TEXT with face FACE."
 135   (if (featurep 'xemacs)
 136       (let ((gl (make-glyph text)))
 137         (and face (set-glyph-face gl face))
 138         (set-extent-property ovl 'invisible t)
 139         (set-extent-property ovl 'end-glyph gl))
 140     (overlay-put ovl 'display text)
 141     (if face (overlay-put ovl 'face face))
 142     (if evap (overlay-put ovl 'evaporate t))))
 143 (defun org-overlay-before-string (ovl text &optional face evap)
 144   "Make overlay OVL display TEXT with face FACE."
 145   (if (featurep 'xemacs)
 146       (let ((gl (make-glyph text)))
 147         (and face (set-glyph-face gl face))
 148         (set-extent-property ovl 'begin-glyph gl))
 149     (if face (org-add-props text nil 'face face))
 150     (overlay-put ovl 'before-string text)
 151     (if evap (overlay-put ovl 'evaporate t))))
 152 (defun org-find-overlays (prop &optional pos delete)
 153   "Find all overlays specifying PROP at POS or point.
 154 If DELETE is non-nil, delete all those overlays."
 155   (let ((overlays (overlays-at (or pos (point))))
 156         ov found)
 157     (while (setq ov (pop overlays))
 158       (if (overlay-get ov prop)
 159           (if delete (delete-overlay ov) (push ov found))))
 160     found))
 161
 162 (defun org-get-x-clipboard (value)
 163   "Get the value of the x clipboard, compatible with XEmacs, and GNU Emacs 21."
 164   (if (eq window-system 'x)
 165       (let ((x (org-get-x-clipboard-compat value)))
 166         (if x (org-no-properties x)))))
 167
 168 (defsubst org-decompose-region (beg end)
 169   "Decompose from BEG to END."
 170   (if (featurep 'xemacs)
 171       (let ((modified-p (buffer-modified-p))
 172             (buffer-read-only nil))
 173         (remove-text-properties beg end '(composition nil))
 174         (set-buffer-modified-p modified-p))
 175     (decompose-region beg end)))
 176
 177 ;; Miscellaneous functions
 178
 179 (defun org-add-hook (hook function &optional append local)
 180   "Add-hook, compatible with both Emacsen."
 181   (if (and local (featurep 'xemacs))
 182       (add-local-hook hook function append)
 183     (add-hook hook function append local)))
 184
 185 (defun org-add-props (string plist &rest props)
 186   "Add text properties to entire string, from beginning to end.
 187 PLIST may be a list of properties, PROPS are individual properties and values
 188 that will be added to PLIST.  Returns the string that was modified."
 189   (add-text-properties
 190    0 (length string) (if props (append plist props) plist) string)
 191   string)
 192 (put 'org-add-props 'lisp-indent-function 2)
 193
 194 (defun org-fit-window-to-buffer (&optional window max-height min-height
 195                                            shrink-only)
 196   "Fit WINDOW to the buffer, but only if it is not a side-by-side window.
 197 WINDOW defaults to the selected window.  MAX-HEIGHT and MIN-HEIGHT are
 198 passed through to `fit-window-to-buffer'.  If SHRINK-ONLY is set, call
 199 `shrink-window-if-larger-than-buffer' instead, the height limit is
 200 ignored in this case."
 201   (cond ((if (fboundp 'window-full-width-p)
 202              (not (window-full-width-p window))
 203            ;; do nothing if another window would suffer
 204            (> (frame-width) (window-width window))))
 205         ((and (fboundp 'fit-window-to-buffer) (not shrink-only))
 206          (fit-window-to-buffer window max-height min-height))
 207         ((fboundp 'shrink-window-if-larger-than-buffer)
 208          (shrink-window-if-larger-than-buffer window)))
 209   (or window (selected-window)))
 210
 211 (defun org-number-sequence (from &optional to inc)
 212   "Call `number-sequence or emulate it."
 213   (if (fboundp 'number-sequence)
 214       (number-sequence from to inc)
 215     (if (or (not to) (= from to))
 216         (list from)
 217       (or inc (setq inc 1))
 218       (when (zerop inc) (error "The increment can not be zero"))
 219       (let (seq (n 0) (next from))
 220         (if (> inc 0)
 221             (while (<= next to)
 222               (setq seq (cons next seq)
 223                     n (1+ n)
 224                     next (+ from (* n inc))))
 225           (while (>= next to)
 226             (setq seq (cons next seq)
 227                   n (1+ n)
 228                   next (+ from (* n inc)))))
 229         (nreverse seq)))))
 230
 231 ;; Region compatibility
 232
 233 (defvar org-ignore-region nil
 234   "To temporarily disable the active region.")
 235
 236 (defun org-region-active-p ()
 237   "Is `transient-mark-mode' on and the region active?
 238 Works on both Emacs and XEmacs."
 239   (if org-ignore-region
 240       nil
 241     (if (featurep 'xemacs)
 242         (and zmacs-regions (region-active-p))
 243       (if (fboundp 'use-region-p)
 244           (use-region-p)
 245         (and transient-mark-mode mark-active))))) ; Emacs 22 and before
 246
 247 (defun org-cursor-to-region-beginning ()
 248   (when (and (org-region-active-p)
 249              (> (point) (region-beginning)))
 250     (exchange-point-and-mark)))
 251
 252 ;; Emacs 22 misses `activate-mark'
 253 (if (fboundp 'activate-mark)
 254     (defalias 'org-activate-mark 'activate-mark)
 255   (defun org-activate-mark ()
 256     (when (mark t)
 257       (setq mark-active t)
 258       (when (and (boundp 'transient-mark-mode)
 259                  (not transient-mark-mode))
 260         (setq transient-mark-mode 'lambda))
 261       (when (boundp 'zmacs-regions)
 262         (setq zmacs-regions t)))))
 263
 264 ;; Invisibility compatibility
 265
 266 (defun org-remove-from-invisibility-spec (arg)
 267   "Remove elements from `buffer-invisibility-spec'."
 268   (if (fboundp 'remove-from-invisibility-spec)
 269       (remove-from-invisibility-spec arg)
 270     (if (consp buffer-invisibility-spec)
 271         (setq buffer-invisibility-spec
 272               (delete arg buffer-invisibility-spec)))))
 273
 274 (defun org-in-invisibility-spec-p (arg)
 275   "Is ARG a member of `buffer-invisibility-spec'?"
 276   (if (consp buffer-invisibility-spec)
 277       (member arg buffer-invisibility-spec)
 278     nil))
 279
 280 (defmacro org-xemacs-without-invisibility (&rest body)
 281   "Turn off extents with invisibility while executing BODY."
 282   `(let ((ext-inv (extent-list nil (point-at-bol) (point-at-eol)
 283                                'all-extents-closed-open 'invisible))
 284          ext-inv-specs)
 285      (dolist (ext ext-inv)
 286        (when (extent-property ext 'invisible)
 287          (add-to-list 'ext-inv-specs (list ext (extent-property
 288                                                 ext 'invisible)))
 289          (set-extent-property ext 'invisible nil)))
 290      ,@body
 291      (dolist (ext-inv-spec ext-inv-specs)
 292        (set-extent-property (car ext-inv-spec) 'invisible
 293                             (cadr ext-inv-spec)))))
 294 (def-edebug-spec org-xemacs-without-invisibility (body))
 295
 296 (defun org-indent-to-column (column &optional minimum buffer)
 297   "Work around a bug with extents with invisibility in XEmacs."
 298   (if (featurep 'xemacs)
 299       (org-xemacs-without-invisibility (indent-to-column column minimum buffer))
 300     (indent-to-column column minimum)))
 301
 302 (defun org-indent-line-to (column)
 303   "Work around a bug with extents with invisibility in XEmacs."
 304   (if (featurep 'xemacs)
 305       (org-xemacs-without-invisibility (indent-line-to column))
 306     (indent-line-to column)))
 307
 308 (defun org-move-to-column (column &optional force buffer)
 309   (if (featurep 'xemacs)
 310       (org-xemacs-without-invisibility (move-to-column column force buffer))
 311     (move-to-column column force)))
 312
 313 (defun org-get-x-clipboard-compat (value)
 314   "Get the clipboard value on XEmacs or Emacs 21."
 315   (cond ((featurep 'xemacs)
 316          (org-no-warnings (get-selection-no-error value)))
 317         ((fboundp 'x-get-selection)
 318          (condition-case nil
 319              (or (x-get-selection value 'UTF8_STRING)
 320                  (x-get-selection value 'COMPOUND_TEXT)
 321                  (x-get-selection value 'STRING)
 322                  (x-get-selection value 'TEXT))
 323            (error nil)))))
 324
 325 (defun org-propertize (string &rest properties)
 326   (if (featurep 'xemacs)
 327       (progn
 328         (add-text-properties 0 (length string) properties string)
 329         string)
 330     (apply 'propertize string properties)))
 331
 332 (defmacro org-find-library-dir (library)
 333   `(file-name-directory (or (locate-library ,library) "")))
 334
 335 (defun org-count-lines (s)
 336   "How many lines in string S?"
 337   (let ((start 0) (n 1))
 338     (while (string-match "\n" s start)
 339       (setq start (match-end 0) n (1+ n)))
 340     (if (and (> (length s) 0) (= (aref s (1- (length s))) ?\n))
 341         (setq n (1- n)))
 342     n))
 343
 344 (defun org-kill-new (string &rest args)
 345   (remove-text-properties 0 (length string) '(line-prefix t wrap-prefix t)
 346                           string)
 347   (apply 'kill-new string args))
 348
 349 (defun org-select-frame-set-input-focus (frame)
 350   "Select FRAME, raise it, and set input focus, if possible."
 351   (cond ((featurep 'xemacs)
 352          (if (fboundp 'select-frame-set-input-focus)
 353              (select-frame-set-input-focus frame)
 354            (raise-frame frame)
 355            (select-frame frame)
 356            (focus-frame frame)))
 357         ;; `select-frame-set-input-focus' defined in Emacs 21 will not
 358         ;; set the input focus.
 359         ((>= emacs-major-version 22)
 360          (select-frame-set-input-focus frame))
 361         (t
 362          (raise-frame frame)
 363          (select-frame frame)
 364          (cond ((memq window-system '(x ns mac))
 365                 (x-focus-frame frame))
 366                ((eq window-system 'w32)
 367                 (w32-focus-frame frame)))
 368          (when focus-follows-mouse
 369            (set-mouse-position frame (1- (frame-width frame)) 0)))))
 370
 371 (defun org-float-time (&optional time)
 372   "Convert time value TIME to a floating point number.
 373 TIME defaults to the current time."
 374   (if (featurep 'xemacs)
 375       (time-to-seconds (or time (current-time)))
 376     (float-time time)))
 377
 378 ;; `user-error' is only available from 24.2.50 on
 379 (unless (fboundp 'user-error)
 380   (defalias 'user-error 'error))
 381
 382 (defmacro org-no-popups (&rest body)
 383   "Suppress popup windows.
 384 Let-bind some variables to nil around BODY to achieve the desired
 385 effect, which variables to use depends on the Emacs version."
 386     (if (org-version-check "24.2.50" "" :predicate)
 387         `(let (pop-up-frames display-buffer-alist)
 388            ,@body)
 389       `(let (pop-up-frames special-display-buffer-names special-display-regexps special-display-function)
 390          ,@body)))
 391
 392 (if (fboundp 'string-match-p)
 393     (defalias 'org-string-match-p 'string-match-p)
 394   (defun org-string-match-p (regexp string &optional start)
 395     (save-match-data
 396       (funcall 'string-match regexp string start))))
 397
 398 (if (fboundp 'looking-at-p)
 399     (defalias 'org-looking-at-p 'looking-at-p)
 400   (defun org-looking-at-p (&rest args)
 401     (save-match-data
 402       (apply 'looking-at args))))
 403
 404 ;; XEmacs does not have `looking-back'.
 405 (if (fboundp 'looking-back)
 406     (defalias 'org-looking-back 'looking-back)
 407   (defun org-looking-back (regexp &optional limit greedy)
 408     "Return non-nil if text before point matches regular expression REGEXP.
 409 Like `looking-at' except matches before point, and is slower.
 410 LIMIT if non-nil speeds up the search by specifying a minimum
 411 starting position, to avoid checking matches that would start
 412 before LIMIT.
 413
 414 If GREEDY is non-nil, extend the match backwards as far as
 415 possible, stopping when a single additional previous character
 416 cannot be part of a match for REGEXP.  When the match is
 417 extended, its starting position is allowed to occur before
 418 LIMIT."
 419     (let ((start (point))
 420           (pos
 421            (save-excursion
 422              (and (re-search-backward (concat "\\(?:" regexp "\\)\\=") limit t)
 423                   (point)))))
 424       (if (and greedy pos)
 425           (save-restriction
 426             (narrow-to-region (point-min) start)
 427             (while (and (> pos (point-min))
 428                         (save-excursion
 429                           (goto-char pos)
 430                           (backward-char 1)
 431                           (looking-at (concat "\\(?:"  regexp "\\)\\'"))))
 432               (setq pos (1- pos)))
 433             (save-excursion
 434               (goto-char pos)
 435               (looking-at (concat "\\(?:"  regexp "\\)\\'")))))
 436       (not (null pos)))))
 437
 438 (defun org-floor* (x &optional y)
 439   "Return a list of the floor of X and the fractional part of X.
 440 With two arguments, return floor and remainder of their quotient."
 441   (let ((q (floor x y)))
 442     (list q (- x (if y (* y q) q)))))
 443
 444 ;; `pop-to-buffer-same-window' has been introduced in Emacs 24.1.
 445 (defun org-pop-to-buffer-same-window
 446   (&optional buffer-or-name norecord label)
 447   "Pop to buffer specified by BUFFER-OR-NAME in the selected window."
 448   (if (fboundp 'pop-to-buffer-same-window)
 449       (funcall
 450        'pop-to-buffer-same-window buffer-or-name norecord)
 451     (funcall 'switch-to-buffer buffer-or-name norecord)))
 452
 453 ;; RECURSIVE has been introduced with Emacs 23.2.
 454 ;; This is copying and adapted from `tramp-compat-delete-directory'
 455 (defun org-delete-directory (directory &optional recursive)
 456   "Compatibility function for `delete-directory'."
 457   (if (null recursive)
 458       (delete-directory directory)
 459     (condition-case nil
 460         (funcall 'delete-directory directory recursive)
 461       ;; This Emacs version does not support the RECURSIVE flag.  We
 462       ;; use the implementation from Emacs 23.2.
 463       (wrong-number-of-arguments
 464        (setq directory (directory-file-name (expand-file-name directory)))
 465        (if (not (file-symlink-p directory))
 466            (mapc (lambda (file)
 467                    (if (eq t (car (file-attributes file)))
 468                        (org-delete-directory file recursive)
 469                      (delete-file file)))
 470                  (directory-files
 471                   directory 'full "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")))
 472        (delete-directory directory)))))
 473
 474 ;;;###autoload
 475 (defmacro org-check-version ()
 476   "Try very hard to provide sensible version strings."
 477   (let* ((org-dir        (org-find-library-dir "org"))
 478          (org-version.el (concat org-dir "org-version.el"))
 479          (org-fixup.el   (concat org-dir "../mk/org-fixup.el")))
 480     (if (require 'org-version org-version.el 'noerror)
 481         '(progn
 482            (autoload 'org-release     "org-version.el")
 483            (autoload 'org-git-version "org-version.el"))
 484       (if (require 'org-fixup org-fixup.el 'noerror)
 485           '(org-fixup)
 486         ;; provide fallback definitions and complain
 487         (warn "Could not define org version correctly.  Check installation!")
 488         '(progn
 489            (defun org-release () "N/A")
 490            (defun org-git-version () "N/A !!check installation!!"))))))
 491
 492 (defun org-file-equal-p (f1 f2)
 493   "Return t if files F1 and F2 are the same.
 494 Implements `file-equal-p' for older emacsen and XEmacs."
 495   (if (fboundp 'file-equal-p)
 496       (file-equal-p f1 f2)
 497     (let (f1-attr f2-attr)
 498       (and (setq f1-attr (file-attributes (file-truename f1)))
 499            (setq f2-attr (file-attributes (file-truename f2)))
 500            (equal f1-attr f2-attr)))))
 501
 502 (defmacro org-with-silent-modifications (&rest body)
 503   (if (fboundp 'with-silent-modifications)
 504       `(with-silent-modifications ,@body)
 505     `(org-unmodified ,@body)))
 506 (def-edebug-spec org-with-silent-modifications (body))
 507
 508 (provide 'org-compat)
 509
 510 ;;; org-compat.el ends here