lisp/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008, 2009 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.30d
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements globally unique identifiers for Org-mode entries.
  29 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  30 ;; are provided that create and retrieve such identifiers, and that find
  31 ;; entries based on the identifier.
  32
  33 ;; Identifiers consist of a prefix (default "Org" given by the variable
  34 ;; `org-id-prefix') and a unique part that can be created by a number
  35 ;; of different methods, see the variable `org-id-method'.
  36 ;; Org has a builtin method that uses a compact encoding of the creation
  37 ;; time of the ID, with microsecond accuracy.  This virtually
  38 ;; guarantees globally unique identifiers, even if several people are
  39 ;; creating IDs at the same time in files that will eventually be used
  40 ;; together.  As an external method `uuidgen' is supported, if installed
  41 ;; on the system.
  42 ;;
  43 ;; This file defines the following API:
  44 ;;
  45 ;; org-id-get-create
  46 ;;        Create an ID for the entry at point if it does not yet have one.
  47 ;;        Returns the ID (old or new).  This function can be used
  48 ;;        interactively, with prefix argument the creation of a new ID is
  49 ;;        forced, even if there was an old one.
  50 ;;
  51 ;; org-id-get
  52 ;;        Get the ID property of an entry.  Using appropriate arguments
  53 ;;        to the function, it can also create the ID for this entry.
  54 ;;
  55 ;; org-id-goto
  56 ;;        Command to go to a specific ID, this command can be used
  57 ;;        interactively.
  58 ;;
  59 ;; org-id-get-with-outline-path-completion
  60 ;;        Retrieve the ID of an entry, using outline path completion.
  61 ;;        This function can work for multiple files.
  62 ;;
  63 ;; org-id-get-with-outline-drilling
  64 ;;        Retrieve the ID of an entry, using outline path completion.
  65 ;;        This function only works for the current file.
  66 ;;
  67 ;; org-id-find
  68 ;;        Find the location of an entry with specific id.
  69 ;;
  70
  71 (require 'org)
  72
  73 (declare-function message-make-fqdn "message" ())
  74
  75 ;;; Customization
  76
  77 (defgroup org-id nil
  78   "Options concerning global entry identifiers in Org-mode."
  79   :tag "Org ID"
  80   :group 'org)
  81
  82 (defcustom org-id-uuid-program "uuidgen"
  83   "The uuidgen program."
  84   :group 'org-id
  85   :type 'string)
  86
  87 (defcustom org-id-method
  88   (condition-case nil
  89       (if (string-match "\\`[-0-9a-fA-F]\\{36\\}\\'"
  90                         (org-trim (shell-command-to-string
  91                                    org-id-uuid-program)))
  92           'uuidgen
  93         'org)
  94     (error 'org))
  95   "The method that should be used to create new IDs.
  96
  97 If `uuidgen' is available on the system, it will be used as the default method.
  98 if not, the method `org' is used.
  99 An ID will consist of the optional prefix specified in `org-id-prefix',
 100 and a unique part created by the method this variable specifies.
 101
 102 Allowed values are:
 103
 104 org        Org's own internal method, using an encoding of the current time to
 105            microsecond accuracy, and optionally the current domain of the
 106            computer.  See the variable `org-id-include-domain'.
 107
 108 uuidgen    Call the external command uuidgen."
 109   :group 'org-id
 110   :type '(choice
 111           (const :tag "Org's internal method" org)
 112           (const :tag "external: uuidgen" uuidgen)))
 113
 114 (defcustom org-id-prefix nil
 115   "The prefix for IDs.
 116
 117 This may be a string, or it can be nil to indicate that no prefix is required.
 118 When a string, the string should have no space characters as IDs are expected
 119 to have no space characters in them."
 120   :group 'org-id
 121   :type '(choice
 122           (const :tag "No prefix")
 123           (string :tag "Prefix")))
 124
 125 (defcustom org-id-include-domain nil
 126   "Non-nil means, add the domain name to new IDs.
 127 This ensures global uniqueness of IDs, and is also suggested by
 128 RFC 2445 in combination with RFC 822.  This is only relevant if
 129 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 130 be added.
 131 The default is to not use this because we have no really good way to get
 132 the true domain, and Org entries will normally not be shared with enough
 133 people to make this necessary."
 134   :group 'org-id
 135   :type 'boolean)
 136
 137 (defcustom org-id-track-globally t
 138   "Non-nil means, track IDs through files, so that links work globally.
 139 This work by maintaining a hash table for IDs and writing this table
 140 to disk when exiting Emacs.  Because of this, it works best if you use
 141 a single Emacs process, not many.
 142
 143 When nil, IDs are not tracked.  Links to IDs will still work within
 144 a buffer, but not if the entry is located in another file.
 145 IDs can still be used if the entry with the id is in the same file as
 146 the link."
 147   :group 'org-id
 148   :type 'boolean)
 149
 150 (defcustom org-id-locations-file (convert-standard-filename
 151                                   "~/.emacs.d/.org-id-locations")
 152   "The file for remembering in which file an ID was defined.
 153 This variable is only relevant when `org-id-track-globally' is set."
 154   :group 'org-id
 155   :type 'file)
 156
 157 (defvar org-id-locations nil
 158   "List of files with IDs in those files.
 159 Depending on `org-id-use-hash' this can also be a hash table mapping IDs
 160 to files.")
 161
 162 (defvar org-id-files nil
 163   "List of files that contain IDs.")
 164
 165 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 166   "Files to be searched for IDs, besides the agenda files.
 167 When Org reparses files to remake the list of files and IDs it is tracking,
 168 it will normally scan the agenda files, the archives related to agenda files,
 169 any files that are listed as ID containing in the current register, and
 170 any Org-mode files currently visited by Emacs.
 171 You can list additional files here.
 172 This variable is only relevant when `org-id-track-globally' is set."
 173   :group 'org-id
 174   :type
 175   '(choice
 176     (symbol :tag "Variable")
 177     (repeat :tag "List of files"
 178             (file))))
 179
 180 (defcustom org-id-search-archives t
 181   "Non-nil means, search also the archive files of agenda files for entries.
 182 This is a possibility to reduce overhead, but it means that entries moved
 183 to the archives can no longer be found by ID.
 184 This variable is only relevant when `org-id-track-globally' is set."
 185   :group 'org-id
 186   :type 'boolean)
 187
 188 ;;; The API functions
 189
 190 ;;;###autoload
 191 (defun org-id-get-create (&optional force)
 192   "Create an ID for the current entry and return it.
 193 If the entry already has an ID, just return it.
 194 With optional argument FORCE, force the creation of a new ID."
 195   (interactive "P")
 196   (when force
 197     (org-entry-put (point) "ID" nil))
 198   (org-id-get (point) 'create))
 199
 200 ;;;###autoload
 201 (defun org-id-copy ()
 202   "Copy the ID of the entry at point to the kill ring.
 203 Create an ID if necessary."
 204   (interactive)
 205   (org-kill-new (org-id-get nil 'create)))
 206
 207 ;;;###autoload
 208 (defun org-id-get (&optional pom create prefix)
 209   "Get the ID property of the entry at point-or-marker POM.
 210 If POM is nil, refer to the entry at point.
 211 If the entry does not have an ID, the function returns nil.
 212 However, when CREATE is non nil, create an ID if none is present already.
 213 PREFIX will be passed through to `org-id-new'.
 214 In any case, the ID of the entry is returned."
 215   (let ((id (org-entry-get pom "ID")))
 216     (cond
 217      ((and id (stringp id) (string-match "\\S-" id))
 218       id)
 219      (create
 220       (setq id (org-id-new prefix))
 221       (org-entry-put pom "ID" id)
 222       (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 223       id)
 224      (t nil))))
 225
 226 ;;;###autoload
 227 (defun org-id-get-with-outline-path-completion (&optional targets)
 228   "Use outline-path-completion to retrieve the ID of an entry.
 229 TARGETS may be a setting for `org-refile-targets' to define the eligible
 230 headlines.  When omitted, all headlines in all agenda files are
 231 eligible.
 232 It returns the ID of the entry.  If necessary, the ID is created."
 233   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 234          (org-refile-use-outline-path
 235           (if (caar org-refile-targets) 'file t))
 236          (org-refile-target-verify-function nil)
 237          (spos (org-refile-get-location "Entry: "))
 238          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 239                                      (get-file-buffer (nth 1 spos))))))
 240     (prog1 (org-id-get pom 'create)
 241       (move-marker pom nil))))
 242
 243 ;;;###autoload
 244 (defun org-id-get-with-outline-drilling (&optional targets)
 245   "Use an outline-cycling interface to retrieve the ID of an entry.
 246 This only finds entries in the current buffer, using `org-get-location'.
 247 It returns the ID of the entry.  If necessary, the ID is created."
 248   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 249          (pom (and spos (move-marker (make-marker) (car spos)))))
 250     (prog1 (org-id-get pom 'create)
 251       (move-marker pom nil))))
 252
 253 ;;;###autoload
 254 (defun org-id-goto (id)
 255   "Switch to the buffer containing the entry with id ID.
 256 Move the cursor to that entry in that buffer."
 257   (interactive "sID: ")
 258   (let ((m (org-id-find id 'marker)))
 259     (unless m
 260       (error "Cannot find entry with ID \"%s\"" id))
 261     (switch-to-buffer (marker-buffer m))
 262     (goto-char m)
 263     (move-marker m nil)
 264     (org-show-context)))
 265
 266 ;;;###autoload
 267 (defun org-id-find (id &optional markerp)
 268   "Return the location of the entry with the id ID.
 269 The return value is a cons cell (file-name . position), or nil
 270 if there is no entry with that ID.
 271 With optional argument MARKERP, return the position as a new marker."
 272   (cond
 273    ((symbolp id) (setq id (symbol-name id)))
 274    ((numberp id) (setq id (number-to-string id))))
 275   (let ((file (org-id-find-id-file id))
 276         org-agenda-new-buffers where)
 277     (when file
 278       (setq where (org-id-find-id-in-file id file markerp)))
 279     (unless where
 280       (org-id-update-id-locations)
 281       (setq file (org-id-find-id-file id))
 282       (when file
 283         (setq where (org-id-find-id-in-file id file markerp))))
 284     where))
 285
 286 ;;; Internal functions
 287
 288 ;; Creating new IDs
 289
 290 (defun org-id-new (&optional prefix)
 291   "Create a new globally unique ID.
 292
 293 An ID consists of two parts separated by a colon:
 294 - a prefix
 295 - a unique part that will be created according to `org-id-method'.
 296
 297 PREFIX can specify the prefix, the default is given by the variable
 298 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 299 prefix even if `org-id-prefix' specifies one.
 300
 301 So a typical ID could look like \"Org:4nd91V40HI\"."
 302   (let* ((prefix (if (eq prefix 'none)
 303                      ""
 304                    (concat (or prefix org-id-prefix) ":")))
 305          unique)
 306     (if (equal prefix ":") (setq prefix ""))
 307     (cond
 308      ((eq org-id-method 'uuidgen)
 309       (setq unique (org-trim (shell-command-to-string org-id-uuid-program))))
 310      ((eq org-id-method 'org)
 311       (let* ((etime (org-id-reverse-string (org-id-time-to-b36)))
 312              (postfix (if org-id-include-domain
 313                           (progn
 314                             (require 'message)
 315                             (concat "@" (message-make-fqdn))))))
 316         (setq unique (concat etime postfix))))
 317      (t (error "Invalid `org-id-method'")))
 318     (concat prefix unique)))
 319
 320 (defun org-id-reverse-string (s)
 321   (mapconcat 'char-to-string (nreverse (string-to-list s)) ""))
 322
 323 (defun org-id-int-to-b36-one-digit (i)
 324   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 325   (cond
 326    ((< i 10) (+ ?0 i))
 327    ((< i 36) (+ ?a i -10))
 328    (t (error "Larger that 35"))))
 329
 330 (defun org-id-b36-to-int-one-digit (i)
 331   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 332 The input I may be a character, or a single-letter string."
 333   (and (stringp i) (setq i (string-to-char i)))
 334   (cond
 335    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 336    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 337    (t (error "Invalid b36 letter"))))
 338
 339 (defun org-id-int-to-b36 (i &optional length)
 340   "Convert an integer to a base-36 number represented as a string."
 341   (let ((s ""))
 342     (while (> i 0)
 343       (setq s (concat (char-to-string
 344                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 345             i (/ i 36)))
 346     (setq length (max 1 (or length 1)))
 347     (if (< (length s) length)
 348         (setq s (concat (make-string (- length (length s)) ?0) s)))
 349     s))
 350
 351 (defun org-id-b36-to-int (s)
 352   "Convert a base-36 string into the corresponding integer."
 353   (let ((r 0))
 354     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 355           s)
 356     r))
 357
 358 (defun org-id-time-to-b36 (&optional time)
 359   "Encode TIME as a 10-digit string.
 360 This string holds the time to micro-second accuracy, and can be decoded
 361 using `org-id-decode'."
 362   (setq time (or time (current-time)))
 363   (concat (org-id-int-to-b36 (nth 0 time) 4)
 364           (org-id-int-to-b36 (nth 1 time) 4)
 365           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 366
 367 (defun org-id-decode (id)
 368   "Split ID into the prefix and the time value that was used to create it.
 369 The return value is (prefix . time) where PREFIX is nil or a string,
 370 and time is the usual three-integer representation of time."
 371   (let (prefix time parts)
 372     (setq parts (org-split-string id ":"))
 373     (if (= 2 (length parts))
 374         (setq prefix (car parts) time (nth 1 parts))
 375       (setq prefix nil time (nth 0 parts)))
 376     (setq time (org-id-reverse-string time))
 377     (setq time (list (org-id-b36-to-int (substring time 0 4))
 378                      (org-id-b36-to-int (substring time 4 8))
 379                      (org-id-b36-to-int (substring time 8 12))))
 380     (cons prefix time)))
 381
 382 ;; Storing ID locations (files)
 383
 384 (defun org-id-update-id-locations (&optional files)
 385   "Scan relevant files for IDs.
 386 Store the relation between files and corresponding IDs.
 387 This will scan all agenda files, all associated archives, and all
 388 files currently mentioned in `org-id-locations'.
 389 When FILES is given, scan these files instead.
 390 When CHECK is given, prepare detailed information about duplicate IDs."
 391   (interactive)
 392   (if (not org-id-track-globally)
 393       (error "Please turn on `org-id-track-globally' if you want to track IDs.")
 394     (let ((files
 395            (or files
 396                (append
 397                 ;; Agenda files and all associated archives
 398                 (org-agenda-files t org-id-search-archives)
 399                 ;; Explicit extra files
 400                 (if (symbolp org-id-extra-files)
 401                     (symbol-value org-id-extra-files)
 402                   org-id-extra-files)
 403               ;; Files associated with live org-mode buffers
 404                 (delq nil
 405                       (mapcar (lambda (b)
 406                                 (with-current-buffer b
 407                                   (and (org-mode-p) (buffer-file-name))))
 408                               (buffer-list)))
 409                 ;; All files known to have IDs
 410                 org-id-files)))
 411           org-agenda-new-buffers
 412           file nfiles tfile ids reg found id seen (ndup 0))
 413       (setq nfiles (length files))
 414       (while (setq file (pop files))
 415         (message "Finding ID locations (%d/%d files): %s"
 416                  (- nfiles (length files)) nfiles file)
 417         (setq tfile (file-truename file))
 418         (when (and (file-exists-p file) (not (member tfile seen)))
 419           (push tfile seen)
 420           (setq ids nil)
 421           (with-current-buffer (org-get-agenda-file-buffer file)
 422             (save-excursion
 423               (save-restriction
 424                 (widen)
 425                 (goto-char (point-min))
 426                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 427                                           nil t)
 428                   (setq id (org-match-string-no-properties 1))
 429                   (if (member id found)
 430                       (progn
 431                         (message "Duplicate ID \"%s\", also in file %s"
 432                                  id (car (delq
 433                                           nil
 434                                           (mapcar
 435                                            (lambda (x)
 436                                              (if (member id (cdr x)) (car x)))
 437                                            reg))))
 438                         (when (= ndup 0)
 439                           (ding)
 440                           (sit-for 2))
 441                         (setq ndup (1+ ndup)))
 442                     (push id found)
 443                     (push id ids)))
 444                 (push (cons (abbreviate-file-name file) ids) reg))))))
 445       (org-release-buffers org-agenda-new-buffers)
 446       (setq org-agenda-new-buffers nil)
 447       (setq org-id-locations reg)
 448       (setq org-id-files (mapcar 'car org-id-locations))
 449       (org-id-locations-save) ;; this function can also handle the alist form
 450       ;; now convert to a hash
 451       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 452       (if (> ndup 0)
 453           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 454         (message "%d unique files scanned for IDs" (length org-id-files)))
 455       org-id-locations)))
 456
 457 (defun org-id-locations-save ()
 458   "Save `org-id-locations' in `org-id-locations-file'."
 459   (when org-id-track-globally
 460     (let ((out (if (hash-table-p org-id-locations)
 461                    (org-id-hash-to-alist org-id-locations)
 462                  org-id-locations)))
 463       (with-temp-file org-id-locations-file
 464         (print out (current-buffer))))))
 465
 466 (defun org-id-locations-load ()
 467   "Read the data from `org-id-locations-file'."
 468   (setq org-id-locations nil)
 469   (when org-id-track-globally
 470     (with-temp-buffer
 471       (condition-case nil
 472           (progn
 473             (insert-file-contents-literally org-id-locations-file)
 474             (goto-char (point-min))
 475             (setq org-id-locations (read (current-buffer))))
 476         (error
 477          (message "Could not read org-id-values from %s. Setting it to nil."
 478                   org-id-locations-file))))
 479     (setq org-id-files (mapcar 'car org-id-locations))
 480     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 481
 482 (defun org-id-add-location (id file)
 483   "Add the ID with location FILE to the database of ID locations."
 484   ;; Only if global tracking is on, and when the buffer has a file
 485   (when (and org-id-track-globally id file)
 486     (unless org-id-locations (org-id-locations-load))
 487     (puthash id (abbreviate-file-name file) org-id-locations)
 488     (add-to-list 'org-id-files (abbreviate-file-name file))))
 489
 490 (add-hook 'kill-emacs-hook 'org-id-locations-save)
 491
 492 (defun org-id-hash-to-alist (hash)
 493   "Turn an org-id hash into an alist, so that it can be written to a file."
 494   (let (res x)
 495     (maphash
 496      (lambda (k v)
 497        (if (setq x (member v res))
 498            (setcdr x (cons k (cdr x)))
 499          (push (list v k) res)))
 500      hash)
 501     res))
 502
 503 (defun org-id-alist-to-hash (list)
 504   "Turn an org-id location list into a hash table."
 505   (let ((res (make-hash-table
 506               :test 'equal
 507               :size (apply '+ (mapcar 'length list))))
 508         f)
 509     (mapc
 510      (lambda (x)
 511        (setq f (car x))
 512        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 513      list)
 514     res))
 515
 516 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 517   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 518   (when org-id-track-globally
 519     (save-match-data
 520       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 521       (when (bufferp buffer-or-file)
 522         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 523                                  buffer-or-file))
 524         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 525       (when buffer-or-file
 526         (let ((fname (abbreviate-file-name buffer-or-file))
 527               (s 0))
 528           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 529             (setq s (match-end 0))
 530             (org-id-add-location (match-string 1 txt) fname)))))))
 531
 532 ;; Finding entries with specified id
 533
 534 ;;;###autoload
 535 (defun org-id-find-id-file (id)
 536   "Query the id database for the file in which this ID is located."
 537   (unless org-id-locations (org-id-locations-load))
 538   (or (gethash id org-id-locations)
 539       ;; ball back on current buffer
 540       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 541                             (current-buffer)))))
 542
 543 (defun org-id-find-id-in-file (id file &optional markerp)
 544   "Return the position of the entry ID in FILE.
 545 If that files does not exist, or if it does not contain this ID,
 546 return nil.
 547 The position is returned as a cons cell (file-name . position).  With
 548 optional argument MARKERP, return the position as a new marker."
 549   (let (org-agenda-new-buffers buf pos)
 550     (cond
 551      ((not file) nil)
 552      ((not (file-exists-p file)) nil)
 553      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 554           (setq pos (org-find-entry-with-id id))
 555           (when pos
 556             (if markerp
 557                 (move-marker (make-marker) pos buf)
 558               (cons file pos))))))))
 559
 560 ;; id link type
 561
 562 ;; Calling the following function is hard-coded into `org-store-link',
 563 ;; so we do have to add it to `org-store-link-functions'.
 564
 565 (defun org-id-store-link ()
 566   "Store a link to the current entry, using its ID."
 567   (interactive)
 568   (let* ((link (org-make-link "id:" (org-id-get-create)))
 569          (desc (save-excursion
 570                  (org-back-to-heading t)
 571                  (or (and (looking-at org-complex-heading-regexp)
 572                           (if (match-end 4) (match-string 4) (match-string 0)))
 573                      link))))
 574     (org-store-link-props :link link :description desc :type "id")
 575     link))
 576
 577 (defun org-id-open (id)
 578   "Go to the entry with id ID."
 579   (org-mark-ring-push)
 580   (let ((m (org-id-find id 'marker))
 581         cmd)
 582     (unless m
 583       (error "Cannot find entry with ID \"%s\"" id))
 584     ;; Use a buffer-switching command in analogy to finding files
 585     (setq cmd
 586           (or
 587            (cdr
 588             (assq
 589              (cdr (assq 'file org-link-frame-setup))
 590              '((find-file . switch-to-buffer)
 591                (find-file-other-window . switch-to-buffer-other-window)
 592                (find-file-other-frame . switch-to-buffer-other-frame))))
 593            'switch-to-buffer-other-window))
 594     (if (not (equal (current-buffer) (marker-buffer m)))
 595         (funcall cmd (marker-buffer m)))
 596     (goto-char m)
 597     (move-marker m nil)
 598     (org-show-context)))
 599
 600 (org-add-link-type "id" 'org-id-open)
 601
 602 (provide 'org-id)
 603
 604 ;;; org-id.el ends here
 605
 606 ;; arch-tag: e5abaca4-e16f-4b25-832a-540cfb63a712
 607
 608