lisp/ob-sql.el

   1 ;;; ob-sql.el --- Babel Functions for SQL            -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating sql source code.
  27 ;; (see also ob-sqlite.el)
  28 ;;
  29 ;; SQL is somewhat unique in that there are many different engines for
  30 ;; the evaluation of sql (Mysql, PostgreSQL, etc...), so much of this
  31 ;; file will have to be implemented engine by engine.
  32 ;;
  33 ;; Also SQL evaluation generally takes place inside of a database.
  34 ;;
  35 ;; Header args used:
  36 ;; - engine
  37 ;; - cmdline
  38 ;; - dbhost
  39 ;; - dbport
  40 ;; - dbuser
  41 ;; - dbpassword
  42 ;; - database
  43 ;; - colnames (default, nil, means "yes")
  44 ;; - result-params
  45 ;; - out-file
  46 ;;
  47 ;; The following are used but not really implemented for SQL:
  48 ;; - colname-names
  49 ;; - rownames
  50 ;; - rowname-names
  51 ;;
  52 ;; Engines supported:
  53 ;; - mysql
  54 ;; - dbi
  55 ;; - mssql
  56 ;; - sqsh
  57 ;; - postgresql
  58 ;; - oracle
  59 ;;
  60 ;; TODO:
  61 ;;
  62 ;; - support for sessions
  63 ;; - support for more engines
  64 ;; - what's a reasonable way to drop table data into SQL?
  65 ;;
  66
  67 ;;; Code:
  68 (require 'ob)
  69
  70 (declare-function org-table-import "org-table" (file arg))
  71 (declare-function orgtbl-to-csv "org-table" (table params))
  72 (declare-function org-table-to-lisp "org-table" (&optional txt))
  73 (declare-function cygwin-convert-file-name-to-windows "cygw32.c" (file &optional absolute-p))
  74
  75 (defvar org-babel-default-header-args:sql '())
  76
  77 (defconst org-babel-header-args:sql
  78   '((engine            . :any)
  79     (out-file          . :any)
  80     (dbhost            . :any)
  81     (dbport            . :any)
  82     (dbuser            . :any)
  83     (dbpassword        . :any)
  84     (database          . :any))
  85   "SQL-specific header arguments.")
  86
  87 (defun org-babel-expand-body:sql (body params)
  88   "Expand BODY according to the values of PARAMS."
  89   (org-babel-sql-expand-vars
  90    body (org-babel--get-vars params)))
  91
  92 (defun org-babel-sql-dbstring-mysql (host port user password database)
  93   "Make MySQL cmd line args for database connection.  Pass nil to omit that arg."
  94   (combine-and-quote-strings
  95    (delq nil
  96          (list (when host     (concat "-h" host))
  97                (when port     (format "-P%d" port))
  98                (when user     (concat "-u" user))
  99                (when password (concat "-p" password))
 100                (when database (concat "-D" database))))))
 101
 102 (defun org-babel-sql-dbstring-postgresql (host port user database)
 103   "Make PostgreSQL command line args for database connection.
 104 Pass nil to omit that arg."
 105   (combine-and-quote-strings
 106    (delq nil
 107          (list (when host (concat "-h" host))
 108                (when port (format "-p%d" port))
 109                (when user (concat "-U" user))
 110                (when database (concat "-d" database))))))
 111
 112 (defun org-babel-sql-dbstring-oracle (host port user password database)
 113   "Make Oracle command line args for database connection."
 114   (format "%s/%s@%s:%s/%s" user password host port database))
 115
 116 (defun org-babel-sql-dbstring-mssql (host user password database)
 117   "Make sqlcmd commmand line args for database connection.
 118 `sqlcmd' is the preferred command line tool to access Microsoft
 119 SQL Server on Windows and Linux platform."
 120   (mapconcat #'identity
 121              (delq nil
 122                    (list (when host (format "-S \"%s\"" host))
 123                          (when user (format "-U \"%s\"" user))
 124                          (when password (format "-P \"%s\"" password))
 125                          (when database (format "-d \"%s\"" database))))
 126              " "))
 127
 128 (defun org-babel-sql-dbstring-sqsh (host user password database)
 129   "Make sqsh commmand line args for database connection.
 130 \"sqsh\" is one method to access Sybase or MS SQL via Linux platform"
 131   (mapconcat #'identity
 132              (delq nil
 133                    (list  (when host     (format "-S \"%s\"" host))
 134                           (when user     (format "-U \"%s\"" user))
 135                           (when password (format "-P \"%s\"" password))
 136                           (when database (format "-D \"%s\"" database))))
 137              " "))
 138
 139
 140 (defun org-babel-sql-convert-standard-filename (file)
 141   "Convert the file name to OS standard.
 142 If in Cygwin environment, uses Cygwin specific function to
 143 convert the file name. Otherwise, uses Emacs' standard conversion
 144 function."
 145   (format "\"%s\""
 146           (if (fboundp 'cygwin-convert-file-name-to-windows)
 147               (cygwin-convert-file-name-to-windows file)
 148             (convert-standard-filename file))))
 149
 150 (defun org-babel-execute:sql (body params)
 151   "Execute a block of Sql code with Babel.
 152 This function is called by `org-babel-execute-src-block'."
 153   (let* ((result-params (cdr (assq :result-params params)))
 154          (cmdline (cdr (assq :cmdline params)))
 155          (dbhost (cdr (assq :dbhost params)))
 156          (dbport (cdr (assq :dbport params)))
 157          (dbuser (cdr (assq :dbuser params)))
 158          (dbpassword (cdr (assq :dbpassword params)))
 159          (database (cdr (assq :database params)))
 160          (engine (cdr (assq :engine params)))
 161          (colnames-p (not (equal "no" (cdr (assq :colnames params)))))
 162          (in-file (org-babel-temp-file "sql-in-"))
 163          (out-file (or (cdr (assq :out-file params))
 164                        (org-babel-temp-file "sql-out-")))
 165          (header-delim "")
 166          (command (pcase (intern engine)
 167                     (`dbi (format "dbish --batch %s < %s | sed '%s' > %s"
 168                                   (or cmdline "")
 169                                   (org-babel-process-file-name in-file)
 170                                   "/^+/d;s/^|//;s/(NULL)/ /g;$d"
 171                                   (org-babel-process-file-name out-file)))
 172                     (`monetdb (format "mclient -f tab %s < %s > %s"
 173                                       (or cmdline "")
 174                                       (org-babel-process-file-name in-file)
 175                                       (org-babel-process-file-name out-file)))
 176                     (`mssql (format "sqlcmd %s -s \"\t\" %s -i %s -o %s"
 177                                     (or cmdline "")
 178                                     (org-babel-sql-dbstring-mssql
 179                                      dbhost dbuser dbpassword database)
 180                                     (org-babel-sql-convert-standard-filename
 181                                      (org-babel-process-file-name in-file))
 182                                     (org-babel-sql-convert-standard-filename
 183                                      (org-babel-process-file-name out-file))))
 184                     (`mysql (format "mysql %s %s %s < %s > %s"
 185                                     (org-babel-sql-dbstring-mysql
 186                                      dbhost dbport dbuser dbpassword database)
 187                                     (if colnames-p "" "-N")
 188                                     (or cmdline "")
 189                                     (org-babel-process-file-name in-file)
 190                                     (org-babel-process-file-name out-file)))
 191                     (`postgresql (format
 192                                   "%spsql --set=\"ON_ERROR_STOP=1\" %s -A -P \
 193 footer=off -F \"\t\"  %s -f %s -o %s %s"
 194                                   (if dbpassword
 195                                       (format "PGPASSWORD=%s " dbpassword)
 196                                     "")
 197                                   (if colnames-p "" "-t")
 198                                   (org-babel-sql-dbstring-postgresql
 199                                    dbhost dbport dbuser database)
 200                                   (org-babel-process-file-name in-file)
 201                                   (org-babel-process-file-name out-file)
 202                                   (or cmdline "")))
 203                     (`sqsh (format "sqsh %s %s -i %s -o %s -m csv"
 204                                    (or cmdline "")
 205                                    (org-babel-sql-dbstring-sqsh
 206                                     dbhost dbuser dbpassword database)
 207                                    (org-babel-sql-convert-standard-filename
 208                                     (org-babel-process-file-name in-file))
 209                                    (org-babel-sql-convert-standard-filename
 210                                     (org-babel-process-file-name out-file))))
 211                     (`oracle (format
 212                               "sqlplus -s %s < %s > %s"
 213                               (org-babel-sql-dbstring-oracle
 214                                dbhost dbport dbuser dbpassword database)
 215                               (org-babel-process-file-name in-file)
 216                               (org-babel-process-file-name out-file)))
 217                     (_ (error "No support for the %s SQL engine" engine)))))
 218     (with-temp-file in-file
 219       (insert
 220        (pcase (intern engine)
 221          (`dbi "/format partbox\n")
 222          (`oracle "SET PAGESIZE 50000
 223 SET NEWPAGE 0
 224 SET TAB OFF
 225 SET SPACE 0
 226 SET LINESIZE 9999
 227 SET ECHO OFF
 228 SET FEEDBACK OFF
 229 SET VERIFY OFF
 230 SET HEADING ON
 231 SET MARKUP HTML OFF SPOOL OFF
 232 SET COLSEP '|'
 233
 234 ")
 235          ((or `mssql `sqsh) "SET NOCOUNT ON
 236
 237 ")
 238          (_ ""))
 239        (org-babel-expand-body:sql body params)
 240        ;; "sqsh" requires "go" inserted at EOF.
 241        (if (string= engine "sqsh") "\ngo" "")))
 242     (org-babel-eval command "")
 243     (org-babel-result-cond result-params
 244       (with-temp-buffer
 245         (progn (insert-file-contents-literally out-file) (buffer-string)))
 246       (with-temp-buffer
 247         (cond
 248          ((memq (intern engine) '(dbi mysql postgresql sqsh))
 249           ;; Add header row delimiter after column-names header in first line
 250           (cond
 251            (colnames-p
 252             (with-temp-buffer
 253               (insert-file-contents out-file)
 254               (goto-char (point-min))
 255               (forward-line 1)
 256               (insert "-\n")
 257               (setq header-delim "-")
 258               (write-file out-file)))))
 259          (t
 260           ;; Need to figure out the delimiter for the header row
 261           (with-temp-buffer
 262             (insert-file-contents out-file)
 263             (goto-char (point-min))
 264             (when (re-search-forward "^\\(-+\\)[^-]" nil t)
 265               (setq header-delim (match-string-no-properties 1)))
 266             (goto-char (point-max))
 267             (forward-char -1)
 268             (while (looking-at "\n")
 269               (delete-char 1)
 270               (goto-char (point-max))
 271               (forward-char -1))
 272             (write-file out-file))))
 273         (org-table-import out-file (if (string= engine "sqsh") '(4) '(16)))
 274         (org-babel-reassemble-table
 275          (mapcar (lambda (x)
 276                    (if (string= (car x) header-delim)
 277                        'hline
 278                      x))
 279                  (org-table-to-lisp))
 280          (org-babel-pick-name (cdr (assq :colname-names params))
 281                               (cdr (assq :colnames params)))
 282          (org-babel-pick-name (cdr (assq :rowname-names params))
 283                               (cdr (assq :rownames params))))))))
 284
 285 (defun org-babel-sql-expand-vars (body vars)
 286   "Expand the variables held in VARS in BODY."
 287   (mapc
 288    (lambda (pair)
 289      (setq body
 290            (replace-regexp-in-string
 291             (format "$%s" (car pair))
 292             (let ((val (cdr pair)))
 293               (if (listp val)
 294                   (let ((data-file (org-babel-temp-file "sql-data-")))
 295                     (with-temp-file data-file
 296                       (insert (orgtbl-to-csv
 297                                val '(:fmt (lambda (el) (if (stringp el)
 298                                                       el
 299                                                     (format "%S" el)))))))
 300                     data-file)
 301                 (if (stringp val) val (format "%S" val))))
 302             body)))
 303    vars)
 304   body)
 305
 306 (defun org-babel-prep-session:sql (_session _params)
 307   "Raise an error because Sql sessions aren't implemented."
 308   (error "SQL sessions not yet implemented"))
 309
 310 (provide 'ob-sql)
 311
 312
 313
 314 ;;; ob-sql.el ends here