lisp/ob-python.el

   1 ;;; ob-python.el --- org-babel functions for python evaluation
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (eval-when-compile (require 'cl))
  32
  33 (declare-function org-remove-indentation "org" )
  34 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  35 (declare-function py-toggle-shells "ext:python-mode" (arg))
  36 (declare-function run-python "ext:python" (&optional cmd noshow new))
  37
  38 (defvar org-babel-tangle-lang-exts)
  39 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  40
  41 (defvar org-babel-default-header-args:python '())
  42
  43 (defvar org-babel-python-command "python"
  44   "Name of command for executing Python code.")
  45
  46 (defvar org-babel-python-mode (if (featurep 'xemacs) 'python-mode 'python)
  47   "Preferred python mode for use in running python interactively.
  48 This will typically be either 'python or 'python-mode.")
  49
  50 (defvar org-src-preserve-indentation)
  51
  52 (defcustom org-babel-python-hline-to "None"
  53   "Replace hlines in incoming tables with this when translating to python."
  54   :group 'org-babel
  55   :type 'string)
  56
  57 (defcustom org-babel-python-None-to 'hline
  58   "Replace 'None' in python tables with this before returning."
  59   :group 'org-babel
  60   :type 'string)
  61
  62 (defun org-babel-execute:python (body params)
  63   "Execute a block of Python code with Babel.
  64 This function is called by `org-babel-execute-src-block'."
  65   (let* ((session (org-babel-python-initiate-session
  66                    (cdr (assoc :session params))))
  67          (result-params (cdr (assoc :result-params params)))
  68          (result-type (cdr (assoc :result-type params)))
  69          (return-val (when (and (eq result-type 'value) (not session))
  70                        (cdr (assoc :return params))))
  71          (preamble (cdr (assoc :preamble params)))
  72          (full-body
  73           (org-babel-expand-body:generic
  74            (concat body (if return-val (format "\nreturn %s" return-val) ""))
  75            params (org-babel-variable-assignments:python params)))
  76          (result (org-babel-python-evaluate
  77                   session full-body result-type result-params preamble)))
  78     (org-babel-reassemble-table
  79      result
  80      (org-babel-pick-name (cdr (assoc :colname-names params))
  81                           (cdr (assoc :colnames params)))
  82      (org-babel-pick-name (cdr (assoc :rowname-names params))
  83                           (cdr (assoc :rownames params))))))
  84
  85 (defun org-babel-prep-session:python (session params)
  86   "Prepare SESSION according to the header arguments in PARAMS.
  87 VARS contains resolved variable references"
  88   (let* ((session (org-babel-python-initiate-session session))
  89          (var-lines
  90           (org-babel-variable-assignments:python params)))
  91     (org-babel-comint-in-buffer session
  92       (mapc (lambda (var)
  93               (end-of-line 1) (insert var) (comint-send-input)
  94               (org-babel-comint-wait-for-output session)) var-lines))
  95     session))
  96
  97 (defun org-babel-load-session:python (session body params)
  98   "Load BODY into SESSION."
  99   (save-window-excursion
 100     (let ((buffer (org-babel-prep-session:python session params)))
 101       (with-current-buffer buffer
 102         (goto-char (process-mark (get-buffer-process (current-buffer))))
 103         (insert (org-babel-chomp body)))
 104       buffer)))
 105
 106 ;; helper functions
 107
 108 (defun org-babel-variable-assignments:python (params)
 109   "Return a list of Python statements assigning the block's variables."
 110   (mapcar
 111    (lambda (pair)
 112      (format "%s=%s"
 113              (car pair)
 114              (org-babel-python-var-to-python (cdr pair))))
 115    (mapcar #'cdr (org-babel-get-header params :var))))
 116
 117 (defun org-babel-python-var-to-python (var)
 118   "Convert an elisp value to a python variable.
 119 Convert an elisp value, VAR, into a string of python source code
 120 specifying a variable of the same value."
 121   (if (listp var)
 122       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 123     (if (equal var 'hline)
 124         org-babel-python-hline-to
 125       (format
 126        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 127        var))))
 128
 129 (defun org-babel-python-table-or-string (results)
 130   "Convert RESULTS into an appropriate elisp value.
 131 If the results look like a list or tuple, then convert them into an
 132 Emacs-lisp table, otherwise return the results as a string."
 133   ((lambda (res)
 134      (if (listp res)
 135          (mapcar (lambda (el) (if (equal el 'None)
 136                              org-babel-python-None-to el))
 137                  res)
 138        res))
 139    (org-babel-script-escape results)))
 140
 141 (defvar org-babel-python-buffers '((:default . nil)))
 142
 143 (defun org-babel-python-session-buffer (session)
 144   "Return the buffer associated with SESSION."
 145   (cdr (assoc session org-babel-python-buffers)))
 146
 147 (defvar py-default-interpreter)
 148 (defun org-babel-python-initiate-session-by-key (&optional session)
 149   "Initiate a python session.
 150 If there is not a current inferior-process-buffer in SESSION
 151 then create.  Return the initialized session."
 152   (require org-babel-python-mode)
 153   (save-window-excursion
 154     (let* ((session (if session (intern session) :default))
 155            (python-buffer (org-babel-python-session-buffer session)))
 156       (cond
 157        ((and (eq 'python org-babel-python-mode)
 158              (fboundp 'run-python)) ; python.el
 159         (run-python))
 160        ((and (eq 'python-mode org-babel-python-mode)
 161              (fboundp 'py-shell)) ; python-mode.el
 162         ;; Make sure that py-which-bufname is initialized, as otherwise
 163         ;; it will be overwritten the first time a Python buffer is
 164         ;; created.
 165         (py-toggle-shells py-default-interpreter)
 166         ;; `py-shell' creates a buffer whose name is the value of
 167         ;; `py-which-bufname' with '*'s at the beginning and end
 168         (let* ((bufname (if (and python-buffer (buffer-live-p python-buffer))
 169                             (replace-regexp-in-string ;; zap surrounding *
 170                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 171                           (concat "Python-" (symbol-name session))))
 172                (py-which-bufname bufname))
 173           (py-shell)
 174           (setq python-buffer (concat "*" bufname "*"))))
 175        (t
 176         (error "No function available for running an inferior Python")))
 177       (setq org-babel-python-buffers
 178             (cons (cons session python-buffer)
 179                   (assq-delete-all session org-babel-python-buffers)))
 180       session)))
 181
 182 (defun org-babel-python-initiate-session (&optional session params)
 183   "Create a session named SESSION according to PARAMS."
 184   (unless (string= session "none")
 185     (org-babel-python-session-buffer
 186      (org-babel-python-initiate-session-by-key session))))
 187
 188 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 189   "A string to indicate that evaluation has completed.")
 190 (defvar org-babel-python-wrapper-method
 191   "
 192 def main():
 193 %s
 194
 195 open('%s', 'w').write( str(main()) )")
 196 (defvar org-babel-python-pp-wrapper-method
 197   "
 198 import pprint
 199 def main():
 200 %s
 201
 202 open('%s', 'w').write( pprint.pformat(main()) )")
 203
 204 (defun org-babel-python-evaluate
 205   (session body &optional result-type result-params preamble)
 206   "Evaluate BODY as Python code."
 207   (if session
 208       (org-babel-python-evaluate-session
 209        session body result-type result-params)
 210     (org-babel-python-evaluate-external-process
 211      body result-type result-params preamble)))
 212
 213 (defun org-babel-python-evaluate-external-process
 214   (body &optional result-type result-params preamble)
 215   "Evaluate BODY in external python process.
 216 If RESULT-TYPE equals 'output then return standard output as a
 217 string.  If RESULT-TYPE equals 'value then return the value of the
 218 last statement in BODY, as elisp."
 219   ((lambda (raw)
 220      (org-babel-result-cond result-params
 221        raw
 222        (org-babel-python-table-or-string (org-babel-trim raw))))
 223    (case result-type
 224      (output (org-babel-eval org-babel-python-command
 225                              (concat (if preamble (concat preamble "\n") "")
 226                                      body)))
 227      (value (let ((tmp-file (org-babel-temp-file "python-")))
 228               (org-babel-eval
 229                org-babel-python-command
 230                (concat
 231                 (if preamble (concat preamble "\n") "")
 232                 (format
 233                  (if (member "pp" result-params)
 234                      org-babel-python-pp-wrapper-method
 235                    org-babel-python-wrapper-method)
 236                  (mapconcat
 237                   (lambda (line) (format "\t%s" line))
 238                   (split-string
 239                    (org-remove-indentation
 240                     (org-babel-trim body))
 241                    "[\r\n]") "\n")
 242                  (org-babel-process-file-name tmp-file 'noquote))))
 243               (org-babel-eval-read-file tmp-file))))))
 244
 245 (defun org-babel-python-evaluate-session
 246   (session body &optional result-type result-params)
 247   "Pass BODY to the Python process in SESSION.
 248 If RESULT-TYPE equals 'output then return standard output as a
 249 string.  If RESULT-TYPE equals 'value then return the value of the
 250 last statement in BODY, as elisp."
 251   (let* ((send-wait (lambda () (comint-send-input nil t) (sleep-for 0 5)))
 252          (dump-last-value
 253           (lambda
 254             (tmp-file pp)
 255             (mapc
 256              (lambda (statement) (insert statement) (funcall send-wait))
 257              (if pp
 258                  (list
 259                   "import pprint"
 260                   (format "open('%s', 'w').write(pprint.pformat(_))"
 261                           (org-babel-process-file-name tmp-file 'noquote)))
 262                (list (format "open('%s', 'w').write(str(_))"
 263                              (org-babel-process-file-name tmp-file 'noquote)))))))
 264          (input-body (lambda (body)
 265                        (mapc (lambda (line) (insert line) (funcall send-wait))
 266                              (split-string body "[\r\n]"))
 267                        (funcall send-wait))))
 268     ((lambda (results)
 269        (unless (string= (substring org-babel-python-eoe-indicator 1 -1) results)
 270          (org-babel-result-cond result-params
 271            results
 272            (org-babel-python-table-or-string results))))
 273      (case result-type
 274        (output
 275         (mapconcat
 276          #'org-babel-trim
 277          (butlast
 278           (org-babel-comint-with-output
 279               (session org-babel-python-eoe-indicator t body)
 280             (funcall input-body body)
 281             (funcall send-wait) (funcall send-wait)
 282             (insert org-babel-python-eoe-indicator)
 283             (funcall send-wait))
 284           2) "\n"))
 285        (value
 286         (let ((tmp-file (org-babel-temp-file "python-")))
 287           (org-babel-comint-with-output
 288               (session org-babel-python-eoe-indicator nil body)
 289             (let ((comint-process-echoes nil))
 290               (funcall input-body body)
 291               (funcall dump-last-value tmp-file (member "pp" result-params))
 292               (funcall send-wait) (funcall send-wait)
 293               (insert org-babel-python-eoe-indicator)
 294               (funcall send-wait)))
 295           (org-babel-eval-read-file tmp-file)))))))
 296
 297 (defun org-babel-python-read-string (string)
 298   "Strip 's from around Python string."
 299   (if (string-match "^'\\([^\000]+\\)'$" string)
 300       (match-string 1 string)
 301     string))
 302
 303 (provide 'ob-python)
 304
 305
 306
 307 ;;; ob-python.el ends here