recipes/apr/apr_1.3.3.bb

   1 DESCRIPTION = "Apache Portable Runtime (APR) library"
   2 SECTION = "libs"
   3 LICENSE = "Apache License, Version 2.0"
   4
   5 PR = "r4"
   6
   7 SRC_URI = "${APACHE_MIRROR}/apr/${P}.tar.bz2 \
   8            file://configure_fixes.patch;patch=1 \
   9            file://cleanup.patch;patch=1 \
  10            file://configfix.patch;patch=1"
  11
  12 inherit autotools lib_package binconfig
  13
  14 OE_BINCONFIG_EXTRA_MANGLE = " -e 's:location=source:location=installed:'"
  15
  16 do_configure_prepend() {
  17         cd ${S}
  18         ./buildconf
  19 }
  20
  21 do_stage() {
  22         autotools_stage_all
  23         install -d ${STAGING_DATADIR}/apr
  24         cp ${S}/build/apr_rules.mk ${STAGING_DATADIR}/apr/
  25         sed -i s,apr_builddir=.*,apr_builddir=,g ${STAGING_DATADIR}/apr/apr_rules.mk
  26         sed -i s,apr_builders=.*,apr_builders=,g ${STAGING_DATADIR}/apr/apr_rules.mk
  27         sed -i s,LIBTOOL=.*,LIBTOOL=\$\(SHELL\)\ ${TARGET_PREFIX}libtool,g ${STAGING_DATADIR}/apr/apr_rules.mk
  28         sed -i s,\$\(apr_builders\),${STAGING_DATADIR}/apr/,g ${STAGING_DATADIR}/apr/apr_rules.mk
  29         cp ${S}/build/mkdir.sh ${STAGING_DATADIR}/apr/
  30         cp ${S}/build/make_exports.awk ${STAGING_DATADIR}/apr/
  31         cp ${S}/build/make_var_export.awk ${STAGING_DATADIR}/apr/
  32 }