recipes/sablevm/sablevm_1.12.bb

   1 DESCRIPTION = "A highly-portable Java virtual machine implementing the Java virtual machine specification, second edition."
   2 HOMEPAGE = "http://sablevm.org"
   3 LICENSE = "LGPL"
   4 PRIORITY = "optional"
   5 SECTION = "interpreters"
   6
   7 DEPENDS = "libffi libtool popt \
   8            sablevm-classpath"
   9 #          unzip"
  10 RRECOMMENDS = "sablevm-classpath (>= ${PV})"
  11
  12 SRC_URI = "${SOURCEFORGE_MIRROR}/sablevm/${PN}-${PV}.tar.gz \
  13            file://no-internal-libs.patch;patch=1"
  14
  15 inherit autotools update-alternatives
  16
  17 EXTRA_OECONF = "--enable-real-life-brokenness \
  18                 --disable-errors-on-warnings --disable-signals-for-exceptions"
  19
  20 PROVIDES = "virtual/java"
  21 ALTERNATIVE_NAME = "java"
  22 ALTERNATIVE_PATH = "${bindir}/java-sablevm"
  23 ALTERNATIVE_PRIORITY = "350"
  24
  25 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc lib${PN} lib${PN}-dev"
  26
  27 FILES_${PN} = "${bindir} \
  28                ${libdir}/${PN}/bin"
  29
  30 FILES_lib${PN} = "${libdir}/lib${PN}-*.so"
  31
  32 FILES_lib${PN}-dev = "${includedir}/jni* \
  33                       ${libdir}/lib${PN}.so \
  34                       ${libdir}/lib${PN}.la"
  35
  36 do_configure() {
  37         # remove internal copies of libpopt and libffi
  38         rm -rf src/libpopt src/libffi
  39
  40         autotools_do_configure
  41 }
  42
  43 do_install() {
  44         autotools_do_install
  45
  46         install -d ${D}${docdir}
  47         mv ${D}${datadir}/${PN} ${D}${docdir}/
  48
  49         # symlink only present in the deb...
  50         install -d ${D}${libdir}/${PN}/bin
  51         cd ${D}${libdir}/${PN}/bin && ln -sf ../../../bin/java-sablevm java
  52 }