classes/patch.bbclass

   1 # Copyright (C) 2006  OpenedHand LTD
   2
   3 # Point to an empty file so any user's custom settings don't break things
   4 QUILTRCFILE ?= "${STAGING_BINDIR_NATIVE}/quiltrc"
   5
   6 PATCHDEPENDENCY = "${PATCHTOOL}-native:do_populate_sysroot"
   7
   8 PATCHTOOL[type] = "choice"
   9 PATCHTOOL[choices] = "patch quilt git"
  10 PATCHRESOLVE[type] = "choice"
  11 PATCHRESOLVE[choices] = "noop user"
  12
  13 python patch_do_patch() {
  14         import oe.patch
  15         import oe.unpack
  16
  17         src_uri = (bb.data.getVar('SRC_URI', d, 1) or '').split()
  18         if not src_uri:
  19                 return
  20
  21         patchsetmap = {
  22                 "patch": oe.patch.PatchTree,
  23                 "quilt": oe.patch.QuiltTree,
  24                 "git": oe.patch.GitApplyTree,
  25         }
  26
  27         cls = patchsetmap[bb.data.getVar('PATCHTOOL', d, 1) or 'quilt']
  28
  29         resolvermap = {
  30                 "noop": oe.patch.NOOPResolver,
  31                 "user": oe.patch.UserResolver,
  32         }
  33
  34         rcls = resolvermap[bb.data.getVar('PATCHRESOLVE', d, 1) or 'user']
  35
  36         s = bb.data.getVar('S', d, 1)
  37
  38         path = os.getenv('PATH')
  39         os.putenv('PATH', bb.data.getVar('PATH', d, 1))
  40
  41         classes = {}
  42
  43         src_uri = d.getVar("SRC_URI", True).split()
  44         srcurldata = bb.fetch.init(src_uri, d, True)
  45         workdir = bb.data.getVar('WORKDIR', d, 1)
  46         for url in src_uri:
  47                 urldata = srcurldata[url]
  48
  49                 local = urldata.localpath
  50                 if not local:
  51                         raise bb.build.FuncFailed('Unable to locate local file for %s' % url)
  52
  53                 base, ext = os.path.splitext(os.path.basename(local))
  54                 if ext in ('.gz', '.bz2', '.Z'):
  55                         local = oe.path.join(workdir, base)
  56
  57                 if not oe.unpack.is_patch(local, urldata.parm):
  58                         continue
  59
  60                 parm = urldata.parm
  61
  62                 if "striplevel" in parm:
  63                         striplevel = parm["striplevel"]
  64                 elif "pnum" in parm:
  65                         bb.msg.warn(None, "Deprecated usage of 'pnum' url parameter in '%s', please use 'striplevel'" % url)
  66                         striplevel = parm["pnum"]
  67                 else:
  68                         striplevel = '1'
  69
  70                 if "pname" in parm:
  71                         pname = parm["pname"]
  72                 else:
  73                         pname = os.path.basename(local)
  74
  75                 if "mindate" in parm or "maxdate" in parm:
  76                         pn = bb.data.getVar('PN', d, 1)
  77                         srcdate = bb.data.getVar('SRCDATE_%s' % pn, d, 1)
  78                         if not srcdate:
  79                                 srcdate = bb.data.getVar('SRCDATE', d, 1)
  80
  81                         if srcdate == "now":
  82                                 srcdate = bb.data.getVar('DATE', d, 1)
  83
  84                         if "maxdate" in parm and parm["maxdate"] < srcdate:
  85                                 bb.note("Patch '%s' is outdated" % pname)
  86                                 continue
  87
  88                         if "mindate" in parm and parm["mindate"] > srcdate:
  89                                 bb.note("Patch '%s' is predated" % pname)
  90                                 continue
  91
  92
  93                 if "minrev" in parm:
  94                         srcrev = bb.data.getVar('SRCREV', d, 1)
  95                         if srcrev and srcrev < parm["minrev"]:
  96                                 bb.note("Patch '%s' applies to later revisions" % pname)
  97                                 continue
  98
  99                 if "maxrev" in parm:
 100                         srcrev = bb.data.getVar('SRCREV', d, 1)
 101                         if srcrev and srcrev > parm["maxrev"]:
 102                                 bb.note("Patch '%s' applies to earlier revisions" % pname)
 103                                 continue
 104
 105                 if "patchdir" in parm:
 106                         patchdir = parm["patchdir"]
 107                         if not os.path.isabs(patchdir):
 108                                 patchdir = os.path.join(s, patchdir)
 109                 else:
 110                         patchdir = s
 111
 112                 if not patchdir in classes:
 113                         patchset = cls(patchdir, d)
 114                         resolver = rcls(patchset)
 115                         classes[patchdir] = (patchset, resolver)
 116                         patchset.Clean()
 117                 else:
 118                         patchset, resolver = classes[patchdir]
 119
 120                 bb.note("Applying patch '%s' (%s)" % (pname, oe.path.format_display(local, d)))
 121                 try:
 122                         patchset.Import({"file":local, "remote":url, "strippath": striplevel}, True)
 123                         resolver.Resolve()
 124                 except Exception, exc:
 125                         bb.fatal(str(exc))
 126 }
 127
 128 def patch_deps(d):
 129     import oe.unpack
 130
 131     src_uri = d.getVar("SRC_URI", True).split()
 132     srcurldata = bb.fetch.init(src_uri, d, True)
 133     for url in src_uri:
 134         urldata = srcurldata[url]
 135         local = urldata.localpath
 136         if local:
 137             base, ext = os.path.splitext(os.path.basename(local))
 138             if ext in ('.gz', '.bz2', '.Z', '.xz'):
 139                 local = base
 140             if oe.unpack.is_patch(local, urldata.parm):
 141                 return "${PATCHDEPENDENCY}"
 142     return ""
 143
 144 addtask patch after do_unpack
 145 do_patch[dirs] = "${WORKDIR}"
 146 do_patch[depends] = "${@patch_deps(d)}"
 147
 148 EXPORT_FUNCTIONS do_patch