classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel virtual/kernel-${PV}"
   4 DEPENDS += "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules bluez-dtl1-workaround"
   5
   6 # we include gcc above, we dont need virtual/libc
   7 INHIBIT_DEFAULT_DEPS = "1"
   8
   9 KERNEL_IMAGETYPE ?= "zImage"
  10
  11 # Add dependency on mkimage for kernels that build a uImage
  12
  13 python __anonymous () {
  14     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  15     if kerneltype == 'uImage':
  16         depends = bb.data.getVar("DEPENDS", d, 1)
  17         depends = "%s u-boot-mkimage-native" % depends
  18         bb.data.setVar("DEPENDS", depends, d)
  19
  20     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  21     if image:
  22         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  23
  24     machine_kernel_pr = bb.data.getVar('MACHINE_KERNEL_PR', d, True)
  25
  26     if machine_kernel_pr:
  27        bb.data.setVar('PR', machine_kernel_pr, d)
  28 }
  29
  30 INITRAMFS_IMAGE ?= ""
  31 INITRAMFS_TASK ?= ""
  32
  33 inherit kernel-arch
  34
  35 PACKAGES_DYNAMIC += "kernel-*"
  36 PACKAGES_DYNAMIC += "kernel-module-*"
  37 PACKAGES_DYNAMIC += "kernel-image-*"
  38 PACKAGES_DYNAMIC += "kernel-firmware-*"
  39
  40 export OS = "${TARGET_OS}"
  41 export CROSS_COMPILE = "${TARGET_PREFIX}"
  42
  43 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  44
  45 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  46
  47 KERNEL_ARSUFFIX ?= ""
  48 KERNEL_CCSUFFIX ?= ""
  49 KERNEL_LDSUFFIX ?= ""
  50 KERNEL_NMSUFFIX ?= ""
  51 KERNEL_OBJCOPYSUFFIX ?= ""
  52
  53 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  54 # specific options necessary for building the kernel and modules.
  55 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  56 TARGET_AR_KERNEL_ARCH ?= ""
  57 HOST_AR_KERNEL_ARCH ?= "${TARGET_AR_KERNEL_ARCH}"
  58 TARGET_CC_KERNEL_ARCH ?= ""
  59 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  60 TARGET_LD_KERNEL_ARCH ?= ""
  61 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  62 TARGET_NM_KERNEL_ARCH ?= ""
  63 HOST_NM_KERNEL_ARCH ?= "${TARGET_NM_KERNEL_ARCH}"
  64 TARGET_OBJCOPY_KERNEL_ARCH ?= ""
  65 HOST_OBJCOPY_KERNEL_ARCH ?= "${TARGET_OBJCOPY_KERNEL_ARCH}"
  66
  67 KERNEL_AR = "${AR}${KERNEL_ARSUFFIX} ${HOST_AR_KERNEL_ARCH}"
  68 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  69 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  70 KERNEL_NM = "${NM}${KERNEL_NMSUFFIX} ${HOST_NM_KERNEL_ARCH}"
  71 KERNEL_OBJCOPY = "${OBJCOPY}${KERNEL_OBJCOPYSUFFIX} ${HOST_OBJCOPY_KERNEL_ARCH}"
  72
  73 KERNEL_EXTRA_OEMAKE = " \
  74         AR='${KERNEL_AR}' \
  75         CC='${KERNEL_CC}' \
  76         LD='${KERNEL_LD}' \
  77         NM='${KERNEL_NM}' \
  78         OBJCOPY='${KERNEL_OBJCOPY}' \
  79 "
  80
  81 # Where built kernel lies in the kernel tree
  82 KERNEL_OUTPUT ?= "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  83 KERNEL_IMAGEDEST = "boot"
  84
  85 #
  86 # configuration
  87 #
  88 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  89
  90 KERNEL_VERSION = "${@get_kernelversion('${B}')}"
  91 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  92
  93 KERNEL_LOCALVERSION ?= ""
  94
  95 # kernels are generally machine specific
  96 PACKAGE_ARCH = "${MACHINE_ARCH}"
  97
  98 # U-Boot support
  99 UBOOT_ENTRYPOINT ?= "20008000"
 100 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
 101
 102 # For the kernel, we don't want the '-e MAKEFLAGS=' in EXTRA_OEMAKE.
 103 # We don't want to override kernel Makefile variables from the environment
 104 EXTRA_OEMAKE = ""
 105
 106 kernel_do_compile() {
 107         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 108         oe_runmake include/linux/version.h ${KERNEL_EXTRA_OEMAKE}
 109         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
 110                 oe_runmake dep ${KERNEL_EXTRA_OEMAKE}
 111         fi
 112         oe_runmake ${KERNEL_IMAGETYPE} ${KERNEL_EXTRA_OEMAKE}
 113 }
 114
 115 do_compile_kernelmodules() {
 116         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 117         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 118                 oe_runmake modules ${KERNEL_EXTRA_OEMAKE}
 119         else
 120                 oenote "no modules to compile"
 121         fi
 122 }
 123 addtask compile_kernelmodules after do_compile before do_install
 124
 125 kernel_do_install() {
 126         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 127         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 128                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 129         else
 130                 oenote "no modules to install"
 131         fi
 132
 133         install -d ${D}/${KERNEL_IMAGEDEST}
 134         install -d ${D}/boot
 135         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 136         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 137         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 138         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 139         [ -e Module.symvers ] && install -m 0644 Module.symvers ${D}/boot/Module.symvers-${KERNEL_VERSION}
 140         install -d ${D}/etc/modutils
 141         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 142                 install -d ${D}/etc/modprobe.d
 143         fi
 144
 145         # Check if scripts/genksyms exists and if so, build it
 146         if [ -e scripts/genksyms/ ]; then
 147                 oe_runmake SUBDIRS="scripts/genksyms"
 148         fi
 149
 150         # we need to set kerneldir here as some kernels have a do_install_append
 151         # which assumes kerneldir is set
 152         kerneldir=${D}/kernel/
 153 }
 154
 155 sysroot_stage_all_append() {
 156
 157         kerneldir=${SYSROOT_DESTDIR}${STAGING_KERNEL_DIR}
 158
 159         if [ -e include/asm ] ; then
 160                 # This link is generated only in kernel before 2.6.33-rc1, don't stage it for newer kernels
 161                 ASMDIR=`readlink include/asm`
 162
 163                 mkdir -p $kerneldir/include/$ASMDIR
 164                 cp -fR include/$ASMDIR/* $kerneldir/include/$ASMDIR/
 165         fi
 166
 167         # Kernel 2.6.27 moved headers from includes/asm-${ARCH} to arch/${ARCH}/include/asm
 168         if [ -e arch/${ARCH}/include/asm/ ] ; then
 169                 if [ -e include/asm ] ; then
 170                         cp -fR arch/${ARCH}/include/asm/* $kerneldir/include/$ASMDIR/
 171                 fi
 172                 install -d $kerneldir/arch/${ARCH}/include
 173                 cp -fR arch/${ARCH}/* $kerneldir/arch/${ARCH}/
 174
 175         # Check for arch/x86 on i386
 176         elif [ -d arch/x86/include/asm/ ]; then
 177                 mkdir -p $kerneldir/include/asm-x86/
 178                 cp -fR arch/x86/include/asm/* $kerneldir/include/asm-x86/
 179                 install -d $kerneldir/arch/x86/include
 180                 cp -fR arch/x86/* $kerneldir/arch/x86/
 181         fi
 182
 183         if [ -e include/asm ] ; then
 184                 rm -f $kerneldir/include/asm
 185                 ln -sf $ASMDIR $kerneldir/include/asm
 186         fi
 187
 188         mkdir -p $kerneldir/include/asm-generic
 189         cp -fR include/asm-generic/* $kerneldir/include/asm-generic/
 190
 191         for entry in drivers/crypto drivers/media include/generated include/linux include/net include/pcmcia include/media include/acpi include/sound include/video include/scsi include/trace include/mtd include/rdma include/drm include/xen crypto/ocf; do
 192                 if [ -d $entry ]; then
 193                         mkdir -p $kerneldir/$entry
 194                         cp -fR $entry/* $kerneldir/$entry/
 195                 fi
 196         done
 197         if [ -f include/Kbuild ]; then
 198                 cp -fR include/Kbuild $kerneldir/include
 199         fi
 200
 201         if [ -d drivers/sound ]; then
 202                 # 2.4 alsa needs some headers from this directory
 203                 mkdir -p $kerneldir/include/drivers/sound
 204                 cp -fR drivers/sound/*.h $kerneldir/include/drivers/sound/
 205         fi
 206
 207         install -m 0644 .config $kerneldir/config-${KERNEL_VERSION}
 208         ln -sf config-${KERNEL_VERSION} $kerneldir/.config
 209         ln -sf config-${KERNEL_VERSION} $kerneldir/kernel-config
 210         echo "${KERNEL_VERSION}" >$kerneldir/kernel-abiversion
 211         echo "${S}" >$kerneldir/kernel-source
 212         echo "${KERNEL_CCSUFFIX}" >$kerneldir/kernel-ccsuffix
 213         echo "${KERNEL_LDSUFFIX}" >$kerneldir/kernel-ldsuffix
 214         [ -e Rules.make ] && install -m 0644 Rules.make $kerneldir/
 215         [ -e Makefile ] && install -m 0644 Makefile $kerneldir/
 216
 217         # Check if arch/${ARCH}/Makefile exists and install it
 218         if [ -e arch/${ARCH}/Makefile ]; then
 219                 install -d $kerneldir/arch/${ARCH}
 220                 install -m 0644 arch/${ARCH}/Makefile* $kerneldir/arch/${ARCH}
 221         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 222         elif [ -e arch/x86/Makefile ]; then
 223                 install -d $kerneldir/arch/x86
 224                 install -m 0644 arch/x86/Makefile* $kerneldir/arch/x86
 225         fi
 226         cp -fR include/config* $kerneldir/include/
 227         # Install kernel images and system.map to staging
 228         [ -e vmlinux ] && install -m 0644 vmlinux $kerneldir/
 229         install -m 0644 ${KERNEL_OUTPUT} $kerneldir/${KERNEL_IMAGETYPE}
 230         install -m 0644 System.map $kerneldir/System.map-${KERNEL_VERSION}
 231         [ -e Module.symvers ] && install -m 0644 Module.symvers $kerneldir/
 232
 233         cp -fR scripts $kerneldir/
 234 }
 235
 236 kernel_do_configure() {
 237         yes '' | oe_runmake oldconfig
 238         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
 239                 for img in cpio.gz cpio.lzo cpio.lzma; do
 240                 if [ -e "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.$img" ]; then
 241                         cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.$img" initramfs.$img
 242                 fi
 243                 done
 244         fi
 245 }
 246 do_configure[depends] += "${INITRAMFS_TASK}"
 247
 248 pkg_postinst_kernel () {
 249         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 250 }
 251
 252 pkg_postrm_kernel () {
 253         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 254 }
 255
 256 inherit cml1
 257
 258 EXPORT_FUNCTIONS do_compile do_install do_configure
 259
 260 # kernel-base becomes kernel-${KERNEL_VERSION}
 261 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 262 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 263 FILES = ""
 264 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 265 FILES_kernel-dev = "/boot/System.map* /boot/Module.symvers* /boot/config*"
 266 FILES_kernel-vmlinux = "/boot/vmlinux*"
 267 RDEPENDS_kernel = "kernel-base"
 268 # Allow machines to override this dependency if kernel image files are
 269 # not wanted in images as standard
 270 RDEPENDS_kernel-base ?= "kernel-image"
 271 PKG_kernel-image = "kernel-image-${@legitimize_package_name('${KERNEL_VERSION}')}"
 272 PKG_kernel-base = "kernel-${@legitimize_package_name('${KERNEL_VERSION}')}"
 273 ALLOW_EMPTY_kernel = "1"
 274 ALLOW_EMPTY_kernel-base = "1"
 275 ALLOW_EMPTY_kernel-image = "1"
 276
 277 # Userspace workarounds for kernel modules issues
 278 # This is shame, fix the kernel instead!
 279 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 280
 281 # renamed modules
 282 RPROVIDES_kernel-module-aes-generic = "kernel-module-aes"
 283
 284 pkg_postinst_kernel-image () {
 285 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 286         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 287 fi
 288 if [ -n "$D" ]; then
 289         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 290 else
 291         depmod -a ${KERNEL_VERSION}
 292 fi
 293 }
 294
 295 pkg_postinst_modules () {
 296 if [ -n "$D" ]; then
 297         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 298 else
 299         depmod -a ${KERNEL_VERSION}
 300         update-modules || true
 301 fi
 302 }
 303
 304 pkg_postrm_modules () {
 305 update-modules || true
 306 }
 307
 308 autoload_postinst_fragment() {
 309 if [ x"$D" = "x" ]; then
 310         modprobe %s || true
 311 fi
 312 }
 313
 314 # autoload defaults (alphabetically sorted)
 315 module_autoload_hidp = "hidp"
 316 module_autoload_ipv6 = "ipv6"
 317 module_autoload_ipsec = "ipsec"
 318 module_autoload_ircomm-tty = "ircomm-tty"
 319 module_autoload_rfcomm = "rfcomm"
 320 module_autoload_sa1100-rtc = "sa1100-rtc"
 321 # sa1100-rtc was renamed in 2.6.23 onwards
 322 module_autoload_rtc-sa1100 = "rtc-sa1100"
 323
 324 # alias defaults (alphabetically sorted)
 325 module_conf_af_packet = "alias net-pf-17 af_packet"
 326 module_conf_bluez = "alias net-pf-31 bluez"
 327 module_conf_bnep = "alias bt-proto-4 bnep"
 328 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 329 module_conf_l2cap = "alias bt-proto-0 l2cap"
 330 module_conf_sco = "alias bt-proto-2 sco"
 331 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 332
 333 python populate_packages_prepend () {
 334         import os
 335         def extract_modinfo(file):
 336                 import tempfile, re
 337                 tempfile.tempdir = bb.data.getVar("WORKDIR", d, 1)
 338                 tf = tempfile.mkstemp()
 339                 tmpfile = tf[1]
 340                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 341                 os.system(cmd)
 342                 f = open(tmpfile)
 343                 l = f.read().split("\000")
 344                 f.close()
 345                 os.close(tf[0])
 346                 os.unlink(tmpfile)
 347                 exp = re.compile("([^=]+)=(.*)")
 348                 vals = {}
 349                 for i in l:
 350                         m = exp.match(i)
 351                         if not m:
 352                                 continue
 353                         vals[m.group(1)] = m.group(2)
 354                 return vals
 355
 356         def parse_depmod():
 357                 import re
 358
 359                 dvar = bb.data.getVar('PKGD', d, 1)
 360                 if not dvar:
 361                         bb.error("PKGD not defined")
 362                         return
 363
 364                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 365                 kernelver_stripped = kernelver
 366                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 367                 if m:
 368                         kernelver_stripped = m.group(1)
 369                 path = bb.data.getVar("PATH", d, 1)
 370                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 371                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 372
 373                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 374                 f = os.popen(cmd, 'r')
 375
 376                 deps = {}
 377                 pattern0 = "^(.*\.k?o):..*$"
 378                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 379                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 380                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 381                 pattern4 = "^\t(.*\.k?o)\s*$"
 382
 383                 line = f.readline()
 384                 while line:
 385                         if not re.match(pattern0, line):
 386                                 line = f.readline()
 387                                 continue
 388                         m1 = re.match(pattern1, line)
 389                         if m1:
 390                                 deps[m1.group(1)] = m1.group(2).split()
 391                         else:
 392                                 m2 = re.match(pattern2, line)
 393                                 if m2:
 394                                         deps[m2.group(1)] = m2.group(2).split()
 395                                         line = f.readline()
 396                                         m3 = re.match(pattern3, line)
 397                                         while m3:
 398                                                 deps[m2.group(1)].extend(m3.group(1).split())
 399                                                 line = f.readline()
 400                                                 m3 = re.match(pattern3, line)
 401                                         m4 = re.match(pattern4, line)
 402                                         deps[m2.group(1)].extend(m4.group(1).split())
 403                         line = f.readline()
 404                 f.close()
 405                 return deps
 406
 407         def get_dependencies(file, pattern, format):
 408                 prefix = os.path.normpath(os.path.join(
 409                         os.path.join(bb.data.getVar('PKGD', d, 1) or ''),
 410                         'lib/modules',
 411                         bb.data.getVar('KERNEL_VERSION', d, 1)
 412                 )) + '/'
 413                 file = file.replace(prefix, '', 1)
 414
 415                 if module_deps.has_key(file):
 416                         import re
 417                         dependencies = []
 418                         for i in module_deps[file]:
 419                                 m = re.match(pattern, os.path.basename(i))
 420                                 if not m:
 421                                         continue
 422                                 on = legitimize_package_name(m.group(1))
 423                                 dependency_pkg = format % on
 424                                 dependencies.append(dependency_pkg)
 425                         return dependencies
 426                 return []
 427
 428         def frob_metadata(file, pkg, pattern, format, basename):
 429                 import re
 430                 vals = extract_modinfo(file)
 431
 432                 dvar = bb.data.getVar('PKGD', d, 1)
 433
 434                 # If autoloading is requested, output /etc/modutils/<name> and append
 435                 # appropriate modprobe commands to the postinst
 436                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 437                 if not autoload:
 438                     # Also, try canonical name with dashes
 439                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 440                 if autoload:
 441                         name = '%s/etc/modutils/%s' % (dvar, basename)
 442                         f = open(name, 'w')
 443                         for m in autoload.split():
 444                                 f.write('%s\n' % m)
 445                         f.close()
 446                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 447                         if not postinst:
 448                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 449                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 450                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 451
 452                 # Write out any modconf fragment
 453                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 454                 if modconf:
 455                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 456                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 457                         else:
 458                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 459                         f = open(name, 'w')
 460                         f.write("%s\n" % modconf)
 461                         f.close()
 462
 463                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 464                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 465                 bb.data.setVar('FILES_%s' % pkg, files, d)
 466
 467                 if vals.has_key("description"):
 468                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 469                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 470
 471                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 472                 if rdepends_str:
 473                         rdepends = rdepends_str.split()
 474                 else:
 475                         rdepends = []
 476                 rdepends.extend(get_dependencies(file, pattern, format))
 477                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 478
 479         module_deps = parse_depmod()
 480         module_regex = '^(.*)\.k?o$'
 481         module_pattern = 'kernel-module-%s'
 482
 483         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 484         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 485
 486         maybe_update_modules = "update-modules "
 487         if bb.data.getVar("ONLINE_PACKAGE_MANAGEMENT", d) == "none":
 488                 maybe_update_modules = ""
 489
 490         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.bin$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 491         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.fw$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 492         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='%skernel-%s' % (maybe_update_modules, bb.data.getVar("KERNEL_VERSION", d, 1)))
 493
 494         import re
 495         metapkg = "kernel-modules"
 496         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 497         bb.data.setVar('FILES_' + metapkg, "", d)
 498         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 499         depchains = (d.getVar("DEPCHAIN_POST", True) or "").split()
 500         for l in module_deps.values():
 501                 for i in l:
 502                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 503                         blacklist.append(pkg)
 504         metapkg_rrecommends = []
 505         packages = bb.data.getVar('PACKAGES', d, 1).split()
 506         for pkg in packages[1:]:
 507                 if not pkg in blacklist and not pkg in metapkg_rrecommends and not any(pkg.endswith(post) for post in depchains):
 508                         metapkg_rrecommends.append(pkg)
 509         bb.data.setVar('RRECOMMENDS_' + metapkg, ' '.join(metapkg_rrecommends), d)
 510         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 511         packages.append(metapkg)
 512         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 513 }
 514
 515 # Support checking the kernel size since some kernels need to reside in partitions
 516 # with a fixed length or there is a limit in transferring the kernel to memory
 517 do_sizecheck() {
 518         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" ]; then
 519                 size=`ls -l ${KERNEL_OUTPUT} | awk '{ print $5}'`
 520                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 521                         rm ${KERNEL_OUTPUT}
 522                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 523                 fi
 524         fi
 525 }
 526
 527 addtask sizecheck before do_install after do_compile
 528
 529 do_uboot_mkimage() {
 530     if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 531         ENTRYPOINT=${UBOOT_ENTRYPOINT}
 532         if test -n "${UBOOT_ENTRYSYMBOL}"; then
 533             ENTRYPOINT=`${HOST_PREFIX}nm ${S}/vmlinux | \
 534                    awk '$3=="${UBOOT_ENTRYSYMBOL}" {print $1}'`
 535         fi
 536         if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 537             ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 538             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin arch/${ARCH}/boot/uImage
 539             rm -f linux.bin
 540         else
 541             ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 542             rm -f linux.bin.gz
 543             gzip -9 linux.bin
 544             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz arch/${ARCH}/boot/uImage
 545             rm -f linux.bin.gz
 546         fi
 547     fi
 548 }
 549
 550 addtask uboot_mkimage before do_install after do_compile
 551
 552 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 553 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 554 MODULES_IMAGE_BASE_NAME ?= modules-${PV}-${PR}-${MACHINE}
 555
 556 do_deploy() {
 557         install -d ${DEPLOY_DIR_IMAGE}
 558         install -m 0644 ${KERNEL_OUTPUT} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 559         package_stagefile_shell ${S}/${KERNEL_OUTPUT}
 560         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 561
 562         if [ -d "${PKGD}/lib" ]; then
 563                 fakeroot tar -cvzf ${DEPLOY_DIR_IMAGE}/${MODULES_IMAGE_BASE_NAME}.tgz -C ${PKGD} lib
 564                 package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${MODULES_IMAGE_BASE_NAME}.tgz
 565         fi
 566
 567         cd ${DEPLOY_DIR_IMAGE}
 568         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 569         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 570         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 571 }
 572
 573 do_deploy[dirs] = "${S}"
 574 do_deploy[depends] += "fakeroot-native:do_populate_sysroot"
 575
 576 addtask deploy before do_build after do_package