recipes/gettext/gettext_0.18.bb

   1 DESCRIPTION = "The GNU internationalization library."
   2 HOMEPAGE = "http://www.gnu.org/software/gettext/gettext.html"
   3 SECTION = "libs"
   4 LICENSE = "GPLv3"
   5 PR = "r6"
   6 DEPENDS = "libxml2 gettext-native virtual/libiconv ncurses expat"
   7 DEPENDS_virtclass-native = "libxml2-native"
   8 PROVIDES = "virtual/libintl"
   9 PROVIDES_virtclass-native = "virtual/libintl-native"
  10 RCONFLICTS_gettext-libintl = "proxy-libintl"
  11
  12 BBCLASSEXTEND = "native nativesdk"
  13
  14 SRC_URI = "${GNU_MIRROR}/gettext/gettext-${PV}.tar.gz \
  15            file://autotools.patch \
  16            file://gettext-autoconf-lib-link-no-L.patch \
  17            file://gnulib-uclibc-sched_param-def.patch \
  18           "
  19
  20 SRC_URI_append_libc-uclibc = " file://gettext-error_print_progname.patch"
  21
  22 nolargefile = "${@base_contains('DISTRO_FEATURES', 'largefile', '', '-DNO_LARGEFILE_SOURCE', d)}"
  23 EXTRA_OEMAKE_append_libc-uclibc = "'CFLAGS=${CFLAGS} ${nolargefile}'"
  24
  25 PARALLEL_MAKE = ""
  26
  27 inherit autotools
  28
  29 NATIVECONF = "--disable-rpath"
  30 NATIVECONF_virtclass-native += "--enable-relocatable --disable-curses"
  31
  32 EXTRA_OECONF += "--without-lispdir \
  33                  --disable-csharp \
  34                  --disable-libasprintf \
  35                  --disable-java \
  36                  --disable-native-java \
  37                  --disable-openmp \
  38                  --with-included-glib \
  39                  --without-emacs \
  40                  --with-included-libcroco \
  41                  ${NATIVECONF} \
  42                 "
  43
  44 acpaths = '-I ${S}/gnulib-local/m4/ \
  45            -I ${S}/gettext-runtime/m4 \
  46            -I ${S}/gettext-tools/m4'
  47
  48
  49 # these lack the .x behind the .so, but shouldn't be in the -dev package
  50 # Otherwise you get the following results:
  51 # 7.4M    glibc/images/ep93xx/Angstrom-console-image-glibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
  52 # 25M     uclibc/images/ep93xx/Angstrom-console-image-uclibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
  53 # because gettext depends on gettext-dev, which pulls in more -dev packages:
  54 # 15228   KiB /ep93xx/libstdc++-dev_4.2.2-r2_ep93xx.ipk
  55 # 1300    KiB /ep93xx/uclibc-dev_0.9.29-r8_ep93xx.ipk
  56 # 140     KiB /armv4t/gettext-dev_0.14.1-r6_armv4t.ipk
  57 # 4       KiB /ep93xx/libgcc-s-dev_4.2.2-r2_ep93xx.ipk
  58
  59 PACKAGES =+ "gettext-libintl libgettextlib libgettextsrc"
  60
  61 FILES_gettext-libintl = "${libdir}/libintl*.so.*"
  62 FILES_libgettextlib = "${libdir}/libgettextlib-*.so*"
  63 FILES_libgettextsrc = "${libdir}/libgettextsrc-*.so*"
  64
  65 SRC_URI[md5sum] = "d52a3e061032a1ed13856d42fc86f0fd"
  66 SRC_URI[sha256sum] = "02342c1de18c03c601f8b91cbd896b70486a4b945bd816f34541e0d7b5a96fe5"