recipes/gettext/gettext_0.17.bb

   1 DESCRIPTION = "The GNU internationalization library."
   2 HOMEPAGE = "http://www.gnu.org/software/gettext/gettext.html"
   3 SECTION = "libs"
   4 LICENSE = "GPLv3"
   5 PR = "r9"
   6 DEPENDS = "gettext-native virtual/libiconv ncurses expat"
   7 DEPENDS_virtclass-native = "libxml2-native"
   8 PROVIDES = "virtual/libintl"
   9 PROVIDES_virtclass-native = "virtual/libintl-native"
  10 RCONFLICTS_gettext-libintl = "proxy-libintl"
  11
  12 BBCLASSEXTEND = "native nativesdk"
  13
  14 SRC_URI = "${GNU_MIRROR}/gettext/gettext-${PV}.tar.gz \
  15            file://autotools.patch \
  16            file://wchar-uclibc.patch \
  17            file://use_open_properly.patch \
  18            file://gettext-autoconf-lib-link-no-L.patch \
  19            file://m4_copy.patch \
  20           "
  21
  22 SRC_URI_append_libc-uclibc = " file://gettext-error_print_progname.patch"
  23
  24 PARALLEL_MAKE = ""
  25
  26 inherit autotools
  27
  28 EXTRA_OECONF += "--without-lispdir \
  29                  --disable-csharp \
  30                  --disable-libasprintf \
  31                  --disable-java \
  32                  --disable-native-java \
  33                  --disable-openmp \
  34                  --with-included-glib \
  35                  --without-emacs \
  36                 "
  37
  38 acpaths = '-I ${S}/autoconf-lib-link/m4/ \
  39            -I ${S}/gettext-runtime/m4 \
  40            -I ${S}/gettext-tools/m4'
  41
  42
  43 # these lack the .x behind the .so, but shouldn't be in the -dev package
  44 # Otherwise you get the following results:
  45 # 7.4M    glibc/images/ep93xx/Angstrom-console-image-glibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
  46 # 25M     uclibc/images/ep93xx/Angstrom-console-image-uclibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
  47 # because gettext depends on gettext-dev, which pulls in more -dev packages:
  48 # 15228   KiB /ep93xx/libstdc++-dev_4.2.2-r2_ep93xx.ipk
  49 # 1300    KiB /ep93xx/uclibc-dev_0.9.29-r8_ep93xx.ipk
  50 # 140     KiB /armv4t/gettext-dev_0.14.1-r6_armv4t.ipk
  51 # 4       KiB /ep93xx/libgcc-s-dev_4.2.2-r2_ep93xx.ipk
  52
  53 PACKAGES =+ "gettext-libintl libgettextlib libgettextsrc"
  54
  55 FILES_gettext-libintl = "${libdir}/libintl*.so.*"
  56 FILES_libgettextlib = "${libdir}/libgettextlib-*.so*"
  57 FILES_libgettextsrc = "${libdir}/libgettextsrc-*.so*"
  58
  59
  60 SRC_URI[md5sum] = "58a2bc6d39c0ba57823034d55d65d606"
  61 SRC_URI[sha256sum] = "209638bb8e162f22c281145a34e220c66f1f6e9ff5e4c50c6f2ef2ded59537ba"