lisp/org-timer.el

   1 ;;; org-timer.el --- Timer code for Org mode
   2
   3 ;; Copyright (C) 2008-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements two types of timers for Org buffers:
  28 ;;
  29 ;; - A relative timer that counts up (from 0 or a specified offset)
  30 ;; - A countdown timer that counts down from a specified time
  31 ;;
  32 ;; The relative and countdown timers differ in their entry points.
  33 ;; Use `org-timer' or `org-timer-start' to start the relative timer,
  34 ;; and `org-timer-set-timer' to start the countdown timer.
  35
  36 ;;; Code:
  37
  38 (require 'org)
  39 (require 'org-clock)
  40
  41 (declare-function org-agenda-error "org-agenda" ())
  42
  43 (defvar org-timer-start-time nil
  44   "t=0 for the running timer.")
  45
  46 (defvar org-timer-pause-time nil
  47   "Time when the timer was paused.")
  48
  49 (defvar org-timer-countdown-timer nil
  50   "Current countdown timer.
  51 This is a timer object if there is an active countdown timer,
  52 'paused' if there is a paused countdown timer, and nil
  53 otherwise.")
  54
  55 (defvar org-timer-countdown-timer-title nil
  56   "Title for notification displayed when a countdown finishes.")
  57
  58 (defconst org-timer-re "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
  59   "Regular expression used to match timer stamps.")
  60
  61 (defcustom org-timer-format "%s "
  62   "The format to insert the time of the timer.
  63 This format must contain one instance of \"%s\" which will be replaced by
  64 the value of the timer."
  65   :group 'org-time
  66   :type 'string)
  67
  68 (defcustom org-timer-default-timer "0"
  69   "The default timer when a timer is set, in minutes or hh:mm:ss format.
  70 When 0, the user is prompted for a value."
  71   :group 'org-time
  72   :version "25.1"
  73   :package-version '(Org . "8.3")
  74   :type 'string)
  75
  76 (defcustom org-timer-display 'mode-line
  77   "When a timer is running, org-mode can display it in the mode
  78 line and/or frame title.
  79 Allowed values are:
  80
  81 both         displays in both mode line and frame title
  82 mode-line    displays only in mode line (default)
  83 frame-title  displays only in frame title
  84 nil          current timer is not displayed"
  85   :group 'org-time
  86   :type '(choice
  87           (const :tag "Mode line" mode-line)
  88           (const :tag "Frame title" frame-title)
  89           (const :tag "Both" both)
  90           (const :tag "None" nil)))
  91
  92 (defvar org-timer-start-hook nil
  93   "Hook run after relative timer is started.")
  94
  95 (defvar org-timer-stop-hook nil
  96   "Hook run before relative or countdown timer is stopped.")
  97
  98 (defvar org-timer-pause-hook nil
  99   "Hook run before relative or countdown timer is paused.")
 100
 101 (defvar org-timer-continue-hook nil
 102   "Hook run after relative or countdown timer is continued.")
 103
 104 (defvar org-timer-set-hook nil
 105   "Hook run after countdown timer is set.")
 106
 107 (defvar org-timer-done-hook nil
 108   "Hook run after countdown timer reaches zero.")
 109
 110 ;;;###autoload
 111 (defun org-timer-start (&optional offset)
 112   "Set the starting time for the relative timer to now.
 113 When called with prefix argument OFFSET, prompt the user for an offset time,
 114 with the default taken from a timer stamp at point, if any.
 115 If OFFSET is a string or an integer, it is directly taken to be the offset
 116 without user interaction.
 117 When called with a double prefix arg, all timer strings in the active
 118 region will be shifted by a specific amount.  You will be prompted for
 119 the amount, with the default to make the first timer string in
 120 the region 0:00:00."
 121   (interactive "P")
 122   (cond
 123    ((equal offset '(16))
 124     (call-interactively 'org-timer-change-times-in-region))
 125    (org-timer-countdown-timer
 126     (user-error "Countdown timer is running.  Cancel first"))
 127    (t
 128     (let (delta def s)
 129       (if (not offset)
 130           (setq org-timer-start-time (current-time))
 131         (cond
 132          ((integerp offset) (setq delta offset))
 133          ((stringp offset) (setq delta (org-timer-hms-to-secs offset)))
 134          (t
 135           (setq def (if (org-in-regexp org-timer-re)
 136                         (match-string 0)
 137                       "0:00:00")
 138                 s (read-string
 139                    (format "Restart timer with offset [%s]: " def)))
 140           (unless (string-match "\\S-" s) (setq s def))
 141           (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete s)))))
 142         (setq org-timer-start-time
 143               (seconds-to-time
 144                ;; Pass `current-time' result to `org-float-time'
 145                ;; (instead of calling without arguments) so that only
 146                ;; `current-time' has to be overriden in tests.
 147                (- (org-float-time (current-time)) delta))))
 148       (setq org-timer-pause-time nil)
 149       (org-timer-set-mode-line 'on)
 150       (message "Timer start time set to %s, current value is %s"
 151                (format-time-string "%T" org-timer-start-time)
 152                (org-timer-secs-to-hms (or delta 0)))
 153       (run-hooks 'org-timer-start-hook)))))
 154
 155 (defun org-timer-pause-or-continue (&optional stop)
 156   "Pause or continue the relative or countdown timer.
 157 With prefix arg STOP, stop it entirely."
 158   (interactive "P")
 159   (cond
 160    (stop (org-timer-stop))
 161    ((not org-timer-start-time) (error "No timer is running"))
 162    (org-timer-pause-time
 163     (let ((start-secs (org-float-time org-timer-start-time))
 164           (pause-secs (org-float-time org-timer-pause-time)))
 165       (if org-timer-countdown-timer
 166           (progn
 167             (let ((new-secs (- start-secs pause-secs)))
 168               (setq org-timer-countdown-timer
 169                     (org-timer--run-countdown-timer
 170                      new-secs org-timer-countdown-timer-title))
 171               (setq org-timer-start-time
 172                     (time-add (current-time) (seconds-to-time new-secs)))))
 173         (setq org-timer-start-time
 174               ;; Pass `current-time' result to `org-float-time'
 175               ;; (instead of calling without arguments) so that only
 176               ;; `current-time' has to be overriden in tests.
 177               (seconds-to-time (- (org-float-time (current-time))
 178                                   (- pause-secs start-secs)))))
 179       (setq org-timer-pause-time nil)
 180       (org-timer-set-mode-line 'on)
 181       (run-hooks 'org-timer-continue-hook)
 182       (message "Timer continues at %s" (org-timer-value-string))))
 183    (t
 184     ;; pause timer
 185     (when org-timer-countdown-timer
 186       (cancel-timer org-timer-countdown-timer)
 187       (setq org-timer-countdown-timer 'pause))
 188     (run-hooks 'org-timer-pause-hook)
 189     (setq org-timer-pause-time (current-time))
 190     (org-timer-set-mode-line 'pause)
 191     (message "Timer paused at %s" (org-timer-value-string)))))
 192
 193 (defun org-timer-stop ()
 194   "Stop the relative or countdown timer."
 195   (interactive)
 196   (unless org-timer-start-time
 197     (user-error "No timer running"))
 198   (when (timerp org-timer-countdown-timer)
 199     (cancel-timer org-timer-countdown-timer))
 200   (run-hooks 'org-timer-stop-hook)
 201   (setq org-timer-start-time nil
 202         org-timer-pause-time nil
 203         org-timer-countdown-timer nil)
 204   (org-timer-set-mode-line 'off)
 205   (message "Timer stopped"))
 206
 207 ;;;###autoload
 208 (defun org-timer (&optional restart no-insert-p)
 209   "Insert a H:MM:SS string from the timer into the buffer.
 210 The first time this command is used, the timer is started.  When used with
 211 a \\[universal-argument] prefix, force restarting the timer.
 212 When used with a double prefix argument \\[universal-argument], change all the timer string
 213 in the region by a fixed amount.  This can be used to recalibrate a timer
 214 that was not started at the correct moment.
 215
 216 If NO-INSERT-P is non-nil, return the string instead of inserting
 217 it in the buffer."
 218   (interactive "P")
 219   (if (equal restart '(16))
 220       (org-timer-start restart)
 221     (when (or (equal restart '(4)) (not org-timer-start-time))
 222       (org-timer-start))
 223     (if no-insert-p
 224         (org-timer-value-string)
 225       (insert (org-timer-value-string)))))
 226
 227 (defun org-timer-value-string ()
 228   "Set the timer string."
 229   (format org-timer-format
 230           (org-timer-secs-to-hms
 231            (abs (floor (org-timer-seconds))))))
 232
 233 (defun org-timer-seconds ()
 234   ;; Pass `current-time' result to `org-float-time' (instead of
 235   ;; calling without arguments) so that only `current-time' has to be
 236   ;; overriden in tests.
 237   (if org-timer-countdown-timer
 238       (- (org-float-time org-timer-start-time)
 239          (org-float-time (or org-timer-pause-time (current-time))))
 240     (- (org-float-time (or org-timer-pause-time (current-time)))
 241        (org-float-time org-timer-start-time))))
 242
 243 ;;;###autoload
 244 (defun org-timer-change-times-in-region (beg end delta)
 245   "Change all h:mm:ss time in region by a DELTA."
 246   (interactive
 247    "r\nsEnter time difference like \"-1:08:26\".  Default is first time to zero: ")
 248   (let ((re "[-+]?[0-9]+:[0-9]\\{2\\}:[0-9]\\{2\\}") p)
 249     (unless (string-match "\\S-" delta)
 250       (save-excursion
 251         (goto-char beg)
 252         (when (re-search-forward re end t)
 253           (setq delta (match-string 0))
 254           (if (equal (string-to-char delta) ?-)
 255               (setq delta (substring delta 1))
 256             (setq delta (concat "-" delta))))))
 257     (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete delta)))
 258     (when (= delta 0) (error "No change"))
 259     (save-excursion
 260       (goto-char end)
 261       (while (re-search-backward re beg t)
 262         (setq p (point))
 263         (replace-match
 264          (save-match-data
 265            (org-timer-secs-to-hms (+ (org-timer-hms-to-secs (match-string 0)) delta)))
 266          t t)
 267         (goto-char p)))))
 268
 269 ;;;###autoload
 270 (defun org-timer-item (&optional arg)
 271   "Insert a description-type item with the current timer value."
 272   (interactive "P")
 273   (let ((itemp (org-in-item-p)) (pos (point)))
 274     (cond
 275      ;; In a timer list, insert with `org-list-insert-item',
 276      ;; then fix the list.
 277      ((and itemp (goto-char itemp) (org-at-item-timer-p))
 278       (let* ((struct (org-list-struct))
 279              (prevs (org-list-prevs-alist struct))
 280              (s (concat (org-timer (when arg '(4)) t) ":: ")))
 281         (setq struct (org-list-insert-item pos struct prevs nil s))
 282         (org-list-write-struct struct (org-list-parents-alist struct))
 283         (looking-at org-list-full-item-re)
 284         (goto-char (match-end 0))))
 285      ;; In a list of another type, don't break anything: throw an error.
 286      (itemp (goto-char pos) (error "This is not a timer list"))
 287      ;; Else, start a new list.
 288      (t
 289       (beginning-of-line)
 290       (org-indent-line)
 291       (insert  "- ")
 292       (org-timer (when arg '(4)))
 293       (insert ":: ")))))
 294
 295 (defun org-timer-fix-incomplete (hms)
 296   "If hms is a H:MM:SS string with missing hour or hour and minute, fix it."
 297   (if (string-match "\\(?:\\([0-9]+:\\)?\\([0-9]+:\\)\\)?\\([0-9]+\\)" hms)
 298       (replace-match
 299        (format "%d:%02d:%02d"
 300                (if (match-end 1) (string-to-number (match-string 1 hms)) 0)
 301                (if (match-end 2) (string-to-number (match-string 2 hms)) 0)
 302                (string-to-number (match-string 3 hms)))
 303        t t hms)
 304     (error "Cannot parse HMS string \"%s\"" hms)))
 305
 306 (defun org-timer-hms-to-secs (hms)
 307   "Convert h:mm:ss string to an integer time.
 308 If the string starts with a minus sign, the integer will be negative."
 309   (if (not (string-match
 310             "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
 311             hms))
 312       0
 313     (let* ((h (string-to-number (match-string 1 hms)))
 314            (m (string-to-number (match-string 2 hms)))
 315            (s (string-to-number (match-string 3 hms)))
 316            (sign (equal (substring (match-string 1 hms) 0 1) "-")))
 317       (setq h (abs h))
 318       (* (if sign -1 1) (+ s (* 60 (+ m (* 60 h))))))))
 319
 320 (defun org-timer-secs-to-hms (s)
 321   "Convert integer S into h:mm:ss.
 322 If the integer is negative, the string will start with \"-\"."
 323   (let (sign m h)
 324     (setq sign (if (< s 0) "-" "")
 325           s (abs s)
 326           m (/ s 60) s (- s (* 60 m))
 327           h (/ m 60) m (- m (* 60 h)))
 328     (format "%s%d:%02d:%02d" sign h m s)))
 329
 330 (defvar org-timer-mode-line-timer nil)
 331 (defvar org-timer-mode-line-string nil)
 332
 333 (defun org-timer-set-mode-line (value)
 334   "Set the mode-line display for relative or countdown timer.
 335 VALUE can be `on', `off', or `pause'."
 336   (when (or (eq org-timer-display 'mode-line)
 337             (eq org-timer-display 'both))
 338     (or global-mode-string (setq global-mode-string '("")))
 339     (or (memq 'org-timer-mode-line-string global-mode-string)
 340         (setq global-mode-string
 341               (append global-mode-string '(org-timer-mode-line-string)))))
 342   (when (or (eq org-timer-display 'frame-title)
 343             (eq org-timer-display 'both))
 344     (or (memq 'org-timer-mode-line-string frame-title-format)
 345         (setq frame-title-format
 346               (append frame-title-format '(org-timer-mode-line-string)))))
 347   (cond
 348    ((equal value 'off)
 349     (when org-timer-mode-line-timer
 350       (cancel-timer org-timer-mode-line-timer)
 351       (setq org-timer-mode-line-timer nil))
 352     (when (or (eq org-timer-display 'mode-line)
 353               (eq org-timer-display 'both))
 354       (setq global-mode-string
 355             (delq 'org-timer-mode-line-string global-mode-string)))
 356     (when (or (eq org-timer-display 'frame-title)
 357               (eq org-timer-display 'both))
 358       (setq frame-title-format
 359             (delq 'org-timer-mode-line-string frame-title-format)))
 360     (force-mode-line-update))
 361    ((equal value 'pause)
 362     (when org-timer-mode-line-timer
 363       (cancel-timer org-timer-mode-line-timer)
 364       (setq org-timer-mode-line-timer nil)))
 365    ((equal value 'on)
 366     (when (or (eq org-timer-display 'mode-line)
 367               (eq org-timer-display 'both))
 368       (or global-mode-string (setq global-mode-string '("")))
 369       (or (memq 'org-timer-mode-line-string global-mode-string)
 370           (setq global-mode-string
 371                 (append global-mode-string '(org-timer-mode-line-string)))))
 372     (when (or (eq org-timer-display 'frame-title)
 373               (eq org-timer-display 'both))
 374       (or (memq 'org-timer-mode-line-string frame-title-format)
 375           (setq frame-title-format
 376                 (append frame-title-format '(org-timer-mode-line-string)))))
 377     (org-timer-update-mode-line)
 378     (when org-timer-mode-line-timer
 379       (cancel-timer org-timer-mode-line-timer)
 380       (setq org-timer-mode-line-timer nil))
 381     (when org-timer-display
 382       (setq org-timer-mode-line-timer
 383             (run-with-timer 1 1 'org-timer-update-mode-line))))))
 384
 385 (defun org-timer-update-mode-line ()
 386   "Update the timer time in the mode line."
 387   (if org-timer-pause-time
 388       nil
 389     (setq org-timer-mode-line-string
 390           (concat " <" (substring (org-timer-value-string) 0 -1) ">"))
 391     (force-mode-line-update)))
 392
 393 (defun org-timer-show-remaining-time ()
 394   "Display the remaining time before the timer ends."
 395   (interactive)
 396   (require 'time)
 397   (if (not org-timer-countdown-timer)
 398       (message "No timer set")
 399     (let* ((rtime (decode-time
 400                    (time-subtract (timer--time org-timer-countdown-timer)
 401                                   (current-time))))
 402            (rsecs (nth 0 rtime))
 403            (rmins (nth 1 rtime)))
 404       (message "%d minute(s) %d seconds left before next time out"
 405                rmins rsecs))))
 406
 407 ;;;###autoload
 408 (defun org-timer-set-timer (&optional opt)
 409   "Prompt for a duration in minutes or hh:mm:ss and set a timer.
 410
 411 If `org-timer-default-timer' is not \"0\", suggest this value as
 412 the default duration for the timer.  If a timer is already set,
 413 prompt the user if she wants to replace it.
 414
 415 Called with a numeric prefix argument, use this numeric value as
 416 the duration of the timer in minutes.
 417
 418 Called with a `C-u' prefix arguments, use `org-timer-default-timer'
 419 without prompting the user for a duration.
 420
 421 With two `C-u' prefix arguments, use `org-timer-default-timer'
 422 without prompting the user for a duration and automatically
 423 replace any running timer.
 424
 425 By default, the timer duration will be set to the number of
 426 minutes in the Effort property, if any.  You can ignore this by
 427 using three `C-u' prefix arguments."
 428   (interactive "P")
 429   (when (and org-timer-start-time
 430              (not org-timer-countdown-timer))
 431     (user-error "Relative timer is running.  Stop first"))
 432   (let* ((default-timer
 433            ;; `org-timer-default-timer' used to be a number, don't choke:
 434            (if (numberp org-timer-default-timer)
 435                (number-to-string org-timer-default-timer)
 436              org-timer-default-timer))
 437          (effort-minutes (ignore-errors (org-get-at-eol 'effort-minutes 1)))
 438          (minutes (or (and (not (equal opt '(64)))
 439                            effort-minutes
 440                            (number-to-string effort-minutes))
 441                       (and (numberp opt) (number-to-string opt))
 442                       (and (consp opt) default-timer)
 443                       (and (stringp opt) opt)
 444                       (read-from-minibuffer
 445                        "How much time left? (minutes or h:mm:ss) "
 446                        (and (not (string-equal default-timer "0")) default-timer)))))
 447     (when (string-match "\\`[0-9]+\\'" minutes)
 448       (setq minutes (concat minutes ":00")))
 449     (if (not (string-match "[0-9]+" minutes))
 450         (org-timer-show-remaining-time)
 451       (let ((secs (org-timer-hms-to-secs (org-timer-fix-incomplete minutes)))
 452             (hl (org-timer--get-timer-title)))
 453         (if (or (not org-timer-countdown-timer)
 454                 (equal opt '(16))
 455                 (y-or-n-p "Replace current timer? "))
 456             (progn
 457               (when (timerp org-timer-countdown-timer)
 458                 (cancel-timer org-timer-countdown-timer))
 459               (setq org-timer-countdown-timer-title
 460                     (org-timer--get-timer-title))
 461               (setq org-timer-countdown-timer
 462                     (org-timer--run-countdown-timer
 463                      secs org-timer-countdown-timer-title))
 464               (run-hooks 'org-timer-set-hook)
 465               (setq org-timer-start-time
 466                     (time-add (current-time) (seconds-to-time secs)))
 467               (setq org-timer-pause-time nil)
 468               (org-timer-set-mode-line 'on))
 469           (message "No timer set"))))))
 470
 471 (defun org-timer--run-countdown-timer (secs title)
 472   "Start countdown timer that will last SECS.
 473 TITLE will be appended to the notification message displayed when
 474 time is up."
 475   (let ((msg (format "%s: time out" title)))
 476     (run-with-timer
 477      secs nil `(lambda ()
 478                  (setq org-timer-countdown-timer nil
 479                        org-timer-start-time nil)
 480                  (org-notify ,msg ,org-clock-sound)
 481                  (org-timer-set-mode-line 'off)
 482                  (run-hooks 'org-timer-done-hook)))))
 483
 484 (defun org-timer--get-timer-title ()
 485   "Construct timer title from heading or file name of Org buffer."
 486   (cond
 487    ((derived-mode-p 'org-agenda-mode)
 488     (let* ((marker (or (get-text-property (point) 'org-marker)
 489                        (org-agenda-error)))
 490            (hdmarker (or (get-text-property (point) 'org-hd-marker)
 491                          marker)))
 492       (with-current-buffer (marker-buffer marker)
 493         (org-with-wide-buffer
 494          (goto-char hdmarker)
 495          (org-show-entry)
 496          (or (ignore-errors (org-get-heading))
 497              (buffer-name (buffer-base-buffer)))))))
 498    ((derived-mode-p 'org-mode)
 499     (or (ignore-errors (org-get-heading))
 500         (buffer-name (buffer-base-buffer))))
 501    (t (error "Not in an Org buffer"))))
 502
 503 (provide 'org-timer)
 504
 505 ;; Local variables:
 506 ;; generated-autoload-file: "org-loaddefs.el"
 507 ;; End:
 508
 509 ;;; org-timer.el ends here