recipes/tcp-wrappers/tcp-wrappers_7.6.bb

   1 DESCRIPTION = "Tools for monitoring and filtering incoming requests for tcp \
   2               services."
   3 LICENSE = "tcp-wrappers"
   4 PRIORITY = "optional"
   5 SECTION = "console/network"
   6 PR ="r3"
   7
   8
   9 PACKAGES = "${PN}-dbg libwrap libwrap-doc libwrap-dev tcp-wrappers tcp-wrappers-doc"
  10 FILES_libwrap = "${libdir}/lib*.so.*"
  11 FILES_libwrap-doc = "${mandir}/man3 ${mandir}/man5"
  12 FILES_libwrap-dev = "${libdir}/lib*.so ${includedir}"
  13 FILES_tcp-wrappers = "${bindir}"
  14 FILES_tcp-wrappers-doc = "${mandir}/man8"
  15
  16 SRC_URI = "ftp://ftp.porcupine.org/pub/security/tcp_wrappers_${PV}.tar.gz \
  17            file://00_man_quoting.diff;patch=1 \
  18            file://01_man_portability;patch=1 \
  19            file://05_wildcard_matching;patch=1 \
  20            file://06_fix_gethostbyname;patch=1 \
  21            file://10_usagi-ipv6;patch=1 \
  22            file://11_tcpd_blacklist;patch=1 \
  23            file://11_usagi_fix;patch=1 \
  24            file://12_makefile_config;patch=1 \
  25            file://13_shlib_weaksym;patch=1 \
  26            file://14_cidr_support;patch=1 \
  27            file://15_match_clarify;patch=1 \
  28            file://expand_remote_port;patch=1 \
  29            file://have_strerror;patch=1 \
  30            file://man_fromhost;patch=1 \
  31            file://restore_sigalarm;patch=1 \
  32            file://rfc931.diff;patch=1 \
  33            file://safe_finger;patch=1 \
  34            file://sig_fix;patch=1 \
  35            file://siglongjmp;patch=1 \
  36            file://size_t;patch=1 \
  37            file://tcpdchk_libwrapped;patch=1 \
  38            file://ldflags;patch=1 \
  39            \
  40            file://try-from.8 \
  41            file://safe_finger.8"
  42
  43 S = "${WORKDIR}/tcp_wrappers_${PV}"
  44
  45 PARALLEL_MAKE = ""
  46 EXTRA_OEMAKE = "'CC=${CC}' \
  47                 'AR=${AR}' \
  48                 'RANLIB=${RANLIB}' \
  49                 'REAL_DAEMON_DIR=${sbindir}' \
  50                 'STYLE=-DPROCESS_OPTIONS' \
  51                 'FACILITY=LOG_DAEMON' \
  52                 'SEVERITY=LOG_INFO' \
  53                 'BUGS=' \
  54                 'VSYSLOG=' \
  55                 'RFC931_TIMEOUT=10' \
  56                 'ACCESS=-DHOSTS_ACCESS' \
  57                 'KILL_OPT=-DKILL_IP_OPTIONS' \
  58                 'UMASK=-DDAEMON_UMASK=022' \
  59                 'NETGROUP=${EXTRA_OEMAKE_NETGROUP}' \
  60                 'LIBS=-lnsl' \
  61                 'ARFLAGS=rv' \
  62                 'AUX_OBJ=weak_symbols.o' \
  63                 'TLI=' \
  64                 'COPTS=' \
  65                 'EXTRA_CFLAGS=${CFLAGS} -DSYS_ERRLIST_DEFINED -DHAVE_STRERROR -DHAVE_WEAKSYMS -D_REENTRANT -DINET6=1 -Dss_family=__ss_family -Dss_len=__ss_len'"
  66
  67 EXTRA_OEMAKE_NETGROUP = "-DNETGROUP"
  68 EXTRA_OEMAKE_NETGROUP_linux-uclibc = ""
  69
  70 do_compile () {
  71         oe_runmake 'TABLES=-DHOSTS_DENY=\"${sysconfdir}/hosts.deny\" -DHOSTS_ALLOW=\"${sysconfdir}/hosts.allow\"' \
  72                    all
  73 }
  74
  75 BINS = "safe_finger tcpd tcpdchk try-from tcpdmatch"
  76 MANS3 = "hosts_access"
  77 MANS5 = "hosts_options"
  78 MANS8 = "tcpd tcpdchk tcpdmatch"
  79 do_install () {
  80         oe_libinstall -C shared -so libwrap ${D}${libdir}/
  81
  82         install -d ${D}${sbindir}
  83         for b in ${BINS}; do
  84                 install -m 0755 $b ${D}${sbindir}/ || exit 1
  85         done
  86
  87         install -d ${D}${mandir}/man3
  88         for m in ${MANS3}; do
  89                 install -m 0644 $m.3 ${D}${mandir}/man3/ || exit 1
  90         done
  91
  92         install -d ${D}${mandir}/man5
  93         for m in ${MANS5}; do
  94                 install -m 0644 $m.5 ${D}${mandir}/man5/ || exit 1
  95         done
  96
  97         install -d ${D}${mandir}/man8
  98         for m in ${MANS8}; do
  99                 install -m 0644 $m.8 ${D}${mandir}/man8/ || exit 1
 100         done
 101
 102         install -m 0644 ${WORKDIR}/try-from.8 ${D}${mandir}/man8/
 103         install -m 0644 ${WORKDIR}/safe_finger.8 ${D}${mandir}/man8/
 104
 105         install -d ${D}${includedir}
 106         install -m 0644 tcpd.h ${D}${includedir}/
 107 }
 108
 109 do_stage() {
 110         oe_libinstall -C shared -so  libwrap ${STAGING_LIBDIR}
 111                 install -m 0644 tcpd.h ${STAGING_INCDIR}
 112 }
 113