lisp/ox-md.el

   1 ;;; ox-md.el --- Markdown Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2012, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp, markdown
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; This library implements a Markdown back-end (vanilla flavour) for
  24 ;; Org exporter, based on `html' back-end.
  25 ;;
  26 ;; It provides two commands for export, depending on the desired
  27 ;; output: `org-md-export-as-markdown' (temporary buffer) and
  28 ;; `org-md-export-to-markdown' ("md" file).
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33 (require 'ox-html)
  34
  35
  36 \f
  37 ;;; User-Configurable Variables
  38
  39 (defgroup org-export-md nil
  40   "Options specific to Markdown export back-end."
  41   :tag "Org Markdown"
  42   :group 'org-export
  43   :version "24.4"
  44   :package-version '(Org . "8.0"))
  45
  46 (defcustom org-md-headline-style 'atx
  47   "Style used to format headlines.
  48 This variable can be set to either `atx' or `setext'."
  49   :group 'org-export-md
  50   :type '(choice
  51           (const :tag "Use \"atx\" style" atx)
  52           (const :tag "Use \"Setext\" style" setext)))
  53
  54
  55 \f
  56 ;;; Define Back-End
  57
  58 (org-export-define-derived-backend 'md 'html
  59   :export-block '("MD" "MARKDOWN")
  60   :filters-alist '((:filter-parse-tree . org-md-separate-elements))
  61   :menu-entry
  62   '(?m "Export to Markdown"
  63        ((?M "To temporary buffer"
  64             (lambda (a s v b) (org-md-export-as-markdown a s v)))
  65         (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
  66         (?o "To file and open"
  67             (lambda (a s v b)
  68               (if a (org-md-export-to-markdown t s v)
  69                 (org-open-file (org-md-export-to-markdown nil s v)))))))
  70   :translate-alist '((bold . org-md-bold)
  71                      (code . org-md-verbatim)
  72                      (underline . org-md-verbatim)
  73                      (comment . (lambda (&rest args) ""))
  74                      (comment-block . (lambda (&rest args) ""))
  75                      (example-block . org-md-example-block)
  76                      (fixed-width . org-md-example-block)
  77                      (footnote-definition . ignore)
  78                      (footnote-reference . ignore)
  79                      (headline . org-md-headline)
  80                      (horizontal-rule . org-md-horizontal-rule)
  81                      (inline-src-block . org-md-verbatim)
  82                      (italic . org-md-italic)
  83                      (item . org-md-item)
  84                      (line-break . org-md-line-break)
  85                      (link . org-md-link)
  86                      (paragraph . org-md-paragraph)
  87                      (plain-list . org-md-plain-list)
  88                      (plain-text . org-md-plain-text)
  89                      (quote-block . org-md-quote-block)
  90                      (quote-section . org-md-example-block)
  91                      (section . org-md-section)
  92                      (src-block . org-md-example-block)
  93                      (template . org-md-template)
  94                      (verbatim . org-md-verbatim)))
  95
  96
  97 \f
  98 ;;; Filters
  99
 100 (defun org-md-separate-elements (tree backend info)
 101   "Make sure elements are separated by at least one blank line.
 102
 103 TREE is the parse tree being exported.  BACKEND is the export
 104 back-end used.  INFO is a plist used as a communication channel.
 105
 106 Assume BACKEND is `md'."
 107   (org-element-map tree org-element-all-elements
 108     (lambda (elem)
 109       (unless (eq (org-element-type elem) 'org-data)
 110         (org-element-put-property
 111          elem :post-blank
 112          (let ((post-blank (org-element-property :post-blank elem)))
 113            (if (not post-blank) 1 (max 1 post-blank)))))))
 114   ;; Return updated tree.
 115   tree)
 116
 117
 118 \f
 119 ;;; Transcode Functions
 120
 121 ;;;; Bold
 122
 123 (defun org-md-bold (bold contents info)
 124   "Transcode BOLD object into Markdown format.
 125 CONTENTS is the text within bold markup.  INFO is a plist used as
 126 a communication channel."
 127   (format "**%s**" contents))
 128
 129
 130 ;;;; Code and Verbatim
 131
 132 (defun org-md-verbatim (verbatim contents info)
 133   "Transcode VERBATIM object into Markdown format.
 134 CONTENTS is nil.  INFO is a plist used as a communication
 135 channel."
 136   (let ((value (org-element-property :value verbatim)))
 137     (format (cond ((not (string-match "`" value)) "`%s`")
 138                   ((or (string-match "\\``" value)
 139                        (string-match "`\\'" value))
 140                    "`` %s ``")
 141                   (t "``%s``"))
 142             value)))
 143
 144
 145 ;;;; Example Block and Src Block
 146
 147 (defun org-md-example-block (example-block contents info)
 148   "Transcode EXAMPLE-BLOCK element into Markdown format.
 149 CONTENTS is nil.  INFO is a plist used as a communication
 150 channel."
 151   (replace-regexp-in-string
 152    "^" "    "
 153    (org-remove-indentation
 154     (org-element-property :value example-block))))
 155
 156
 157 ;;;; Headline
 158
 159 (defun org-md-headline (headline contents info)
 160   "Transcode HEADLINE element into Markdown format.
 161 CONTENTS is the headline contents.  INFO is a plist used as
 162 a communication channel."
 163   (unless (org-element-property :footnote-section-p headline)
 164     (let* ((level (org-export-get-relative-level headline info))
 165            (title (org-export-data (org-element-property :title headline) info))
 166            (todo (and (plist-get info :with-todo-keywords)
 167                       (let ((todo (org-element-property :todo-keyword
 168                                                         headline)))
 169                         (and todo (concat (org-export-data todo info) " ")))))
 170            (tags (and (plist-get info :with-tags)
 171                       (let ((tag-list (org-export-get-tags headline info)))
 172                         (and tag-list
 173                              (format "     :%s:"
 174                                      (mapconcat 'identity tag-list ":"))))))
 175            (priority
 176             (and (plist-get info :with-priority)
 177                  (let ((char (org-element-property :priority headline)))
 178                    (and char (format "[#%c] " char)))))
 179            ;; Headline text without tags.
 180            (heading (concat todo priority title)))
 181       (cond
 182        ;; Cannot create a headline.  Fall-back to a list.
 183        ((or (org-export-low-level-p headline info)
 184             (not (memq org-md-headline-style '(atx setext)))
 185             (and (eq org-md-headline-style 'atx) (> level 6))
 186             (and (eq org-md-headline-style 'setext) (> level 2)))
 187         (let ((bullet
 188                (if (not (org-export-numbered-headline-p headline info)) "-"
 189                  (concat (number-to-string
 190                           (car (last (org-export-get-headline-number
 191                                       headline info))))
 192                          "."))))
 193           (concat bullet (make-string (- 4 (length bullet)) ? ) heading tags
 194                   "\n\n"
 195                   (and contents
 196                        (replace-regexp-in-string "^" "    " contents)))))
 197        ;; Use "Setext" style.
 198        ((eq org-md-headline-style 'setext)
 199         (concat heading tags "\n"
 200                 (make-string (length heading) (if (= level 1) ?= ?-))
 201                 "\n\n"
 202                 contents))
 203        ;; Use "atx" style.
 204        (t (concat (make-string level ?#) " " heading tags "\n\n" contents))))))
 205
 206
 207 ;;;; Horizontal Rule
 208
 209 (defun org-md-horizontal-rule (horizontal-rule contents info)
 210   "Transcode HORIZONTAL-RULE element into Markdown format.
 211 CONTENTS is the horizontal rule contents.  INFO is a plist used
 212 as a communication channel."
 213   "---")
 214
 215
 216 ;;;; Italic
 217
 218 (defun org-md-italic (italic contents info)
 219   "Transcode ITALIC object into Markdown format.
 220 CONTENTS is the text within italic markup.  INFO is a plist used
 221 as a communication channel."
 222   (format "*%s*" contents))
 223
 224
 225 ;;;; Item
 226
 227 (defun org-md-item (item contents info)
 228   "Transcode ITEM element into Markdown format.
 229 CONTENTS is the item contents.  INFO is a plist used as
 230 a communication channel."
 231   (let* ((type (org-element-property :type (org-export-get-parent item)))
 232          (struct (org-element-property :structure item))
 233          (bullet (if (not (eq type 'ordered)) "-"
 234                    (concat (number-to-string
 235                             (car (last (org-list-get-item-number
 236                                         (org-element-property :begin item)
 237                                         struct
 238                                         (org-list-prevs-alist struct)
 239                                         (org-list-parents-alist struct)))))
 240                            "."))))
 241     (concat bullet
 242             (make-string (- 4 (length bullet)) ? )
 243             (case (org-element-property :checkbox item)
 244               (on "[X] ")
 245               (trans "[-] ")
 246               (off "[ ] "))
 247             (let ((tag (org-element-property :tag item)))
 248               (and tag (format "**%s:** "(org-export-data tag info))))
 249             (org-trim (replace-regexp-in-string "^" "    " contents)))))
 250
 251
 252 ;;;; Line Break
 253
 254 (defun org-md-line-break (line-break contents info)
 255   "Transcode LINE-BREAK object into Markdown format.
 256 CONTENTS is nil.  INFO is a plist used as a communication
 257 channel."
 258   "  \n")
 259
 260
 261 ;;;; Link
 262
 263 (defun org-md-link (link contents info)
 264   "Transcode LINE-BREAK object into Markdown format.
 265 CONTENTS is the link's description.  INFO is a plist used as
 266 a communication channel."
 267   (let ((--link-org-files-as-html-maybe
 268          (function
 269           (lambda (raw-path info)
 270             ;; Treat links to `file.org' as links to `file.html', if
 271             ;; needed.  See `org-html-link-org-files-as-html'.
 272             (cond
 273              ((and org-html-link-org-files-as-html
 274                    (string= ".org"
 275                             (downcase (file-name-extension raw-path "."))))
 276               (concat (file-name-sans-extension raw-path) "."
 277                       (plist-get info :html-extension)))
 278              (t raw-path)))))
 279         (type (org-element-property :type link)))
 280     (cond ((member type '("custom-id" "id"))
 281            (let ((destination (org-export-resolve-id-link link info)))
 282              (if (stringp destination)  ; External file.
 283                  (let ((path (funcall --link-org-files-as-html-maybe
 284                                       destination info)))
 285                    (if (not contents) (format "<%s>" path)
 286                      (format "[%s](%s)" contents path)))
 287                (concat
 288                 (and contents (concat contents " "))
 289                 (format "(%s)"
 290                         (format (org-export-translate "See section %s" :html info)
 291                                 (mapconcat 'number-to-string
 292                                            (org-export-get-headline-number
 293                                             destination info)
 294                                            ".")))))))
 295           ((org-export-inline-image-p link org-html-inline-image-rules)
 296            (let ((path (let ((raw-path (org-element-property :path link)))
 297                          (if (not (file-name-absolute-p raw-path)) raw-path
 298                            (expand-file-name raw-path)))))
 299              (format "![%s](%s)"
 300                      (let ((caption (org-export-get-caption
 301                                      (org-export-get-parent-element link))))
 302                        (when caption (org-export-data caption info)))
 303                      path)))
 304           ((string= type "coderef")
 305            (let ((ref (org-element-property :path link)))
 306              (format (org-export-get-coderef-format ref contents)
 307                      (org-export-resolve-coderef ref info))))
 308           ((equal type "radio")
 309            (let ((destination (org-export-resolve-radio-link link info)))
 310              (org-export-data (org-element-contents destination) info)))
 311           ((equal type "fuzzy")
 312            (let ((destination (org-export-resolve-fuzzy-link link info)))
 313              ;; Ignore invisible "#+TARGET: path".
 314              (unless (eq (org-element-type destination) 'keyword)
 315                (if (org-string-nw-p contents) contents
 316                  (when destination
 317                    (let ((number (org-export-get-ordinal destination info)))
 318                      (when number
 319                        (if (atom number) (number-to-string number)
 320                          (mapconcat 'number-to-string number ".")))))))))
 321           (t (let* ((raw-path (org-element-property :path link))
 322                     (path (cond
 323                            ((member type '("http" "https" "ftp"))
 324                             (concat type ":" raw-path))
 325                            ((equal type "file")
 326                             ;; Treat links to ".org" files as ".html",
 327                             ;; if needed.
 328                             (setq raw-path
 329                                   (funcall --link-org-files-as-html-maybe
 330                                            raw-path info))
 331                             ;; If file path is absolute, prepend it
 332                             ;; with protocol component - "file://".
 333                             (if (not (file-name-absolute-p raw-path)) raw-path
 334                               (concat "file://" (expand-file-name raw-path))))
 335                            (t raw-path))))
 336                (if (not contents) (format "<%s>" path)
 337                  (format "[%s](%s)" contents path)))))))
 338
 339
 340 ;;;; Paragraph
 341
 342 (defun org-md-paragraph (paragraph contents info)
 343   "Transcode PARAGRAPH element into Markdown format.
 344 CONTENTS is the paragraph contents.  INFO is a plist used as
 345 a communication channel."
 346   (let ((first-object (car (org-element-contents paragraph))))
 347     ;; If paragraph starts with a #, protect it.
 348     (if (and (stringp first-object) (string-match "\\`#" first-object))
 349         (replace-regexp-in-string "\\`#" "\\#" contents nil t)
 350       contents)))
 351
 352
 353 ;;;; Plain List
 354
 355 (defun org-md-plain-list (plain-list contents info)
 356   "Transcode PLAIN-LIST element into Markdown format.
 357 CONTENTS is the plain-list contents.  INFO is a plist used as
 358 a communication channel."
 359   contents)
 360
 361
 362 ;;;; Plain Text
 363
 364 (defun org-md-plain-text (text info)
 365   "Transcode a TEXT string into Markdown format.
 366 TEXT is the string to transcode.  INFO is a plist holding
 367 contextual information."
 368   (when (plist-get info :with-smart-quotes)
 369     (setq text (org-export-activate-smart-quotes text :html info)))
 370   ;; Protect ambiguous #.  This will protect # at the beginning of
 371   ;; a line, but not at the beginning of a paragraph.  See
 372   ;; `org-md-paragraph'.
 373   (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
 374   ;; Protect ambiguous !
 375   (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
 376   ;; Protect `, *, _ and \
 377   (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
 378   ;; Handle special strings, if required.
 379   (when (plist-get info :with-special-strings)
 380     (setq text (org-html-convert-special-strings text)))
 381   ;; Handle break preservation, if required.
 382   (when (plist-get info :preserve-breaks)
 383     (setq text (replace-regexp-in-string "[ \t]*\n" "  \n" text)))
 384   ;; Return value.
 385   text)
 386
 387
 388 ;;;; Quote Block
 389
 390 (defun org-md-quote-block (quote-block contents info)
 391   "Transcode QUOTE-BLOCK element into Markdown format.
 392 CONTENTS is the quote-block contents.  INFO is a plist used as
 393 a communication channel."
 394   (replace-regexp-in-string
 395    "^" "> "
 396    (replace-regexp-in-string "\n\\'" "" contents)))
 397
 398
 399 ;;;; Section
 400
 401 (defun org-md-section (section contents info)
 402   "Transcode SECTION element into Markdown format.
 403 CONTENTS is the section contents.  INFO is a plist used as
 404 a communication channel."
 405   contents)
 406
 407
 408 ;;;; Template
 409
 410 (defun org-md-template (contents info)
 411   "Return complete document string after Markdown conversion.
 412 CONTENTS is the transcoded contents string.  INFO is a plist used
 413 as a communication channel."
 414   contents)
 415
 416
 417 \f
 418 ;;; Interactive function
 419
 420 ;;;###autoload
 421 (defun org-md-export-as-markdown (&optional async subtreep visible-only)
 422   "Export current buffer to a Markdown buffer.
 423
 424 If narrowing is active in the current buffer, only export its
 425 narrowed part.
 426
 427 If a region is active, export that region.
 428
 429 A non-nil optional argument ASYNC means the process should happen
 430 asynchronously.  The resulting buffer should be accessible
 431 through the `org-export-stack' interface.
 432
 433 When optional argument SUBTREEP is non-nil, export the sub-tree
 434 at point, extracting information from the headline properties
 435 first.
 436
 437 When optional argument VISIBLE-ONLY is non-nil, don't export
 438 contents of hidden elements.
 439
 440 Export is done in a buffer named \"*Org MD Export*\", which will
 441 be displayed when `org-export-show-temporary-export-buffer' is
 442 non-nil."
 443   (interactive)
 444   (if async
 445       (org-export-async-start
 446           (lambda (output)
 447             (with-current-buffer (get-buffer-create "*Org MD Export*")
 448               (erase-buffer)
 449               (insert output)
 450               (goto-char (point-min))
 451               (text-mode)
 452               (org-export-add-to-stack (current-buffer) 'md)))
 453         `(org-export-as 'md ,subtreep ,visible-only))
 454     (let ((outbuf (org-export-to-buffer
 455                    'md "*Org MD Export*" subtreep visible-only)))
 456       (with-current-buffer outbuf (text-mode))
 457       (when org-export-show-temporary-export-buffer
 458         (switch-to-buffer-other-window outbuf)))))
 459
 460
 461 ;;;###autoload
 462 (defun org-md-export-to-markdown (&optional async subtreep visible-only)
 463   "Export current buffer to a Markdown file.
 464
 465 If narrowing is active in the current buffer, only export its
 466 narrowed part.
 467
 468 If a region is active, export that region.
 469
 470 A non-nil optional argument ASYNC means the process should happen
 471 asynchronously.  The resulting file should be accessible through
 472 the `org-export-stack' interface.
 473
 474 When optional argument SUBTREEP is non-nil, export the sub-tree
 475 at point, extracting information from the headline properties
 476 first.
 477
 478 When optional argument VISIBLE-ONLY is non-nil, don't export
 479 contents of hidden elements.
 480
 481 Return output file's name."
 482   (interactive)
 483   (let ((outfile (org-export-output-file-name ".md" subtreep)))
 484     (if async
 485         (org-export-async-start
 486             (lambda (f) (org-export-add-to-stack f 'md))
 487           `(expand-file-name
 488             (org-export-to-file 'md ,outfile ,subtreep ,visible-only)))
 489       (org-export-to-file 'md outfile subtreep visible-only))))
 490
 491
 492 (provide 'ox-md)
 493
 494 ;; Local variables:
 495 ;; generated-autoload-file: "org-loaddefs.el"
 496 ;; End:
 497
 498 ;;; ox-md.el ends here