recipes/gettext/gettext_0.14.1.bb

   1 DESCRIPTION = "The GNU internationalization library."
   2 HOMEPAGE = "http://www.gnu.org/software/gettext/gettext.html"
   3 SECTION = "libs"
   4 LICENSE = "GPL"
   5 PR = "r12"
   6 DEPENDS = "virtual/libiconv"
   7 DEPENDS_virtclass-native = ""
   8 PROVIDES = "virtual/libintl"
   9 PROVIDES_virtclass-native = ""
  10
  11 SRC_URI = "${GNU_MIRROR}/gettext/gettext-${PV}.tar.gz \
  12            file://gettext-vpath.patch \
  13            file://fixchicken.patch \
  14            file://linklib_from_0.17.patch \
  15            file://gettext-autoconf-lib-link-no-L.patch \
  16            file://getline.m4.patch \
  17            file://disable_java.patch"
  18
  19 SRC_URI_append_libc-uclibc = " file://gettext-error_print_progname.patch"
  20
  21 PARALLEL_MAKE = ""
  22
  23 inherit autotools
  24
  25 EXTRA_OECONF += "--without-lisp --disable-csharp"
  26 acpaths = '-I ${S}/autoconf-lib-link/m4/ \
  27            -I ${S}/gettext-runtime/m4 \
  28            -I ${S}/gettext-tools/m4'
  29
  30 do_configure_prepend() {
  31         rm -f ${S}/config/m4/libtool.m4
  32 }
  33
  34 # these lack the .x behind the .so, but shouldn't be in the -dev package
  35 # Otherwise you get the following results:
  36 # 7.4M    glibc/images/ep93xx/Angstrom-console-image-glibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
  37 # 25M     uclibc/images/ep93xx/Angstrom-console-image-uclibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
  38 # because gettext depends on gettext-dev, which pulls in more -dev packages:
  39 # 15228   KiB /ep93xx/libstdc++-dev_4.2.2-r2_ep93xx.ipk
  40 # 1300    KiB /ep93xx/uclibc-dev_0.9.29-r8_ep93xx.ipk
  41 # 140     KiB /armv4t/gettext-dev_0.14.1-r6_armv4t.ipk
  42 # 4       KiB /ep93xx/libgcc-s-dev_4.2.2-r2_ep93xx.ipk
  43
  44 PACKAGES =+ "libgettextlib libgettextsrc"
  45 FILES_libgettextlib = "${libdir}/libgettextlib-*.so*"
  46 FILES_libgettextsrc = "${libdir}/libgettextsrc-*.so*"
  47
  48
  49 SRC_URI[md5sum] = "78f4b862510beb2e5d43223dd610e77d"
  50 SRC_URI[sha256sum] = "41f20c469c7759acb34cfa7e0b3cac9096d59a58ad800e471f07424a8e7adbb7"